docs/reference/gobject/meson.build

   1 if get_option('with-docs') != 'no'
   2   subdir('xml')
   3
   4   ignore_headers = [
   5     'tests',
   6     'gatomicarray.h',
   7     'gobject_trace.h',
   8     'gtype-private.h'
   9   ]
  10
  11   docpath = join_paths(glib_datadir, 'gtk-doc', 'html')
  12   version_conf = configuration_data()
  13   version_conf.set('GLIB_VERSION', meson.project_version())
  14   configure_file(
  15     input: 'version.xml.in',
  16     output: 'version.xml',
  17     configuration: version_conf
  18   )
  19
  20   gnome.gtkdoc('gobject',
  21     main_xml : 'gobject-docs.xml',
  22     namespace : 'g',
  23     gobject_typesfile : join_paths(meson.current_source_dir(), 'gobject.types'),
  24     mode : 'none',
  25     dependencies : [libgobject_dep, libglib_dep],
  26     src_dir : 'gobject',
  27     scan_args : [
  28       '--deprecated-guards=G_DISABLE_DEPRECATED',
  29       '--ignore-decorators=G_GNUC_INTERNAL|G_GNUC_WARN_UNUSED_RESULT',
  30       '--ignore-headers=' + ' '.join(ignore_headers),
  31     ],
  32     content_files : [
  33       'glib-mkenums.xml',
  34       'glib-genmarshal.xml',
  35       'gobject-query.xml',
  36       'tut_gobject.xml',
  37       'tut_gsignal.xml',
  38       'tut_gtype.xml',
  39       'tut_howto.xml',
  40       'tut_intro.xml',
  41       'tut_tools.xml'
  42     ],
  43     html_assets : [
  44       'images/glue.png'
  45     ],
  46     fixxref_args: [
  47       '--html-dir=' + docpath,
  48       '--extra-dir=' + join_paths(meson.current_build_dir(), '../glib/html'),
  49     ],
  50     install: true
  51   )
  52 endif
  53
  54 if get_option('with-man') != 'no' and xsltproc.found()
  55   manpages = ['glib-mkenums', 'glib-genmarshal', 'gobject-query']
  56   foreach page : manpages
  57     custom_target(page + '-man',
  58       input: page + '.xml',
  59       output: page + '.1',
  60       command: xsltproc_command,
  61       install: true,
  62       install_dir: man1_dir)
  63   endforeach
  64 endif