src/commands/rsync

   1 #!/usr/bin/perl
   2 use strict;
   3 use warnings;
   4
   5 use lib $ENV{GL_LIBDIR};
   6 use Gitolite::Easy;
   7
   8 =for admins
   9
  10 BUNDLE SUPPORT
  11
  12     (1) For each repo in gitolite.conf for which you want bundle support (or
  13         '@all', if you wish), add the following line:
  14
  15             option bundle       =   1
  16
  17         Or you can say:
  18
  19             option bundle.ttl   =   <number>
  20
  21         A bundle file that is more than <number> seconds old (default value
  22         86400, i.e., 1 day) is recreated on the next bundle request.  Increase
  23         this if your repo is not terribly active.
  24
  25         Note: a bundle file is also deleted and recreated if it contains a ref
  26         that was then either deleted or rewound in the repo.  This is checked
  27         on every invocation.
  28
  29     (2) Add 'rsync' to the ENABLE list in the rc file
  30
  31
  32 GENERIC RSYNC SUPPORT
  33
  34     TBD
  35
  36 =cut
  37
  38 =for usage
  39 rsync helper for gitolite
  40
  41 BUNDLE SUPPORT
  42
  43     Admins: see src/commands/rsync for setup instructions
  44
  45     Users:
  46         rsync -P git@host:repo.bundle .
  47             # downloads a file called "<basename of repo>.bundle"; repeat as
  48             # needed till the whole thing is downloaded
  49         git clone repo.bundle repo
  50         cd repo
  51         git remote set-url origin git@host:repo
  52         git fetch origin    # and maybe git pull, etc. to freshen the clone
  53
  54 GENERIC RSYNC SUPPORT
  55
  56     TBD
  57
  58 =cut
  59
  60 usage() if not @ARGV or $ARGV[0] eq '-h';
  61
  62 # rsync driver program.  Several things can be done later, but for now it
  63 # drives just the 'bundle' transfer.
  64
  65 if ( $ENV{SSH_ORIGINAL_COMMAND} =~ /^rsync --server --sender (-[-\w=.]+ )+\. (\S+)\.bundle$/ ) {
  66
  67     my $repo = $2;
  68     $repo =~ s/\.git$//;
  69
  70     # all errors have the same message to avoid leaking info
  71     can_read($repo) or _die "you are not authorised";
  72     my %config = config( $repo, "gitolite-options.bundle" ) or _die "you are not authorised";
  73
  74     my $ttl = $config{'gitolite-options.bundle.ttl'} || 86400;    # in seconds (default 1 day)
  75
  76     my $bundle = bundle_create( $repo, $ttl );
  77
  78     $ENV{SSH_ORIGINAL_COMMAND} =~ s( \S+\.bundle)( $bundle);
  79     trace( 1, "rsync bundle", $ENV{SSH_ORIGINAL_COMMAND} );
  80     Gitolite::Common::_system( split ' ', $ENV{SSH_ORIGINAL_COMMAND} );
  81     exit 0;
  82 }
  83
  84 _warn "invalid rsync command '$ENV{SSH_ORIGINAL_COMMAND}'";
  85 usage();
  86
  87 # ----------------------------------------------------------------------
  88 # helpers
  89 # ----------------------------------------------------------------------
  90
  91 sub bundle_create {
  92     my ( $repo, $ttl ) = @_;
  93     my $bundle = "$repo.bundle";
  94     $bundle =~ s(.*/)();
  95     my $recreate = 0;
  96
  97     my ( %b, %r );
  98     if ( -f $bundle ) {
  99         %b = map { chomp; reverse split; } `git ls-remote --heads --tags $bundle`;
 100         %r = map { chomp; reverse split; } `git ls-remote --heads --tags .`;
 101
 102         for my $ref ( sort keys %b ) {
 103
 104             my $mtime = ( stat $bundle )[9];
 105             if ( time() - $mtime > $ttl ) {
 106                 trace( 1, "bundle too old" );
 107                 $recreate++;
 108                 last;
 109             }
 110
 111             if ( not $r{$ref} ) {
 112                 trace( 1, "ref '$ref' deleted in repo" );
 113                 $recreate++;
 114                 last;
 115             }
 116
 117             if ( $r{$ref} eq $b{$ref} ) {
 118                 # same on both sides; ignore
 119                 delete $r{$ref};
 120                 delete $b{$ref};
 121                 next;
 122             }
 123
 124             `git rev-list --count --left-right $b{$ref}...$r{$ref}` =~ /^(\d+)\s+(\d+)$/ or _die "git too old";
 125             if ($1) {
 126                 trace( 1, "ref '$ref' rewound in repo" );
 127                 $recreate++;
 128                 last;
 129             }
 130
 131         }
 132
 133     } else {
 134         trace( 1, "no bundle found" );
 135         $recreate++;
 136     }
 137
 138     return $bundle if not $recreate;
 139
 140     trace( 1, "creating bundle for '$repo'" );
 141     -f $bundle and ( unlink $bundle or die "a horrible death" );
 142     system("git bundle create $bundle --branches --tags >&2");
 143
 144     return $bundle;
 145 }
 146
 147 sub trace {
 148     Gitolite::Common::trace(@_);
 149 }