git-add--interactive.perl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Git;
   5
   6 binmode(STDOUT, ":raw");
   7
   8 my $repo = Git->repository();
   9
  10 my $menu_use_color = $repo->get_colorbool('color.interactive');
  11 my ($prompt_color, $header_color, $help_color) =
  12         $menu_use_color ? (
  13                 $repo->get_color('color.interactive.prompt', 'bold blue'),
  14                 $repo->get_color('color.interactive.header', 'bold'),
  15                 $repo->get_color('color.interactive.help', 'red bold'),
  16         ) : ();
  17 my $error_color = ();
  18 if ($menu_use_color) {
  19         my $help_color_spec = ($repo->config('color.interactive.help') or
  20                                 'red bold');
  21         $error_color = $repo->get_color('color.interactive.error',
  22                                         $help_color_spec);
  23 }
  24
  25 my $diff_use_color = $repo->get_colorbool('color.diff');
  26 my ($fraginfo_color) =
  27         $diff_use_color ? (
  28                 $repo->get_color('color.diff.frag', 'cyan'),
  29         ) : ();
  30 my ($diff_plain_color) =
  31         $diff_use_color ? (
  32                 $repo->get_color('color.diff.plain', ''),
  33         ) : ();
  34 my ($diff_old_color) =
  35         $diff_use_color ? (
  36                 $repo->get_color('color.diff.old', 'red'),
  37         ) : ();
  38 my ($diff_new_color) =
  39         $diff_use_color ? (
  40                 $repo->get_color('color.diff.new', 'green'),
  41         ) : ();
  42
  43 my $normal_color = $repo->get_color("", "reset");
  44
  45 my $use_readkey = 0;
  46 sub ReadMode;
  47 sub ReadKey;
  48 if ($repo->config_bool("interactive.singlekey")) {
  49         eval {
  50                 require Term::ReadKey;
  51                 Term::ReadKey->import;
  52                 $use_readkey = 1;
  53         };
  54 }
  55
  56 sub colored {
  57         my $color = shift;
  58         my $string = join("", @_);
  59
  60         if (defined $color) {
  61                 # Put a color code at the beginning of each line, a reset at the end
  62                 # color after newlines that are not at the end of the string
  63                 $string =~ s/(\n+)(.)/$1$color$2/g;
  64                 # reset before newlines
  65                 $string =~ s/(\n+)/$normal_color$1/g;
  66                 # codes at beginning and end (if necessary):
  67                 $string =~ s/^/$color/;
  68                 $string =~ s/$/$normal_color/ unless $string =~ /\n$/;
  69         }
  70         return $string;
  71 }
  72
  73 # command line options
  74 my $patch_mode;
  75
  76 sub run_cmd_pipe {
  77         if ($^O eq 'MSWin32' || $^O eq 'msys') {
  78                 my @invalid = grep {m/[":*]/} @_;
  79                 die "$^O does not support: @invalid\n" if @invalid;
  80                 my @args = map { m/ /o ? "\"$_\"": $_ } @_;
  81                 return qx{@args};
  82         } else {
  83                 my $fh = undef;
  84                 open($fh, '-|', @_) or die;
  85                 return <$fh>;
  86         }
  87 }
  88
  89 my ($GIT_DIR) = run_cmd_pipe(qw(git rev-parse --git-dir));
  90
  91 if (!defined $GIT_DIR) {
  92         exit(1); # rev-parse would have already said "not a git repo"
  93 }
  94 chomp($GIT_DIR);
  95
  96 my %cquote_map = (
  97  "b" => chr(8),
  98  "t" => chr(9),
  99  "n" => chr(10),
 100  "v" => chr(11),
 101  "f" => chr(12),
 102  "r" => chr(13),
 103  "\\" => "\\",
 104  "\042" => "\042",
 105 );
 106
 107 sub unquote_path {
 108         local ($_) = @_;
 109         my ($retval, $remainder);
 110         if (!/^\042(.*)\042$/) {
 111                 return $_;
 112         }
 113         ($_, $retval) = ($1, "");
 114         while (/^([^\\]*)\\(.*)$/) {
 115                 $remainder = $2;
 116                 $retval .= $1;
 117                 for ($remainder) {
 118                         if (/^([0-3][0-7][0-7])(.*)$/) {
 119                                 $retval .= chr(oct($1));
 120                                 $_ = $2;
 121                                 last;
 122                         }
 123                         if (/^([\\\042btnvfr])(.*)$/) {
 124                                 $retval .= $cquote_map{$1};
 125                                 $_ = $2;
 126                                 last;
 127                         }
 128                         # This is malformed -- just return it as-is for now.
 129                         return $_[0];
 130                 }
 131                 $_ = $remainder;
 132         }
 133         $retval .= $_;
 134         return $retval;
 135 }
 136
 137 sub refresh {
 138         my $fh;
 139         open $fh, 'git update-index --refresh |'
 140             or die;
 141         while (<$fh>) {
 142                 ;# ignore 'needs update'
 143         }
 144         close $fh;
 145 }
 146
 147 sub list_untracked {
 148         map {
 149                 chomp $_;
 150                 unquote_path($_);
 151         }
 152         run_cmd_pipe(qw(git ls-files --others --exclude-standard --), @ARGV);
 153 }
 154
 155 my $status_fmt = '%12s %12s %s';
 156 my $status_head = sprintf($status_fmt, 'staged', 'unstaged', 'path');
 157
 158 {
 159         my $initial;
 160         sub is_initial_commit {
 161                 $initial = system('git rev-parse HEAD -- >/dev/null 2>&1') != 0
 162                         unless defined $initial;
 163                 return $initial;
 164         }
 165 }
 166
 167 sub get_empty_tree {
 168         return '4b825dc642cb6eb9a060e54bf8d69288fbee4904';
 169 }
 170
 171 # Returns list of hashes, contents of each of which are:
 172 # VALUE:        pathname
 173 # BINARY:       is a binary path
 174 # INDEX:        is index different from HEAD?
 175 # FILE:         is file different from index?
 176 # INDEX_ADDDEL: is it add/delete between HEAD and index?
 177 # FILE_ADDDEL:  is it add/delete between index and file?
 178
 179 sub list_modified {
 180         my ($only) = @_;
 181         my (%data, @return);
 182         my ($add, $del, $adddel, $file);
 183         my @tracked = ();
 184
 185         if (@ARGV) {
 186                 @tracked = map {
 187                         chomp $_;
 188                         unquote_path($_);
 189                 } run_cmd_pipe(qw(git ls-files --exclude-standard --), @ARGV);
 190                 return if (!@tracked);
 191         }
 192
 193         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
 194         for (run_cmd_pipe(qw(git diff-index --cached
 195                              --numstat --summary), $reference,
 196                              '--', @tracked)) {
 197                 if (($add, $del, $file) =
 198                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 199                         my ($change, $bin);
 200                         $file = unquote_path($file);
 201                         if ($add eq '-' && $del eq '-') {
 202                                 $change = 'binary';
 203                                 $bin = 1;
 204                         }
 205                         else {
 206                                 $change = "+$add/-$del";
 207                         }
 208                         $data{$file} = {
 209                                 INDEX => $change,
 210                                 BINARY => $bin,
 211                                 FILE => 'nothing',
 212                         }
 213                 }
 214                 elsif (($adddel, $file) =
 215                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 216                         $file = unquote_path($file);
 217                         $data{$file}{INDEX_ADDDEL} = $adddel;
 218                 }
 219         }
 220
 221         for (run_cmd_pipe(qw(git diff-files --numstat --summary --), @tracked)) {
 222                 if (($add, $del, $file) =
 223                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 224                         $file = unquote_path($file);
 225                         if (!exists $data{$file}) {
 226                                 $data{$file} = +{
 227                                         INDEX => 'unchanged',
 228                                         BINARY => 0,
 229                                 };
 230                         }
 231                         my ($change, $bin);
 232                         if ($add eq '-' && $del eq '-') {
 233                                 $change = 'binary';
 234                                 $bin = 1;
 235                         }
 236                         else {
 237                                 $change = "+$add/-$del";
 238                         }
 239                         $data{$file}{FILE} = $change;
 240                         if ($bin) {
 241                                 $data{$file}{BINARY} = 1;
 242                         }
 243                 }
 244                 elsif (($adddel, $file) =
 245                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 246                         $file = unquote_path($file);
 247                         $data{$file}{FILE_ADDDEL} = $adddel;
 248                 }
 249         }
 250
 251         for (sort keys %data) {
 252                 my $it = $data{$_};
 253
 254                 if ($only) {
 255                         if ($only eq 'index-only') {
 256                                 next if ($it->{INDEX} eq 'unchanged');
 257                         }
 258                         if ($only eq 'file-only') {
 259                                 next if ($it->{FILE} eq 'nothing');
 260                         }
 261                 }
 262                 push @return, +{
 263                         VALUE => $_,
 264                         %$it,
 265                 };
 266         }
 267         return @return;
 268 }
 269
 270 sub find_unique {
 271         my ($string, @stuff) = @_;
 272         my $found = undef;
 273         for (my $i = 0; $i < @stuff; $i++) {
 274                 my $it = $stuff[$i];
 275                 my $hit = undef;
 276                 if (ref $it) {
 277                         if ((ref $it) eq 'ARRAY') {
 278                                 $it = $it->[0];
 279                         }
 280                         else {
 281                                 $it = $it->{VALUE};
 282                         }
 283                 }
 284                 eval {
 285                         if ($it =~ /^$string/) {
 286                                 $hit = 1;
 287                         };
 288                 };
 289                 if (defined $hit && defined $found) {
 290                         return undef;
 291                 }
 292                 if ($hit) {
 293                         $found = $i + 1;
 294                 }
 295         }
 296         return $found;
 297 }
 298
 299 # inserts string into trie and updates count for each character
 300 sub update_trie {
 301         my ($trie, $string) = @_;
 302         foreach (split //, $string) {
 303                 $trie = $trie->{$_} ||= {COUNT => 0};
 304                 $trie->{COUNT}++;
 305         }
 306 }
 307
 308 # returns an array of tuples (prefix, remainder)
 309 sub find_unique_prefixes {
 310         my @stuff = @_;
 311         my @return = ();
 312
 313         # any single prefix exceeding the soft limit is omitted
 314         # if any prefix exceeds the hard limit all are omitted
 315         # 0 indicates no limit
 316         my $soft_limit = 0;
 317         my $hard_limit = 3;
 318
 319         # build a trie modelling all possible options
 320         my %trie;
 321         foreach my $print (@stuff) {
 322                 if ((ref $print) eq 'ARRAY') {
 323                         $print = $print->[0];
 324                 }
 325                 elsif ((ref $print) eq 'HASH') {
 326                         $print = $print->{VALUE};
 327                 }
 328                 update_trie(\%trie, $print);
 329                 push @return, $print;
 330         }
 331
 332         # use the trie to find the unique prefixes
 333         for (my $i = 0; $i < @return; $i++) {
 334                 my $ret = $return[$i];
 335                 my @letters = split //, $ret;
 336                 my %search = %trie;
 337                 my ($prefix, $remainder);
 338                 my $j;
 339                 for ($j = 0; $j < @letters; $j++) {
 340                         my $letter = $letters[$j];
 341                         if ($search{$letter}{COUNT} == 1) {
 342                                 $prefix = substr $ret, 0, $j + 1;
 343                                 $remainder = substr $ret, $j + 1;
 344                                 last;
 345                         }
 346                         else {
 347                                 my $prefix = substr $ret, 0, $j;
 348                                 return ()
 349                                     if ($hard_limit && $j + 1 > $hard_limit);
 350                         }
 351                         %search = %{$search{$letter}};
 352                 }
 353                 if (ord($letters[0]) > 127 ||
 354                     ($soft_limit && $j + 1 > $soft_limit)) {
 355                         $prefix = undef;
 356                         $remainder = $ret;
 357                 }
 358                 $return[$i] = [$prefix, $remainder];
 359         }
 360         return @return;
 361 }
 362
 363 # filters out prefixes which have special meaning to list_and_choose()
 364 sub is_valid_prefix {
 365         my $prefix = shift;
 366         return (defined $prefix) &&
 367             !($prefix =~ /[\s,]/) && # separators
 368             !($prefix =~ /^-/) &&    # deselection
 369             !($prefix =~ /^\d+/) &&  # selection
 370             ($prefix ne '*') &&      # "all" wildcard
 371             ($prefix ne '?');        # prompt help
 372 }
 373
 374 # given a prefix/remainder tuple return a string with the prefix highlighted
 375 # for now use square brackets; later might use ANSI colors (underline, bold)
 376 sub highlight_prefix {
 377         my $prefix = shift;
 378         my $remainder = shift;
 379
 380         if (!defined $prefix) {
 381                 return $remainder;
 382         }
 383
 384         if (!is_valid_prefix($prefix)) {
 385                 return "$prefix$remainder";
 386         }
 387
 388         if (!$menu_use_color) {
 389                 return "[$prefix]$remainder";
 390         }
 391
 392         return "$prompt_color$prefix$normal_color$remainder";
 393 }
 394
 395 sub error_msg {
 396         print STDERR colored $error_color, @_;
 397 }
 398
 399 sub list_and_choose {
 400         my ($opts, @stuff) = @_;
 401         my (@chosen, @return);
 402         my $i;
 403         my @prefixes = find_unique_prefixes(@stuff) unless $opts->{LIST_ONLY};
 404
 405       TOPLOOP:
 406         while (1) {
 407                 my $last_lf = 0;
 408
 409                 if ($opts->{HEADER}) {
 410                         if (!$opts->{LIST_FLAT}) {
 411                                 print "     ";
 412                         }
 413                         print colored $header_color, "$opts->{HEADER}\n";
 414                 }
 415                 for ($i = 0; $i < @stuff; $i++) {
 416                         my $chosen = $chosen[$i] ? '*' : ' ';
 417                         my $print = $stuff[$i];
 418                         my $ref = ref $print;
 419                         my $highlighted = highlight_prefix(@{$prefixes[$i]})
 420                             if @prefixes;
 421                         if ($ref eq 'ARRAY') {
 422                                 $print = $highlighted || $print->[0];
 423                         }
 424                         elsif ($ref eq 'HASH') {
 425                                 my $value = $highlighted || $print->{VALUE};
 426                                 $print = sprintf($status_fmt,
 427                                     $print->{INDEX},
 428                                     $print->{FILE},
 429                                     $value);
 430                         }
 431                         else {
 432                                 $print = $highlighted || $print;
 433                         }
 434                         printf("%s%2d: %s", $chosen, $i+1, $print);
 435                         if (($opts->{LIST_FLAT}) &&
 436                             (($i + 1) % ($opts->{LIST_FLAT}))) {
 437                                 print "\t";
 438                                 $last_lf = 0;
 439                         }
 440                         else {
 441                                 print "\n";
 442                                 $last_lf = 1;
 443                         }
 444                 }
 445                 if (!$last_lf) {
 446                         print "\n";
 447                 }
 448
 449                 return if ($opts->{LIST_ONLY});
 450
 451                 print colored $prompt_color, $opts->{PROMPT};
 452                 if ($opts->{SINGLETON}) {
 453                         print "> ";
 454                 }
 455                 else {
 456                         print ">> ";
 457                 }
 458                 my $line = <STDIN>;
 459                 if (!$line) {
 460                         print "\n";
 461                         $opts->{ON_EOF}->() if $opts->{ON_EOF};
 462                         last;
 463                 }
 464                 chomp $line;
 465                 last if $line eq '';
 466                 if ($line eq '?') {
 467                         $opts->{SINGLETON} ?
 468                             singleton_prompt_help_cmd() :
 469                             prompt_help_cmd();
 470                         next TOPLOOP;
 471                 }
 472                 for my $choice (split(/[\s,]+/, $line)) {
 473                         my $choose = 1;
 474                         my ($bottom, $top);
 475
 476                         # Input that begins with '-'; unchoose
 477                         if ($choice =~ s/^-//) {
 478                                 $choose = 0;
 479                         }
 480                         # A range can be specified like 5-7 or 5-.
 481                         if ($choice =~ /^(\d+)-(\d*)$/) {
 482                                 ($bottom, $top) = ($1, length($2) ? $2 : 1 + @stuff);
 483                         }
 484                         elsif ($choice =~ /^\d+$/) {
 485                                 $bottom = $top = $choice;
 486                         }
 487                         elsif ($choice eq '*') {
 488                                 $bottom = 1;
 489                                 $top = 1 + @stuff;
 490                         }
 491                         else {
 492                                 $bottom = $top = find_unique($choice, @stuff);
 493                                 if (!defined $bottom) {
 494                                         error_msg "Huh ($choice)?\n";
 495                                         next TOPLOOP;
 496                                 }
 497                         }
 498                         if ($opts->{SINGLETON} && $bottom != $top) {
 499                                 error_msg "Huh ($choice)?\n";
 500                                 next TOPLOOP;
 501                         }
 502                         for ($i = $bottom-1; $i <= $top-1; $i++) {
 503                                 next if (@stuff <= $i || $i < 0);
 504                                 $chosen[$i] = $choose;
 505                         }
 506                 }
 507                 last if ($opts->{IMMEDIATE} || $line eq '*');
 508         }
 509         for ($i = 0; $i < @stuff; $i++) {
 510                 if ($chosen[$i]) {
 511                         push @return, $stuff[$i];
 512                 }
 513         }
 514         return @return;
 515 }
 516
 517 sub singleton_prompt_help_cmd {
 518         print colored $help_color, <<\EOF ;
 519 Prompt help:
 520 1          - select a numbered item
 521 foo        - select item based on unique prefix
 522            - (empty) select nothing
 523 EOF
 524 }
 525
 526 sub prompt_help_cmd {
 527         print colored $help_color, <<\EOF ;
 528 Prompt help:
 529 1          - select a single item
 530 3-5        - select a range of items
 531 2-3,6-9    - select multiple ranges
 532 foo        - select item based on unique prefix
 533 -...       - unselect specified items
 534 *          - choose all items
 535            - (empty) finish selecting
 536 EOF
 537 }
 538
 539 sub status_cmd {
 540         list_and_choose({ LIST_ONLY => 1, HEADER => $status_head },
 541                         list_modified());
 542         print "\n";
 543 }
 544
 545 sub say_n_paths {
 546         my $did = shift @_;
 547         my $cnt = scalar @_;
 548         print "$did ";
 549         if (1 < $cnt) {
 550                 print "$cnt paths\n";
 551         }
 552         else {
 553                 print "one path\n";
 554         }
 555 }
 556
 557 sub update_cmd {
 558         my @mods = list_modified('file-only');
 559         return if (!@mods);
 560
 561         my @update = list_and_choose({ PROMPT => 'Update',
 562                                        HEADER => $status_head, },
 563                                      @mods);
 564         if (@update) {
 565                 system(qw(git update-index --add --remove --),
 566                        map { $_->{VALUE} } @update);
 567                 say_n_paths('updated', @update);
 568         }
 569         print "\n";
 570 }
 571
 572 sub revert_cmd {
 573         my @update = list_and_choose({ PROMPT => 'Revert',
 574                                        HEADER => $status_head, },
 575                                      list_modified());
 576         if (@update) {
 577                 if (is_initial_commit()) {
 578                         system(qw(git rm --cached),
 579                                 map { $_->{VALUE} } @update);
 580                 }
 581                 else {
 582                         my @lines = run_cmd_pipe(qw(git ls-tree HEAD --),
 583                                                  map { $_->{VALUE} } @update);
 584                         my $fh;
 585                         open $fh, '| git update-index --index-info'
 586                             or die;
 587                         for (@lines) {
 588                                 print $fh $_;
 589                         }
 590                         close($fh);
 591                         for (@update) {
 592                                 if ($_->{INDEX_ADDDEL} &&
 593                                     $_->{INDEX_ADDDEL} eq 'create') {
 594                                         system(qw(git update-index --force-remove --),
 595                                                $_->{VALUE});
 596                                         print "note: $_->{VALUE} is untracked now.\n";
 597                                 }
 598                         }
 599                 }
 600                 refresh();
 601                 say_n_paths('reverted', @update);
 602         }
 603         print "\n";
 604 }
 605
 606 sub add_untracked_cmd {
 607         my @add = list_and_choose({ PROMPT => 'Add untracked' },
 608                                   list_untracked());
 609         if (@add) {
 610                 system(qw(git update-index --add --), @add);
 611                 say_n_paths('added', @add);
 612         }
 613         print "\n";
 614 }
 615
 616 sub parse_diff {
 617         my ($path) = @_;
 618         my @diff = run_cmd_pipe(qw(git diff-files -p --), $path);
 619         my @colored = ();
 620         if ($diff_use_color) {
 621                 @colored = run_cmd_pipe(qw(git diff-files -p --color --), $path);
 622         }
 623         my (@hunk) = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 624
 625         for (my $i = 0; $i < @diff; $i++) {
 626                 if ($diff[$i] =~ /^@@ /) {
 627                         push @hunk, { TEXT => [], DISPLAY => [],
 628                                 TYPE => 'hunk' };
 629                 }
 630                 push @{$hunk[-1]{TEXT}}, $diff[$i];
 631                 push @{$hunk[-1]{DISPLAY}},
 632                         ($diff_use_color ? $colored[$i] : $diff[$i]);
 633         }
 634         return @hunk;
 635 }
 636
 637 sub parse_diff_header {
 638         my $src = shift;
 639
 640         my $head = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 641         my $mode = { TEXT => [], DISPLAY => [], TYPE => 'mode' };
 642
 643         for (my $i = 0; $i < @{$src->{TEXT}}; $i++) {
 644                 my $dest = $src->{TEXT}->[$i] =~ /^(old|new) mode (\d+)$/ ?
 645                         $mode : $head;
 646                 push @{$dest->{TEXT}}, $src->{TEXT}->[$i];
 647                 push @{$dest->{DISPLAY}}, $src->{DISPLAY}->[$i];
 648         }
 649         return ($head, $mode);
 650 }
 651
 652 sub hunk_splittable {
 653         my ($text) = @_;
 654
 655         my @s = split_hunk($text);
 656         return (1 < @s);
 657 }
 658
 659 sub parse_hunk_header {
 660         my ($line) = @_;
 661         my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) =
 662             $line =~ /^@@ -(\d+)(?:,(\d+))? \+(\d+)(?:,(\d+))? @@/;
 663         $o_cnt = 1 unless defined $o_cnt;
 664         $n_cnt = 1 unless defined $n_cnt;
 665         return ($o_ofs, $o_cnt, $n_ofs, $n_cnt);
 666 }
 667
 668 sub split_hunk {
 669         my ($text, $display) = @_;
 670         my @split = ();
 671         if (!defined $display) {
 672                 $display = $text;
 673         }
 674         # If there are context lines in the middle of a hunk,
 675         # it can be split, but we would need to take care of
 676         # overlaps later.
 677
 678         my ($o_ofs, undef, $n_ofs) = parse_hunk_header($text->[0]);
 679         my $hunk_start = 1;
 680
 681       OUTER:
 682         while (1) {
 683                 my $next_hunk_start = undef;
 684                 my $i = $hunk_start - 1;
 685                 my $this = +{
 686                         TEXT => [],
 687                         DISPLAY => [],
 688                         TYPE => 'hunk',
 689                         OLD => $o_ofs,
 690                         NEW => $n_ofs,
 691                         OCNT => 0,
 692                         NCNT => 0,
 693                         ADDDEL => 0,
 694                         POSTCTX => 0,
 695                         USE => undef,
 696                 };
 697
 698                 while (++$i < @$text) {
 699                         my $line = $text->[$i];
 700                         my $display = $display->[$i];
 701                         if ($line =~ /^ /) {
 702                                 if ($this->{ADDDEL} &&
 703                                     !defined $next_hunk_start) {
 704                                         # We have seen leading context and
 705                                         # adds/dels and then here is another
 706                                         # context, which is trailing for this
 707                                         # split hunk and leading for the next
 708                                         # one.
 709                                         $next_hunk_start = $i;
 710                                 }
 711                                 push @{$this->{TEXT}}, $line;
 712                                 push @{$this->{DISPLAY}}, $display;
 713                                 $this->{OCNT}++;
 714                                 $this->{NCNT}++;
 715                                 if (defined $next_hunk_start) {
 716                                         $this->{POSTCTX}++;
 717                                 }
 718                                 next;
 719                         }
 720
 721                         # add/del
 722                         if (defined $next_hunk_start) {
 723                                 # We are done with the current hunk and
 724                                 # this is the first real change for the
 725                                 # next split one.
 726                                 $hunk_start = $next_hunk_start;
 727                                 $o_ofs = $this->{OLD} + $this->{OCNT};
 728                                 $n_ofs = $this->{NEW} + $this->{NCNT};
 729                                 $o_ofs -= $this->{POSTCTX};
 730                                 $n_ofs -= $this->{POSTCTX};
 731                                 push @split, $this;
 732                                 redo OUTER;
 733                         }
 734                         push @{$this->{TEXT}}, $line;
 735                         push @{$this->{DISPLAY}}, $display;
 736                         $this->{ADDDEL}++;
 737                         if ($line =~ /^-/) {
 738                                 $this->{OCNT}++;
 739                         }
 740                         else {
 741                                 $this->{NCNT}++;
 742                         }
 743                 }
 744
 745                 push @split, $this;
 746                 last;
 747         }
 748
 749         for my $hunk (@split) {
 750                 $o_ofs = $hunk->{OLD};
 751                 $n_ofs = $hunk->{NEW};
 752                 my $o_cnt = $hunk->{OCNT};
 753                 my $n_cnt = $hunk->{NCNT};
 754
 755                 my $head = ("@@ -$o_ofs" .
 756                             (($o_cnt != 1) ? ",$o_cnt" : '') .
 757                             " +$n_ofs" .
 758                             (($n_cnt != 1) ? ",$n_cnt" : '') .
 759                             " @@\n");
 760                 my $display_head = $head;
 761                 unshift @{$hunk->{TEXT}}, $head;
 762                 if ($diff_use_color) {
 763                         $display_head = colored($fraginfo_color, $head);
 764                 }
 765                 unshift @{$hunk->{DISPLAY}}, $display_head;
 766         }
 767         return @split;
 768 }
 769
 770 sub find_last_o_ctx {
 771         my ($it) = @_;
 772         my $text = $it->{TEXT};
 773         my ($o_ofs, $o_cnt) = parse_hunk_header($text->[0]);
 774         my $i = @{$text};
 775         my $last_o_ctx = $o_ofs + $o_cnt;
 776         while (0 < --$i) {
 777                 my $line = $text->[$i];
 778                 if ($line =~ /^ /) {
 779                         $last_o_ctx--;
 780                         next;
 781                 }
 782                 last;
 783         }
 784         return $last_o_ctx;
 785 }
 786
 787 sub merge_hunk {
 788         my ($prev, $this) = @_;
 789         my ($o0_ofs, $o0_cnt, $n0_ofs, $n0_cnt) =
 790             parse_hunk_header($prev->{TEXT}[0]);
 791         my ($o1_ofs, $o1_cnt, $n1_ofs, $n1_cnt) =
 792             parse_hunk_header($this->{TEXT}[0]);
 793
 794         my (@line, $i, $ofs, $o_cnt, $n_cnt);
 795         $ofs = $o0_ofs;
 796         $o_cnt = $n_cnt = 0;
 797         for ($i = 1; $i < @{$prev->{TEXT}}; $i++) {
 798                 my $line = $prev->{TEXT}[$i];
 799                 if ($line =~ /^\+/) {
 800                         $n_cnt++;
 801                         push @line, $line;
 802                         next;
 803                 }
 804
 805                 last if ($o1_ofs <= $ofs);
 806
 807                 $o_cnt++;
 808                 $ofs++;
 809                 if ($line =~ /^ /) {
 810                         $n_cnt++;
 811                 }
 812                 push @line, $line;
 813         }
 814
 815         for ($i = 1; $i < @{$this->{TEXT}}; $i++) {
 816                 my $line = $this->{TEXT}[$i];
 817                 if ($line =~ /^\+/) {
 818                         $n_cnt++;
 819                         push @line, $line;
 820                         next;
 821                 }
 822                 $ofs++;
 823                 $o_cnt++;
 824                 if ($line =~ /^ /) {
 825                         $n_cnt++;
 826                 }
 827                 push @line, $line;
 828         }
 829         my $head = ("@@ -$o0_ofs" .
 830                     (($o_cnt != 1) ? ",$o_cnt" : '') .
 831                     " +$n0_ofs" .
 832                     (($n_cnt != 1) ? ",$n_cnt" : '') .
 833                     " @@\n");
 834         @{$prev->{TEXT}} = ($head, @line);
 835 }
 836
 837 sub coalesce_overlapping_hunks {
 838         my (@in) = @_;
 839         my @out = ();
 840
 841         my ($last_o_ctx, $last_was_dirty);
 842
 843         for (grep { $_->{USE} } @in) {
 844                 if ($_->{TYPE} ne 'hunk') {
 845                         push @out, $_;
 846                         next;
 847                 }
 848                 my $text = $_->{TEXT};
 849                 my ($o_ofs) = parse_hunk_header($text->[0]);
 850                 if (defined $last_o_ctx &&
 851                     $o_ofs <= $last_o_ctx &&
 852                     !$_->{DIRTY} &&
 853                     !$last_was_dirty) {
 854                         merge_hunk($out[-1], $_);
 855                 }
 856                 else {
 857                         push @out, $_;
 858                 }
 859                 $last_o_ctx = find_last_o_ctx($out[-1]);
 860                 $last_was_dirty = $_->{DIRTY};
 861         }
 862         return @out;
 863 }
 864
 865 sub color_diff {
 866         return map {
 867                 colored((/^@/  ? $fraginfo_color :
 868                          /^\+/ ? $diff_new_color :
 869                          /^-/  ? $diff_old_color :
 870                          $diff_plain_color),
 871                         $_);
 872         } @_;
 873 }
 874
 875 sub edit_hunk_manually {
 876         my ($oldtext) = @_;
 877
 878         my $hunkfile = $repo->repo_path . "/addp-hunk-edit.diff";
 879         my $fh;
 880         open $fh, '>', $hunkfile
 881                 or die "failed to open hunk edit file for writing: " . $!;
 882         print $fh "# Manual hunk edit mode -- see bottom for a quick guide\n";
 883         print $fh @$oldtext;
 884         print $fh <<EOF;
 885 # ---
 886 # To remove '-' lines, make them ' ' lines (context).
 887 # To remove '+' lines, delete them.
 888 # Lines starting with # will be removed.
 889 #
 890 # If the patch applies cleanly, the edited hunk will immediately be
 891 # marked for staging. If it does not apply cleanly, you will be given
 892 # an opportunity to edit again. If all lines of the hunk are removed,
 893 # then the edit is aborted and the hunk is left unchanged.
 894 EOF
 895         close $fh;
 896
 897         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor")
 898                 || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 899         system('sh', '-c', $editor.' "$@"', $editor, $hunkfile);
 900
 901         if ($? != 0) {
 902                 return undef;
 903         }
 904
 905         open $fh, '<', $hunkfile
 906                 or die "failed to open hunk edit file for reading: " . $!;
 907         my @newtext = grep { !/^#/ } <$fh>;
 908         close $fh;
 909         unlink $hunkfile;
 910
 911         # Abort if nothing remains
 912         if (!grep { /\S/ } @newtext) {
 913                 return undef;
 914         }
 915
 916         # Reinsert the first hunk header if the user accidentally deleted it
 917         if ($newtext[0] !~ /^@/) {
 918                 unshift @newtext, $oldtext->[0];
 919         }
 920         return \@newtext;
 921 }
 922
 923 sub diff_applies {
 924         my $fh;
 925         open $fh, '| git apply --recount --cached --check';
 926         for my $h (@_) {
 927                 print $fh @{$h->{TEXT}};
 928         }
 929         return close $fh;
 930 }
 931
 932 sub _restore_terminal_and_die {
 933         ReadMode 'restore';
 934         print "\n";
 935         exit 1;
 936 }
 937
 938 sub prompt_single_character {
 939         if ($use_readkey) {
 940                 local $SIG{TERM} = \&_restore_terminal_and_die;
 941                 local $SIG{INT} = \&_restore_terminal_and_die;
 942                 ReadMode 'cbreak';
 943                 my $key = ReadKey 0;
 944                 ReadMode 'restore';
 945                 print "$key" if defined $key;
 946                 print "\n";
 947                 return $key;
 948         } else {
 949                 return <STDIN>;
 950         }
 951 }
 952
 953 sub prompt_yesno {
 954         my ($prompt) = @_;
 955         while (1) {
 956                 print colored $prompt_color, $prompt;
 957                 my $line = prompt_single_character;
 958                 return 0 if $line =~ /^n/i;
 959                 return 1 if $line =~ /^y/i;
 960         }
 961 }
 962
 963 sub edit_hunk_loop {
 964         my ($head, $hunk, $ix) = @_;
 965         my $text = $hunk->[$ix]->{TEXT};
 966
 967         while (1) {
 968                 $text = edit_hunk_manually($text);
 969                 if (!defined $text) {
 970                         return undef;
 971                 }
 972                 my $newhunk = {
 973                         TEXT => $text,
 974                         TYPE => $hunk->[$ix]->{TYPE},
 975                         USE => 1,
 976                         DIRTY => 1,
 977                 };
 978                 if (diff_applies($head,
 979                                  @{$hunk}[0..$ix-1],
 980                                  $newhunk,
 981                                  @{$hunk}[$ix+1..$#{$hunk}])) {
 982                         $newhunk->{DISPLAY} = [color_diff(@{$text})];
 983                         return $newhunk;
 984                 }
 985                 else {
 986                         prompt_yesno(
 987                                 'Your edited hunk does not apply. Edit again '
 988                                 . '(saying "no" discards!) [y/n]? '
 989                                 ) or return undef;
 990                 }
 991         }
 992 }
 993
 994 sub help_patch_cmd {
 995         print colored $help_color, <<\EOF ;
 996 y - stage this hunk
 997 n - do not stage this hunk
 998 q - quit, do not stage this hunk nor any of the remaining ones
 999 a - stage this and all the remaining hunks in the file
1000 d - do not stage this hunk nor any of the remaining hunks in the file
1001 g - select a hunk to go to
1002 / - search for a hunk matching the given regex
1003 j - leave this hunk undecided, see next undecided hunk
1004 J - leave this hunk undecided, see next hunk
1005 k - leave this hunk undecided, see previous undecided hunk
1006 K - leave this hunk undecided, see previous hunk
1007 s - split the current hunk into smaller hunks
1008 e - manually edit the current hunk
1009 ? - print help
1010 EOF
1011 }
1012
1013 sub patch_update_cmd {
1014         my @all_mods = list_modified('file-only');
1015         my @mods = grep { !($_->{BINARY}) } @all_mods;
1016         my @them;
1017
1018         if (!@mods) {
1019                 if (@all_mods) {
1020                         print STDERR "Only binary files changed.\n";
1021                 } else {
1022                         print STDERR "No changes.\n";
1023                 }
1024                 return 0;
1025         }
1026         if ($patch_mode) {
1027                 @them = @mods;
1028         }
1029         else {
1030                 @them = list_and_choose({ PROMPT => 'Patch update',
1031                                           HEADER => $status_head, },
1032                                         @mods);
1033         }
1034         for (@them) {
1035                 return 0 if patch_update_file($_->{VALUE});
1036         }
1037 }
1038
1039 # Generate a one line summary of a hunk.
1040 sub summarize_hunk {
1041         my $rhunk = shift;
1042         my $summary = $rhunk->{TEXT}[0];
1043
1044         # Keep the line numbers, discard extra context.
1045         $summary =~ s/@@(.*?)@@.*/$1 /s;
1046         $summary .= " " x (20 - length $summary);
1047
1048         # Add some user context.
1049         for my $line (@{$rhunk->{TEXT}}) {
1050                 if ($line =~ m/^[+-].*\w/) {
1051                         $summary .= $line;
1052                         last;
1053                 }
1054         }
1055
1056         chomp $summary;
1057         return substr($summary, 0, 80) . "\n";
1058 }
1059
1060
1061 # Print a one-line summary of each hunk in the array ref in
1062 # the first argument, starting wih the index in the 2nd.
1063 sub display_hunks {
1064         my ($hunks, $i) = @_;
1065         my $ctr = 0;
1066         $i ||= 0;
1067         for (; $i < @$hunks && $ctr < 20; $i++, $ctr++) {
1068                 my $status = " ";
1069                 if (defined $hunks->[$i]{USE}) {
1070                         $status = $hunks->[$i]{USE} ? "+" : "-";
1071                 }
1072                 printf "%s%2d: %s",
1073                         $status,
1074                         $i + 1,
1075                         summarize_hunk($hunks->[$i]);
1076         }
1077         return $i;
1078 }
1079
1080 sub patch_update_file {
1081         my $quit = 0;
1082         my ($ix, $num);
1083         my $path = shift;
1084         my ($head, @hunk) = parse_diff($path);
1085         ($head, my $mode) = parse_diff_header($head);
1086         for (@{$head->{DISPLAY}}) {
1087                 print;
1088         }
1089
1090         if (@{$mode->{TEXT}}) {
1091                 unshift @hunk, $mode;
1092         }
1093
1094         $num = scalar @hunk;
1095         $ix = 0;
1096
1097         while (1) {
1098                 my ($prev, $next, $other, $undecided, $i);
1099                 $other = '';
1100
1101                 if ($num <= $ix) {
1102                         $ix = 0;
1103                 }
1104                 for ($i = 0; $i < $ix; $i++) {
1105                         if (!defined $hunk[$i]{USE}) {
1106                                 $prev = 1;
1107                                 $other .= ',k';
1108                                 last;
1109                         }
1110                 }
1111                 if ($ix) {
1112                         $other .= ',K';
1113                 }
1114                 for ($i = $ix + 1; $i < $num; $i++) {
1115                         if (!defined $hunk[$i]{USE}) {
1116                                 $next = 1;
1117                                 $other .= ',j';
1118                                 last;
1119                         }
1120                 }
1121                 if ($ix < $num - 1) {
1122                         $other .= ',J';
1123                 }
1124                 if ($num > 1) {
1125                         $other .= ',g';
1126                 }
1127                 for ($i = 0; $i < $num; $i++) {
1128                         if (!defined $hunk[$i]{USE}) {
1129                                 $undecided = 1;
1130                                 last;
1131                         }
1132                 }
1133                 last if (!$undecided);
1134
1135                 if ($hunk[$ix]{TYPE} eq 'hunk' &&
1136                     hunk_splittable($hunk[$ix]{TEXT})) {
1137                         $other .= ',s';
1138                 }
1139                 if ($hunk[$ix]{TYPE} eq 'hunk') {
1140                         $other .= ',e';
1141                 }
1142                 for (@{$hunk[$ix]{DISPLAY}}) {
1143                         print;
1144                 }
1145                 print colored $prompt_color, 'Stage ',
1146                   ($hunk[$ix]{TYPE} eq 'mode' ? 'mode change' : 'this hunk'),
1147                   " [y,n,q,a,d,/$other,?]? ";
1148                 my $line = prompt_single_character;
1149                 if ($line) {
1150                         if ($line =~ /^y/i) {
1151                                 $hunk[$ix]{USE} = 1;
1152                         }
1153                         elsif ($line =~ /^n/i) {
1154                                 $hunk[$ix]{USE} = 0;
1155                         }
1156                         elsif ($line =~ /^a/i) {
1157                                 while ($ix < $num) {
1158                                         if (!defined $hunk[$ix]{USE}) {
1159                                                 $hunk[$ix]{USE} = 1;
1160                                         }
1161                                         $ix++;
1162                                 }
1163                                 next;
1164                         }
1165                         elsif ($other =~ /g/ && $line =~ /^g(.*)/) {
1166                                 my $response = $1;
1167                                 my $no = $ix > 10 ? $ix - 10 : 0;
1168                                 while ($response eq '') {
1169                                         my $extra = "";
1170                                         $no = display_hunks(\@hunk, $no);
1171                                         if ($no < $num) {
1172                                                 $extra = " (<ret> to see more)";
1173                                         }
1174                                         print "go to which hunk$extra? ";
1175                                         $response = <STDIN>;
1176                                         if (!defined $response) {
1177                                                 $response = '';
1178                                         }
1179                                         chomp $response;
1180                                 }
1181                                 if ($response !~ /^\s*\d+\s*$/) {
1182                                         error_msg "Invalid number: '$response'\n";
1183                                 } elsif (0 < $response && $response <= $num) {
1184                                         $ix = $response - 1;
1185                                 } else {
1186                                         error_msg "Sorry, only $num hunks available.\n";
1187                                 }
1188                                 next;
1189                         }
1190                         elsif ($line =~ /^d/i) {
1191                                 while ($ix < $num) {
1192                                         if (!defined $hunk[$ix]{USE}) {
1193                                                 $hunk[$ix]{USE} = 0;
1194                                         }
1195                                         $ix++;
1196                                 }
1197                                 next;
1198                         }
1199                         elsif ($line =~ /^q/i) {
1200                                 while ($ix < $num) {
1201                                         if (!defined $hunk[$ix]{USE}) {
1202                                                 $hunk[$ix]{USE} = 0;
1203                                         }
1204                                         $ix++;
1205                                 }
1206                                 $quit = 1;
1207                                 next;
1208                         }
1209                         elsif ($line =~ m|^/(.*)|) {
1210                                 my $regex = $1;
1211                                 if ($1 eq "") {
1212                                         print colored $prompt_color, "search for regex? ";
1213                                         $regex = <STDIN>;
1214                                         if (defined $regex) {
1215                                                 chomp $regex;
1216                                         }
1217                                 }
1218                                 my $search_string;
1219                                 eval {
1220                                         $search_string = qr{$regex}m;
1221                                 };
1222                                 if ($@) {
1223                                         my ($err,$exp) = ($@, $1);
1224                                         $err =~ s/ at .*git-add--interactive line \d+, <STDIN> line \d+.*$//;
1225                                         error_msg "Malformed search regexp $exp: $err\n";
1226                                         next;
1227                                 }
1228                                 my $iy = $ix;
1229                                 while (1) {
1230                                         my $text = join ("", @{$hunk[$iy]{TEXT}});
1231                                         last if ($text =~ $search_string);
1232                                         $iy++;
1233                                         $iy = 0 if ($iy >= $num);
1234                                         if ($ix == $iy) {
1235                                                 error_msg "No hunk matches the given pattern\n";
1236                                                 last;
1237                                         }
1238                                 }
1239                                 $ix = $iy;
1240                                 next;
1241                         }
1242                         elsif ($line =~ /^K/) {
1243                                 if ($other =~ /K/) {
1244                                         $ix--;
1245                                 }
1246                                 else {
1247                                         error_msg "No previous hunk\n";
1248                                 }
1249                                 next;
1250                         }
1251                         elsif ($line =~ /^J/) {
1252                                 if ($other =~ /J/) {
1253                                         $ix++;
1254                                 }
1255                                 else {
1256                                         error_msg "No next hunk\n";
1257                                 }
1258                                 next;
1259                         }
1260                         elsif ($line =~ /^k/) {
1261                                 if ($other =~ /k/) {
1262                                         while (1) {
1263                                                 $ix--;
1264                                                 last if (!$ix ||
1265                                                          !defined $hunk[$ix]{USE});
1266                                         }
1267                                 }
1268                                 else {
1269                                         error_msg "No previous hunk\n";
1270                                 }
1271                                 next;
1272                         }
1273                         elsif ($line =~ /^j/) {
1274                                 if ($other !~ /j/) {
1275                                         error_msg "No next hunk\n";
1276                                         next;
1277                                 }
1278                         }
1279                         elsif ($other =~ /s/ && $line =~ /^s/) {
1280                                 my @split = split_hunk($hunk[$ix]{TEXT}, $hunk[$ix]{DISPLAY});
1281                                 if (1 < @split) {
1282                                         print colored $header_color, "Split into ",
1283                                         scalar(@split), " hunks.\n";
1284                                 }
1285                                 splice (@hunk, $ix, 1, @split);
1286                                 $num = scalar @hunk;
1287                                 next;
1288                         }
1289                         elsif ($other =~ /e/ && $line =~ /^e/) {
1290                                 my $newhunk = edit_hunk_loop($head, \@hunk, $ix);
1291                                 if (defined $newhunk) {
1292                                         splice @hunk, $ix, 1, $newhunk;
1293                                 }
1294                         }
1295                         else {
1296                                 help_patch_cmd($other);
1297                                 next;
1298                         }
1299                         # soft increment
1300                         while (1) {
1301                                 $ix++;
1302                                 last if ($ix >= $num ||
1303                                          !defined $hunk[$ix]{USE});
1304                         }
1305                 }
1306         }
1307
1308         @hunk = coalesce_overlapping_hunks(@hunk);
1309
1310         my $n_lofs = 0;
1311         my @result = ();
1312         for (@hunk) {
1313                 if ($_->{USE}) {
1314                         push @result, @{$_->{TEXT}};
1315                 }
1316         }
1317
1318         if (@result) {
1319                 my $fh;
1320
1321                 open $fh, '| git apply --cached --recount';
1322                 for (@{$head->{TEXT}}, @result) {
1323                         print $fh $_;
1324                 }
1325                 if (!close $fh) {
1326                         for (@{$head->{TEXT}}, @result) {
1327                                 print STDERR $_;
1328                         }
1329                 }
1330                 refresh();
1331         }
1332
1333         print "\n";
1334         return $quit;
1335 }
1336
1337 sub diff_cmd {
1338         my @mods = list_modified('index-only');
1339         @mods = grep { !($_->{BINARY}) } @mods;
1340         return if (!@mods);
1341         my (@them) = list_and_choose({ PROMPT => 'Review diff',
1342                                      IMMEDIATE => 1,
1343                                      HEADER => $status_head, },
1344                                    @mods);
1345         return if (!@them);
1346         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
1347         system(qw(git diff -p --cached), $reference, '--',
1348                 map { $_->{VALUE} } @them);
1349 }
1350
1351 sub quit_cmd {
1352         print "Bye.\n";
1353         exit(0);
1354 }
1355
1356 sub help_cmd {
1357         print colored $help_color, <<\EOF ;
1358 status        - show paths with changes
1359 update        - add working tree state to the staged set of changes
1360 revert        - revert staged set of changes back to the HEAD version
1361 patch         - pick hunks and update selectively
1362 diff          - view diff between HEAD and index
1363 add untracked - add contents of untracked files to the staged set of changes
1364 EOF
1365 }
1366
1367 sub process_args {
1368         return unless @ARGV;
1369         my $arg = shift @ARGV;
1370         if ($arg eq "--patch") {
1371                 $patch_mode = 1;
1372                 $arg = shift @ARGV or die "missing --";
1373                 die "invalid argument $arg, expecting --"
1374                     unless $arg eq "--";
1375         }
1376         elsif ($arg ne "--") {
1377                 die "invalid argument $arg, expecting --";
1378         }
1379 }
1380
1381 sub main_loop {
1382         my @cmd = ([ 'status', \&status_cmd, ],
1383                    [ 'update', \&update_cmd, ],
1384                    [ 'revert', \&revert_cmd, ],
1385                    [ 'add untracked', \&add_untracked_cmd, ],
1386                    [ 'patch', \&patch_update_cmd, ],
1387                    [ 'diff', \&diff_cmd, ],
1388                    [ 'quit', \&quit_cmd, ],
1389                    [ 'help', \&help_cmd, ],
1390         );
1391         while (1) {
1392                 my ($it) = list_and_choose({ PROMPT => 'What now',
1393                                              SINGLETON => 1,
1394                                              LIST_FLAT => 4,
1395                                              HEADER => '*** Commands ***',
1396                                              ON_EOF => \&quit_cmd,
1397                                              IMMEDIATE => 1 }, @cmd);
1398                 if ($it) {
1399                         eval {
1400                                 $it->[1]->();
1401                         };
1402                         if ($@) {
1403                                 print "$@";
1404                         }
1405                 }
1406         }
1407 }
1408
1409 process_args();
1410 refresh();
1411 if ($patch_mode) {
1412         patch_update_cmd();
1413 }
1414 else {
1415         status_cmd();
1416         main_loop();
1417 }