configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CANONICAL_BUILD
   8 AC_CANONICAL_HOST
   9 AC_CONFIG_SRCDIR([git.c])
  10
  11 config_file=config.mak.autogen
  12 config_append=config.mak.append
  13 config_in=config.mak.in
  14
  15 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  16
  17
  18 ## Definitions of macros
  19 # GIT_CONF_APPEND_LINE(LINE)
  20 # --------------------------
  21 # Append LINE to file ${config_append}
  22 AC_DEFUN([GIT_CONF_APPEND_LINE],
  23 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  24 #
  25 # GIT_ARG_SET_PATH(PROGRAM)
  26 # -------------------------
  27 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  28 AC_DEFUN([GIT_ARG_SET_PATH],
  29 [AC_ARG_WITH([$1],
  30  [AS_HELP_STRING([--with-$1=PATH],
  31                  [provide PATH to $1])],
  32  [GIT_CONF_APPEND_PATH($1)],[])
  33 ])# GIT_ARG_SET_PATH
  34 #
  35 # GIT_CONF_APPEND_PATH(PROGRAM)
  36 # ------------------------------
  37 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38 # Used by GIT_ARG_SET_PATH(PROGRAM)
  39 AC_DEFUN([GIT_CONF_APPEND_PATH],
  40 [PROGRAM=m4_toupper($1); \
  41 if test "$withval" = "no"; then \
  42         AC_MSG_ERROR([You cannot use git without $1]); \
  43 else \
  44         if test "$withval" = "yes"; then \
  45                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  46         else \
  47                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48         fi; \
  49 fi; \
  50 ]) # GIT_CONF_APPEND_PATH
  51 #
  52 # GIT_PARSE_WITH(PACKAGE)
  53 # -----------------------
  54 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  55 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58 AC_DEFUN([GIT_PARSE_WITH],
  59 [PACKAGE=m4_toupper($1); \
  60 if test "$withval" = "no"; then \
  61         m4_toupper(NO_$1)=YesPlease; \
  62 elif test "$withval" = "yes"; then \
  63         m4_toupper(NO_$1)=; \
  64 else \
  65         m4_toupper(NO_$1)=; \
  66         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  67 fi \
  68 ])# GIT_PARSE_WITH
  69
  70
  71 ## Site configuration related to programs (before tests)
  72 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  73 #
  74 # Define SHELL_PATH to provide path to shell.
  75 GIT_ARG_SET_PATH(shell)
  76 #
  77 # Define PERL_PATH to provide path to Perl.
  78 GIT_ARG_SET_PATH(perl)
  79 #
  80 # Declare the with-tcltk/without-tcltk options.
  81 AC_ARG_WITH(tcltk,
  82 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
  83 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
  84 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
  85 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
  86 GIT_PARSE_WITH(tcltk))
  87 #
  88
  89
  90 ## Checks for programs.
  91 AC_MSG_NOTICE([CHECKS for programs])
  92 #
  93 AC_PROG_CC([cc gcc])
  94 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  95 AC_CHECK_TOOL(AR, ar, :)
  96 AC_CHECK_PROGS(TAR, [gtar tar])
  97 # TCLTK_PATH will be set to some value if we want Tcl/Tk
  98 # or will be empty otherwise.
  99 if test -z "$NO_TCLTK"; then
 100   if test "$with_tcltk" = ""; then
 101   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 102     TCLTK_PATH=wish
 103     AC_SUBST(TCLTK_PATH)
 104   elif test "$with_tcltk" = "yes"; then
 105   # Tcl/Tk check requested.
 106     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 107   else
 108     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 109     TCLTK_PATH="$with_tcltk"
 110     AC_SUBST(TCLTK_PATH)
 111   fi
 112 fi
 113
 114 ## Checks for libraries.
 115 AC_MSG_NOTICE([CHECKS for libraries])
 116 #
 117 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 118 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 119 AC_CHECK_LIB([crypto], [SHA1_Init],
 120 [NEEDS_SSL_WITH_CRYPTO=],
 121 [AC_CHECK_LIB([ssl], [SHA1_Init],
 122  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 123   NEEDS_SSL_WITH_CRYPTO=],
 124  [NO_OPENSSL=YesPlease])])
 125 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 126 AC_SUBST(NO_OPENSSL)
 127 #
 128 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 129 # git-http-push are not built, and you cannot use http:// and https://
 130 # transports.
 131 AC_CHECK_LIB([curl], [curl_global_init],
 132 [NO_CURL=],
 133 [NO_CURL=YesPlease])
 134 AC_SUBST(NO_CURL)
 135 #
 136 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 137 # not built, and you cannot push using http:// and https:// transports.
 138 AC_CHECK_LIB([expat], [XML_ParserCreate],
 139 [NO_EXPAT=],
 140 [NO_EXPAT=YesPlease])
 141 AC_SUBST(NO_EXPAT)
 142 #
 143 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 144 # some Solaris installations).
 145 # Define NO_ICONV if neither libc nor libiconv support iconv.
 146 AC_DEFUN([ICONVTEST_SRC], [
 147 #include <iconv.h>
 148
 149 int main(void)
 150 {
 151         iconv_open("", "");
 152         return 0;
 153 }
 154 ])
 155 AC_MSG_CHECKING([for iconv in -lc])
 156 AC_LINK_IFELSE(ICONVTEST_SRC,
 157         [AC_MSG_RESULT([yes])
 158         NEEDS_LIBICONV=],
 159         [AC_MSG_RESULT([no])
 160         old_LIBS="$LIBS"
 161         LIBS="$LIBS -liconv"
 162         AC_MSG_CHECKING([for iconv in -liconv])
 163         AC_LINK_IFELSE(ICONVTEST_SRC,
 164                 [AC_MSG_RESULT([yes])
 165                 NEEDS_LIBICONV=YesPlease],
 166                 [AC_MSG_RESULT([no])
 167                 NO_ICONV=YesPlease])
 168         LIBS="$old_LIBS"])
 169 AC_SUBST(NEEDS_LIBICONV)
 170 AC_SUBST(NO_ICONV)
 171 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 172 #
 173 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 174 # Patrick Mauritz).
 175 AC_CHECK_LIB([c], [socket],
 176 [NEEDS_SOCKET=],
 177 [NEEDS_SOCKET=YesPlease])
 178 AC_SUBST(NEEDS_SOCKET)
 179 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 180
 181
 182 ## Checks for header files.
 183
 184
 185 ## Checks for typedefs, structures, and compiler characteristics.
 186 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 187 #
 188 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 189 AC_CHECK_MEMBER(struct dirent.d_ino,
 190 [NO_D_INO_IN_DIRENT=],
 191 [NO_D_INO_IN_DIRENT=YesPlease],
 192 [#include <dirent.h>])
 193 AC_SUBST(NO_D_INO_IN_DIRENT)
 194 #
 195 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 196 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 197 AC_CHECK_MEMBER(struct dirent.d_type,
 198 [NO_D_TYPE_IN_DIRENT=],
 199 [NO_D_TYPE_IN_DIRENT=YesPlease],
 200 [#include <dirent.h>])
 201 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 202 #
 203 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 204 # sockaddr_storage.
 205 AC_CHECK_TYPE(struct sockaddr_storage,
 206 [NO_SOCKADDR_STORAGE=],
 207 [NO_SOCKADDR_STORAGE=YesPlease],[
 208 #include <sys/types.h>
 209 #ifdef __MINGW32__
 210 #include <winsock2.h>
 211 #else
 212 #include <sys/socket.h>
 213 #endif
 214 ])
 215 AC_SUBST(NO_SOCKADDR_STORAGE)
 216 #
 217 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 218 AC_CHECK_TYPE([struct addrinfo],[
 219  AC_CHECK_FUNC([getaddrinfo],
 220   [NO_IPV6=],
 221   [NO_IPV6=YesPlease])
 222 ],[NO_IPV6=YesPlease],[
 223 #include <sys/types.h>
 224 #include <sys/socket.h>
 225 #include <netdb.h>
 226 ])
 227 AC_SUBST(NO_IPV6)
 228 #
 229 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 230 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 231 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 232 # some C compilers supported these specifiers prior to C99 as an extension.
 233 if test "$host_os" = "$build_os"; then
 234 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 235  [ac_cv_c_c99_format],
 236 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 237 AC_RUN_IFELSE(
 238         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 239                 [[char buf[64];
 240                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 241                   exit(1);
 242                 else if (strcmp(buf, "12345"))
 243                   exit(2);]])],
 244         [ac_cv_c_c99_format=yes],
 245         [ac_cv_c_c99_format=no])
 246 ])
 247 if test $ac_cv_c_c99_format = no; then
 248         NO_C99_FORMAT=YesPlease
 249 else
 250         NO_C99_FORMAT=
 251 fi
 252 else
 253         echo "Cross-compiling detected. Blindly set NO_C99_FORMAT=YesPlease"
 254         NO_C99_FORMAT=YesPlease
 255 fi
 256 AC_SUBST(NO_C99_FORMAT)
 257
 258
 259 ## Checks for library functions.
 260 ## (in default C library and libraries checked by AC_CHECK_LIB)
 261 AC_MSG_NOTICE([CHECKS for library functions])
 262 #
 263 # Define NO_STRCASESTR if you don't have strcasestr.
 264 AC_CHECK_FUNC(strcasestr,
 265 [NO_STRCASESTR=],
 266 [NO_STRCASESTR=YesPlease])
 267 AC_SUBST(NO_STRCASESTR)
 268 #
 269 # Define NO_STRLCPY if you don't have strlcpy.
 270 AC_CHECK_FUNC(strlcpy,
 271 [NO_STRLCPY=],
 272 [NO_STRLCPY=YesPlease])
 273 AC_SUBST(NO_STRLCPY)
 274 #
 275 # Define NO_SETENV if you don't have setenv in the C library.
 276 AC_CHECK_FUNC(setenv,
 277 [NO_SETENV=],
 278 [NO_SETENV=YesPlease])
 279 AC_SUBST(NO_SETENV)
 280 #
 281 # Define NO_MMAP if you want to avoid mmap.
 282 #
 283 # Define NO_ICONV if your libc does not properly support iconv.
 284
 285
 286 ## Other checks.
 287 # Define USE_PIC if you need the main git objects to be built with -fPIC
 288 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 289 #
 290 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 291 # Enable it on Windows.  By default, symrefs are still used.
 292
 293 ## Site configuration (override autodetection)
 294 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 295 AC_MSG_NOTICE([CHECKS for site configuration])
 296 #
 297 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 298 # tests.  These tests take up a significant amount of the total test time
 299 # but are not needed unless you plan to talk to SVN repos.
 300 #
 301 # Define MOZILLA_SHA1 environment variable when running make to make use of
 302 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 303 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 304 # choice) has very fast version optimized for i586.
 305 #
 306 # Define PPC_SHA1 environment variable when running make to make use of
 307 # a bundled SHA1 routine optimized for PowerPC.
 308 #
 309 # Define ARM_SHA1 environment variable when running make to make use of
 310 # a bundled SHA1 routine optimized for ARM.
 311 #
 312 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 313 # This also implies MOZILLA_SHA1.
 314 #
 315 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 316 # /foo/bar/include and /foo/bar/lib directories.
 317 AC_ARG_WITH(openssl,
 318 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 319 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 320 GIT_PARSE_WITH(openssl))
 321 #
 322 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 323 # git-http-push are not built, and you cannot use http:// and https://
 324 # transports.
 325 #
 326 # Define CURLDIR=/foo/bar if your curl header and library files are in
 327 # /foo/bar/include and /foo/bar/lib directories.
 328 AC_ARG_WITH(curl,
 329 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 330 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 331 GIT_PARSE_WITH(curl))
 332 #
 333 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 334 # not built, and you cannot push using http:// and https:// transports.
 335 #
 336 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 337 # /foo/bar/include and /foo/bar/lib directories.
 338 AC_ARG_WITH(expat,
 339 AS_HELP_STRING([--with-expat],
 340 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 341 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 342 GIT_PARSE_WITH(expat))
 343 #
 344 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 345 # installed in /sw, but don't want GIT to link against any libraries
 346 # installed there.  If defined you may specify your own (or Fink's)
 347 # include directories and library directories by defining CFLAGS
 348 # and LDFLAGS appropriately.
 349 #
 350 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 351 # have DarwinPorts installed in /opt/local, but don't want GIT to
 352 # link against any libraries installed there.  If defined you may
 353 # specify your own (or DarwinPort's) include directories and
 354 # library directories by defining CFLAGS and LDFLAGS appropriately.
 355 #
 356 # Define NO_MMAP if you want to avoid mmap.
 357 #
 358 # Define NO_ICONV if your libc does not properly support iconv.
 359 AC_ARG_WITH(iconv,
 360 AS_HELP_STRING([--without-iconv],
 361 [if your architecture doesn't properly support iconv])
 362 AS_HELP_STRING([--with-iconv=PATH],
 363 [PATH is prefix for libiconv library and headers])
 364 AS_HELP_STRING([],
 365 [used only if you need linking with libiconv]),
 366 GIT_PARSE_WITH(iconv))
 367
 368 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 369 #
 370 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 371 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 372 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 373 # randomly break unless your underlying filesystem supports those sub-second
 374 # times (my ext3 doesn't).
 375 #
 376 # Define USE_STDEV below if you want git to care about the underlying device
 377 # change being considered an inode change from the update-cache perspective.
 378
 379
 380 ## Output files
 381 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 382 AC_OUTPUT
 383
 384
 385 ## Cleanup
 386 rm -f "${config_append}"