configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78
  79
  80 ## Checks for programs.
  81 AC_MSG_NOTICE([CHECKS for programs])
  82 #
  83 AC_PROG_CC([cc gcc])
  84 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  85 AC_CHECK_TOOL(AR, ar, :)
  86 AC_CHECK_PROGS(TAR, [gtar tar])
  87
  88 ## Checks for libraries.
  89 AC_MSG_NOTICE([CHECKS for libraries])
  90 #
  91 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  92 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
  93 AC_CHECK_LIB([crypto], [SHA1_Init],
  94 [NEEDS_SSL_WITH_CRYPTO=],
  95 [AC_CHECK_LIB([ssl], [SHA1_Init],
  96  [NEEDS_SSL_WITH_CRYPTO=YesPlease
  97   NEEDS_SSL_WITH_CRYPTO=],
  98  [NO_OPENSSL=YesPlease])])
  99 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 100 AC_SUBST(NO_OPENSSL)
 101 #
 102 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 103 # git-http-push are not built, and you cannot use http:// and https://
 104 # transports.
 105 AC_CHECK_LIB([curl], [curl_global_init],
 106 [NO_CURL=],
 107 [NO_CURL=YesPlease])
 108 AC_SUBST(NO_CURL)
 109 #
 110 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 111 # not built, and you cannot push using http:// and https:// transports.
 112 AC_CHECK_LIB([expat], [XML_ParserCreate],
 113 [NO_EXPAT=],
 114 [NO_EXPAT=YesPlease])
 115 AC_SUBST(NO_EXPAT)
 116 #
 117 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 118 # Define NO_ICONV if neither libc nor libiconv support iconv.
 119 AC_CHECK_LIB([c], [iconv],
 120         [NEEDS_LIBICONV=],
 121         AC_CHECK_LIB([iconv], [iconv],
 122                 [NEEDS_LIBICONV=YesPlease],
 123                 [NO_ICONV=YesPlease]))
 124 AC_SUBST(NEEDS_LIBICONV)
 125 AC_SUBST(NO_ICONV)
 126 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 127 #
 128 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 129 # Patrick Mauritz).
 130 AC_CHECK_LIB([c], [socket],
 131 [NEEDS_SOCKET=],
 132 [NEEDS_SOCKET=YesPlease])
 133 AC_SUBST(NEEDS_SOCKET)
 134 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 135
 136
 137 ## Checks for header files.
 138
 139
 140 ## Checks for typedefs, structures, and compiler characteristics.
 141 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 142 #
 143 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 144 AC_CHECK_MEMBER(struct dirent.d_ino,
 145 [NO_D_INO_IN_DIRENT=],
 146 [NO_D_INO_IN_DIRENT=YesPlease],
 147 [#include <dirent.h>])
 148 AC_SUBST(NO_D_INO_IN_DIRENT)
 149 #
 150 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 151 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 152 AC_CHECK_MEMBER(struct dirent.d_type,
 153 [NO_D_TYPE_IN_DIRENT=],
 154 [NO_D_TYPE_IN_DIRENT=YesPlease],
 155 [#include <dirent.h>])
 156 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 157 #
 158 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 159 # sockaddr_storage.
 160 AC_CHECK_TYPE(struct sockaddr_storage,
 161 [NO_SOCKADDR_STORAGE=],
 162 [NO_SOCKADDR_STORAGE=YesPlease],[
 163 #include <sys/types.h>
 164 #include <sys/socket.h>
 165 ])
 166 AC_SUBST(NO_SOCKADDR_STORAGE)
 167 #
 168 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 169 AC_CHECK_TYPE([struct addrinfo],[
 170  AC_CHECK_FUNC([getaddrinfo],
 171   [NO_IPV6=],
 172   [NO_IPV6=YesPlease])
 173 ],[NO_IPV6=YesPlease],[
 174 #include <sys/types.h>
 175 #include <sys/socket.h>
 176 #include <netdb.h>
 177 ])
 178 AC_SUBST(NO_IPV6)
 179 #
 180 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 181 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 182 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 183 # some C compilers supported these specifiers prior to C99 as an extension.
 184 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 185  [ac_cv_c_c99_format],
 186 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 187 AC_RUN_IFELSE(
 188         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 189                 [[char buf[64];
 190                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 191                   exit(1);
 192                 else if (strcmp(buf, "12345"))
 193                   exit(2);]])],
 194         [ac_cv_c_c99_format=yes],
 195         [ac_cv_c_c99_format=no])
 196 ])
 197 if test $ac_cv_c_c99_format = no; then
 198         NO_C99_FORMAT=YesPlease
 199 else
 200         NO_C99_FORMAT=
 201 fi
 202 AC_SUBST(NO_C99_FORMAT)
 203
 204
 205 ## Checks for library functions.
 206 ## (in default C library and libraries checked by AC_CHECK_LIB)
 207 AC_MSG_NOTICE([CHECKS for library functions])
 208 #
 209 # Define NO_STRCASESTR if you don't have strcasestr.
 210 AC_CHECK_FUNC(strcasestr,
 211 [NO_STRCASESTR=],
 212 [NO_STRCASESTR=YesPlease])
 213 AC_SUBST(NO_STRCASESTR)
 214 #
 215 # Define NO_STRLCPY if you don't have strlcpy.
 216 AC_CHECK_FUNC(strlcpy,
 217 [NO_STRLCPY=],
 218 [NO_STRLCPY=YesPlease])
 219 AC_SUBST(NO_STRLCPY)
 220 #
 221 # Define NO_SETENV if you don't have setenv in the C library.
 222 AC_CHECK_FUNC(setenv,
 223 [NO_SETENV=],
 224 [NO_SETENV=YesPlease])
 225 AC_SUBST(NO_SETENV)
 226 #
 227 # Define NO_MMAP if you want to avoid mmap.
 228 #
 229 # Define NO_ICONV if your libc does not properly support iconv.
 230
 231
 232 ## Other checks.
 233 # Define USE_PIC if you need the main git objects to be built with -fPIC
 234 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 235 #
 236 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 237 # Enable it on Windows.  By default, symrefs are still used.
 238
 239 ## Site configuration (override autodetection)
 240 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 241 AC_MSG_NOTICE([CHECKS for site configuration])
 242 #
 243 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 244 # tests.  These tests take up a significant amount of the total test time
 245 # but are not needed unless you plan to talk to SVN repos.
 246 #
 247 # Define MOZILLA_SHA1 environment variable when running make to make use of
 248 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 249 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 250 # choice) has very fast version optimized for i586.
 251 #
 252 # Define PPC_SHA1 environment variable when running make to make use of
 253 # a bundled SHA1 routine optimized for PowerPC.
 254 #
 255 # Define ARM_SHA1 environment variable when running make to make use of
 256 # a bundled SHA1 routine optimized for ARM.
 257 #
 258 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 259 # This also implies MOZILLA_SHA1.
 260 #
 261 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 262 # /foo/bar/include and /foo/bar/lib directories.
 263 AC_ARG_WITH(openssl,
 264 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 265 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 266 GIT_PARSE_WITH(openssl))
 267 #
 268 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 269 # git-http-push are not built, and you cannot use http:// and https://
 270 # transports.
 271 #
 272 # Define CURLDIR=/foo/bar if your curl header and library files are in
 273 # /foo/bar/include and /foo/bar/lib directories.
 274 AC_ARG_WITH(curl,
 275 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 276 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 277 GIT_PARSE_WITH(curl))
 278 #
 279 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 280 # not built, and you cannot push using http:// and https:// transports.
 281 #
 282 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 283 # /foo/bar/include and /foo/bar/lib directories.
 284 AC_ARG_WITH(expat,
 285 AS_HELP_STRING([--with-expat],
 286 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 287 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 288 GIT_PARSE_WITH(expat))
 289 #
 290 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 291 # installed in /sw, but don't want GIT to link against any libraries
 292 # installed there.  If defined you may specify your own (or Fink's)
 293 # include directories and library directories by defining CFLAGS
 294 # and LDFLAGS appropriately.
 295 #
 296 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 297 # have DarwinPorts installed in /opt/local, but don't want GIT to
 298 # link against any libraries installed there.  If defined you may
 299 # specify your own (or DarwinPort's) include directories and
 300 # library directories by defining CFLAGS and LDFLAGS appropriately.
 301 #
 302 # Define NO_MMAP if you want to avoid mmap.
 303 #
 304 # Define NO_ICONV if your libc does not properly support iconv.
 305 AC_ARG_WITH(iconv,
 306 AS_HELP_STRING([--without-iconv],
 307 [if your architecture doesn't properly support iconv])
 308 AS_HELP_STRING([--with-iconv=PATH],
 309 [PATH is prefix for libiconv library and headers])
 310 AS_HELP_STRING([],
 311 [used only if you need linking with libiconv]),
 312 GIT_PARSE_WITH(iconv))
 313
 314 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 315 #
 316 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 317 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 318 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 319 # randomly break unless your underlying filesystem supports those sub-second
 320 # times (my ext3 doesn't).
 321 #
 322 # Define USE_STDEV below if you want git to care about the underlying device
 323 # change being considered an inode change from the update-cache perspective.
 324
 325
 326 ## Output files
 327 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 328 AC_OUTPUT
 329
 330
 331 ## Cleanup
 332 rm -f "${config_append}"