| blob | 513cac83b3177f2e281f62859adc5ed67efd8886 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [57])
34 m4_define([glib_micro_version], [1])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 AC_ARG_ENABLE(mem_pools,
252 [AS_HELP_STRING([--disable-mem-pools],
253 [disable all glib memory pools])],,
254 [disable_mem_pools=no])
256 GLIB_TESTS
258 AC_MSG_CHECKING([whether to disable memory pools])
259 AS_IF([test "x$disable_mem_pools" = "xno"], [
260 AC_MSG_RESULT([no])
261 ], [
262 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
263 AC_MSG_RESULT([yes])
264 ])
266 dnl location to install runtime libraries, e.g. ../../lib to install
267 dnl to /lib if libdir is /usr/lib
268 AC_ARG_WITH(runtime-libdir,
269 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
270 [install runtime libraries relative to libdir])],
271 [],
272 [with_runtime_libdir=""])
273 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
274 AC_SUBST(GLIB_RUNTIME_LIBDIR)
275 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
277 dnl Check for a working C++ compiler, but do not bail out, if none is found.
278 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
279 AC_LANG_SAVE
280 AC_LANG_CPLUSPLUS
281 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
282 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
283 AC_LANG_RESTORE
285 AM_PROG_CC_C_O
286 AC_PROG_INSTALL
288 AC_SYS_LARGEFILE
290 PKG_PROG_PKG_CONFIG(0.16)
292 if test "x$enable_debug" = "xyes"; then
293 if test "x$cflags_set" != "x" ; then
294 case " $CFLAGS " in
295 *[[\ \ ]]-g[[\ \ ]]*) ;;
296 *) CFLAGS="$CFLAGS -g" ;;
297 esac
298 fi
299 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
300 else
301 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
303 if test "x$enable_debug" = "xno"; then
304 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
305 fi
306 fi
308 # Ensure MSVC-compatible struct packing convention is used when
309 # compiling for Win32 with gcc.
310 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
311 # gcc2 uses "-fnative-struct".
312 if test x"$glib_native_win32" = xyes; then
313 if test x"$GCC" = xyes; then
314 msnative_struct=''
315 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
316 if test -z "$ac_cv_prog_CC"; then
317 our_gcc="$CC"
318 else
319 our_gcc="$ac_cv_prog_CC"
320 fi
321 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
322 2.)
323 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
324 msnative_struct='-fnative-struct'
325 fi
326 ;;
327 *)
328 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
329 msnative_struct='-mms-bitfields'
330 fi
331 ;;
332 esac
333 if test x"$msnative_struct" = x ; then
334 AC_MSG_RESULT([no way])
335 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
336 else
337 CFLAGS="$CFLAGS $msnative_struct"
338 AC_MSG_RESULT([${msnative_struct}])
339 fi
340 fi
341 fi
342 GLIB_EXTRA_CFLAGS="${msnative_struct}"
343 AC_SUBST(GLIB_EXTRA_CFLAGS)
345 AC_EXEEXT
347 AC_PROG_AWK
348 AC_CHECK_PROGS(PERL, [perl5 perl])
350 # option to specify python interpreter to use; this just sets $PYTHON, so that
351 # we will fallback to reading $PYTHON if --with-python is not given, and
352 # python.m4 will get the expected input
353 AC_ARG_WITH(python,
354 AS_HELP_STRING([--with-python=PATH],
355 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
356 [PYTHON="$withval"], [])
357 if test x"$PYTHON" = xyes; then
358 AC_MSG_ERROR([--with-python option requires a path or program argument])
359 fi
360 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
363 dnl ***********************
364 dnl *** Tests for iconv ***
365 dnl ***********************
366 dnl
367 dnl We do this before the gettext checks, to avoid distortion
369 dnl On Windows we use a native implementation
371 AS_IF([ test x"$glib_native_win32" = xyes], [
372 with_libiconv=native
373 ], [
374 AC_ARG_WITH(libiconv,
375 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
376 [use the libiconv library])],,
377 [with_libiconv=maybe])
379 found_iconv=no
380 case $with_libiconv in
381 maybe)
382 # Check in the C library first
383 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
384 # Check if we have GNU libiconv
385 if test $found_iconv = "no"; then
386 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
387 fi
388 # Check if we have a iconv in -liconv, possibly from vendor
389 if test $found_iconv = "no"; then
390 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
391 fi
392 ;;
393 no)
394 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
395 ;;
396 gnu|yes)
397 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
398 ;;
399 native)
400 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
401 ;;
402 esac
404 if test "x$found_iconv" = "xno" ; then
405 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
406 fi
407 ])
409 dnl
410 dnl zlib support
411 dnl
412 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
413 AS_IF([test "x$found_zlib" = "xno"], [
414 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
415 if test "x$found_zlib" = "xno" ; then
416 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
417 fi
418 ZLIB_LIBS='-lz'
419 AC_SUBST(ZLIB_LIBS)
420 ])
422 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
423 AC_SUBST(LIBFFI_CFLAGS)
424 AC_SUBST(LIBFFI_LIBS)
426 dnl
427 dnl gettext support
428 dnl
430 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
431 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
432 GLIB_GNU_GETTEXT
434 if test "$gt_cv_have_gettext" != "yes" ; then
435 AC_MSG_ERROR([
436 *** You must have either have gettext support in your C library, or use the
437 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
438 ])
439 fi
441 LIBS="$INTLLIBS $LIBS"
443 GETTEXT_PACKAGE=glib20
444 AC_SUBST(GETTEXT_PACKAGE)
445 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
446 [Define the gettext package to be used])
448 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
450 dnl
451 dnl Now we are done with gettext checks, figure out ICONV_LIBS
452 dnl
454 AS_IF([test x"$glib_native_win32" != xyes], [
455 if test x$with_libiconv != xno ; then
456 case " $INTLLIBS " in
457 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
458 *) ICONV_LIBS="-liconv" ;;
459 esac
460 fi
461 ])
462 AC_SUBST(ICONV_LIBS)
464 case $with_libiconv in
465 gnu)
466 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
467 ;;
468 native)
469 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
470 ;;
471 esac
473 dnl Initialize libtool
474 LT_PREREQ([2.2])
475 LT_INIT([disable-static win32-dll])
476 dnl when using libtool 2.x create libtool early, because it's used in configure
477 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
480 AS_IF([test "$glib_native_win32" = "yes"], [
481 if test x$enable_static = xyes -a x$enable_shared = xyes; then
482 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
483 fi
484 if test x$enable_static = xyes; then
485 glib_win32_static_compilation=yes
486 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
487 #define GOBJECT_STATIC_COMPILATION 1"
488 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
489 fi
490 ])
491 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
493 # Checks for library functions.
494 AC_FUNC_ALLOCA
495 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
496 AC_CHECK_FUNCS(timegm gmtime_r)
497 AC_FUNC_STRERROR_R()
499 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
500 [AC_TRY_LINK([#include <unistd.h>
501 extern int __libc_enable_secure;],
502 [return __libc_enable_secure;],
503 glib_cv_have_libc_enable_secure=yes,
504 glib_cv_have_libc_enable_secure=no)])
505 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
506 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
507 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
508 ])
510 AC_CHECK_SIZEOF(char)
511 AC_CHECK_SIZEOF(short)
512 AC_CHECK_SIZEOF(long)
513 AC_CHECK_SIZEOF(int)
514 AC_CHECK_SIZEOF(void *)
515 AC_CHECK_SIZEOF(long long)
516 AC_CHECK_SIZEOF(__int64)
518 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
519 [AC_TRY_LINK([#include <signal.h>
520 #include <sys/types.h>
521 sig_atomic_t val = 42;],
522 [return val == 42 ? 0 : 1],
523 ac_cv_type_sig_atomic_t=yes,
524 ac_cv_type_sig_atomic_t=no)])
525 if test x$ac_cv_type_sig_atomic_t = xyes; then
526 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
527 [Define if you have the 'sig_atomic_t' type.])
528 fi
530 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
531 :
532 else
533 AC_MSG_ERROR([
534 *** GLib requires a 64 bit type. You might want to consider
535 *** using the GNU C compiler.
536 ])
537 fi
539 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
540 # long long is a 64 bit integer.
541 AC_MSG_CHECKING(for format to printf and scanf a guint64)
542 AC_CACHE_VAL(glib_cv_long_long_format,[
543 for format in ll q I64; do
544 AC_TRY_RUN([#include <stdio.h>
545 int main()
546 {
547 long long b, a = -0x3AFAFAFAFAFAFAFALL;
548 char buffer[1000];
549 sprintf (buffer, "%${format}u", a);
550 sscanf (buffer, "%${format}u", &b);
551 exit (b!=a);
552 }
553 ],
554 [glib_cv_long_long_format=${format}
555 break],
556 [],[:])
557 done])
558 AS_IF([ test -n "$glib_cv_long_long_format"], [
559 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
560 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
561 if test x"$glib_cv_long_long_format" = xI64; then
562 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
563 fi
564 ], [AC_MSG_RESULT(none)])
565 ],[ test x$ac_cv_sizeof___int64 = x8], [
566 # __int64 is a 64 bit integer.
567 AC_MSG_CHECKING(for format to printf and scanf a guint64)
568 # We know this is MSVCRT.DLL, and what the formats are
569 glib_cv_long_long_format=I64
570 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
571 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
572 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
573 ])
575 AC_C_CONST
577 dnl
578 dnl check in which direction the stack grows
579 dnl
580 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
581 AC_TRY_RUN([
582 volatile int *a = 0, *b = 0;
583 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
584 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
585 ],
586 glib_cv_stack_grows=yes
587 ,
588 glib_cv_stack_grows=no
589 ,)
590 ])
592 # check for flavours of varargs macros
593 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
594 AC_TRY_COMPILE([],[
595 int a(int p1, int p2, int p3);
596 #define call_a(...) a(1,__VA_ARGS__)
597 call_a(2,3);
598 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
599 AC_MSG_RESULT($g_have_iso_c_varargs)
601 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
602 AS_IF([test "$CXX" = ""], [
603 dnl No C++ compiler
604 g_have_iso_cxx_varargs=no
605 else
606 AC_LANG_CPLUSPLUS
607 AC_TRY_COMPILE([],[
608 int a(int p1, int p2, int p3);
609 #define call_a(...) a(1,__VA_ARGS__)
610 call_a(2,3);
611 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
612 AC_LANG_C
613 ])
614 AC_MSG_RESULT($g_have_iso_cxx_varargs)
616 AC_MSG_CHECKING(for GNUC varargs macros)
617 AC_TRY_COMPILE([],[
618 int a(int p1, int p2, int p3);
619 #define call_a(params...) a(1,params)
620 call_a(2,3);
621 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
622 AC_MSG_RESULT($g_have_gnuc_varargs)
624 # check for GNUC visibility support
625 AC_MSG_CHECKING(for GNUC visibility attribute)
626 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
627 void
628 __attribute__ ((visibility ("hidden")))
629 f_hidden (void)
630 {
631 }
632 void
633 __attribute__ ((visibility ("internal")))
634 f_internal (void)
635 {
636 }
637 void
638 __attribute__ ((visibility ("protected")))
639 f_protected (void)
640 {
641 }
642 void
643 __attribute__ ((visibility ("default")))
644 f_default (void)
645 {
646 }
647 int main (void)
648 {
649 f_hidden();
650 f_internal();
651 f_protected();
652 f_default();
653 return 0;
654 }
655 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
656 AC_MSG_RESULT($g_have_gnuc_visibility)
657 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
659 AC_MSG_CHECKING([whether using Sun Studio C compiler])
660 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
661 #else
662 # include "error: this is not Sun Studio."
663 #endif
664 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
665 AC_MSG_RESULT($g_have_sunstudio_visibility)
666 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
668 # check for bytesex stuff
669 AC_C_BIGENDIAN
670 if test x$ac_cv_c_bigendian = xuniversal ; then
671 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
672 fi
675 # check for header files
676 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
677 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
678 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
679 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
680 AC_CHECK_HEADERS([linux/magic.h])
681 AC_CHECK_HEADERS([termios.h])
683 # Some versions of MSC lack these
684 AC_CHECK_HEADERS([dirent.h sys/time.h])
686 # We don't care about this, but we need to keep including it in
687 # glibconfig.h for backward compatibility
688 AC_CHECK_HEADERS([values.h])
690 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
691 [#if HAVE_SYS_PARAM_H
692 #include <sys/param.h>
693 #endif
694 ])
695 AC_CHECK_FUNCS(sysctlbyname)
697 AC_HEADER_MAJOR
698 AC_CHECK_HEADERS([xlocale.h])
700 # check for structure fields
701 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
702 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
703 #include <sys/stat.h>
704 #ifdef G_OS_UNIX
705 #include <unistd.h>
706 #endif
707 #ifdef HAVE_SYS_STATFS_H
708 #include <sys/statfs.h>
709 #endif
710 #ifdef HAVE_SYS_PARAM_H
711 #include <sys/param.h>
712 #endif
713 #ifdef HAVE_SYS_MOUNT_H
714 #include <sys/mount.h>
715 #endif])
716 # struct statvfs.f_basetype is available on Solaris but not for Linux.
717 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
718 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
719 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
721 AC_STRUCT_DIRENT_D_TYPE
723 # Checks for libcharset
724 AM_LANGINFO_CODESET
725 gl_GLIBC21
726 AC_ARG_WITH(charsetalias-dir,
727 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
728 [],
729 [with_charsetalias_dir='${libdir}'])
730 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
731 AC_SUBST(GLIB_CHARSETALIAS_DIR)
733 # check additional type sizes
734 AC_CHECK_SIZEOF(size_t)
736 dnl Try to figure out whether gsize should be long or int
737 AC_MSG_CHECKING([for the appropriate definition for size_t])
739 case $ac_cv_sizeof_size_t in
740 $ac_cv_sizeof_short)
741 glib_size_type=short
742 ;;
743 $ac_cv_sizeof_int)
744 glib_size_type=int
745 ;;
746 $ac_cv_sizeof_long)
747 glib_size_type=long
748 ;;
749 $ac_cv_sizeof_long_long)
750 glib_size_type='long long'
751 ;;
752 $ac_cv_sizeof__int64)
753 glib_size_type='__int64'
754 ;;
755 *) AC_MSG_ERROR([No type matching size_t in size])
756 ;;
757 esac
759 dnl If int/long are the same size, we see which one produces
760 dnl warnings when used in the location as size_t. (This matters
761 dnl on AIX with xlc)
762 dnl
763 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
764 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
765 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
766 #if defined(_AIX) && !defined(__GNUC__)
767 #pragma options langlvl=stdc89
768 #endif
769 #include <stddef.h>
770 int main ()
771 {
772 size_t s = 1;
773 unsigned int *size_int = &s;
774 return (int)*size_int;
775 }
776 ]])],glib_size_type=int,
777 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
778 #if defined(_AIX) && !defined(__GNUC__)
779 #pragma options langlvl=stdc89
780 #endif
781 #include <stddef.h>
782 int main ()
783 {
784 size_t s = 1;
785 unsigned long *size_long = &s;
786 return (int)*size_long;
787 }
788 ]])],glib_size_type=long)])
789 ])
791 AC_MSG_RESULT(unsigned $glib_size_type)
793 AC_CHECK_SIZEOF(ssize_t)
795 dnl Try to figure out whether gssize should be long or int
796 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
798 case $ac_cv_sizeof_ssize_t in
799 $ac_cv_sizeof_short)
800 glib_ssize_type=short
801 ;;
802 $ac_cv_sizeof_int)
803 glib_ssize_type=int
804 ;;
805 $ac_cv_sizeof_long)
806 glib_ssize_type=long
807 ;;
808 $ac_cv_sizeof_long_long)
809 glib_ssize_type='long long'
810 ;;
811 $ac_cv_sizeof__int64)
812 glib_ssize_type='__int64'
813 ;;
814 *) AC_MSG_ERROR([No type matching ssize_t in size])
815 ;;
816 esac
818 dnl If int/long are the same size, we see which one produces
819 dnl warnings when used in the location as ssize_t. (This matters
820 dnl on Android where ssize_t is long and size_t is unsigned int)
821 dnl
822 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
823 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
824 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
825 #if defined(_AIX) && !defined(__GNUC__)
826 #pragma options langlvl=stdc89
827 #endif
828 #include <stddef.h>
829 #ifdef HAVE_INTTYPES_H
830 # include <inttypes.h>
831 #endif
832 #ifdef HAVE_STDINT_H
833 # include <stdint.h>
834 #endif
835 #include <sys/types.h>
836 int main ()
837 {
838 ssize_t s = 1;
839 int *size_int = &s;
840 return (int)*size_int;
841 }
842 ]])],glib_ssize_type=int,
843 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
844 #if defined(_AIX) && !defined(__GNUC__)
845 #pragma options langlvl=stdc89
846 #endif
847 #include <stddef.h>
848 #ifdef HAVE_INTTYPES_H
849 # include <inttypes.h>
850 #endif
851 #ifdef HAVE_STDINT_H
852 # include <stdint.h>
853 #endif
854 #include <sys/types.h>
855 int main ()
856 {
857 ssize_t s = 1;
858 long *size_long = &s;
859 return (int)*size_long;
860 }
861 ]])],glib_ssize_type=long)])
862 ])
864 AC_MSG_RESULT($glib_ssize_type)
866 # Check for some functions
867 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
868 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
869 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
870 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
871 AC_CHECK_FUNCS(splice)
872 AC_CHECK_FUNCS(prlimit)
874 # To avoid finding a compatibility unusable statfs, which typically
875 # successfully compiles, but warns to use the newer statvfs interface:
876 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
877 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
879 AC_MSG_CHECKING([whether to use statfs or statvfs])
880 # Some systems have both statfs and statvfs, pick the most "native" for these
881 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
882 [
883 # on solaris and irix, statfs doesn't even have the f_bavail field
884 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
885 [ac_cv_func_statfs=no],
886 # else, at least on linux, statfs is the actual syscall
887 [ac_cv_func_statvfs=no])
888 ])
890 AS_IF([test x$ac_cv_func_statfs = xyes],
891 [
892 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
893 AC_MSG_RESULT([statfs])
894 ],
895 [test x$ac_cv_func_statvfs = xyes],
896 [
897 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
898 AC_MSG_RESULT([statvfs])
899 ],
900 [ AC_MSG_RESULT([neither])])
902 AC_CHECK_HEADERS(crt_externs.h)
903 AC_CHECK_FUNCS(_NSGetEnviron)
905 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
907 # Internet address families
908 if test $glib_native_win32 = yes; then
909 glib_inet_includes=["
910 #include <winsock2.h>
911 "]
912 else
913 glib_inet_includes=["
914 #include <sys/types.h>
915 #include <sys/socket.h>
916 "]
917 fi
919 glib_failed=false
920 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
921 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
922 # winsock defines this even though it doesn't support it
923 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
924 if $glib_failed ; then
925 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
926 fi
928 glib_failed=false
929 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
930 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
931 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
932 if $glib_failed ; then
933 AC_MSG_ERROR([Could not determine values for MSG_* constants])
934 fi
936 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
938 AC_MSG_CHECKING([for SIOCGIFADDR])
939 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
940 [[
941 #include <sys/ioctl.h>
942 #include <net/if.h>
943 ]],
944 [[
945 struct ifreq ifr;
946 ioctl(0, SIOCGIFADDR, &ifr);
947 ]])], [
948 AC_MSG_RESULT(yes)
949 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
950 ], [
951 AC_MSG_RESULT(no)
952 ])
954 AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
955 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
956 [[
957 #include <netinet/in.h>
958 ]],
959 [[
960 struct ip_mreq_source mc_req_src;
961 mc_req_src.imr_interface.s_addr = 0;
962 ]])], [
963 AC_MSG_RESULT(yes)
964 ], [
965 AC_MSG_RESULT(no)
966 AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
967 ])
969 AS_IF([test $glib_native_win32 = yes], [
970 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
971 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
972 # they aren't present at run-time (on Windows 2000).
973 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
974 AC_SUBST(WSPIAPI_INCLUDE)
975 ], [
976 # Android does not have C_IN in public headers, we define it wherever necessary
977 AS_IF([test $glib_native_android != yes], [
978 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
979 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
980 #include <arpa/nameser.h>],
981 [int qclass = C_IN;])],
982 [AC_MSG_RESULT([no])],
983 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
984 #include <arpa/nameser.h>
985 #include <arpa/nameser_compat.h>],
986 [int qclass = C_IN;])],
987 [AC_MSG_RESULT([yes])
988 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
989 [AC_MSG_ERROR([could not compile test program either way])])])])
990 AC_SUBST(NAMESER_COMPAT_INCLUDE)
992 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
993 NETWORK_LIBS=""
994 AC_MSG_CHECKING([for res_query])
995 AC_TRY_LINK([#include <sys/types.h>
996 #include <netinet/in.h>
997 #include <arpa/nameser.h>
998 #include <resolv.h>
999 ],[
1000 res_query("test", 0, 0, (void *)0, 0);
1001 ],[AC_MSG_RESULT([yes])],
1002 [save_libs="$LIBS"
1003 LIBS="-lresolv $LIBS"
1004 AC_TRY_LINK([#include <sys/types.h>
1005 #include <netinet/in.h>
1006 #include <arpa/nameser.h>
1007 #include <resolv.h>
1008 ],[
1009 res_query("test", 0, 0, (void *)0, 0);
1010 ],[AC_MSG_RESULT([in -lresolv])
1011 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1012 [LIBS="-lbind $save_libs"
1013 AC_TRY_LINK([#include <resolv.h>],
1014 [res_query("test", 0, 0, (void *)0, 0);],
1015 [AC_MSG_RESULT([in -lbind])
1016 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1017 [AC_MSG_ERROR(not found)])])
1018 LIBS="$save_libs"])
1019 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1020 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1021 [AC_MSG_ERROR(Could not find socket())]))
1022 save_libs="$LIBS"
1023 LIBS="$LIBS $NETWORK_LIBS"
1025 AC_MSG_CHECKING([for res_init])
1026 AC_TRY_LINK([#include <sys/types.h>
1027 #include <netinet/in.h>
1028 #include <arpa/nameser.h>
1029 #include <resolv.h>
1030 ],[
1031 res_init();
1032 ],[AC_MSG_RESULT([yes])
1033 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1034 ],[AC_MSG_RESULT([no])])
1036 AC_MSG_CHECKING([for res_nclose])
1037 AC_TRY_LINK([#include <sys/types.h>
1038 #include <netinet/in.h>
1039 #include <arpa/nameser.h>
1040 #include <resolv.h>
1041 ],[
1042 struct __res_state res;
1043 res_nclose(&res);
1044 ],[AC_MSG_RESULT([yes])
1045 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1046 ],[AC_MSG_RESULT([no])])
1048 AC_MSG_CHECKING([for res_ndestroy])
1049 AC_TRY_LINK([#include <sys/types.h>
1050 #include <netinet/in.h>
1051 #include <arpa/nameser.h>
1052 #include <resolv.h>
1053 ],[
1054 struct __res_state res;
1055 res_ndestroy(&res);
1056 ],[AC_MSG_RESULT([yes])
1057 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1058 ],[AC_MSG_RESULT([no])])
1060 AC_MSG_CHECKING([for res_ninit])
1061 AC_TRY_LINK([#include <sys/types.h>
1062 #include <netinet/in.h>
1063 #include <arpa/nameser.h>
1064 #include <resolv.h>
1065 ],[
1066 struct __res_state res;
1067 res_ninit(&res);
1068 ],[AC_MSG_RESULT([yes])
1069 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1070 ],[AC_MSG_RESULT([no])])
1072 AC_MSG_CHECKING([for res_nquery])
1073 AC_TRY_LINK([#include <sys/types.h>
1074 #include <netinet/in.h>
1075 #include <arpa/nameser.h>
1076 #include <resolv.h>
1077 ],[
1078 struct __res_state res;
1079 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1080 ],[AC_MSG_RESULT([yes])
1081 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1082 ],[AC_MSG_RESULT([no])])
1083 LIBS="$save_libs"
1084 ])
1085 AC_SUBST(NETWORK_LIBS)
1087 AC_CHECK_HEADER([linux/netlink.h],
1088 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1089 [#include <sys/socket.h>])
1090 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1092 AC_CHECK_TYPE([struct ip_mreqn], [
1093 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1094 [#include <netinet/in.h>])
1096 case $host in
1097 *-*-solaris* )
1098 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1099 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1100 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1101 ;;
1102 esac
1104 dnl
1105 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1106 dnl
1107 AS_IF([test "$ac_cv_func_statfs" = yes], [
1108 AC_MSG_CHECKING([number of arguments to statfs()])
1109 AC_TRY_COMPILE([#include <unistd.h>
1110 #ifdef HAVE_SYS_PARAM_H
1111 #include <sys/param.h>
1112 #endif
1113 #ifdef HAVE_SYS_VFS_H
1114 #include <sys/vfs.h>
1115 #endif
1116 #ifdef HAVE_SYS_MOUNT_H
1117 #include <sys/mount.h>
1118 #endif
1119 #ifdef HAVE_SYS_STATFS_H
1120 #include <sys/statfs.h>
1121 #endif], [struct statfs st;
1122 statfs("/", &st);],[
1123 AC_MSG_RESULT([2])
1124 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1125 AC_TRY_COMPILE([#include <unistd.h>
1126 #ifdef HAVE_SYS_PARAM_H
1127 #include <sys/param.h>
1128 #endif
1129 #ifdef HAVE_SYS_VFS_H
1130 #include <sys/vfs.h>
1131 #endif
1132 #ifdef HAVE_SYS_MOUNT_H
1133 #include <sys/mount.h>
1134 #endif
1135 #ifdef HAVE_SYS_STATFS_H
1136 #include <sys/statfs.h>
1137 #endif], [struct statfs st;
1138 statfs("/", &st, sizeof (st), 0);],[
1139 AC_MSG_RESULT([4])
1140 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1141 AC_MSG_RESULT(unknown)
1142 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1143 ])
1145 dnl
1146 dnl open takes O_DIRECTORY as an option
1147 dnl
1148 AC_MSG_CHECKING([open() option O_DIRECTORY])
1149 AC_TRY_COMPILE([#include <fcntl.h>
1150 #include <sys/types.h>
1151 #include <sys/stat.h>],
1152 [open(0, O_DIRECTORY, 0);],[
1153 AC_MSG_RESULT([yes])
1154 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1155 AC_MSG_RESULT([no])])
1157 #
1158 # Check whether to use an included printf
1159 #
1160 AC_FUNC_VSNPRINTF_C99
1161 AC_FUNC_PRINTF_UNIX98
1163 AC_ARG_ENABLE(included-printf,
1164 [AS_HELP_STRING([--enable-included-printf],
1165 [use included printf [default=auto]])],
1166 enable_included_printf="$enableval")
1168 need_included_printf=no
1169 if test "x$enable_included_printf" = "xyes" ; then
1170 need_included_printf=yes
1171 fi
1172 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1173 need_included_printf=yes
1174 fi
1175 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1176 need_included_printf=yes
1177 fi
1178 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1179 test -z "$glib_cv_long_long_format" ; then
1180 need_included_printf=yes
1181 fi
1183 if test "x$enable_included_printf" = "xno" &&
1184 test "x$need_included_printf" = "xyes" ; then
1185 AC_MSG_ERROR([
1186 *** Your C library's printf doesn't appear to have the features that
1187 *** GLib needs, but you specified --enable-included-printf=no.])
1188 fi
1190 enable_included_printf=$need_included_printf
1192 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1193 AS_IF([test "$enable_included_printf" != "yes"], [
1194 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1195 ], [
1196 if test -z "$glib_cv_long_long_format" ; then
1197 glib_cv_long_long_format="ll"
1198 fi
1199 AC_DEFINE(HAVE_VASPRINTF,1)
1200 ])
1202 # Checks needed for gnulib vasnprintf
1203 bh_C_SIGNED
1204 jm_AC_TYPE_LONG_LONG
1205 gt_TYPE_LONGDOUBLE
1206 gt_TYPE_WCHAR_T
1207 gt_TYPE_WINT_T
1208 AC_TYPE_SIZE_T
1209 AC_CHECK_TYPES(ptrdiff_t)
1210 jm_AC_TYPE_INTMAX_T
1211 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1212 AC_FUNC_SNPRINTF_C99
1214 # Check if <sys/select.h> needs to be included for fd_set
1215 AC_MSG_CHECKING([for fd_set])
1216 AC_TRY_COMPILE([#include <sys/types.h>],
1217 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1218 AS_IF([test "$gtk_ok" = "yes"], [
1219 AC_MSG_RESULT([yes, found in sys/types.h])
1220 ], [
1221 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1222 if test "$gtk_ok" = "yes"; then
1223 # *** FIXME: give it a different name
1224 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1225 AC_MSG_RESULT([yes, found in sys/select.h])
1226 else
1227 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1228 AC_MSG_RESULT(no)
1229 fi
1230 ])
1232 dnl Check for nl_langinfo and CODESET
1233 AC_LANG_SAVE
1234 AC_LANG_C
1235 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1236 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1237 [char *codeset = nl_langinfo (CODESET);])],
1238 [glib_cv_langinfo_codeset=yes],
1239 [glib_cv_langinfo_codeset=no])])
1240 if test x$glib_cv_langinfo_codeset = xyes; then
1241 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1242 fi
1244 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1245 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1246 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1247 [char *str;
1248 str = nl_langinfo (PM_STR);
1249 str = nl_langinfo (D_T_FMT);
1250 str = nl_langinfo (D_FMT);
1251 str = nl_langinfo (T_FMT);
1252 str = nl_langinfo (T_FMT_AMPM);
1253 str = nl_langinfo (MON_1);
1254 str = nl_langinfo (ABMON_12);
1255 str = nl_langinfo (DAY_1);
1256 str = nl_langinfo (ABDAY_7);])],
1257 [glib_cv_langinfo_time=yes],
1258 [glib_cv_langinfo_time=no])])
1259 if test x$glib_cv_langinfo_time = xyes; then
1260 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1261 fi
1263 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1264 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1265 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1266 [char *str;
1267 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1268 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1269 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1270 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1271 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1272 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1273 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1274 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1275 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1276 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1277 [glib_cv_langinfo_outdigit=yes],
1278 [glib_cv_langinfo_outdigit=no])])
1279 if test x$glib_cv_langinfo_outdigit = xyes; then
1280 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1281 fi
1283 dnl Check for nl_langinfo and ALTMON_n
1284 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1285 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1286 [char *str;
1287 str = nl_langinfo (ALTMON_1);
1288 str = nl_langinfo (ALTMON_2);
1289 str = nl_langinfo (ALTMON_3);
1290 str = nl_langinfo (ALTMON_4);
1291 str = nl_langinfo (ALTMON_5);
1292 str = nl_langinfo (ALTMON_6);
1293 str = nl_langinfo (ALTMON_7);
1294 str = nl_langinfo (ALTMON_8);
1295 str = nl_langinfo (ALTMON_9);
1296 str = nl_langinfo (ALTMON_10);
1297 str = nl_langinfo (ALTMON_11);
1298 str = nl_langinfo (ALTMON_12);])],
1299 [glib_cv_langinfo_altmon=yes],
1300 [glib_cv_langinfo_altmon=no])])
1301 if test x$glib_cv_langinfo_altmon = xyes; then
1302 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1303 fi
1305 dnl Check for nl_langinfo and _NL_ABALTMON_n
1306 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1307 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1308 [char *str;
1309 str = nl_langinfo (_NL_ABALTMON_1);
1310 str = nl_langinfo (_NL_ABALTMON_2);
1311 str = nl_langinfo (_NL_ABALTMON_3);
1312 str = nl_langinfo (_NL_ABALTMON_4);
1313 str = nl_langinfo (_NL_ABALTMON_5);
1314 str = nl_langinfo (_NL_ABALTMON_6);
1315 str = nl_langinfo (_NL_ABALTMON_7);
1316 str = nl_langinfo (_NL_ABALTMON_8);
1317 str = nl_langinfo (_NL_ABALTMON_9);
1318 str = nl_langinfo (_NL_ABALTMON_10);
1319 str = nl_langinfo (_NL_ABALTMON_11);
1320 str = nl_langinfo (_NL_ABALTMON_12);])],
1321 [glib_cv_langinfo_abaltmon=yes],
1322 [glib_cv_langinfo_abaltmon=no])])
1323 if test x$glib_cv_langinfo_abaltmon = xyes; then
1324 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1325 fi
1326 AC_LANG_RESTORE
1328 dnl ****************************************
1329 dnl *** posix_memalign ***
1330 dnl ****************************************
1331 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1332 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1333 glib_cv_compliant_posix_memalign=0
1334 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1335 AC_TRY_RUN([
1336 #define _XOPEN_SOURCE 600
1337 #include <stdlib.h> /* posix_memalign() should be defined here */
1338 /* some systems break if #include <malloc.h> used */
1339 static void test_memalign (size_t boundary, size_t size) {
1340 void *mem = 0;
1341 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1342 exit (1);
1343 else
1344 free (mem);
1345 }
1346 int main() {
1347 test_memalign ( 128, 128 - 2 * sizeof (void*));
1348 test_memalign ( 256, 256 - 2 * sizeof (void*));
1349 test_memalign ( 512, 512 - 2 * sizeof (void*));
1350 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1351 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1352 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1353 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1354 test_memalign (16384, 16384 - 2 * sizeof (void*));
1355 test_memalign (32768, 32768 - 2 * sizeof (void*));
1356 exit (0); /* success */
1357 }
1358 ],
1359 [glib_cv_compliant_posix_memalign=1], [], [:])
1360 :
1361 fi
1362 ])
1363 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1364 AC_MSG_RESULT(yes)
1365 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1366 ], [
1367 AC_MSG_RESULT(no)
1368 ])
1371 dnl ****************************************
1372 dnl *** strlcpy/strlcat ***
1373 dnl ****************************************
1374 # Check for strlcpy
1375 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1376 AC_TRY_RUN([#include <stdlib.h>
1377 #include <string.h>
1378 int main() {
1379 char p[10];
1380 (void) strlcpy (p, "hi", 10);
1381 if (strlcat (p, "bye", 0) != 3)
1382 return 1;
1383 return 0;
1384 }], glib_cv_have_strlcpy=yes,
1385 glib_cv_have_strlcpy=no,
1386 glib_cv_have_strlcpy=no)])
1387 if test "$glib_cv_have_strlcpy" = "yes"; then
1388 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1389 fi
1392 dnl **********************
1393 dnl *** va_copy checks ***
1394 dnl **********************
1395 dnl we currently check for all three va_copy possibilities, so we get
1396 dnl all results in config.log for bug reports.
1397 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1398 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1399 #include <stdlib.h>
1400 void f (int i, ...) {
1401 va_list args1, args2;
1402 va_start (args1, i);
1403 va_copy (args2, args1);
1404 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1405 exit (1);
1406 va_end (args1); va_end (args2);
1407 }
1408 int main() {
1409 f (0, 42);
1410 return 0;
1411 }]])],
1412 [glib_cv_va_copy=yes],
1413 [glib_cv_va_copy=no])
1414 ])
1415 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1416 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1417 #include <stdlib.h>
1418 void f (int i, ...) {
1419 va_list args1, args2;
1420 va_start (args1, i);
1421 __va_copy (args2, args1);
1422 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1423 exit (1);
1424 va_end (args1); va_end (args2);
1425 }
1426 int main() {
1427 f (0, 42);
1428 return 0;
1429 }]])],
1430 [glib_cv___va_copy=yes],
1431 [glib_cv___va_copy=no])
1432 ])
1434 if test "x$glib_cv_va_copy" = "xyes"; then
1435 g_va_copy_func=va_copy
1436 else if test "x$glib_cv___va_copy" = "xyes"; then
1437 g_va_copy_func=__va_copy
1438 fi
1439 fi
1441 if test -n "$g_va_copy_func"; then
1442 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1443 fi
1445 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1446 AC_TRY_RUN([#include <stdarg.h>
1447 #include <stdlib.h>
1448 void f (int i, ...) {
1449 va_list args1, args2;
1450 va_start (args1, i);
1451 args2 = args1;
1452 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1453 exit (1);
1454 va_end (args1); va_end (args2);
1455 }
1456 int main() {
1457 f (0, 42);
1458 return 0;
1459 }],
1460 [glib_cv_va_val_copy=yes],
1461 [glib_cv_va_val_copy=no],
1462 [glib_cv_va_val_copy=yes])
1463 ])
1465 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1466 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1467 ])
1469 dnl ***********************
1470 dnl *** g_module checks ***
1471 dnl ***********************
1472 G_MODULE_LIBS=
1473 G_MODULE_LIBS_EXTRA=
1474 G_MODULE_PLUGIN_LIBS=
1475 if test x"$glib_native_win32" = xyes; then
1476 dnl No use for this on Win32
1477 G_MODULE_LDFLAGS=
1478 else
1479 export SED
1480 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1481 fi
1482 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1483 G_MODULE_NEED_USCORE=0
1484 G_MODULE_BROKEN_RTLD_GLOBAL=0
1485 G_MODULE_HAVE_DLERROR=0
1486 dnl *** force native WIN32 shared lib loader
1487 if test -z "$G_MODULE_IMPL"; then
1488 case "$host" in
1489 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1490 esac
1491 fi
1492 dnl *** force native AIX library loader
1493 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1494 if test -z "$G_MODULE_IMPL"; then
1495 case "$host" in
1496 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1497 esac
1498 fi
1499 dnl *** dlopen() and dlsym() in system libraries
1500 AS_IF([ test -z "$G_MODULE_IMPL"], [
1501 AC_CHECK_FUNC(dlopen,
1502 [AC_CHECK_FUNC(dlsym,
1503 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1504 [])
1505 ])
1506 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1507 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1508 AC_CHECK_FUNC(NSLinkModule,
1509 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1510 G_MODULE_NEED_USCORE=1],
1511 [])
1512 ])
1513 dnl *** dlopen() and dlsym() in libdl
1514 AS_IF([ test -z "$G_MODULE_IMPL"], [
1515 AC_CHECK_LIB(dl, dlopen,
1516 [AC_CHECK_LIB(dl, dlsym,
1517 [G_MODULE_LIBS=-ldl
1518 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1519 [])
1520 ])
1521 dnl *** additional checks for G_MODULE_IMPL_DL
1522 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1523 LIBS_orig="$LIBS"
1524 LDFLAGS_orig="$LDFLAGS"
1525 LIBS="$G_MODULE_LIBS $LIBS"
1526 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1527 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1528 echo "void glib_plugin_test(void) { }" > plugin.c
1529 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1530 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1531 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1532 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1533 -shrext ".o" -avoid-version plugin.lo \
1534 -rpath /dont/care >/dev/null 2>&1
1535 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1536 glib_cv_rtldglobal_broken,[
1537 AC_TRY_RUN([
1538 #include <dlfcn.h>
1539 #ifndef RTLD_GLOBAL
1540 # define RTLD_GLOBAL 0
1541 #endif
1542 #ifndef RTLD_LAZY
1543 # define RTLD_LAZY 0
1544 #endif
1545 int glib_plugin_test;
1546 int main () {
1547 void *handle, *global, *local;
1548 global = &glib_plugin_test;
1549 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1550 if (!handle) return 0;
1551 local = dlsym (handle, "glib_plugin_test");
1552 return global == local;
1553 } ],
1554 [glib_cv_rtldglobal_broken=no],
1555 [glib_cv_rtldglobal_broken=yes],
1556 [glib_cv_rtldglobal_broken=no])
1557 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1558 rmdir ${objdir} 2>/dev/null
1559 ])
1560 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1561 G_MODULE_BROKEN_RTLD_GLOBAL=1
1562 else
1563 G_MODULE_BROKEN_RTLD_GLOBAL=0
1564 fi
1565 dnl *** check whether we need preceeding underscores
1566 AC_CACHE_CHECK([for preceeding underscore in symbols],
1567 glib_cv_uscore,[
1568 AC_TRY_RUN([#include <dlfcn.h>
1569 int glib_underscore_test (void) { return 42; }
1570 int main() {
1571 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1572 handle = dlopen ((void*)0, 0);
1573 if (handle) {
1574 f1 = dlsym (handle, "glib_underscore_test");
1575 f2 = dlsym (handle, "_glib_underscore_test");
1576 } return (!f2 || f1);
1577 }],
1578 [glib_cv_uscore=yes],
1579 [glib_cv_uscore=no],
1580 [])
1581 rm -f plugin.c plugin.$ac_objext plugin.lo
1582 ])
1583 GLIB_ASSERT_SET(glib_cv_uscore)
1584 if test "x$glib_cv_uscore" = "xyes"; then
1585 G_MODULE_NEED_USCORE=1
1586 else
1587 G_MODULE_NEED_USCORE=0
1588 fi
1590 AC_CHECK_DECL([RTLD_LAZY],
1591 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1592 [], [[#include <dlfcn.h>]])
1593 AC_CHECK_DECL([RTLD_NOW],
1594 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1595 [], [[#include <dlfcn.h>]])
1596 AC_CHECK_DECL([RTLD_GLOBAL],
1597 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1598 [], [[#include <dlfcn.h>]])
1600 LDFLAGS="$LDFLAGS_orig"
1601 dnl *** check for having dlerror()
1602 AC_CHECK_FUNC(dlerror,
1603 [G_MODULE_HAVE_DLERROR=1],
1604 [G_MODULE_HAVE_DLERROR=0])
1605 LIBS="$LIBS_orig"
1606 ])
1607 dnl *** done, have we got an implementation?
1608 if test -z "$G_MODULE_IMPL"; then
1609 G_MODULE_IMPL=0
1610 G_MODULE_SUPPORTED=false
1611 else
1612 G_MODULE_SUPPORTED=true
1613 fi
1615 AC_MSG_CHECKING(for the suffix of module shared libraries)
1616 export SED
1617 module=yes eval std_shrext=$shrext_cmds
1618 # chop the initial dot
1619 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1620 AC_MSG_RESULT(.$glib_gmodule_suffix)
1621 # any reason it may fail?
1622 if test "x$glib_gmodule_suffix" = x; then
1623 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1624 fi
1626 AC_SUBST(G_MODULE_SUPPORTED)
1627 AC_SUBST(G_MODULE_IMPL)
1628 AC_SUBST(G_MODULE_LIBS)
1629 AC_SUBST(G_MODULE_LIBS_EXTRA)
1630 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1631 AC_SUBST(G_MODULE_LDFLAGS)
1632 AC_SUBST(G_MODULE_HAVE_DLERROR)
1633 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1634 AC_SUBST(G_MODULE_NEED_USCORE)
1635 AC_SUBST(GLIB_DEBUG_FLAGS)
1637 dnl **********************
1638 dnl *** g_spawn checks ***
1639 dnl **********************
1641 AC_MSG_CHECKING(for gspawn implementation)
1642 case "$host" in
1643 *-*-mingw*)
1644 GSPAWN=gspawn-win32.lo
1645 ;;
1646 *)
1647 GSPAWN=gspawn.lo
1648 ;;
1649 esac
1650 AC_MSG_RESULT($GSPAWN)
1651 AC_SUBST(GSPAWN)
1653 dnl *************************
1654 dnl *** GIOChannel checks ***
1655 dnl *************************
1657 AC_MSG_CHECKING(for GIOChannel implementation)
1658 case "$host" in
1659 *-*-mingw*)
1660 GIO=giowin32.lo
1661 ;;
1662 *)
1663 GIO=giounix.lo
1664 ;;
1665 esac
1666 AC_MSG_RESULT($GIO)
1667 AC_SUBST(GIO)
1669 dnl *********************************
1670 dnl *** Directory for GIO modules ***
1671 dnl *********************************
1673 AC_ARG_WITH(gio-module-dir,
1674 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1675 [load gio modules from this directory [LIBDIR/gio/modules]])],
1676 [],
1677 [with_gio_module_dir='${libdir}/gio/modules'])
1678 GIO_MODULE_DIR=$with_gio_module_dir
1679 AC_SUBST(GIO_MODULE_DIR)
1681 dnl **********************************
1682 dnl *** Check for libselinux (GIO) ***
1683 dnl **********************************
1684 AC_ARG_ENABLE(selinux,
1685 AS_HELP_STRING([--disable-selinux],
1686 [build without selinux support]))
1687 msg_selinux=no
1688 SELINUX_LIBS=
1689 AS_IF([ test "x$enable_selinux" != "xno"], [
1691 AC_CHECK_LIB(selinux, is_selinux_enabled,
1692 [AC_CHECK_HEADERS(selinux/selinux.h,
1693 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1694 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1695 SELINUX_LIBS="-lselinux"
1696 msg_selinux=yes])
1697 ])
1698 ])
1699 ])
1700 AC_SUBST(SELINUX_LIBS)
1702 dnl *****************************
1703 dnl ** Check for inotify (GIO) **
1704 dnl *****************************
1705 inotify_support=no
1706 AC_CHECK_HEADERS([sys/inotify.h],
1707 [
1708 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1709 ])
1711 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1713 dnl ****************************
1714 dnl ** Check for kqueue (GIO) **
1715 dnl ****************************
1716 kqueue_support=no
1717 AC_CHECK_HEADERS([sys/event.h],
1718 [
1719 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1720 ])
1722 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1724 dnl ****************************
1725 dnl *** Checks for FAM (GIO) ***
1726 dnl ****************************
1728 should_disable_fam=no
1730 AC_ARG_ENABLE(fam,
1731 AS_HELP_STRING([--disable-fam],
1732 [don't use fam for file system monitoring]),
1733 [
1734 if test "x$enable_fam" = "xno"; then
1735 should_disable_fam=yes
1736 fi
1737 ]
1738 )
1739 fam_support=no
1740 FAM_LIBS=
1741 if test "x$should_disable_fam" = "xno"; then
1742 AC_CHECK_LIB(fam, FAMOpen,
1743 [AC_CHECK_HEADERS(fam.h,
1744 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1745 AC_CHECK_LIB(fam, FAMNoExists,
1746 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1747 FAM_LIBS="-lfam"]
1748 fam_support=yes,
1749 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1750 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1751 AC_SUBST(FAM_LIBS)
1752 fi
1753 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1756 dnl *****************************
1757 dnl *** Check for xattr (GIO) ***
1758 dnl *****************************
1759 AC_ARG_ENABLE(xattr,
1760 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1761 msg_xattr=no
1762 XATTR_LIBS=
1763 AS_IF([ test "x$enable_xattr" != "xno"], [
1765 dnl either glibc or libattr can provide xattr support
1767 dnl for both of them, we check for getxattr being in
1768 dnl the library and a valid xattr header.
1770 dnl try glibc
1771 AC_CHECK_LIB(c, getxattr,
1772 [AC_CHECK_HEADERS(sys/xattr.h,
1773 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1774 msg_xattr=yes])
1775 ])
1777 AS_IF([ test "x$msg_xattr" != "xyes"], [
1778 dnl failure. try libattr
1779 AC_CHECK_LIB(attr, getxattr,
1780 [AC_CHECK_HEADERS(attr/xattr.h,
1781 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1782 XATTR_LIBS="-lattr"
1783 msg_xattr=yes])
1784 ])
1785 ])
1787 AS_IF([ test "x$msg_xattr" = "xyes"], [
1788 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1789 AC_TRY_COMPILE([
1790 #include <stdio.h>
1791 #ifdef HAVE_SYS_TYPES_H
1792 #include <sys/types.h>
1793 #endif
1794 #ifdef HAVE_SYS_XATTR_H
1795 #include <sys/xattr.h>
1796 #elif HAVE_ATTR_XATTR_H
1797 #include <attr/xattr.h>
1798 #endif
1799 ],
1800 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1801 [
1802 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1803 AC_MSG_RESULT([yes])
1804 ],
1805 [AC_MSG_RESULT([no])]
1806 )
1807 ])
1808 ])
1809 AC_SUBST(XATTR_LIBS)
1811 dnl ************************
1812 dnl *** check for libelf ***
1813 dnl ************************
1814 AC_ARG_ENABLE(libelf,
1815 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1816 AS_IF([ test "x$enable_libelf" != "xno"],[
1817 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1818 AS_IF([ test $have_libelf = maybe ], [
1819 glib_save_LIBS=$LIBS
1820 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1821 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1822 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1823 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1824 LIBS=$glib_save_LIBS
1826 if test $have_libelf != no; then
1827 LIBELF_LIBS=-lelf
1828 have_libelf=yes
1829 fi
1830 ])
1831 ])
1833 if test x$have_libelf = xyes; then
1834 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1835 fi
1837 dnl ************************
1838 dnl *** check for libmount ***
1839 dnl ************************
1841 dnl The fallback code doesn't really implement the same behaviors - e.g.
1842 dnl so on linux we want to require libmount unless specifically disabled
1843 dnl
1844 enable_libmount_default=${glib_os_linux:-no}
1845 AC_ARG_ENABLE(libmount,
1846 [AS_HELP_STRING([--enable-libmount],
1847 [build with libmount support [default for Linux]])],,
1848 [enable_libmount=$enable_libmount_default])
1849 AS_IF([ test "x$enable_libmount" = "xyes"],[
1850 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1851 if test $have_libmount = no ; then
1852 AC_MSG_ERROR([*** Could not find libmount])
1853 fi
1854 ])
1856 if test x$have_libmount = xyes; then
1857 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1858 fi
1859 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1861 dnl ****************************************
1862 dnl *** platform dependent source checks ***
1863 dnl ****************************************
1865 AC_MSG_CHECKING(for platform-dependent source)
1866 case "$host" in
1867 *-*-cygwin*|*-*-mingw*)
1868 PLATFORMDEP=gwin32.lo
1869 ;;
1870 *)
1871 PLATFORMDEP=
1872 ;;
1873 esac
1874 AC_MSG_RESULT($PLATFORMDEP)
1875 AC_SUBST(PLATFORMDEP)
1877 AC_MSG_CHECKING([whether to compile timeloop])
1878 case "$host" in
1879 *-*-cygwin*|*-*-mingw*|*-*-minix)
1880 enable_timeloop=no
1881 ;;
1882 *)
1883 enable_timeloop=yes
1884 ;;
1885 esac
1886 AC_MSG_RESULT($enable_timeloop)
1887 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1889 AC_MSG_CHECKING([if building for some Win32 platform])
1890 case "$host" in
1891 *-*-mingw*|*-*-cygwin*)
1892 platform_win32=yes
1893 ;;
1894 *)
1895 platform_win32=no
1896 ;;
1897 esac
1898 AC_MSG_RESULT($platform_win32)
1899 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1901 dnl ***********************
1902 dnl *** g_thread checks ***
1903 dnl ***********************
1905 AC_ARG_WITH(threads,
1906 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1907 [specify a thread implementation to use])],
1908 [],
1909 [with_threads=yes])
1911 dnl error and warning message
1912 dnl *************************
1914 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1916 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1917 platform (normally it's "_REENTRANT"). I'll not use any flag on
1918 compilation now, but then your programs might not work.
1919 Please provide information on how it is done on your system."
1921 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1922 "
1924 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1925 provide information on your thread implementation."
1927 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1928 functions will not be MT-safe during their first call because
1929 there is no working 'getpwuid_r' on your system."
1931 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1932 because there is no 'localtime_r' on your system."
1934 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1935 linking threaded applications. As GLib cannot do that
1936 automatically, you will get an linkg error everytime you are
1937 not using the right compiler. In that case you have to relink
1938 with the right compiler. Ususally just '_r' is appended
1939 to the compiler name."
1941 dnl determination of thread implementation
1942 dnl ***************************************
1944 AC_MSG_CHECKING(for thread implementation)
1946 have_threads=no
1947 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1948 AS_IF([ test "x$have_threads" = xno], [
1949 AC_TRY_COMPILE([#include <pthread.h>],
1950 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1951 have_threads=posix)
1952 ])
1953 # Tru64Unix requires -pthread to find pthread.h. See #103020
1954 if test "x$have_threads" = xno; then
1955 glib_save_CPPFLAGS="$CPPFLAGS"
1956 CPPFLAGS="$CPPFLAGS -pthread"
1957 AC_TRY_COMPILE([#include <pthread.h>],
1958 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1959 have_threads=posix)
1960 CPPFLAGS="$glib_save_CPPFLAGS"
1961 fi
1962 ])
1963 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1964 case $host in
1965 *-*-mingw*)
1966 have_threads=win32
1967 ;;
1968 esac
1969 fi
1971 if test "x$have_threads" = xno; then
1972 AC_MSG_RESULT(none available)
1973 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1974 else
1975 AC_MSG_RESULT($have_threads)
1976 fi
1979 dnl determination of G_THREAD_CFLAGS
1980 dnl ********************************
1982 G_THREAD_LIBS=
1983 G_THREAD_LIBS_EXTRA=
1984 G_THREAD_CFLAGS=
1986 dnl
1987 dnl Test program for basic POSIX threads functionality
1988 dnl
1989 m4_define([glib_thread_test],[
1990 #include <pthread.h>
1991 int check_me = 0;
1992 void* func(void* data) {check_me = 42; return &check_me;}
1993 int main()
1994 { pthread_t t;
1995 void *ret;
1996 pthread_create (&t, $1, func, 0);
1997 pthread_join (t, &ret);
1998 return (check_me != 42 || ret != &check_me);
1999 }])
2001 AS_IF([ test x"$have_threads" = xposix], [
2002 # First we test for posix, whether -pthread or -pthreads do the trick as
2003 # both CPPFLAG and LIBS.
2004 # One of them does for most gcc versions and some other platforms/compilers
2005 # too and could be considered as the canonical way to go.
2006 case $host in
2007 *-*-cygwin*|*-*-darwin*)
2008 # skip cygwin and darwin -pthread or -pthreads test
2009 ;;
2010 *-solaris*)
2011 # These compiler/linker flags work with both Sun Studio and gcc
2012 # Sun Studio expands -mt to -D_REENTRANT and -lthread
2013 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2014 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2015 G_THREAD_LIBS="-lpthread -lthread"
2016 ;;
2017 *)
2018 for flag in pthread pthreads mt; do
2019 glib_save_CFLAGS="$CFLAGS"
2020 CFLAGS="$CFLAGS -$flag"
2021 AC_TRY_RUN(glib_thread_test(0),
2022 glib_flag_works=yes,
2023 glib_flag_works=no,
2024 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2025 glib_flag_works=yes,
2026 glib_flag_works=no)])
2027 CFLAGS="$glib_save_CFLAGS"
2028 if test $glib_flag_works = yes ; then
2029 G_THREAD_CFLAGS=-$flag
2030 G_THREAD_LIBS=-$flag
2031 break;
2032 fi
2033 done
2034 ;;
2035 esac
2036 ])
2038 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2040 # The canonical -pthread[s] does not work. Try something different.
2042 case $host in
2043 *-aix*)
2044 if test x"$GCC" = xyes; then
2045 # GCC 3.0 and above needs -pthread.
2046 # Should be coverd by the case above.
2047 # GCC 2.x and below needs -mthreads
2048 G_THREAD_CFLAGS="-mthreads"
2049 G_THREAD_LIBS=$G_THREAD_CFLAGS
2050 else
2051 # We are probably using the aix compiler. Normaly a
2052 # program would have to be compiled with the _r variant
2053 # of the corresponding compiler, but we as GLib cannot
2054 # do that: but the good news is that for compiling the
2055 # only difference is the added -D_THREAD_SAFE compile
2056 # option. This is according to the "C for AIX User's
2057 # Guide".
2058 G_THREAD_CFLAGS="-D_THREAD_SAFE"
2059 fi
2060 ;;
2061 *-sysv5uw7*) # UnixWare 7
2062 # We are not using gcc with -pthread. Catched above.
2063 G_THREAD_CFLAGS="-Kthread"
2064 G_THREAD_LIBS=$G_THREAD_CFLAGS
2065 ;;
2066 *-mingw*)
2067 # No flag needed when using MSVCRT.DLL
2068 G_THREAD_CFLAGS=""
2069 ;;
2070 *)
2071 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2072 ;;
2073 esac
2074 ])
2076 # if we are not finding the localtime_r function, then we probably are
2077 # not using the proper multithread flag
2079 glib_save_CPPFLAGS="$CPPFLAGS"
2080 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2082 # First we test, whether localtime_r is declared in time.h
2083 # directly. Then we test whether a macro localtime_r exists, in
2084 # which case localtime_r in the test program is replaced and thus
2085 # if we still find localtime_r in the output, it is not defined as
2086 # a macro.
2088 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2089 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2090 localtime_r(a,b)],
2091 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2093 CPPFLAGS="$glib_save_CPPFLAGS"
2095 AC_MSG_CHECKING(thread related cflags)
2096 AC_MSG_RESULT($G_THREAD_CFLAGS)
2097 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2099 dnl determination of G_THREAD_LIBS
2100 dnl ******************************
2102 AS_IF([test x$have_threads = xposix], [
2103 glib_save_CPPFLAGS="$CPPFLAGS"
2104 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2105 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2106 case $host in
2107 *-aix*)
2108 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2109 # probably using the aix compiler.
2110 AC_MSG_WARN($AIX_COMPILE_INFO)
2111 ;;
2112 *)
2113 G_THREAD_LIBS=error
2114 glib_save_LIBS="$LIBS"
2115 for thread_lib in "" pthread pthread32 pthreads thread; do
2116 if test x"$thread_lib" = x; then
2117 add_thread_lib=""
2118 IN=""
2119 else
2120 add_thread_lib="-l$thread_lib"
2121 IN=" in -l$thread_lib"
2122 fi
2123 if test x"$have_threads" = xposix; then
2124 defattr=0
2125 else
2126 defattr=pthread_attr_default
2127 fi
2129 LIBS="$add_thread_lib $glib_save_LIBS"
2131 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2132 AC_TRY_RUN(glib_thread_test($defattr),
2133 glib_result=yes,
2134 glib_result=no,
2135 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2136 glib_result=yes,
2137 glib_result=no)])
2138 AC_MSG_RESULT($glib_result)
2140 if test "$glib_result" = "yes" ; then
2141 G_THREAD_LIBS="$add_thread_lib"
2142 break
2143 fi
2144 done
2145 if test "x$G_THREAD_LIBS" = xerror; then
2146 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2147 fi
2148 LIBS="$glib_save_LIBS"
2149 ;;
2150 esac
2151 ])
2153 g_threads_impl="POSIX"
2154 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2155 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2156 CPPFLAGS="$glib_save_CPPFLAGS"
2157 ], [test x$have_threads = xwin32], [
2158 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2159 g_threads_impl="WIN32"
2160 ], [
2161 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2162 g_threads_impl="NONE"
2163 G_THREAD_LIBS=error
2164 ])
2165 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2166 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2167 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2169 if test "x$G_THREAD_LIBS" = xerror; then
2170 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2171 fi
2173 AC_MSG_CHECKING(thread related libraries)
2174 AC_MSG_RESULT($G_THREAD_LIBS)
2176 dnl check for mt safe function variants and some posix functions
2177 dnl ************************************************************
2179 glib_save_LIBS="$LIBS"
2180 # we are not doing the following for now, as this might require glib
2181 # to always be linked with the thread libs on some platforms.
2182 # LIBS="$LIBS $G_THREAD_LIBS"
2183 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2185 LIBS="$G_THREAD_LIBS $LIBS"
2186 AS_IF([ test x"$have_threads" = xposix], [
2187 glib_save_CPPFLAGS="$CPPFLAGS"
2188 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2189 # This is not AC_CHECK_FUNC to also work with function
2190 # name mangling in header files.
2191 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2192 AC_LINK_IFELSE(
2193 [AC_LANG_PROGRAM(
2194 [#include <pthread.h>],
2195 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2196 [AC_MSG_RESULT(yes)
2197 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2198 [Have function pthread_attr_setstacksize])],
2199 [AC_MSG_RESULT(no)])
2200 AC_MSG_CHECKING(for pthread_condattr_setclock)
2201 AC_LINK_IFELSE(
2202 [AC_LANG_PROGRAM(
2203 [#include <pthread.h>],
2204 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2205 [AC_MSG_RESULT(yes)
2206 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2207 [Have function pthread_condattr_setclock])],
2208 [AC_MSG_RESULT(no)])
2209 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2210 AC_LINK_IFELSE(
2211 [AC_LANG_PROGRAM(
2212 [#include <pthread.h>],
2213 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2214 [AC_MSG_RESULT(yes)
2215 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2216 [Have function pthread_cond_timedwait_relative_np])],
2217 [AC_MSG_RESULT(no)])
2218 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2219 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2220 AC_LINK_IFELSE(
2221 [AC_LANG_PROGRAM(
2222 [#include <pthread.h>],
2223 [pthread_setname_np("example")])],
2224 [AC_MSG_RESULT(yes)
2225 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2226 [Have function pthread_setname_np(const char*)])],
2227 [AC_MSG_RESULT(no)])
2228 dnl Sets thread names on Solaris 11.3 & higher
2229 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2230 AC_LINK_IFELSE(
2231 [AC_LANG_PROGRAM(
2232 [#include <pthread.h>],
2233 [pthread_setname_np(pthread_self(), "example")])],
2234 [AC_MSG_RESULT(yes)
2235 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2236 [Have function pthread_setname_np(pthread_t, const char*)])],
2237 [AC_MSG_RESULT(no)])
2238 AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2239 AC_LINK_IFELSE(
2240 [AC_LANG_PROGRAM(
2241 [#include <pthread.h>],
2242 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2243 [AC_MSG_RESULT(yes)
2244 AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2245 [Have function pthread_getname_np(pthread_t, name, len)])],
2246 [AC_MSG_RESULT(no)])
2247 CPPFLAGS="$glib_save_CPPFLAGS"
2248 ])
2250 LIBS="$glib_save_LIBS"
2252 # now spit out all the warnings.
2253 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2254 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2255 fi
2256 if test "$ac_cv_func_localtime_r" != "yes"; then
2257 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2258 fi
2260 #
2261 # Hack to deal with:
2262 #
2263 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2264 # building shared libraries with linux.
2265 # b) FreeBSD doesn't do this either.
2266 #
2267 case $host in
2268 *android*)
2269 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2270 ;;
2271 *-*-freebsd*|*-*-linux*)
2272 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2273 ;;
2274 *)
2275 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2276 ;;
2277 esac
2279 AC_SUBST(G_THREAD_CFLAGS)
2280 AC_SUBST(G_THREAD_LIBS)
2281 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2282 AC_SUBST(G_THREAD_LIBS_EXTRA)
2284 AC_CHECK_FUNCS(clock_gettime, [], [
2285 AC_CHECK_LIB(rt, clock_gettime, [
2286 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2287 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2288 ])
2289 ])
2292 dnl ************************
2293 dnl *** g_atomic_* tests ***
2294 dnl ************************
2296 dnl We need to decide at configure time if GLib will use real atomic
2297 dnl operations ("lock free") or emulated ones with a mutex. This is
2298 dnl because we must put this information in glibconfig.h so we know if
2299 dnl it is safe or not to inline using compiler intrinsics directly from
2300 dnl the header.
2301 dnl
2302 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2303 dnl user is interested in knowing if they can use the atomic ops across
2304 dnl processes.
2305 dnl
2306 dnl We can currently support the atomic ops natively when building GLib
2307 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2308 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2309 dnl we are using GCC (and not mingw*).
2310 dnl
2311 dnl Note that the atomic ops are only available with GCC on x86 when
2312 dnl using -march=i486 or higher. If we detect that the atomic ops are
2313 dnl not available but would be available given the right flags, we want
2314 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2315 dnl that then to silently fall back on emulated atomic ops just because
2316 dnl the user had the wrong build environment.
2318 dnl We may add other compilers here in the future...
2320 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2321 case $host in
2322 *-*-mingw*)
2323 glib_cv_g_atomic_lock_free=yes
2324 ;;
2325 *)
2326 AC_TRY_LINK([],
2327 [volatile int atomic = 2;\
2328 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2329 [glib_cv_g_atomic_lock_free=yes],
2330 [glib_cv_g_atomic_lock_free=no])
2331 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2332 SAVE_CFLAGS="${CFLAGS}"
2333 CFLAGS="-march=i486"
2334 AC_TRY_LINK([],
2335 [volatile int atomic = 2;\
2336 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2337 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2338 [])
2339 CFLAGS="${SAVE_CFLAGS}"
2340 fi
2341 ;;
2342 esac])
2345 case $host in
2346 *-*-mingw*)
2347 ;;
2348 *)
2349 # Some compilers support atomic operations but do not define
2350 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2351 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2352 AC_TRY_LINK([],
2353 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2354 [],
2355 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2356 fi
2357 ;;
2358 esac
2360 dnl We need a more robust approach here...
2361 case $host_cpu in
2362 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2363 glib_memory_barrier_needed=no
2364 ;;
2365 sparc*|alpha*|powerpc*|ia64)
2366 glib_memory_barrier_needed=yes
2367 ;;
2368 *)
2369 glib_memory_barrier_needed=yes
2370 ;;
2371 esac
2373 dnl ************************
2374 dnl ** Check for futex(2) **
2375 dnl ************************
2376 AC_CACHE_CHECK(for futex(2) system call,
2377 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2378 #include <linux/futex.h>
2379 #include <sys/syscall.h>
2380 #include <unistd.h>
2381 ],[
2382 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2383 ])],glib_cv_futex=yes,glib_cv_futex=no))
2384 if test x"$glib_cv_futex" = xyes; then
2385 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2386 fi
2388 AC_CACHE_CHECK(for eventfd(2) system call,
2389 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2390 #include <sys/eventfd.h>
2391 #include <unistd.h>
2392 ],[
2393 eventfd (0, EFD_CLOEXEC);
2394 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2395 if test x"$glib_cv_eventfd" = x"yes"; then
2396 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2397 fi
2398 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2400 dnl ****************************************
2401 dnl *** GLib POLL* compatibility defines ***
2402 dnl ****************************************
2404 glib_poll_includes=["
2405 #include <sys/types.h>
2406 #include <poll.h>
2407 "]
2409 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2410 test $ac_cv_func_poll = yes ], [
2411 glib_failed=false
2412 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2413 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2414 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2415 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2416 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2417 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2418 if $glib_failed ; then
2419 AC_MSG_ERROR([Could not determine values for POLL* constants])
2420 fi
2421 ], [
2422 glib_cv_value_POLLIN=1
2423 glib_cv_value_POLLOUT=4
2424 glib_cv_value_POLLPRI=2
2425 glib_cv_value_POLLERR=8
2426 glib_cv_value_POLLHUP=16
2427 glib_cv_value_POLLNVAL=32
2428 ])
2430 AC_MSG_CHECKING([for broken poll])
2431 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2432 #include <stdlib.h>
2433 #include <fcntl.h>
2434 #include <poll.h>
2435 int main(void) {
2436 struct pollfd fds[1];
2437 int fd;
2438 fd = open("/dev/null", 1);
2439 fds[0].fd = fd;
2440 fds[0].events = POLLIN;
2441 fds[0].revents = 0;
2442 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2443 exit(1); /* Does not work for devices -- fail */
2444 }
2445 exit(0);
2446 }]])],
2447 [broken_poll=no],
2448 [broken_poll=yes
2449 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2450 [broken_poll="no (cross compiling)"])
2451 AC_MSG_RESULT($broken_poll)
2453 dnl *********************
2454 dnl *** GRegex checks ***
2455 dnl *********************
2457 PCRE_REQUIRED_VERSION=8.13
2459 # Check if we should use the internal or the system-supplied pcre
2460 AC_ARG_WITH(pcre,
2461 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2462 [whether to use system PCRE [default=system]])],
2463 [],
2464 [with_pcre=system])
2466 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2468 AS_IF([ test "x$with_pcre" = xsystem], [
2469 PKG_CHECK_MODULES(PCRE,
2470 libpcre >= $PCRE_REQUIRED_VERSION)
2471 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2472 glib_save_CFLAGS="$CFLAGS"
2473 glib_save_LIBS="$LIBS"
2474 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2475 AC_TRY_RUN([#include <pcre.h>
2476 int main () {
2477 int support;
2478 pcre_config (PCRE_CONFIG_UTF8, &support);
2479 if (!support)
2480 return 1;
2481 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2482 if (!support)
2483 return 1;
2484 return 0;
2485 }],
2486 glib_cv_pcre_has_unicode=yes,
2487 glib_cv_pcre_has_unicode=no,
2488 glib_cv_pcre_has_unicode=yes)
2489 CFLAGS="$glib_save_CFLAGS"
2490 LIBS="$glib_save_LIBS"
2491 ])
2492 if test "$glib_cv_pcre_has_unicode" = "no"; then
2493 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2494 fi
2495 AC_SUBST(PCRE_CFLAGS)
2496 AC_SUBST(PCRE_LIBS)
2497 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2498 PCRE_REQUIRES=libpcre
2499 AC_SUBST(PCRE_REQUIRES)
2500 ], [
2501 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2502 AS_IF([ test x"$GCC" = xyes], [
2503 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2504 save_CFLAGS="$CFLAGS"
2505 CFLAGS="$CFLAGS -Wno-pointer-sign"
2506 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2507 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2508 CFLAGS="$save_CFLAGS"
2509 ])
2510 ])
2511 AC_SUBST(PCRE_WARN_CFLAGS)
2513 dnl **********************
2514 dnl *** Win32 API libs ***
2515 dnl **********************
2517 case $host in
2518 *-*-cygwin*)
2519 G_LIBS_EXTRA="-luser32 -lkernel32"
2520 ;;
2521 *-*-mingw*)
2522 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2523 ;;
2524 *)
2525 G_LIBS_EXTRA=""
2526 ;;
2527 esac
2528 AC_SUBST(G_LIBS_EXTRA)
2530 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2531 dnl since we need it for g_iconv()
2533 AC_MSG_CHECKING([for EILSEQ])
2534 AC_TRY_COMPILE([
2535 #include <errno.h>
2536 ],
2537 [
2538 int error = EILSEQ;
2539 ], have_eilseq=yes, have_eilseq=no);
2540 AC_MSG_RESULT($have_eilseq)
2542 dnl Add a conditional we can use when cross-compiling, so we avoid running
2543 dnl binaries
2544 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2546 dnl **************************
2547 dnl *** Checks for gtk-doc ***
2548 dnl **************************
2549 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2550 # it on it's own line.
2551 m4_ifdef([GTK_DOC_CHECK], [
2552 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2553 ],[
2554 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2555 ])
2557 AC_ARG_ENABLE(man,
2558 [AS_HELP_STRING([--enable-man],
2559 [generate man pages [default=auto]])],,
2560 enable_man=maybe)
2562 AS_IF([test "$enable_man" != no], [
2563 AC_PATH_PROG([XSLTPROC], [xsltproc])
2564 AS_IF([test -z "$XSLTPROC"], [
2565 AS_IF([test "$enable_man" = yes], [
2566 AC_MSG_ERROR([xsltproc is required for --enable-man])
2567 ])
2568 enable_man=no
2569 ])
2570 ])
2572 AS_IF([ test "$enable_man" != no ], [
2573 dnl check for DocBook DTD in the local catalog
2574 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2575 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2576 AS_IF([test "$have_docbook_dtd" != yes], [
2577 AS_IF([test "$enable_man" = yes ], [
2578 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2579 ])
2580 enable_man=no
2581 ])
2582 ])
2584 AS_IF([test "$enable_man" != no], [
2585 dnl check for DocBook XSL stylesheets in the local catalog
2586 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2587 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2588 AS_IF([ test "$have_docbook_style" != yes ], [
2589 AS_IF([ test "$enable_man" = yes ], [
2590 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2591 ])
2592 enable_man=no
2593 ])
2594 ])
2596 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2598 AC_MSG_CHECKING([whether to generate man pages])
2599 AS_IF([ test "$enable_man" != no ], [
2600 AC_MSG_RESULT([yes])
2601 ], [
2602 AC_MSG_RESULT([no])
2603 ])
2605 dnl
2606 dnl Tracing
2607 dnl
2609 AC_ARG_ENABLE([dtrace],
2610 [AS_HELP_STRING([--enable-dtrace],
2611 [include tracing support for dtrace])])
2612 have_dtrace=no
2613 AC_MSG_CHECKING([whether to include dtrace tracing support])
2614 AS_IF([ test "x$enable_dtrace" != xno], [
2615 if test x$glib_have_carbon = xyes; then
2616 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2617 else
2618 AC_MSG_RESULT([yes])
2619 AC_CHECK_PROGS(DTRACE, dtrace)
2620 if test -z "$DTRACE"; then
2621 if test "x$enable_dtrace" = xyes; then
2622 AC_MSG_ERROR([dtrace not found])
2623 fi
2624 else
2625 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2626 [if test "x$enable_dtrace" = xyes; then
2627 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2628 fi])
2629 fi
2630 fi
2631 ], [
2632 AC_MSG_RESULT([no])
2633 ])
2634 if test "x$have_dtrace" = xyes; then
2635 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2636 fi
2637 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2639 AC_MSG_CHECKING([whether to include systemtap tracing support])
2640 AC_ARG_ENABLE([systemtap],
2641 [AS_HELP_STRING([--enable-systemtap],
2642 [include tracing support for systemtap])])
2643 have_systemtap=no
2644 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2645 have_systemtap=yes
2646 fi
2647 AC_MSG_RESULT(${have_systemtap})
2649 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2651 AC_ARG_WITH([tapset-install-dir],
2652 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2653 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2654 [if test "x${withval}" = x; then
2655 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2656 else
2657 ABS_TAPSET_DIR="${withval}"
2658 fi],
2659 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2660 AC_SUBST(ABS_TAPSET_DIR)
2662 dnl ************************************
2663 dnl *** Enable lcov coverage reports ***
2664 dnl ************************************
2666 AC_ARG_ENABLE(coverage,
2667 AS_HELP_STRING([--enable-coverage],
2668 [enable coverage testing with gcov]),
2669 [use_gcov=$enableval], [use_gcov=no])
2671 AS_IF([ test "x$use_gcov" = "xyes"], [
2672 dnl we need gcc:
2673 if test "$GCC" != "yes"; then
2674 AC_MSG_ERROR([GCC is required for --enable-coverage])
2675 fi
2677 dnl Check if ccache is being used
2678 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2679 case `$SHTOOL path $CC` in
2680 *ccache*[)] gcc_ccache=yes;;
2681 *[)] gcc_ccache=no;;
2682 esac
2684 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2685 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2686 fi
2688 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2689 AC_CHECK_PROG(LTP, lcov, lcov)
2690 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2692 AS_IF([ test "$LTP" ], [
2693 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2694 glib_cv_ltp_version=invalid
2695 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2696 for ltp_check_version in $ltp_version_list; do
2697 if test "$ltp_version" = "$ltp_check_version"; then
2698 glib_cv_ltp_version="$ltp_check_version (ok)"
2699 fi
2700 done
2701 ])
2702 ], [
2703 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2704 AC_MSG_ERROR([$ltp_msg])
2705 ])
2707 case $glib_cv_ltp_version in
2708 ""|invalid[)]
2709 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2710 AC_MSG_ERROR([$ltp_msg])
2711 LTP="exit 0;"
2712 ;;
2713 esac
2715 if test -z "$LTP_GENHTML"; then
2716 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2717 fi
2719 dnl Remove all optimization flags from CFLAGS
2720 changequote({,})
2721 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2722 changequote([,])
2724 dnl Add the special gcc flags
2725 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2726 LDFLAGS="$LDFLAGS -lgcov"
2727 ])
2729 dnl *******************************
2730 dnl *** Disable strict aliasing ***
2731 dnl *******************************
2732 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2733 AS_IF([test "${GCC}" = "yes"],[
2734 CFLAGS="$CFLAGS -fno-strict-aliasing"
2735 ])
2737 dnl ******************************
2738 dnl *** output the whole stuff ***
2739 dnl ******************************
2741 dnl this section will only be run if config.status is invoked with no
2742 dnl arguments, or with "glib/glibconfig.h" as an argument.
2743 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2744 [
2745 outfile=glib/glibconfig.h-tmp
2746 cat > $outfile <<\_______EOF
2747 /* glibconfig.h
2748 *
2749 * This is a generated file. Please modify 'configure.ac'
2750 */
2752 #ifndef __GLIBCONFIG_H__
2753 #define __GLIBCONFIG_H__
2755 #include <glib/gmacros.h>
2757 _______EOF
2759 echo '#include <limits.h>' >> $outfile
2760 echo '#include <float.h>' >> $outfile
2761 if test x$glib_values_h = xyes; then
2762 echo '#include <values.h>' >> $outfile
2763 fi
2764 if test "$glib_header_alloca_h" = "yes"; then
2765 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2766 fi
2767 if test x$glib_included_printf != xyes; then
2768 echo "
2769 /* Specifies that GLib's g_print*() functions wrap the
2770 * system printf functions. This is useful to know, for example,
2771 * when using glibc's register_printf_function().
2772 */" >> $outfile
2773 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2774 fi
2776 cat >> $outfile <<_______EOF
2778 G_BEGIN_DECLS
2780 #define G_MINFLOAT FLT_MIN
2781 #define G_MAXFLOAT FLT_MAX
2782 #define G_MINDOUBLE DBL_MIN
2783 #define G_MAXDOUBLE DBL_MAX
2784 #define G_MINSHORT SHRT_MIN
2785 #define G_MAXSHORT SHRT_MAX
2786 #define G_MAXUSHORT USHRT_MAX
2787 #define G_MININT INT_MIN
2788 #define G_MAXINT INT_MAX
2789 #define G_MAXUINT UINT_MAX
2790 #define G_MINLONG LONG_MIN
2791 #define G_MAXLONG LONG_MAX
2792 #define G_MAXULONG ULONG_MAX
2794 _______EOF
2797 ### this should always be true in a modern C/C++ compiler
2798 ### and is statically asserted by glib-init.c
2799 cat >>$outfile <<_______EOF
2800 typedef signed char gint8;
2801 typedef unsigned char guint8;
2802 _______EOF
2805 if test -n "$gint16"; then
2806 cat >>$outfile <<_______EOF
2807 typedef signed $gint16 gint16;
2808 typedef unsigned $gint16 guint16;
2809 #define G_GINT16_MODIFIER $gint16_modifier
2810 #define G_GINT16_FORMAT $gint16_format
2811 #define G_GUINT16_FORMAT $guint16_format
2812 _______EOF
2813 fi
2816 if test -n "$gint32"; then
2817 cat >>$outfile <<_______EOF
2818 typedef signed $gint32 gint32;
2819 typedef unsigned $gint32 guint32;
2820 #define G_GINT32_MODIFIER $gint32_modifier
2821 #define G_GINT32_FORMAT $gint32_format
2822 #define G_GUINT32_FORMAT $guint32_format
2823 _______EOF
2824 fi
2826 cat >>$outfile <<_______EOF
2827 #define G_HAVE_GINT64 1 /* deprecated, always true */
2829 ${glib_extension}typedef signed $gint64 gint64;
2830 ${glib_extension}typedef unsigned $gint64 guint64;
2832 #define G_GINT64_CONSTANT(val) $gint64_constant
2833 #define G_GUINT64_CONSTANT(val) $guint64_constant
2834 _______EOF
2836 if test x$gint64_format != x ; then
2837 cat >>$outfile <<_______EOF
2838 #define G_GINT64_MODIFIER $gint64_modifier
2839 #define G_GINT64_FORMAT $gint64_format
2840 #define G_GUINT64_FORMAT $guint64_format
2841 _______EOF
2842 else
2843 cat >>$outfile <<_______EOF
2844 #undef G_GINT64_MODIFIER
2845 #undef G_GINT64_FORMAT
2846 #undef G_GUINT64_FORMAT
2847 _______EOF
2848 fi
2850 cat >>$outfile <<_______EOF
2852 #define GLIB_SIZEOF_VOID_P $glib_void_p
2853 #define GLIB_SIZEOF_LONG $glib_long
2854 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2855 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2857 _______EOF
2859 cat >>$outfile <<_______EOF
2860 typedef signed $glib_ssize_type_define gssize;
2861 typedef unsigned $glib_size_type_define gsize;
2862 #define G_GSIZE_MODIFIER $gsize_modifier
2863 #define G_GSSIZE_MODIFIER $gssize_modifier
2864 #define G_GSIZE_FORMAT $gsize_format
2865 #define G_GSSIZE_FORMAT $gssize_format
2867 #define G_MAXSIZE G_MAXU$glib_msize_type
2868 #define G_MINSSIZE G_MIN$glib_mssize_type
2869 #define G_MAXSSIZE G_MAX$glib_mssize_type
2871 typedef gint64 goffset;
2872 #define G_MINOFFSET G_MININT64
2873 #define G_MAXOFFSET G_MAXINT64
2875 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2876 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2877 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2879 #define G_POLLFD_FORMAT $g_pollfd_format
2881 _______EOF
2883 if test -z "$glib_unknown_void_p"; then
2884 cat >>$outfile <<_______EOF
2886 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2887 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2889 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2890 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2892 typedef signed $glib_intptr_type_define gintptr;
2893 typedef unsigned $glib_intptr_type_define guintptr;
2895 #define G_GINTPTR_MODIFIER $gintptr_modifier
2896 #define G_GINTPTR_FORMAT $gintptr_format
2897 #define G_GUINTPTR_FORMAT $guintptr_format
2898 _______EOF
2899 else
2900 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2901 fi
2905 cat >>$outfile <<_______EOF
2906 #ifndef G_DISABLE_DEPRECATED
2907 #define g_ATEXIT(proc) (atexit (proc))
2908 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2909 #endif
2910 $glib_defines
2911 $glib_os
2912 $glib_static_compilation
2914 $glib_vacopy
2916 _______EOF
2918 if test x$g_have_iso_c_varargs = xyes ; then
2919 cat >>$outfile <<_______EOF
2920 #ifndef __cplusplus
2921 # define G_HAVE_ISO_VARARGS 1
2922 #endif
2923 _______EOF
2924 fi
2925 if test x$g_have_iso_cxx_varargs = xyes ; then
2926 cat >>$outfile <<_______EOF
2927 #ifdef __cplusplus
2928 # define G_HAVE_ISO_VARARGS 1
2929 #endif
2930 _______EOF
2931 fi
2932 if test x$g_have_gnuc_varargs = xyes ; then
2933 cat >>$outfile <<_______EOF
2935 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2936 * is passed ISO vararg support is turned off, and there is no work
2937 * around to turn it on, so we unconditionally turn it off.
2938 */
2939 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2940 # undef G_HAVE_ISO_VARARGS
2941 #endif
2943 #define G_HAVE_GNUC_VARARGS 1
2944 _______EOF
2945 fi
2947 case x$g_stack_grows in
2948 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2949 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2950 esac
2953 echo >>$outfile
2954 if test x$g_have_eilseq = xno; then
2955 cat >>$outfile <<_______EOF
2956 #ifndef EILSEQ
2957 /* On some pre-C99 systems, EILSEQ is not defined.
2958 * The correspondence between this and the corresponding definition
2959 * in libiconv is essential.
2960 */
2961 # define EILSEQ ENOENT
2962 #endif
2963 _______EOF
2965 fi
2967 if test x$g_have_gnuc_visibility = xyes; then
2968 cat >>$outfile <<_______EOF
2969 #define G_HAVE_GNUC_VISIBILITY 1
2970 _______EOF
2971 fi
2972 cat >>$outfile <<_______EOF
2973 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2974 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2975 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2976 #define G_GNUC_INTERNAL __hidden
2977 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2978 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2979 #else
2980 #define G_GNUC_INTERNAL
2981 #endif
2982 _______EOF
2984 echo >>$outfile
2985 cat >>$outfile <<_______EOF
2986 #define G_THREADS_ENABLED
2987 #define G_THREADS_IMPL_$g_threads_impl_def
2988 _______EOF
2990 if test x"$g_memory_barrier_needed" != xno; then
2991 echo >>$outfile
2992 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2993 fi
2994 if test x"$g_atomic_lock_free" = xyes; then
2995 echo >>$outfile
2996 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2997 fi
2998 echo >>$outfile
2999 g_bit_sizes="16 32 64"
3000 for bits in $g_bit_sizes; do
3001 cat >>$outfile <<_______EOF
3002 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
3003 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
3004 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3005 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
3006 _______EOF
3007 done
3009 cat >>$outfile <<_______EOF
3010 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
3011 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
3012 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
3013 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
3014 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
3015 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
3016 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
3017 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
3018 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
3019 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
3020 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
3021 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
3022 #define G_BYTE_ORDER $g_byte_order
3024 #define GLIB_SYSDEF_POLLIN =$g_pollin
3025 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3026 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3027 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3028 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3029 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3031 #define G_MODULE_SUFFIX "$g_module_suffix"
3033 typedef $g_pid_type GPid;
3034 #define G_PID_FORMAT $g_pid_format
3036 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3037 #define GLIB_SYSDEF_AF_INET $g_af_inet
3038 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3040 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3041 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3042 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3044 #define G_DIR_SEPARATOR '$g_dir_separator'
3045 #define G_DIR_SEPARATOR_S "$g_dir_separator"
3046 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
3047 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
3049 G_END_DECLS
3051 #endif /* __GLIBCONFIG_H__ */
3052 _______EOF
3055 if cmp -s $outfile glib/glibconfig.h; then
3056 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3057 rm -f $outfile
3058 else
3059 mv $outfile glib/glibconfig.h
3060 fi
3061 ],[
3063 # Note that if two cases are the same, case goes with the first one.
3064 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
3065 # on variable expansion in case labels. Look at the generated config.status
3066 # for a hint.
3068 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3069 glib_header_alloca_h="$ac_cv_working_alloca_h"
3070 else
3071 glib_header_alloca_h="$ac_cv_header_alloca_h"
3072 fi
3074 if test x$enable_included_printf = xyes ; then
3075 glib_included_printf=yes
3076 fi
3078 case 2 in
3079 $ac_cv_sizeof_short)
3080 gint16=short
3081 gint16_modifier='"h"'
3082 gint16_format='"hi"'
3083 guint16_format='"hu"'
3084 ;;
3085 $ac_cv_sizeof_int)
3086 gint16=int
3087 gint16_modifier='""'
3088 gint16_format='"i"'
3089 guint16_format='"u"'
3090 ;;
3091 esac
3092 case 4 in
3093 $ac_cv_sizeof_short)
3094 gint32=short
3095 gint32_modifier='"h"'
3096 gint32_format='"hi"'
3097 guint32_format='"hu"'
3098 ;;
3099 $ac_cv_sizeof_int)
3100 gint32=int
3101 gint32_modifier='""'
3102 gint32_format='"i"'
3103 guint32_format='"u"'
3104 ;;
3105 $ac_cv_sizeof_long)
3106 gint32=long
3107 gint32_modifier='"l"'
3108 gint32_format='"li"'
3109 guint32_format='"lu"'
3110 ;;
3111 esac
3112 case 8 in
3113 $ac_cv_sizeof_int)
3114 gint64=int
3115 gint64_modifier='""'
3116 gint64_format='"i"'
3117 guint64_format='"u"'
3118 glib_extension=
3119 gint64_constant='(val)'
3120 guint64_constant='(val)'
3121 ;;
3122 $ac_cv_sizeof_long)
3123 gint64=long
3124 gint64_modifier='"l"'
3125 gint64_format='"li"'
3126 guint64_format='"lu"'
3127 glib_extension=
3128 gint64_constant='(val##L)'
3129 guint64_constant='(val##UL)'
3130 ;;
3131 $ac_cv_sizeof_long_long)
3132 gint64='long long'
3133 if test -n "$glib_cv_long_long_format"; then
3134 gint64_modifier='"'$glib_cv_long_long_format'"'
3135 gint64_format='"'$glib_cv_long_long_format'i"'
3136 guint64_format='"'$glib_cv_long_long_format'u"'
3137 fi
3138 glib_extension='G_GNUC_EXTENSION '
3139 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3140 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3141 ;;
3142 $ac_cv_sizeof___int64)
3143 gint64='__int64'
3144 if test -n "$glib_cv_long_long_format"; then
3145 gint64_modifier='"'$glib_cv_long_long_format'"'
3146 gint64_format='"'$glib_cv_long_long_format'i"'
3147 guint64_format='"'$glib_cv_long_long_format'u"'
3148 fi
3149 glib_extension=
3150 gint64_constant='(val##i64)'
3151 guint64_constant='(val##ui64)'
3152 ;;
3153 esac
3154 glib_size_t=$ac_cv_sizeof_size_t
3155 glib_ssize_t=$ac_cv_sizeof_ssize_t
3156 glib_size_type_define="$glib_size_type"
3157 glib_ssize_type_define="$glib_ssize_type"
3158 glib_void_p=$ac_cv_sizeof_void_p
3159 glib_long=$ac_cv_sizeof_long
3161 case "$glib_size_type" in
3162 short)
3163 gsize_modifier='"h"'
3164 gsize_format='"hu"'
3165 glib_msize_type='SHRT'
3166 ;;
3167 int)
3168 gsize_modifier='""'
3169 gsize_format='"u"'
3170 glib_msize_type='INT'
3171 ;;
3172 long)
3173 gsize_modifier='"l"'
3174 gsize_format='"lu"'
3175 glib_msize_type='LONG'
3176 ;;
3177 "long long"|__int64)
3178 gsize_modifier='"I64"'
3179 gsize_format='"I64u"'
3180 glib_msize_type='INT64'
3181 ;;
3182 esac
3184 case "$glib_ssize_type" in
3185 short)
3186 gssize_modifier='"h"'
3187 gssize_format='"hi"'
3188 glib_mssize_type='SHRT'
3189 ;;
3190 int)
3191 gssize_modifier='""'
3192 gssize_format='"i"'
3193 glib_mssize_type='INT'
3194 ;;
3195 long)
3196 gssize_modifier='"l"'
3197 gssize_format='"li"'
3198 glib_mssize_type='LONG'
3199 ;;
3200 "long long"|__int64)
3201 gssize_modifier='"I64"'
3202 gssize_format='"I64i"'
3203 glib_mssize_type='INT64'
3204 ;;
3205 esac
3207 gintbits=`expr $ac_cv_sizeof_int \* 8`
3208 glongbits=`expr $ac_cv_sizeof_long \* 8`
3209 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3210 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3212 case $ac_cv_sizeof_void_p in
3213 $ac_cv_sizeof_int)
3214 glib_intptr_type_define=int
3215 gintptr_modifier='""'
3216 gintptr_format='"i"'
3217 guintptr_format='"u"'
3218 glib_gpi_cast='(gint)'
3219 glib_gpui_cast='(guint)'
3220 ;;
3221 $ac_cv_sizeof_long)
3222 glib_intptr_type_define=long
3223 gintptr_modifier='"l"'
3224 gintptr_format='"li"'
3225 guintptr_format='"lu"'
3226 glib_gpi_cast='(glong)'
3227 glib_gpui_cast='(gulong)'
3228 ;;
3229 $ac_cv_sizeof_long_long)
3230 glib_intptr_type_define='long long'
3231 gintptr_modifier='"I64"'
3232 gintptr_format='"I64i"'
3233 guintptr_format='"I64u"'
3234 glib_gpi_cast='(gint64)'
3235 glib_gpui_cast='(guint64)'
3236 ;;
3237 $ac_cv_sizeof___int64)
3238 glib_intptr_type_define=__int64
3239 gintptr_modifier='"I64"'
3240 gintptr_format='"I64i"'
3241 guintptr_format='"I64u"'
3242 glib_gpi_cast='(gint64)'
3243 glib_gpui_cast='(guint64)'
3244 ;;
3245 *)
3246 glib_unknown_void_p=yes
3247 ;;
3248 esac
3251 glib_defines="
3252 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3253 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3254 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3255 "
3257 case xyes in
3258 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3259 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3260 *) glib_vacopy=''
3261 esac
3263 if test x$glib_cv_va_val_copy = xno; then
3264 glib_vacopy="\$glib_vacopy
3265 #define G_VA_COPY_AS_ARRAY 1"
3266 fi
3268 g_have_gnuc_varargs=$g_have_gnuc_varargs
3269 g_have_iso_c_varargs=$g_have_iso_c_varargs
3270 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3272 g_have_gnuc_visibility=$g_have_gnuc_visibility
3273 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3275 if test x$ac_cv_c_bigendian = xyes; then
3276 g_byte_order=G_BIG_ENDIAN
3277 g_bs_native=BE
3278 g_bs_alien=LE
3279 else
3280 g_byte_order=G_LITTLE_ENDIAN
3281 g_bs_native=LE
3282 g_bs_alien=BE
3283 fi
3285 g_pollin=$glib_cv_value_POLLIN
3286 g_pollout=$glib_cv_value_POLLOUT
3287 g_pollpri=$glib_cv_value_POLLPRI
3288 g_pollhup=$glib_cv_value_POLLHUP
3289 g_pollerr=$glib_cv_value_POLLERR
3290 g_pollnval=$glib_cv_value_POLLNVAL
3292 # If a family is not found on the system, define that family to
3293 # a negative value, picking a different one for each undefined
3294 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3295 # This is needed because glib-mkenums doesn't handle optional
3296 # values in enums, and thus we have to have all existing values
3297 # defined in the enum.
3298 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3299 g_af_unix=$glib_cv_value_AF_UNIX
3300 else
3301 g_af_unix=-1
3302 fi
3303 g_af_inet=$glib_cv_value_AF_INET
3304 g_af_inet6=$glib_cv_value_AF_INET6
3306 g_msg_peek=$glib_cv_value_MSG_PEEK
3307 g_msg_oob=$glib_cv_value_MSG_OOB
3308 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3310 g_stack_grows=$glib_cv_stack_grows
3312 g_have_eilseq=$have_eilseq
3314 g_threads_impl_def=$g_threads_impl
3316 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3317 g_memory_barrier_needed="$glib_memory_barrier_needed"
3318 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3320 g_module_suffix="$glib_gmodule_suffix"
3321 g_dir_separator="$glib_dir_separator"
3322 g_searchpath_separator="$glib_searchpath_separator"
3324 g_pid_type="$glib_pid_type"
3325 g_pid_format="\"$glib_pid_format\""
3326 g_pollfd_format="\"$glib_pollfd_format\""
3328 case $host in
3329 *-*-cygwin*)
3330 glib_os="#define G_OS_UNIX
3331 #define G_PLATFORM_WIN32
3332 #define G_WITH_CYGWIN"
3333 ;;
3334 *-*-mingw*)
3335 glib_os="#define G_OS_WIN32
3336 #define G_PLATFORM_WIN32"
3337 ;;
3338 *)
3339 glib_os="#define G_OS_UNIX"
3340 ;;
3341 esac
3342 glib_static_compilation=""
3343 if test x$glib_win32_static_compilation = xyes; then
3344 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3345 #define GOBJECT_STATIC_COMPILATION 1"
3346 fi
3347 ])
3349 # Redo enough to get guint32 and guint64 for the alignment checks below
3350 case 4 in
3351 $ac_cv_sizeof_short)
3352 gint32=short
3353 ;;
3354 $ac_cv_sizeof_int)
3355 gint32=int
3356 ;;
3357 $ac_cv_sizeof_long)
3358 gint32=long
3359 ;;
3360 esac
3361 case 8 in
3362 $ac_cv_sizeof_int)
3363 gint64=int
3364 ;;
3365 $ac_cv_sizeof_long)
3366 gint64=long
3367 ;;
3368 $ac_cv_sizeof_long_long)
3369 gint64='long long'
3370 ;;
3371 $ac_cv_sizeof___int64)
3372 gint64='__int64'
3373 ;;
3374 esac
3376 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3377 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3378 typedef unsigned $gint32 guint32;])
3379 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3380 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3381 typedef unsigned $gint64 guint64;])
3382 AC_CHECK_TYPE([unsigned long])
3383 AC_CHECK_ALIGNOF([unsigned long])
3385 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3386 #
3387 # 1.2.14 required for dbus_message_set_serial
3388 PKG_CHECK_MODULES(DBUS1,
3389 dbus-1 >= 1.2.14,
3390 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3391 have_dbus1=no)
3392 AC_SUBST(DBUS1_CFLAGS)
3393 AC_SUBST(DBUS1_LIBS)
3394 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3396 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3397 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3399 # Check whether MSVC toolset is explicitly set
3400 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3401 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3403 dnl
3404 dnl Check for -Bsymbolic-functions linker flag used to avoid
3405 dnl intra-library PLT jumps, if available.
3406 dnl
3408 AC_ARG_ENABLE(Bsymbolic,
3409 [AS_HELP_STRING([--disable-Bsymbolic],
3410 [avoid linking with -Bsymbolic])],,
3411 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3412 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3413 LDFLAGS=-Wl,-Bsymbolic-functions
3414 LIBS=
3415 AC_TRY_LINK([], [return 0],
3416 AC_MSG_RESULT(yes)
3417 enable_Bsymbolic=yes,
3418 AC_MSG_RESULT(no)
3419 enable_Bsymbolic=no)
3420 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3422 if test "x${enable_Bsymbolic}" = "xyes"; then
3423 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3424 fi
3426 dnl
3427 dnl Check for -z,nodelete linker flag: the type system assumes that
3428 dnl libgobject stays loaded for the lifetime of the process.
3429 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3430 dnl we also try to check for the --fatal-warnings linker flag if
3431 dnl auto-detecting.
3432 dnl
3434 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3435 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3436 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3437 LDFLAGS=-Wl,--fatal-warnings
3438 LIBS=
3439 AC_TRY_LINK([], [return 0],
3440 AC_MSG_RESULT(yes)
3441 [ldflags_fatal=-Wl,--fatal-warnings],
3442 AC_MSG_RESULT(no)
3443 ldflags_fatal=)
3445 AC_MSG_CHECKING([for -z,nodelete linker flag])
3446 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3447 AC_TRY_LINK([], [return 0],
3448 AC_MSG_RESULT(yes)
3449 enable_znodelete=yes,
3450 AC_MSG_RESULT(no)
3451 enable_znodelete=no)
3452 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3454 if test "x${enable_znodelete}" = "xyes"; then
3455 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3456 fi
3458 AC_SUBST(GLIB_LINK_FLAGS)
3460 dnl
3461 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3462 dnl visibility attributes for symbol export control
3463 dnl
3464 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3465 case "$host" in
3466 *-*-mingw*)
3467 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3468 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3469 [defines how to decorate public symbols while building])
3470 CFLAGS="${CFLAGS} -fvisibility=hidden"
3471 ;;
3472 *)
3473 dnl on other compilers, check if we can do -fvisibility=hidden
3474 SAVED_CFLAGS="${CFLAGS}"
3475 CFLAGS="-fvisibility=hidden"
3476 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3477 AC_TRY_COMPILE([], [return 0],
3478 AC_MSG_RESULT(yes)
3479 enable_fvisibility_hidden=yes,
3480 AC_MSG_RESULT(no)
3481 enable_fvisibility_hidden=no)
3482 CFLAGS="${SAVED_CFLAGS}"
3484 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3485 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3486 [defines how to decorate public symbols while building])
3487 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3488 ])
3489 ;;
3490 esac
3491 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3493 dnl Compiler flags; macro originates from systemd
3494 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3495 AC_ARG_ENABLE(compile-warnings,
3496 [AS_HELP_STRING([--disable-compile-warnings],
3497 [Don't use builtin compiler warnings])],,
3498 enable_compile_warnings=yes)
3499 AS_IF([test "x$enable_compile_warnings" != xno], [
3500 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3501 -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3502 -Werror=declaration-after-statement \
3503 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3504 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3505 -Werror=format=2 -Werror=missing-include-dirs])
3506 ])
3507 AC_SUBST(GLIB_WARN_CFLAGS)
3509 #
3510 # Define variables corresponding to the correct include paths to use for
3511 # in-tree building.
3512 #
3514 # for config.h:
3515 config_h_INCLUDES='-I$(top_builddir)'
3516 AC_SUBST(config_h_INCLUDES)
3518 # glib:
3519 # config.h
3520 # $(top_builddir)/glib: for glibconfig.h
3521 # $(top_srcdir)/glib: for glib.h
3522 # $(top_srcdir): for everything
3523 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3524 AC_SUBST(glib_INCLUDES)
3526 # gobject:
3527 # same as glib
3528 gobject_INCLUDES='$(glib_INCLUDES)'
3529 AC_SUBST(gobject_INCLUDES)
3531 # gmodule:
3532 # glib includes
3533 # $(top_srcdir)/gmodule: for gmodule.h
3534 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3535 AC_SUBST(gmodule_INCLUDES)
3537 # gio:
3538 # same as gmodule
3539 gio_INCLUDES='$(gmodule_INCLUDES)'
3540 AC_SUBST(gio_INCLUDES)
3543 AC_CONFIG_FILES([
3544 glib-2.0.pc
3545 gmodule-2.0.pc
3546 gmodule-export-2.0.pc
3547 gmodule-no-export-2.0.pc
3548 gthread-2.0.pc
3549 gobject-2.0.pc
3550 gio-2.0.pc
3551 gio-unix-2.0.pc
3552 gio-windows-2.0.pc
3553 glib-zip
3554 glib-gettextize
3555 Makefile
3556 build/Makefile
3557 build/win32/Makefile
3558 build/win32/dirent/Makefile
3559 win32/Makefile
3560 win32/vs9/Makefile
3561 win32/vs9/glib-version-paths.vsprops
3562 win32/vs10/Makefile
3563 win32/vs10/glib-version-paths.props
3564 win32/vs11/Makefile
3565 win32/vs12/Makefile
3566 win32/vs14/Makefile
3567 win32/vs15/Makefile
3568 glib/Makefile
3569 glib/libcharset/Makefile
3570 glib/gnulib/Makefile
3571 glib/pcre/Makefile
3572 glib/update-pcre/Makefile
3573 glib/tests/Makefile
3574 gmodule/Makefile
3575 gmodule/gmoduleconf.h
3576 gobject/Makefile
3577 gobject/glib-genmarshal
3578 gobject/glib-mkenums
3579 gobject/tests/Makefile
3580 gthread/Makefile
3581 gio/Makefile
3582 gio/gdbus-2.0/codegen/Makefile
3583 gio/gdbus-2.0/codegen/config.py
3584 gio/gnetworking.h
3585 gio/xdgmime/Makefile
3586 gio/inotify/Makefile
3587 gio/kqueue/Makefile
3588 gio/fam/Makefile
3589 gio/win32/Makefile
3590 gio/tests/Makefile
3591 gio/tests/gdbus-object-manager-example/Makefile
3592 gio/tests/services/Makefile
3593 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3594 gio/tests/modules/Makefile
3595 po/Makefile.in
3596 docs/Makefile
3597 docs/reference/Makefile
3598 docs/reference/glib/Makefile
3599 docs/reference/glib/version.xml
3600 docs/reference/gobject/Makefile
3601 docs/reference/gobject/version.xml
3602 docs/reference/gio/Makefile
3603 docs/reference/gio/version.xml
3604 tests/Makefile
3605 tests/gobject/Makefile
3606 tests/refcount/Makefile
3607 m4macros/Makefile
3608 subprojects/Makefile
3609 ])
3611 # We need this command because the configure script will not preserve
3612 # the same attributes of the template files
3613 AC_CONFIG_COMMANDS([chmod-scripts],
3614 [chmod 0755 glib-zip
3615 chmod 0755 glib-gettextize
3616 chmod 0755 gobject/glib-genmarshal
3617 chmod 0755 gobject/glib-mkenums])
3619 # we want to invoke this macro solely so that the config.status script
3620 # and automake generated makefiles know about these generated files.
3621 # They are only needed to distcheck the package
3622 if false; then
3623 AC_CONFIG_FILES([
3624 INSTALL
3625 README
3626 config.h.win32
3627 glib/glibconfig.h.win32
3628 glib/glib.rc
3629 gmodule/gmodule.rc
3630 gobject/gobject.rc
3631 gthread/gthread.rc
3632 gio/gio.rc
3633 ])
3634 fi
3636 AC_OUTPUT