| blob | 737e5e395603497c59a231ca30a6b3089cd5eb83 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [51])
34 m4_define([glib_micro_version], [0])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_cv_stack_grows=no
131 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
132 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
133 # (Sorry, I don't know exactly what is the problem, but it is related to
134 # floating point formatting and decimal point vs. comma.)
135 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
136 # rigorous enough to notice, though.
137 # So preset the autoconf cache variables.
138 ac_cv_func_vsnprintf_c99=no
139 ac_cv_func_snprintf_c99=no
140 case "$host" in
141 x86_64-*-*)
142 LIB_EXE_MACHINE_FLAG=X64
143 glib_pollfd_format='%#I64x'
144 ;;
145 esac
147 AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
148 ;;
149 *)
150 glib_native_win32=no
151 glib_pid_type=int
152 glib_pid_format='i'
153 glib_pollfd_format='%d'
154 ;;
155 esac
156 case $host in
157 *-*-linux*)
158 glib_os_linux=yes
159 ;;
160 esac
162 AC_MSG_RESULT([$glib_native_win32])
164 AC_MSG_CHECKING([for the Android])
165 case $host in
166 *android*)
167 glib_native_android="yes"
168 ;;
169 *)
170 glib_native_android="no"
171 ;;
172 esac
173 AC_MSG_RESULT([$glib_native_android])
175 AC_SUBST(LIB_EXE_MACHINE_FLAG)
177 glib_have_carbon=no
178 AC_MSG_CHECKING([for Mac OS X Carbon support])
179 AC_TRY_CPP([
180 #include <Carbon/Carbon.h>
181 #include <CoreServices/CoreServices.h>
182 ], glib_have_carbon=yes)
184 AC_MSG_RESULT([$glib_have_carbon])
186 glib_have_cocoa=no
187 AC_MSG_CHECKING([for Mac OS X Cocoa support])
188 AC_TRY_CPP([
189 #include <Cocoa/Cocoa.h>
190 #ifdef GNUSTEP_BASE_VERSION
191 #error "Detected GNUstep, not Cocoa"
192 #endif
193 ], glib_have_cocoa=yes)
195 AC_MSG_RESULT([$glib_have_cocoa])
197 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
198 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
199 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
200 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
201 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
202 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
204 AS_IF([test "$glib_native_win32" = "yes"], [
205 AC_CHECK_TOOL(WINDRES, windres, no)
206 if test "$WINDRES" = no; then
207 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
208 fi
209 AC_CHECK_TOOL(NM, nm, no)
210 if test "$NM" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
212 fi
213 AC_CHECK_TOOL(RANLIB, ranlib, :)
214 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
215 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
216 ])
217 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
219 AS_IF([test "x$glib_have_carbon" = "xyes"], [
220 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
221 CARBON_LIBS="-Wl,-framework,Carbon"
222 LDFLAGS="$LDFLAGS $CARBON_LIBS"
223 ], [CARBON_LIBS=""])
225 AC_SUBST([CARBON_LIBS])
227 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
228 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
229 COCOA_LIBS="-Wl,-framework,Foundation"
230 LDFLAGS="$LDFLAGS $COCOA_LIBS"
232 osx_version=`sw_vers -productVersion`
233 osx_min_version="10.9.0"
234 AC_MSG_CHECKING([OSX version >= $osx_min_version])
235 AS_VERSION_COMPARE([$osx_version], [$osx_min_version], [
236 AC_MSG_RESULT([no])
237 AC_MSG_ERROR([OSX version is too old!])
238 ])
239 AC_MSG_RESULT([yes])
240 ], [COCOA_LIBS=""])
242 AC_SUBST([COCOA_LIBS])
244 dnl declare --enable-* args and collect ac_help strings
245 AC_ARG_ENABLE(debug,
246 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
247 [turn on debugging @<:@default=glib_debug_default@:>@]),,
248 enable_debug=glib_debug_default)
250 AC_ARG_ENABLE(gc_friendly,
251 [AS_HELP_STRING([--enable-gc-friendly],
252 [turn on garbage collector friendliness [default=no]])],,
253 [enable_gc_friendly=no])
254 AC_ARG_ENABLE(mem_pools,
255 [AS_HELP_STRING([--disable-mem-pools],
256 [disable all glib memory pools])],,
257 [disable_mem_pools=no])
258 AC_ARG_ENABLE(rebuilds,
259 [AS_HELP_STRING([--disable-rebuilds],
260 [disable all source autogeneration rules])],,
261 [enable_rebuilds=yes])
263 GLIB_TESTS
265 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
266 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
267 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
268 AC_MSG_RESULT([yes])
269 ], [ AC_MSG_RESULT([no]) ])
271 AC_MSG_CHECKING([whether to disable memory pools])
272 AS_IF([test "x$disable_mem_pools" = "xno"], [
273 AC_MSG_RESULT([no])
274 ], [
275 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
276 AC_MSG_RESULT([yes])
277 ])
279 dnl location to install runtime libraries, e.g. ../../lib to install
280 dnl to /lib if libdir is /usr/lib
281 AC_ARG_WITH(runtime-libdir,
282 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
283 [install runtime libraries relative to libdir])],
284 [],
285 [with_runtime_libdir=""])
286 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
287 AC_SUBST(GLIB_RUNTIME_LIBDIR)
288 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
290 dnl Check for a working C++ compiler, but do not bail out, if none is found.
291 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
292 AC_LANG_SAVE
293 AC_LANG_CPLUSPLUS
294 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
295 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
296 AC_LANG_RESTORE
298 AM_PROG_CC_C_O
299 AC_PROG_INSTALL
301 AC_SYS_LARGEFILE
303 PKG_PROG_PKG_CONFIG(0.16)
305 if test "x$enable_debug" = "xyes"; then
306 if test "x$cflags_set" != "x" ; then
307 case " $CFLAGS " in
308 *[[\ \ ]]-g[[\ \ ]]*) ;;
309 *) CFLAGS="$CFLAGS -g" ;;
310 esac
311 fi
312 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
313 else
314 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
316 if test "x$enable_debug" = "xno"; then
317 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
318 fi
319 fi
321 # Ensure MSVC-compatible struct packing convention is used when
322 # compiling for Win32 with gcc.
323 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
324 # gcc2 uses "-fnative-struct".
325 if test x"$glib_native_win32" = xyes; then
326 if test x"$GCC" = xyes; then
327 msnative_struct=''
328 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
329 if test -z "$ac_cv_prog_CC"; then
330 our_gcc="$CC"
331 else
332 our_gcc="$ac_cv_prog_CC"
333 fi
334 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
335 2.)
336 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
337 msnative_struct='-fnative-struct'
338 fi
339 ;;
340 *)
341 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
342 msnative_struct='-mms-bitfields'
343 fi
344 ;;
345 esac
346 if test x"$msnative_struct" = x ; then
347 AC_MSG_RESULT([no way])
348 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
349 else
350 CFLAGS="$CFLAGS $msnative_struct"
351 AC_MSG_RESULT([${msnative_struct}])
352 fi
353 fi
354 fi
355 GLIB_EXTRA_CFLAGS="${msnative_struct}"
356 AC_SUBST(GLIB_EXTRA_CFLAGS)
358 AC_EXEEXT
360 # define a MAINT-like variable REBUILD which is set if Perl
361 # and awk are found, so autogenerated sources can be rebuilt
362 AC_PROG_AWK
363 AC_CHECK_PROGS(PERL, [perl5 perl])
364 # We would like indent, but don't require it.
365 AC_CHECK_PROG(INDENT, indent, indent)
366 REBUILD=\#
367 if test "x$enable_rebuilds" = "xyes" && \
368 test -n "$PERL" && \
369 $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
370 test -n "$AWK" ; then
371 REBUILD=
372 fi
373 AC_SUBST(REBUILD)
375 # Need full path to Perl for glib-mkenums
376 #
377 if test "x$PERL" != x ; then
378 AC_PATH_PROG(PERL_PATH, [$PERL])
379 fi
380 if test "x$PERL_PATH" = x ; then
381 PERL_PATH="/usr/bin/env perl"
382 fi
383 AC_SUBST(PERL_PATH)
385 # option to specify python interpreter to use; this just sets $PYTHON, so that
386 # we will fallback to reading $PYTHON if --with-python is not given, and
387 # python.m4 will get the expected input
388 AC_ARG_WITH(python,
389 AS_HELP_STRING([--with-python=PATH],
390 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
391 [PYTHON="$withval"], [])
392 if test x"$PYTHON" = xyes; then
393 AC_MSG_ERROR([--with-python option requires a path or program argument])
394 fi
395 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
398 dnl ***********************
399 dnl *** Tests for iconv ***
400 dnl ***********************
401 dnl
402 dnl We do this before the gettext checks, to avoid distortion
404 dnl On Windows we use a native implementation
406 AS_IF([ test x"$glib_native_win32" = xyes], [
407 with_libiconv=native
408 ], [
409 AC_ARG_WITH(libiconv,
410 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
411 [use the libiconv library])],,
412 [with_libiconv=maybe])
414 found_iconv=no
415 case $with_libiconv in
416 maybe)
417 # Check in the C library first
418 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
419 # Check if we have GNU libiconv
420 if test $found_iconv = "no"; then
421 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
422 fi
423 # Check if we have a iconv in -liconv, possibly from vendor
424 if test $found_iconv = "no"; then
425 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
426 fi
427 ;;
428 no)
429 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
430 ;;
431 gnu|yes)
432 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
433 ;;
434 native)
435 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
436 ;;
437 esac
439 if test "x$found_iconv" = "xno" ; then
440 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
441 fi
442 ])
444 dnl
445 dnl zlib support
446 dnl
447 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
448 AS_IF([test "x$found_zlib" = "xno"], [
449 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
450 if test "x$found_zlib" = "xno" ; then
451 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
452 fi
453 ZLIB_LIBS='-lz'
454 AC_SUBST(ZLIB_LIBS)
455 ])
457 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
458 AC_SUBST(LIBFFI_CFLAGS)
459 AC_SUBST(LIBFFI_LIBS)
461 dnl
462 dnl gettext support
463 dnl
465 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
466 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
467 GLIB_GNU_GETTEXT
469 if test "$gt_cv_have_gettext" != "yes" ; then
470 AC_MSG_ERROR([
471 *** You must have either have gettext support in your C library, or use the
472 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
473 ])
474 fi
476 LIBS="$INTLLIBS $LIBS"
478 GETTEXT_PACKAGE=glib20
479 AC_SUBST(GETTEXT_PACKAGE)
480 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
481 [Define the gettext package to be used])
483 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
485 dnl
486 dnl Now we are done with gettext checks, figure out ICONV_LIBS
487 dnl
489 AS_IF([test x"$glib_native_win32" != xyes], [
490 if test x$with_libiconv != xno ; then
491 case " $INTLLIBS " in
492 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
493 *) ICONV_LIBS="-liconv" ;;
494 esac
495 fi
496 ])
497 AC_SUBST(ICONV_LIBS)
499 case $with_libiconv in
500 gnu)
501 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
502 ;;
503 native)
504 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
505 ;;
506 esac
508 dnl Initialize libtool
509 LT_PREREQ([2.2])
510 LT_INIT([disable-static win32-dll])
511 dnl when using libtool 2.x create libtool early, because it's used in configure
512 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
515 AS_IF([test "$glib_native_win32" = "yes"], [
516 if test x$enable_static = xyes -a x$enable_shared = xyes; then
517 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
518 fi
519 if test x$enable_static = xyes; then
520 glib_win32_static_compilation=yes
521 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
522 #define GOBJECT_STATIC_COMPILATION 1"
523 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
524 fi
525 ])
526 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
528 # Checks for library functions.
529 AC_FUNC_ALLOCA
530 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
531 AC_CHECK_FUNCS(timegm gmtime_r strerror_r)
533 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
534 [AC_TRY_LINK([#include <unistd.h>
535 extern int __libc_enable_secure;],
536 [return __libc_enable_secure;],
537 glib_cv_have_libc_enable_secure=yes,
538 glib_cv_have_libc_enable_secure=no)])
539 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
540 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
541 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
542 ])
544 AC_CHECK_SIZEOF(char)
545 AC_CHECK_SIZEOF(short)
546 AC_CHECK_SIZEOF(long)
547 AC_CHECK_SIZEOF(int)
548 AC_CHECK_SIZEOF(void *)
549 AC_CHECK_SIZEOF(long long)
550 AC_CHECK_SIZEOF(__int64)
552 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
553 [AC_TRY_LINK([#include <signal.h>
554 #include <sys/types.h>
555 sig_atomic_t val = 42;],
556 [return val == 42 ? 0 : 1],
557 ac_cv_type_sig_atomic_t=yes,
558 ac_cv_type_sig_atomic_t=no)])
559 if test x$ac_cv_type_sig_atomic_t = xyes; then
560 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
561 [Define if you have the 'sig_atomic_t' type.])
562 fi
564 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
565 :
566 else
567 AC_MSG_ERROR([
568 *** GLib requires a 64 bit type. You might want to consider
569 *** using the GNU C compiler.
570 ])
571 fi
573 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
574 # long long is a 64 bit integer.
575 AC_MSG_CHECKING(for format to printf and scanf a guint64)
576 AC_CACHE_VAL(glib_cv_long_long_format,[
577 for format in ll q I64; do
578 AC_TRY_RUN([#include <stdio.h>
579 int main()
580 {
581 long long b, a = -0x3AFAFAFAFAFAFAFALL;
582 char buffer[1000];
583 sprintf (buffer, "%${format}u", a);
584 sscanf (buffer, "%${format}u", &b);
585 exit (b!=a);
586 }
587 ],
588 [glib_cv_long_long_format=${format}
589 break],
590 [],[:])
591 done])
592 AS_IF([ test -n "$glib_cv_long_long_format"], [
593 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
594 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
595 if test x"$glib_cv_long_long_format" = xI64; then
596 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
597 fi
598 ], [AC_MSG_RESULT(none)])
599 ],[ test x$ac_cv_sizeof___int64 = x8], [
600 # __int64 is a 64 bit integer.
601 AC_MSG_CHECKING(for format to printf and scanf a guint64)
602 # We know this is MSVCRT.DLL, and what the formats are
603 glib_cv_long_long_format=I64
604 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
605 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
606 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
607 ])
609 AC_C_CONST
611 dnl
612 dnl check in which direction the stack grows
613 dnl
614 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
615 AC_TRY_RUN([
616 volatile int *a = 0, *b = 0;
617 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
618 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
619 ],
620 glib_cv_stack_grows=yes
621 ,
622 glib_cv_stack_grows=no
623 ,)
624 ])
626 # check for flavours of varargs macros
627 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
628 AC_TRY_COMPILE([],[
629 int a(int p1, int p2, int p3);
630 #define call_a(...) a(1,__VA_ARGS__)
631 call_a(2,3);
632 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
633 AC_MSG_RESULT($g_have_iso_c_varargs)
635 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
636 AS_IF([test "$CXX" = ""], [
637 dnl No C++ compiler
638 g_have_iso_cxx_varargs=no
639 else
640 AC_LANG_CPLUSPLUS
641 AC_TRY_COMPILE([],[
642 int a(int p1, int p2, int p3);
643 #define call_a(...) a(1,__VA_ARGS__)
644 call_a(2,3);
645 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
646 AC_LANG_C
647 ])
648 AC_MSG_RESULT($g_have_iso_cxx_varargs)
650 AC_MSG_CHECKING(for GNUC varargs macros)
651 AC_TRY_COMPILE([],[
652 int a(int p1, int p2, int p3);
653 #define call_a(params...) a(1,params)
654 call_a(2,3);
655 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
656 AC_MSG_RESULT($g_have_gnuc_varargs)
658 # check for GNUC visibility support
659 AC_MSG_CHECKING(for GNUC visibility attribute)
660 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
661 void
662 __attribute__ ((visibility ("hidden")))
663 f_hidden (void)
664 {
665 }
666 void
667 __attribute__ ((visibility ("internal")))
668 f_internal (void)
669 {
670 }
671 void
672 __attribute__ ((visibility ("protected")))
673 f_protected (void)
674 {
675 }
676 void
677 __attribute__ ((visibility ("default")))
678 f_default (void)
679 {
680 }
681 int main (void)
682 {
683 f_hidden();
684 f_internal();
685 f_protected();
686 f_default();
687 return 0;
688 }
689 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
690 AC_MSG_RESULT($g_have_gnuc_visibility)
691 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
693 AC_MSG_CHECKING([whether using Sun Studio C compiler])
694 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
695 #else
696 # include "error: this is not Sun Studio."
697 #endif
698 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
699 AC_MSG_RESULT($g_have_sunstudio_visibility)
700 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
702 # check for bytesex stuff
703 AC_C_BIGENDIAN
704 if test x$ac_cv_c_bigendian = xuniversal ; then
705 AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
706 fi
709 # check for header files
710 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
711 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
712 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
713 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
714 AC_CHECK_HEADERS([linux/magic.h])
716 # Some versions of MSC lack these
717 AC_CHECK_HEADERS([dirent.h sys/time.h])
719 # We don't care about this, but we need to keep including it in
720 # glibconfig.h for backward compatibility
721 AC_CHECK_HEADERS([values.h])
723 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
724 [#if HAVE_SYS_PARAM_H
725 #include <sys/param.h>
726 #endif
727 ])
728 AC_CHECK_FUNCS(sysctlbyname)
730 AC_HEADER_MAJOR
731 AC_CHECK_HEADERS([xlocale.h])
733 # check for structure fields
734 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
735 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
736 #include <sys/stat.h>
737 #ifdef G_OS_UNIX
738 #include <unistd.h>
739 #endif
740 #ifdef HAVE_SYS_STATFS_H
741 #include <sys/statfs.h>
742 #endif
743 #ifdef HAVE_SYS_PARAM_H
744 #include <sys/param.h>
745 #endif
746 #ifdef HAVE_SYS_MOUNT_H
747 #include <sys/mount.h>
748 #endif])
749 # struct statvfs.f_basetype is available on Solaris but not for Linux.
750 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
751 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
752 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
754 AC_STRUCT_DIRENT_D_TYPE
756 # Checks for libcharset
757 AM_LANGINFO_CODESET
758 gl_GLIBC21
760 # check additional type sizes
761 AC_CHECK_SIZEOF(size_t)
763 dnl Try to figure out whether gsize should be long or int
764 AC_MSG_CHECKING([for the appropriate definition for size_t])
766 case $ac_cv_sizeof_size_t in
767 $ac_cv_sizeof_short)
768 glib_size_type=short
769 ;;
770 $ac_cv_sizeof_int)
771 glib_size_type=int
772 ;;
773 $ac_cv_sizeof_long)
774 glib_size_type=long
775 ;;
776 $ac_cv_sizeof_long_long)
777 glib_size_type='long long'
778 ;;
779 $ac_cv_sizeof__int64)
780 glib_size_type='__int64'
781 ;;
782 *) AC_MSG_ERROR([No type matching size_t in size])
783 ;;
784 esac
786 dnl If int/long are the same size, we see which one produces
787 dnl warnings when used in the location as size_t. (This matters
788 dnl on AIX with xlc)
789 dnl
790 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
791 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
792 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
793 #if defined(_AIX) && !defined(__GNUC__)
794 #pragma options langlvl=stdc89
795 #endif
796 #include <stddef.h>
797 int main ()
798 {
799 size_t s = 1;
800 unsigned int *size_int = &s;
801 return (int)*size_int;
802 }
803 ]])],glib_size_type=int,
804 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
805 #if defined(_AIX) && !defined(__GNUC__)
806 #pragma options langlvl=stdc89
807 #endif
808 #include <stddef.h>
809 int main ()
810 {
811 size_t s = 1;
812 unsigned long *size_long = &s;
813 return (int)*size_long;
814 }
815 ]])],glib_size_type=long)])
816 ])
818 AC_MSG_RESULT(unsigned $glib_size_type)
820 AC_CHECK_SIZEOF(ssize_t)
822 dnl Try to figure out whether gssize should be long or int
823 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
825 case $ac_cv_sizeof_ssize_t in
826 $ac_cv_sizeof_short)
827 glib_ssize_type=short
828 ;;
829 $ac_cv_sizeof_int)
830 glib_ssize_type=int
831 ;;
832 $ac_cv_sizeof_long)
833 glib_ssize_type=long
834 ;;
835 $ac_cv_sizeof_long_long)
836 glib_ssize_type='long long'
837 ;;
838 $ac_cv_sizeof__int64)
839 glib_ssize_type='__int64'
840 ;;
841 *) AC_MSG_ERROR([No type matching ssize_t in size])
842 ;;
843 esac
845 dnl If int/long are the same size, we see which one produces
846 dnl warnings when used in the location as ssize_t. (This matters
847 dnl on Android where ssize_t is long and size_t is unsigned int)
848 dnl
849 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
850 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
851 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
852 #if defined(_AIX) && !defined(__GNUC__)
853 #pragma options langlvl=stdc89
854 #endif
855 #include <stddef.h>
856 #ifdef HAVE_INTTYPES_H
857 # include <inttypes.h>
858 #endif
859 #ifdef HAVE_STDINT_H
860 # include <stdint.h>
861 #endif
862 #include <sys/types.h>
863 int main ()
864 {
865 ssize_t s = 1;
866 int *size_int = &s;
867 return (int)*size_int;
868 }
869 ]])],glib_ssize_type=int,
870 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
871 #if defined(_AIX) && !defined(__GNUC__)
872 #pragma options langlvl=stdc89
873 #endif
874 #include <stddef.h>
875 #ifdef HAVE_INTTYPES_H
876 # include <inttypes.h>
877 #endif
878 #ifdef HAVE_STDINT_H
879 # include <stdint.h>
880 #endif
881 #include <sys/types.h>
882 int main ()
883 {
884 ssize_t s = 1;
885 long *size_long = &s;
886 return (int)*size_long;
887 }
888 ]])],glib_ssize_type=long)])
889 ])
891 AC_MSG_RESULT($glib_ssize_type)
893 # Check for some functions
894 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
895 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
896 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
897 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
898 AC_CHECK_FUNCS(splice)
899 AC_CHECK_FUNCS(prlimit)
901 # To avoid finding a compatibility unusable statfs, which typically
902 # successfully compiles, but warns to use the newer statvfs interface:
903 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
904 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
906 AC_MSG_CHECKING([whether to use statfs or statvfs])
907 # Some systems have both statfs and statvfs, pick the most "native" for these
908 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
909 [
910 # on solaris and irix, statfs doesn't even have the f_bavail field
911 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
912 [ac_cv_func_statfs=no],
913 # else, at least on linux, statfs is the actual syscall
914 [ac_cv_func_statvfs=no])
915 ])
917 AS_IF([test x$ac_cv_func_statfs = xyes],
918 [
919 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
920 AC_MSG_RESULT([statfs])
921 ],
922 [test x$ac_cv_func_statvfs = xyes],
923 [
924 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
925 AC_MSG_RESULT([statvfs])
926 ],
927 [ AC_MSG_RESULT([neither])])
929 AC_CHECK_HEADERS(crt_externs.h)
930 AC_CHECK_FUNCS(_NSGetEnviron)
932 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
934 # Internet address families
935 if test $glib_native_win32 = yes; then
936 glib_inet_includes=["
937 #include <winsock2.h>
938 "]
939 else
940 glib_inet_includes=["
941 #include <sys/types.h>
942 #include <sys/socket.h>
943 "]
944 fi
946 glib_failed=false
947 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
948 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
949 # winsock defines this even though it doesn't support it
950 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
951 if $glib_failed ; then
952 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
953 fi
955 glib_failed=false
956 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
957 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
958 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
959 if $glib_failed ; then
960 AC_MSG_ERROR([Could not determine values for MSG_* constants])
961 fi
963 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
965 AS_IF([test $glib_native_win32 = yes], [
966 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
967 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
968 # they aren't present at run-time (on Windows 2000).
969 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
970 AC_SUBST(WSPIAPI_INCLUDE)
971 ], [
972 # Android does not have C_IN in public headers, we define it wherever necessary
973 AS_IF([test $glib_native_android != yes], [
974 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
975 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
976 #include <arpa/nameser.h>],
977 [int qclass = C_IN;])],
978 [AC_MSG_RESULT([no])],
979 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
980 #include <arpa/nameser.h>
981 #include <arpa/nameser_compat.h>],
982 [int qclass = C_IN;])],
983 [AC_MSG_RESULT([yes])
984 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
985 [AC_MSG_ERROR([could not compile test program either way])])])])
986 AC_SUBST(NAMESER_COMPAT_INCLUDE)
988 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
989 NETWORK_LIBS=""
990 AC_MSG_CHECKING([for res_query])
991 AC_TRY_LINK([#include <sys/types.h>
992 #include <netinet/in.h>
993 #include <arpa/nameser.h>
994 #include <resolv.h>
995 ],[
996 res_query("test", 0, 0, (void *)0, 0);
997 ],[AC_MSG_RESULT([yes])],
998 [save_libs="$LIBS"
999 LIBS="-lresolv $LIBS"
1000 AC_TRY_LINK([#include <sys/types.h>
1001 #include <netinet/in.h>
1002 #include <arpa/nameser.h>
1003 #include <resolv.h>
1004 ],[
1005 res_query("test", 0, 0, (void *)0, 0);
1006 ],[AC_MSG_RESULT([in -lresolv])
1007 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1008 [LIBS="-lbind $save_libs"
1009 AC_TRY_LINK([#include <resolv.h>],
1010 [res_query("test", 0, 0, (void *)0, 0);],
1011 [AC_MSG_RESULT([in -lbind])
1012 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1013 [AC_MSG_ERROR(not found)])])
1014 LIBS="$save_libs"])
1015 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1016 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1017 [AC_MSG_ERROR(Could not find socket())]))
1018 save_libs="$LIBS"
1019 LIBS="$LIBS $NETWORK_LIBS"
1020 AC_MSG_CHECKING([for res_init])
1021 AC_TRY_LINK([#include <sys/types.h>
1022 #include <netinet/in.h>
1023 #include <arpa/nameser.h>
1024 #include <resolv.h>
1025 ],[
1026 res_init();
1027 ],[AC_MSG_RESULT([yes])
1028 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1029 ],[AC_MSG_RESULT([no])])
1030 LIBS="$save_libs"
1031 ])
1032 AC_SUBST(NETWORK_LIBS)
1034 AC_CHECK_HEADER([linux/netlink.h],
1035 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1036 [#include <sys/socket.h>])
1037 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1039 AC_CHECK_TYPE([struct ip_mreqn], [
1040 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1041 [#include <netinet/in.h>])
1043 case $host in
1044 *-*-solaris* )
1045 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1046 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1047 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1048 ;;
1049 esac
1051 dnl
1052 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1053 dnl
1054 AS_IF([test "$ac_cv_func_statfs" = yes], [
1055 AC_MSG_CHECKING([number of arguments to statfs()])
1056 AC_TRY_COMPILE([#include <unistd.h>
1057 #ifdef HAVE_SYS_PARAM_H
1058 #include <sys/param.h>
1059 #endif
1060 #ifdef HAVE_SYS_VFS_H
1061 #include <sys/vfs.h>
1062 #endif
1063 #ifdef HAVE_SYS_MOUNT_H
1064 #include <sys/mount.h>
1065 #endif
1066 #ifdef HAVE_SYS_STATFS_H
1067 #include <sys/statfs.h>
1068 #endif], [struct statfs st;
1069 statfs("/", &st);],[
1070 AC_MSG_RESULT([2])
1071 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1072 AC_TRY_COMPILE([#include <unistd.h>
1073 #ifdef HAVE_SYS_PARAM_H
1074 #include <sys/param.h>
1075 #endif
1076 #ifdef HAVE_SYS_VFS_H
1077 #include <sys/vfs.h>
1078 #endif
1079 #ifdef HAVE_SYS_MOUNT_H
1080 #include <sys/mount.h>
1081 #endif
1082 #ifdef HAVE_SYS_STATFS_H
1083 #include <sys/statfs.h>
1084 #endif], [struct statfs st;
1085 statfs("/", &st, sizeof (st), 0);],[
1086 AC_MSG_RESULT([4])
1087 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1088 AC_MSG_RESULT(unknown)
1089 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1090 ])
1092 dnl
1093 dnl open takes O_DIRECTORY as an option
1094 dnl
1095 AC_MSG_CHECKING([open() option O_DIRECTORY])
1096 AC_TRY_COMPILE([#include <fcntl.h>
1097 #include <sys/types.h>
1098 #include <sys/stat.h>],
1099 [open(0, O_DIRECTORY, 0);],[
1100 AC_MSG_RESULT([yes])
1101 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1102 AC_MSG_RESULT([no])])
1104 #
1105 # Check whether to use an included printf
1106 #
1107 AC_FUNC_VSNPRINTF_C99
1108 AC_FUNC_PRINTF_UNIX98
1110 AC_ARG_ENABLE(included-printf,
1111 [AS_HELP_STRING([--enable-included-printf],
1112 [use included printf [default=auto]])],
1113 enable_included_printf="$enableval")
1115 need_included_printf=no
1116 if test "x$enable_included_printf" = "xyes" ; then
1117 need_included_printf=yes
1118 fi
1119 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1120 need_included_printf=yes
1121 fi
1122 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1123 need_included_printf=yes
1124 fi
1125 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1126 test -z "$glib_cv_long_long_format" ; then
1127 need_included_printf=yes
1128 fi
1130 if test "x$enable_included_printf" = "xno" &&
1131 test "x$need_included_printf" = "xyes" ; then
1132 AC_MSG_ERROR([
1133 *** Your C library's printf doesn't appear to have the features that
1134 *** GLib needs, but you specified --enable-included-printf=no.])
1135 fi
1137 enable_included_printf=$need_included_printf
1139 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1140 AS_IF([test "$enable_included_printf" != "yes"], [
1141 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1142 ], [
1143 if test -z "$glib_cv_long_long_format" ; then
1144 glib_cv_long_long_format="ll"
1145 fi
1146 AC_DEFINE(HAVE_VASPRINTF,1)
1147 ])
1149 # Checks needed for gnulib vasnprintf
1150 bh_C_SIGNED
1151 jm_AC_TYPE_LONG_LONG
1152 gt_TYPE_LONGDOUBLE
1153 gt_TYPE_WCHAR_T
1154 gt_TYPE_WINT_T
1155 AC_TYPE_SIZE_T
1156 AC_CHECK_TYPES(ptrdiff_t)
1157 jm_AC_TYPE_INTMAX_T
1158 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1159 AC_FUNC_SNPRINTF_C99
1161 # Check if <sys/select.h> needs to be included for fd_set
1162 AC_MSG_CHECKING([for fd_set])
1163 AC_TRY_COMPILE([#include <sys/types.h>],
1164 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1165 AS_IF([test "$gtk_ok" = "yes"], [
1166 AC_MSG_RESULT([yes, found in sys/types.h])
1167 ], [
1168 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1169 if test "$gtk_ok" = "yes"; then
1170 # *** FIXME: give it a different name
1171 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1172 AC_MSG_RESULT([yes, found in sys/select.h])
1173 else
1174 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1175 AC_MSG_RESULT(no)
1176 fi
1177 ])
1179 dnl Check for nl_langinfo and CODESET
1180 AC_LANG_SAVE
1181 AC_LANG_C
1182 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1183 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1184 [char *codeset = nl_langinfo (CODESET);])],
1185 [glib_cv_langinfo_codeset=yes],
1186 [glib_cv_langinfo_codeset=no])])
1187 if test x$glib_cv_langinfo_codeset = xyes; then
1188 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1189 fi
1191 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1192 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1193 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1194 [char *str;
1195 str = nl_langinfo (PM_STR);
1196 str = nl_langinfo (D_T_FMT);
1197 str = nl_langinfo (D_FMT);
1198 str = nl_langinfo (T_FMT);
1199 str = nl_langinfo (T_FMT_AMPM);
1200 str = nl_langinfo (MON_1);
1201 str = nl_langinfo (ABMON_12);
1202 str = nl_langinfo (DAY_1);
1203 str = nl_langinfo (ABDAY_7);])],
1204 [glib_cv_langinfo_time=yes],
1205 [glib_cv_langinfo_time=no])])
1206 if test x$glib_cv_langinfo_time = xyes; then
1207 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1208 fi
1210 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1211 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1212 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1213 [char *str;
1214 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1215 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1216 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1217 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1218 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1219 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1220 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1222 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1223 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1224 [glib_cv_langinfo_outdigit=yes],
1225 [glib_cv_langinfo_outdigit=no])])
1226 if test x$glib_cv_langinfo_outdigit = xyes; then
1227 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1228 fi
1229 AC_LANG_RESTORE
1231 dnl ****************************************
1232 dnl *** posix_memalign ***
1233 dnl ****************************************
1234 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1235 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1236 glib_cv_compliant_posix_memalign=0
1237 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1238 AC_TRY_RUN([
1239 #define _XOPEN_SOURCE 600
1240 #include <stdlib.h> /* posix_memalign() should be defined here */
1241 /* some systems break if #include <malloc.h> used */
1242 static void test_memalign (size_t boundary, size_t size) {
1243 void *mem = 0;
1244 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1245 exit (1);
1246 else
1247 free (mem);
1248 }
1249 int main() {
1250 test_memalign ( 128, 128 - 2 * sizeof (void*));
1251 test_memalign ( 256, 256 - 2 * sizeof (void*));
1252 test_memalign ( 512, 512 - 2 * sizeof (void*));
1253 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1254 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1255 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1256 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1257 test_memalign (16384, 16384 - 2 * sizeof (void*));
1258 test_memalign (32768, 32768 - 2 * sizeof (void*));
1259 exit (0); /* success */
1260 }
1261 ],
1262 [glib_cv_compliant_posix_memalign=1], [], [:])
1263 :
1264 fi
1265 ])
1266 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1267 AC_MSG_RESULT(yes)
1268 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1269 ], [
1270 AC_MSG_RESULT(no)
1271 ])
1274 dnl ****************************************
1275 dnl *** strlcpy/strlcat ***
1276 dnl ****************************************
1277 # Check for strlcpy
1278 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1279 AC_TRY_RUN([#include <stdlib.h>
1280 #include <string.h>
1281 int main() {
1282 char p[10];
1283 (void) strlcpy (p, "hi", 10);
1284 if (strlcat (p, "bye", 0) != 3)
1285 return 1;
1286 return 0;
1287 }], glib_cv_have_strlcpy=yes,
1288 glib_cv_have_strlcpy=no,
1289 glib_cv_have_strlcpy=no)])
1290 if test "$glib_cv_have_strlcpy" = "yes"; then
1291 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1292 fi
1295 dnl **********************
1296 dnl *** va_copy checks ***
1297 dnl **********************
1298 dnl we currently check for all three va_copy possibilities, so we get
1299 dnl all results in config.log for bug reports.
1300 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1301 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1302 #include <stdlib.h>
1303 void f (int i, ...) {
1304 va_list args1, args2;
1305 va_start (args1, i);
1306 va_copy (args2, args1);
1307 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1308 exit (1);
1309 va_end (args1); va_end (args2);
1310 }
1311 int main() {
1312 f (0, 42);
1313 return 0;
1314 }]])],
1315 [glib_cv_va_copy=yes],
1316 [glib_cv_va_copy=no])
1317 ])
1318 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1319 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1320 #include <stdlib.h>
1321 void f (int i, ...) {
1322 va_list args1, args2;
1323 va_start (args1, i);
1324 __va_copy (args2, args1);
1325 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1326 exit (1);
1327 va_end (args1); va_end (args2);
1328 }
1329 int main() {
1330 f (0, 42);
1331 return 0;
1332 }]])],
1333 [glib_cv___va_copy=yes],
1334 [glib_cv___va_copy=no])
1335 ])
1337 if test "x$glib_cv_va_copy" = "xyes"; then
1338 g_va_copy_func=va_copy
1339 else if test "x$glib_cv___va_copy" = "xyes"; then
1340 g_va_copy_func=__va_copy
1341 fi
1342 fi
1344 if test -n "$g_va_copy_func"; then
1345 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1346 fi
1348 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1349 AC_TRY_RUN([#include <stdarg.h>
1350 #include <stdlib.h>
1351 void f (int i, ...) {
1352 va_list args1, args2;
1353 va_start (args1, i);
1354 args2 = args1;
1355 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1356 exit (1);
1357 va_end (args1); va_end (args2);
1358 }
1359 int main() {
1360 f (0, 42);
1361 return 0;
1362 }],
1363 [glib_cv_va_val_copy=yes],
1364 [glib_cv_va_val_copy=no],
1365 [glib_cv_va_val_copy=yes])
1366 ])
1368 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1369 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1370 ])
1372 dnl ***********************
1373 dnl *** g_module checks ***
1374 dnl ***********************
1375 G_MODULE_LIBS=
1376 G_MODULE_LIBS_EXTRA=
1377 G_MODULE_PLUGIN_LIBS=
1378 if test x"$glib_native_win32" = xyes; then
1379 dnl No use for this on Win32
1380 G_MODULE_LDFLAGS=
1381 else
1382 export SED
1383 G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1384 fi
1385 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1386 G_MODULE_NEED_USCORE=0
1387 G_MODULE_BROKEN_RTLD_GLOBAL=0
1388 G_MODULE_HAVE_DLERROR=0
1389 dnl *** force native WIN32 shared lib loader
1390 if test -z "$G_MODULE_IMPL"; then
1391 case "$host" in
1392 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1393 esac
1394 fi
1395 dnl *** force native AIX library loader
1396 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1397 if test -z "$G_MODULE_IMPL"; then
1398 case "$host" in
1399 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1400 esac
1401 fi
1402 dnl *** dlopen() and dlsym() in system libraries
1403 AS_IF([ test -z "$G_MODULE_IMPL"], [
1404 AC_CHECK_FUNC(dlopen,
1405 [AC_CHECK_FUNC(dlsym,
1406 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1407 [])
1408 ])
1409 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1410 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1411 AC_CHECK_FUNC(NSLinkModule,
1412 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1413 G_MODULE_NEED_USCORE=1],
1414 [])
1415 ])
1416 dnl *** dlopen() and dlsym() in libdl
1417 AS_IF([ test -z "$G_MODULE_IMPL"], [
1418 AC_CHECK_LIB(dl, dlopen,
1419 [AC_CHECK_LIB(dl, dlsym,
1420 [G_MODULE_LIBS=-ldl
1421 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1422 [])
1423 ])
1424 dnl *** additional checks for G_MODULE_IMPL_DL
1425 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1426 LIBS_orig="$LIBS"
1427 LDFLAGS_orig="$LDFLAGS"
1428 LIBS="$G_MODULE_LIBS $LIBS"
1429 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1430 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1431 echo "void glib_plugin_test(void) { }" > plugin.c
1432 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1433 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1434 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1435 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1436 -shrext ".o" -avoid-version plugin.lo \
1437 -rpath /dont/care >/dev/null 2>&1
1438 eval `./libtool --config | grep ^objdir`
1439 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1440 glib_cv_rtldglobal_broken,[
1441 AC_TRY_RUN([
1442 #include <dlfcn.h>
1443 #ifndef RTLD_GLOBAL
1444 # define RTLD_GLOBAL 0
1445 #endif
1446 #ifndef RTLD_LAZY
1447 # define RTLD_LAZY 0
1448 #endif
1449 int glib_plugin_test;
1450 int main () {
1451 void *handle, *global, *local;
1452 global = &glib_plugin_test;
1453 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1454 if (!handle) return 0;
1455 local = dlsym (handle, "glib_plugin_test");
1456 return global == local;
1457 } ],
1458 [glib_cv_rtldglobal_broken=no],
1459 [glib_cv_rtldglobal_broken=yes],
1460 [glib_cv_rtldglobal_broken=no])
1461 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1462 rmdir ${objdir} 2>/dev/null
1463 ])
1464 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1465 G_MODULE_BROKEN_RTLD_GLOBAL=1
1466 else
1467 G_MODULE_BROKEN_RTLD_GLOBAL=0
1468 fi
1469 dnl *** check whether we need preceeding underscores
1470 AC_CACHE_CHECK([for preceeding underscore in symbols],
1471 glib_cv_uscore,[
1472 AC_TRY_RUN([#include <dlfcn.h>
1473 int glib_underscore_test (void) { return 42; }
1474 int main() {
1475 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1476 handle = dlopen ((void*)0, 0);
1477 if (handle) {
1478 f1 = dlsym (handle, "glib_underscore_test");
1479 f2 = dlsym (handle, "_glib_underscore_test");
1480 } return (!f2 || f1);
1481 }],
1482 [glib_cv_uscore=yes],
1483 [glib_cv_uscore=no],
1484 [])
1485 rm -f plugin.c plugin.$ac_objext plugin.lo
1486 ])
1487 GLIB_ASSERT_SET(glib_cv_uscore)
1488 if test "x$glib_cv_uscore" = "xyes"; then
1489 G_MODULE_NEED_USCORE=1
1490 else
1491 G_MODULE_NEED_USCORE=0
1492 fi
1494 LDFLAGS="$LDFLAGS_orig"
1495 dnl *** check for having dlerror()
1496 AC_CHECK_FUNC(dlerror,
1497 [G_MODULE_HAVE_DLERROR=1],
1498 [G_MODULE_HAVE_DLERROR=0])
1499 LIBS="$LIBS_orig"
1500 ])
1501 dnl *** done, have we got an implementation?
1502 if test -z "$G_MODULE_IMPL"; then
1503 G_MODULE_IMPL=0
1504 G_MODULE_SUPPORTED=false
1505 else
1506 G_MODULE_SUPPORTED=true
1507 fi
1509 AC_MSG_CHECKING(for the suffix of module shared libraries)
1510 export SED
1511 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1512 eval $shrext_cmds
1513 module=yes eval std_shrext=$shrext_cmds
1514 # chop the initial dot
1515 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1516 AC_MSG_RESULT(.$glib_gmodule_suffix)
1517 # any reason it may fail?
1518 if test "x$glib_gmodule_suffix" = x; then
1519 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1520 fi
1522 AC_SUBST(G_MODULE_SUPPORTED)
1523 AC_SUBST(G_MODULE_IMPL)
1524 AC_SUBST(G_MODULE_LIBS)
1525 AC_SUBST(G_MODULE_LIBS_EXTRA)
1526 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1527 AC_SUBST(G_MODULE_LDFLAGS)
1528 AC_SUBST(G_MODULE_HAVE_DLERROR)
1529 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1530 AC_SUBST(G_MODULE_NEED_USCORE)
1531 AC_SUBST(GLIB_DEBUG_FLAGS)
1533 dnl **********************
1534 dnl *** g_spawn checks ***
1535 dnl **********************
1537 AC_MSG_CHECKING(for gspawn implementation)
1538 case "$host" in
1539 *-*-mingw*)
1540 GSPAWN=gspawn-win32.lo
1541 ;;
1542 *)
1543 GSPAWN=gspawn.lo
1544 ;;
1545 esac
1546 AC_MSG_RESULT($GSPAWN)
1547 AC_SUBST(GSPAWN)
1549 dnl *************************
1550 dnl *** GIOChannel checks ***
1551 dnl *************************
1553 AC_MSG_CHECKING(for GIOChannel implementation)
1554 case "$host" in
1555 *-*-mingw*)
1556 GIO=giowin32.lo
1557 ;;
1558 *)
1559 GIO=giounix.lo
1560 ;;
1561 esac
1562 AC_MSG_RESULT($GIO)
1563 AC_SUBST(GIO)
1565 dnl *********************************
1566 dnl *** Directory for GIO modules ***
1567 dnl *********************************
1569 AC_ARG_WITH(gio-module-dir,
1570 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1571 [load gio modules from this directory [LIBDIR/gio/modules]])],
1572 [],
1573 [with_gio_module_dir='${libdir}/gio/modules'])
1574 GIO_MODULE_DIR=$with_gio_module_dir
1575 AC_SUBST(GIO_MODULE_DIR)
1577 dnl **********************************
1578 dnl *** Check for libselinux (GIO) ***
1579 dnl **********************************
1580 AC_ARG_ENABLE(selinux,
1581 AS_HELP_STRING([--disable-selinux],
1582 [build without selinux support]))
1583 msg_selinux=no
1584 SELINUX_LIBS=
1585 AS_IF([ test "x$enable_selinux" != "xno"], [
1587 AC_CHECK_LIB(selinux, is_selinux_enabled,
1588 [AC_CHECK_HEADERS(selinux/selinux.h,
1589 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1590 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1591 SELINUX_LIBS="-lselinux"
1592 msg_selinux=yes])
1593 ])
1594 ])
1595 ])
1596 AC_SUBST(SELINUX_LIBS)
1598 dnl *****************************
1599 dnl ** Check for inotify (GIO) **
1600 dnl *****************************
1601 inotify_support=no
1602 AC_CHECK_HEADERS([sys/inotify.h],
1603 [
1604 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1605 ])
1607 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1609 dnl ****************************
1610 dnl ** Check for kqueue (GIO) **
1611 dnl ****************************
1612 kqueue_support=no
1613 AC_CHECK_HEADERS([sys/event.h],
1614 [
1615 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1616 ])
1618 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1620 dnl ****************************
1621 dnl *** Checks for FAM (GIO) ***
1622 dnl ****************************
1624 should_disable_fam=no
1626 AC_ARG_ENABLE(fam,
1627 AS_HELP_STRING([--disable-fam],
1628 [don't use fam for file system monitoring]),
1629 [
1630 if test "x$enable_fam" = "xno"; then
1631 should_disable_fam=yes
1632 fi
1633 ]
1634 )
1635 fam_support=no
1636 FAM_LIBS=
1637 if test "x$should_disable_fam" = "xno"; then
1638 AC_CHECK_LIB(fam, FAMOpen,
1639 [AC_CHECK_HEADERS(fam.h,
1640 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1641 AC_CHECK_LIB(fam, FAMNoExists,
1642 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1643 FAM_LIBS="-lfam"]
1644 fam_support=yes,
1645 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1646 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1647 AC_SUBST(FAM_LIBS)
1648 fi
1649 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1652 dnl *****************************
1653 dnl *** Check for xattr (GIO) ***
1654 dnl *****************************
1655 AC_ARG_ENABLE(xattr,
1656 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1657 msg_xattr=no
1658 XATTR_LIBS=
1659 AS_IF([ test "x$enable_xattr" != "xno"], [
1661 dnl either glibc or libattr can provide xattr support
1663 dnl for both of them, we check for getxattr being in
1664 dnl the library and a valid xattr header.
1666 dnl try glibc
1667 AC_CHECK_LIB(c, getxattr,
1668 [AC_CHECK_HEADERS(sys/xattr.h,
1669 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1670 msg_xattr=yes])
1671 ])
1673 AS_IF([ test "x$msg_xattr" != "xyes"], [
1674 dnl failure. try libattr
1675 AC_CHECK_LIB(attr, getxattr,
1676 [AC_CHECK_HEADERS(attr/xattr.h,
1677 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1678 XATTR_LIBS="-lattr"
1679 msg_xattr=yes])
1680 ])
1681 ])
1683 AS_IF([ test "x$msg_xattr" = "xyes"], [
1684 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1685 AC_TRY_COMPILE([
1686 #include <stdio.h>
1687 #ifdef HAVE_SYS_TYPES_H
1688 #include <sys/types.h>
1689 #endif
1690 #ifdef HAVE_SYS_XATTR_H
1691 #include <sys/xattr.h>
1692 #elif HAVE_ATTR_XATTR_H
1693 #include <attr/xattr.h>
1694 #endif
1695 ],
1696 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1697 [
1698 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1699 AC_MSG_RESULT([yes])
1700 ],
1701 [AC_MSG_RESULT([no])]
1702 )
1703 ])
1704 ])
1705 AC_SUBST(XATTR_LIBS)
1707 dnl ************************
1708 dnl *** check for libelf ***
1709 dnl ************************
1710 AC_ARG_ENABLE(libelf,
1711 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1712 AS_IF([ test "x$enable_libelf" != "xno"],[
1713 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1714 AS_IF([ test $have_libelf = maybe ], [
1715 glib_save_LIBS=$LIBS
1716 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1717 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1718 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1719 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1720 LIBS=$glib_save_LIBS
1722 if test $have_libelf != no; then
1723 LIBELF_LIBS=-lelf
1724 have_libelf=yes
1725 fi
1726 ])
1727 ])
1729 if test x$have_libelf = xyes; then
1730 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1731 fi
1733 dnl ************************
1734 dnl *** check for libmount ***
1735 dnl ************************
1737 dnl The fallback code doesn't really implement the same behaviors - e.g.
1738 dnl so on linux we want to require libmount unless specifically disabled
1739 dnl
1740 enable_libmount_default=${glib_os_linux:-no}
1741 AC_ARG_ENABLE(libmount,
1742 [AS_HELP_STRING([--enable-libmount],
1743 [build with libmount support [default for Linux]])],,
1744 [enable_libmount=$enable_libmount_default])
1745 AS_IF([ test "x$enable_libmount" = "xyes"],[
1746 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.28], [have_libmount=yes], [have_libmount=maybe])
1747 AS_IF([ test $have_libmount = maybe ], [
1748 glib_save_LIBS=$LIBS
1749 AC_CHECK_HEADER([libmount/libmount.h], [:], [have_libmount=no])
1750 LIBS=$glib_save_LIBS
1752 if test $have_libmount != no; then
1753 LIBMOUNT_LIBS=-lmount
1754 have_libmount=yes
1755 fi
1756 ])
1757 if test $have_libmount = no ; then
1758 AC_MSG_ERROR([*** Could not find libmount])
1759 fi
1760 ])
1762 if test x$have_libmount = xyes; then
1763 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1764 fi
1765 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1767 dnl ****************************************
1768 dnl *** platform dependent source checks ***
1769 dnl ****************************************
1771 AC_MSG_CHECKING(for platform-dependent source)
1772 case "$host" in
1773 *-*-cygwin*|*-*-mingw*)
1774 PLATFORMDEP=gwin32.lo
1775 ;;
1776 *)
1777 PLATFORMDEP=
1778 ;;
1779 esac
1780 AC_MSG_RESULT($PLATFORMDEP)
1781 AC_SUBST(PLATFORMDEP)
1783 AC_MSG_CHECKING([whether to compile timeloop])
1784 case "$host" in
1785 *-*-cygwin*|*-*-mingw*|*-*-minix)
1786 enable_timeloop=no
1787 ;;
1788 *)
1789 enable_timeloop=yes
1790 ;;
1791 esac
1792 AC_MSG_RESULT($enable_timeloop)
1793 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1795 AC_MSG_CHECKING([if building for some Win32 platform])
1796 case "$host" in
1797 *-*-mingw*|*-*-cygwin*)
1798 platform_win32=yes
1799 ;;
1800 *)
1801 platform_win32=no
1802 ;;
1803 esac
1804 AC_MSG_RESULT($platform_win32)
1805 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1807 dnl ***********************
1808 dnl *** g_thread checks ***
1809 dnl ***********************
1811 AC_ARG_WITH(threads,
1812 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1813 [specify a thread implementation to use])],
1814 [],
1815 [with_threads=yes])
1817 dnl error and warning message
1818 dnl *************************
1820 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1822 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1823 platform (normally it's "_REENTRANT"). I'll not use any flag on
1824 compilation now, but then your programs might not work.
1825 Please provide information on how it is done on your system."
1827 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1828 "
1830 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1831 provide information on your thread implementation."
1833 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1834 functions will not be MT-safe during their first call because
1835 there is no working 'getpwuid_r' on your system."
1837 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1838 because there is no 'localtime_r' on your system."
1840 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1841 linking threaded applications. As GLib cannot do that
1842 automatically, you will get an linkg error everytime you are
1843 not using the right compiler. In that case you have to relink
1844 with the right compiler. Ususally just '_r' is appended
1845 to the compiler name."
1847 dnl determination of thread implementation
1848 dnl ***************************************
1850 AC_MSG_CHECKING(for thread implementation)
1852 have_threads=no
1853 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1854 AS_IF([ test "x$have_threads" = xno], [
1855 AC_TRY_COMPILE([#include <pthread.h>],
1856 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1857 have_threads=posix)
1858 ])
1859 # Tru64Unix requires -pthread to find pthread.h. See #103020
1860 if test "x$have_threads" = xno; then
1861 glib_save_CPPFLAGS="$CPPFLAGS"
1862 CPPFLAGS="$CPPFLAGS -pthread"
1863 AC_TRY_COMPILE([#include <pthread.h>],
1864 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1865 have_threads=posix)
1866 CPPFLAGS="$glib_save_CPPFLAGS"
1867 fi
1868 ])
1869 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1870 case $host in
1871 *-*-mingw*)
1872 have_threads=win32
1873 ;;
1874 esac
1875 fi
1877 if test "x$have_threads" = xno; then
1878 AC_MSG_RESULT(none available)
1879 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1880 else
1881 AC_MSG_RESULT($have_threads)
1882 fi
1885 dnl determination of G_THREAD_CFLAGS
1886 dnl ********************************
1888 G_THREAD_LIBS=
1889 G_THREAD_LIBS_EXTRA=
1890 G_THREAD_CFLAGS=
1892 dnl
1893 dnl Test program for basic POSIX threads functionality
1894 dnl
1895 m4_define([glib_thread_test],[
1896 #include <pthread.h>
1897 int check_me = 0;
1898 void* func(void* data) {check_me = 42; return &check_me;}
1899 int main()
1900 { pthread_t t;
1901 void *ret;
1902 pthread_create (&t, $1, func, 0);
1903 pthread_join (t, &ret);
1904 return (check_me != 42 || ret != &check_me);
1905 }])
1907 AS_IF([ test x"$have_threads" = xposix], [
1908 # First we test for posix, whether -pthread or -pthreads do the trick as
1909 # both CPPFLAG and LIBS.
1910 # One of them does for most gcc versions and some other platforms/compilers
1911 # too and could be considered as the canonical way to go.
1912 case $host in
1913 *-*-cygwin*|*-*-darwin*)
1914 # skip cygwin and darwin -pthread or -pthreads test
1915 ;;
1916 *-solaris*)
1917 # These compiler/linker flags work with both Sun Studio and gcc
1918 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1919 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1920 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1921 G_THREAD_LIBS="-lpthread -lthread"
1922 ;;
1923 *)
1924 for flag in pthread pthreads mt; do
1925 glib_save_CFLAGS="$CFLAGS"
1926 CFLAGS="$CFLAGS -$flag"
1927 AC_TRY_RUN(glib_thread_test(0),
1928 glib_flag_works=yes,
1929 glib_flag_works=no,
1930 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1931 glib_flag_works=yes,
1932 glib_flag_works=no)])
1933 CFLAGS="$glib_save_CFLAGS"
1934 if test $glib_flag_works = yes ; then
1935 G_THREAD_CFLAGS=-$flag
1936 G_THREAD_LIBS=-$flag
1937 break;
1938 fi
1939 done
1940 ;;
1941 esac
1942 ])
1944 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1946 # The canonical -pthread[s] does not work. Try something different.
1948 case $host in
1949 *-aix*)
1950 if test x"$GCC" = xyes; then
1951 # GCC 3.0 and above needs -pthread.
1952 # Should be coverd by the case above.
1953 # GCC 2.x and below needs -mthreads
1954 G_THREAD_CFLAGS="-mthreads"
1955 G_THREAD_LIBS=$G_THREAD_CFLAGS
1956 else
1957 # We are probably using the aix compiler. Normaly a
1958 # program would have to be compiled with the _r variant
1959 # of the corresponding compiler, but we as GLib cannot
1960 # do that: but the good news is that for compiling the
1961 # only difference is the added -D_THREAD_SAFE compile
1962 # option. This is according to the "C for AIX User's
1963 # Guide".
1964 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1965 fi
1966 ;;
1967 *-sysv5uw7*) # UnixWare 7
1968 # We are not using gcc with -pthread. Catched above.
1969 G_THREAD_CFLAGS="-Kthread"
1970 G_THREAD_LIBS=$G_THREAD_CFLAGS
1971 ;;
1972 *-mingw*)
1973 # No flag needed when using MSVCRT.DLL
1974 G_THREAD_CFLAGS=""
1975 ;;
1976 *)
1977 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1978 ;;
1979 esac
1980 ])
1982 # if we are not finding the localtime_r function, then we probably are
1983 # not using the proper multithread flag
1985 glib_save_CPPFLAGS="$CPPFLAGS"
1986 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1988 # First we test, whether localtime_r is declared in time.h
1989 # directly. Then we test whether a macro localtime_r exists, in
1990 # which case localtime_r in the test program is replaced and thus
1991 # if we still find localtime_r in the output, it is not defined as
1992 # a macro.
1994 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1995 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1996 localtime_r(a,b)],
1997 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1999 CPPFLAGS="$glib_save_CPPFLAGS"
2001 AC_MSG_CHECKING(thread related cflags)
2002 AC_MSG_RESULT($G_THREAD_CFLAGS)
2003 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2005 dnl determination of G_THREAD_LIBS
2006 dnl ******************************
2008 AS_IF([test x$have_threads = xposix], [
2009 glib_save_CPPFLAGS="$CPPFLAGS"
2010 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2011 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2012 case $host in
2013 *-aix*)
2014 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2015 # probably using the aix compiler.
2016 AC_MSG_WARN($AIX_COMPILE_INFO)
2017 ;;
2018 *)
2019 G_THREAD_LIBS=error
2020 glib_save_LIBS="$LIBS"
2021 for thread_lib in "" pthread pthread32 pthreads thread; do
2022 if test x"$thread_lib" = x; then
2023 add_thread_lib=""
2024 IN=""
2025 else
2026 add_thread_lib="-l$thread_lib"
2027 IN=" in -l$thread_lib"
2028 fi
2029 if test x"$have_threads" = xposix; then
2030 defattr=0
2031 else
2032 defattr=pthread_attr_default
2033 fi
2035 LIBS="$add_thread_lib $glib_save_LIBS"
2037 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2038 AC_TRY_RUN(glib_thread_test($defattr),
2039 glib_result=yes,
2040 glib_result=no,
2041 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2042 glib_result=yes,
2043 glib_result=no)])
2044 AC_MSG_RESULT($glib_result)
2046 if test "$glib_result" = "yes" ; then
2047 G_THREAD_LIBS="$add_thread_lib"
2048 break
2049 fi
2050 done
2051 if test "x$G_THREAD_LIBS" = xerror; then
2052 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2053 fi
2054 LIBS="$glib_save_LIBS"
2055 ;;
2056 esac
2057 ])
2059 g_threads_impl="POSIX"
2060 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2061 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2062 CPPFLAGS="$glib_save_CPPFLAGS"
2063 ], [test x$have_threads = xwin32], [
2064 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2065 g_threads_impl="WIN32"
2066 ], [
2067 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2068 g_threads_impl="NONE"
2069 G_THREAD_LIBS=error
2070 ])
2071 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2072 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2073 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2075 if test "x$G_THREAD_LIBS" = xerror; then
2076 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2077 fi
2079 AC_MSG_CHECKING(thread related libraries)
2080 AC_MSG_RESULT($G_THREAD_LIBS)
2082 dnl check for mt safe function variants and some posix functions
2083 dnl ************************************************************
2085 glib_save_LIBS="$LIBS"
2086 # we are not doing the following for now, as this might require glib
2087 # to always be linked with the thread libs on some platforms.
2088 # LIBS="$LIBS $G_THREAD_LIBS"
2089 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2091 LIBS="$G_THREAD_LIBS $LIBS"
2092 AS_IF([ test x"$have_threads" = xposix], [
2093 glib_save_CPPFLAGS="$CPPFLAGS"
2094 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2095 # This is not AC_CHECK_FUNC to also work with function
2096 # name mangling in header files.
2097 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2098 AC_LINK_IFELSE(
2099 [AC_LANG_PROGRAM(
2100 [#include <pthread.h>],
2101 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2102 [AC_MSG_RESULT(yes)
2103 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2104 [Have function pthread_attr_setstacksize])],
2105 [AC_MSG_RESULT(no)])
2106 AC_MSG_CHECKING(for pthread_condattr_setclock)
2107 AC_LINK_IFELSE(
2108 [AC_LANG_PROGRAM(
2109 [#include <pthread.h>],
2110 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2111 [AC_MSG_RESULT(yes)
2112 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2113 [Have function pthread_condattr_setclock])],
2114 [AC_MSG_RESULT(no)])
2115 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2116 AC_LINK_IFELSE(
2117 [AC_LANG_PROGRAM(
2118 [#include <pthread.h>],
2119 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2120 [AC_MSG_RESULT(yes)
2121 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2122 [Have function pthread_cond_timedwait_relative_np])],
2123 [AC_MSG_RESULT(no)])
2124 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2125 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2126 AC_LINK_IFELSE(
2127 [AC_LANG_PROGRAM(
2128 [#include <pthread.h>],
2129 [pthread_setname_np("example")])],
2130 [AC_MSG_RESULT(yes)
2131 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2132 [Have function pthread_setname_np(const char*)])],
2133 [AC_MSG_RESULT(no)])
2134 dnl Sets thread names on Solaris 11.3 & higher
2135 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2136 AC_LINK_IFELSE(
2137 [AC_LANG_PROGRAM(
2138 [#include <pthread.h>],
2139 [pthread_setname_np(pthread_self(), "example")])],
2140 [AC_MSG_RESULT(yes)
2141 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2142 [Have function pthread_setname_np(pthread_t, const char*)])],
2143 [AC_MSG_RESULT(no)])
2144 CPPFLAGS="$glib_save_CPPFLAGS"
2145 ])
2147 LIBS="$glib_save_LIBS"
2149 # now spit out all the warnings.
2150 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2151 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2152 fi
2153 if test "$ac_cv_func_localtime_r" != "yes"; then
2154 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2155 fi
2157 #
2158 # Hack to deal with:
2159 #
2160 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2161 # building shared libraries with linux.
2162 # b) FreeBSD doesn't do this either.
2163 #
2164 case $host in
2165 *android*)
2166 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2167 ;;
2168 *-*-freebsd*|*-*-linux*)
2169 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2170 ;;
2171 *)
2172 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2173 ;;
2174 esac
2176 AC_SUBST(G_THREAD_CFLAGS)
2177 AC_SUBST(G_THREAD_LIBS)
2178 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2179 AC_SUBST(G_THREAD_LIBS_EXTRA)
2181 AC_CHECK_FUNCS(clock_gettime, [], [
2182 AC_CHECK_LIB(rt, clock_gettime, [
2183 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2184 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2185 ])
2186 ])
2189 dnl ************************
2190 dnl *** g_atomic_* tests ***
2191 dnl ************************
2193 dnl We need to decide at configure time if GLib will use real atomic
2194 dnl operations ("lock free") or emulated ones with a mutex. This is
2195 dnl because we must put this information in glibconfig.h so we know if
2196 dnl it is safe or not to inline using compiler intrinsics directly from
2197 dnl the header.
2198 dnl
2199 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2200 dnl user is interested in knowing if they can use the atomic ops across
2201 dnl processes.
2202 dnl
2203 dnl We can currently support the atomic ops natively when building GLib
2204 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2205 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2206 dnl we are using GCC (and not mingw*).
2207 dnl
2208 dnl Note that the atomic ops are only available with GCC on x86 when
2209 dnl using -march=i486 or higher. If we detect that the atomic ops are
2210 dnl not available but would be available given the right flags, we want
2211 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2212 dnl that then to silently fall back on emulated atomic ops just because
2213 dnl the user had the wrong build environment.
2215 dnl We may add other compilers here in the future...
2217 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2218 case $host in
2219 *-*-mingw*)
2220 glib_cv_g_atomic_lock_free=yes
2221 ;;
2222 *)
2223 AC_TRY_LINK([],
2224 [volatile int atomic = 2;\
2225 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2226 [glib_cv_g_atomic_lock_free=yes],
2227 [glib_cv_g_atomic_lock_free=no])
2228 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2229 SAVE_CFLAGS="${CFLAGS}"
2230 CFLAGS="-march=i486"
2231 AC_TRY_LINK([],
2232 [volatile int atomic = 2;\
2233 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2234 [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2235 [])
2236 CFLAGS="${SAVE_CFLAGS}"
2237 fi
2238 ;;
2239 esac])
2242 case $host in
2243 *-*-mingw*)
2244 ;;
2245 *)
2246 # Some compilers support atomic operations but do not define
2247 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2248 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2249 AC_TRY_LINK([],
2250 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2251 [],
2252 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2253 fi
2254 ;;
2255 esac
2257 dnl We need a more robust approach here...
2258 case $host_cpu in
2259 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2260 glib_memory_barrier_needed=no
2261 ;;
2262 sparc*|alpha*|powerpc*|ia64)
2263 glib_memory_barrier_needed=yes
2264 ;;
2265 *)
2266 glib_memory_barrier_needed=yes
2267 ;;
2268 esac
2270 dnl ************************
2271 dnl ** Check for futex(2) **
2272 dnl ************************
2273 AC_CACHE_CHECK(for futex(2) system call,
2274 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2275 #include <linux/futex.h>
2276 #include <sys/syscall.h>
2277 #include <unistd.h>
2278 ],[
2279 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2280 ])],glib_cv_futex=yes,glib_cv_futex=no))
2281 if test x"$glib_cv_futex" = xyes; then
2282 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2283 fi
2285 AC_CACHE_CHECK(for eventfd(2) system call,
2286 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2287 #include <sys/eventfd.h>
2288 #include <unistd.h>
2289 ],[
2290 eventfd (0, EFD_CLOEXEC);
2291 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2292 if test x"$glib_cv_eventfd" = x"yes"; then
2293 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2294 fi
2295 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2297 dnl ****************************************
2298 dnl *** GLib POLL* compatibility defines ***
2299 dnl ****************************************
2301 glib_poll_includes=["
2302 #include <sys/types.h>
2303 #include <poll.h>
2304 "]
2306 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2307 test $ac_cv_func_poll = yes ], [
2308 glib_failed=false
2309 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2310 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2311 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2312 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2313 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2314 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2315 if $glib_failed ; then
2316 AC_MSG_ERROR([Could not determine values for POLL* constants])
2317 fi
2318 ], [
2319 glib_cv_value_POLLIN=1
2320 glib_cv_value_POLLOUT=4
2321 glib_cv_value_POLLPRI=2
2322 glib_cv_value_POLLERR=8
2323 glib_cv_value_POLLHUP=16
2324 glib_cv_value_POLLNVAL=32
2325 ])
2327 AC_MSG_CHECKING([for broken poll])
2328 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2329 #include <stdlib.h>
2330 #include <fcntl.h>
2331 #include <poll.h>
2332 int main(void) {
2333 struct pollfd fds[1];
2334 int fd;
2335 fd = open("/dev/null", 1);
2336 fds[0].fd = fd;
2337 fds[0].events = POLLIN;
2338 fds[0].revents = 0;
2339 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2340 exit(1); /* Does not work for devices -- fail */
2341 }
2342 exit(0);
2343 }]])],
2344 [broken_poll=no],
2345 [broken_poll=yes
2346 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2347 [broken_poll="no (cross compiling)"])
2348 AC_MSG_RESULT($broken_poll)
2350 dnl *********************
2351 dnl *** GRegex checks ***
2352 dnl *********************
2354 PCRE_REQUIRED_VERSION=8.13
2356 # Check if we should use the internal or the system-supplied pcre
2357 AC_ARG_WITH(pcre,
2358 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2359 [whether to use system PCRE [default=system]])],
2360 [],
2361 [with_pcre=system])
2363 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2365 AS_IF([ test "x$with_pcre" = xsystem], [
2366 PKG_CHECK_MODULES(PCRE,
2367 libpcre >= $PCRE_REQUIRED_VERSION)
2368 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2369 glib_save_CFLAGS="$CFLAGS"
2370 glib_save_LIBS="$LIBS"
2371 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2372 AC_TRY_RUN([#include <pcre.h>
2373 int main () {
2374 int support;
2375 pcre_config (PCRE_CONFIG_UTF8, &support);
2376 if (!support)
2377 return 1;
2378 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2379 if (!support)
2380 return 1;
2381 return 0;
2382 }],
2383 glib_cv_pcre_has_unicode=yes,
2384 glib_cv_pcre_has_unicode=no,
2385 glib_cv_pcre_has_unicode=yes)
2386 CFLAGS="$glib_save_CFLAGS"
2387 LIBS="$glib_save_LIBS"
2388 ])
2389 if test "$glib_cv_pcre_has_unicode" = "no"; then
2390 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2391 fi
2392 AC_SUBST(PCRE_CFLAGS)
2393 AC_SUBST(PCRE_LIBS)
2394 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2395 PCRE_REQUIRES=libpcre
2396 AC_SUBST(PCRE_REQUIRES)
2397 ], [
2398 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2399 AS_IF([ test x"$GCC" = xyes], [
2400 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2401 save_CFLAGS="$CFLAGS"
2402 CFLAGS="$CFLAGS -Wno-pointer-sign"
2403 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2404 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2405 CFLAGS="$save_CFLAGS"
2406 ])
2407 ])
2408 AC_SUBST(PCRE_WARN_CFLAGS)
2410 dnl **********************
2411 dnl *** Win32 API libs ***
2412 dnl **********************
2414 case $host in
2415 *-*-cygwin*)
2416 G_LIBS_EXTRA="-luser32 -lkernel32"
2417 ;;
2418 *-*-mingw*)
2419 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2420 ;;
2421 *)
2422 G_LIBS_EXTRA=""
2423 ;;
2424 esac
2425 AC_SUBST(G_LIBS_EXTRA)
2427 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2428 dnl since we need it for g_iconv()
2430 AC_MSG_CHECKING([for EILSEQ])
2431 AC_TRY_COMPILE([
2432 #include <errno.h>
2433 ],
2434 [
2435 int error = EILSEQ;
2436 ], have_eilseq=yes, have_eilseq=no);
2437 AC_MSG_RESULT($have_eilseq)
2439 dnl Add a conditional we can use when cross-compiling, so we avoid running
2440 dnl binaries
2441 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2443 dnl **************************
2444 dnl *** Checks for gtk-doc ***
2445 dnl **************************
2446 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2447 # it on it's own line.
2448 m4_ifdef([GTK_DOC_CHECK], [
2449 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2450 ],[
2451 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2452 ])
2454 AC_ARG_ENABLE(man,
2455 [AS_HELP_STRING([--enable-man],
2456 [generate man pages [default=auto]])],,
2457 enable_man=maybe)
2459 AS_IF([test "$enable_man" != no], [
2460 AC_PATH_PROG([XSLTPROC], [xsltproc])
2461 AS_IF([test -z "$XSLTPROC"], [
2462 AS_IF([test "$enable_man" = yes], [
2463 AC_MSG_ERROR([xsltproc is required for --enable-man])
2464 ])
2465 enable_man=no
2466 ])
2467 ])
2469 AS_IF([ test "$enable_man" != no ], [
2470 dnl check for DocBook DTD in the local catalog
2471 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2472 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2473 AS_IF([test "$have_docbook_dtd" != yes], [
2474 AS_IF([test "$enable_man" = yes ], [
2475 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2476 ])
2477 enable_man=no
2478 ])
2479 ])
2481 AS_IF([test "$enable_man" != no], [
2482 dnl check for DocBook XSL stylesheets in the local catalog
2483 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2484 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2485 AS_IF([ test "$have_docbook_style" != yes ], [
2486 AS_IF([ test "$enable_man" = yes ], [
2487 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2488 ])
2489 enable_man=no
2490 ])
2491 ])
2493 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2495 AC_MSG_CHECKING([whether to generate man pages])
2496 AS_IF([ test "$enable_man" != no ], [
2497 AC_MSG_RESULT([yes])
2498 ], [
2499 AC_MSG_RESULT([no])
2500 ])
2502 dnl
2503 dnl Tracing
2504 dnl
2506 AC_ARG_ENABLE([dtrace],
2507 [AS_HELP_STRING([--enable-dtrace],
2508 [include tracing support for dtrace])])
2509 have_dtrace=no
2510 AC_MSG_CHECKING([whether to include dtrace tracing support])
2511 AS_IF([ test "x$enable_dtrace" != xno], [
2512 if test x$glib_have_carbon = xyes; then
2513 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2514 else
2515 AC_MSG_RESULT([yes])
2516 AC_CHECK_PROGS(DTRACE, dtrace)
2517 if test -z "$DTRACE"; then
2518 if test "x$enable_dtrace" = xyes; then
2519 AC_MSG_ERROR([dtrace not found])
2520 fi
2521 else
2522 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2523 [if test "x$enable_dtrace" = xyes; then
2524 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2525 fi])
2526 fi
2527 fi
2528 ], [
2529 AC_MSG_RESULT([no])
2530 ])
2531 if test "x$have_dtrace" = xyes; then
2532 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2533 fi
2534 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2536 AC_MSG_CHECKING([whether to include systemtap tracing support])
2537 AC_ARG_ENABLE([systemtap],
2538 [AS_HELP_STRING([--enable-systemtap],
2539 [include tracing support for systemtap])])
2540 have_systemtap=no
2541 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2542 have_systemtap=yes
2543 fi
2544 AC_MSG_RESULT(${have_systemtap})
2546 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2548 AC_ARG_WITH([tapset-install-dir],
2549 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2550 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2551 [if test "x${withval}" = x; then
2552 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2553 else
2554 ABS_TAPSET_DIR="${withval}"
2555 fi],
2556 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2557 AC_SUBST(ABS_TAPSET_DIR)
2559 dnl ************************************
2560 dnl *** Enable lcov coverage reports ***
2561 dnl ************************************
2563 AC_ARG_ENABLE(coverage,
2564 AS_HELP_STRING([--enable-coverage],
2565 [enable coverage testing with gcov]),
2566 [use_gcov=$enableval], [use_gcov=no])
2568 AS_IF([ test "x$use_gcov" = "xyes"], [
2569 dnl we need gcc:
2570 if test "$GCC" != "yes"; then
2571 AC_MSG_ERROR([GCC is required for --enable-coverage])
2572 fi
2574 dnl Check if ccache is being used
2575 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2576 case `$SHTOOL path $CC` in
2577 *ccache*[)] gcc_ccache=yes;;
2578 *[)] gcc_ccache=no;;
2579 esac
2581 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2582 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2583 fi
2585 ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2586 AC_CHECK_PROG(LTP, lcov, lcov)
2587 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2589 AS_IF([ test "$LTP" ], [
2590 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2591 glib_cv_ltp_version=invalid
2592 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2593 for ltp_check_version in $ltp_version_list; do
2594 if test "$ltp_version" = "$ltp_check_version"; then
2595 glib_cv_ltp_version="$ltp_check_version (ok)"
2596 fi
2597 done
2598 ])
2599 ], [
2600 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2601 AC_MSG_ERROR([$ltp_msg])
2602 ])
2604 case $glib_cv_ltp_version in
2605 ""|invalid[)]
2606 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2607 AC_MSG_ERROR([$ltp_msg])
2608 LTP="exit 0;"
2609 ;;
2610 esac
2612 if test -z "$LTP_GENHTML"; then
2613 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2614 fi
2616 dnl Remove all optimization flags from CFLAGS
2617 changequote({,})
2618 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2619 changequote([,])
2621 dnl Add the special gcc flags
2622 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2623 LDFLAGS="$LDFLAGS -lgcov"
2624 ])
2626 dnl ******************************
2627 dnl *** output the whole stuff ***
2628 dnl ******************************
2630 dnl this section will only be run if config.status is invoked with no
2631 dnl arguments, or with "glib/glibconfig.h" as an argument.
2632 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2633 [
2634 outfile=glib/glibconfig.h-tmp
2635 cat > $outfile <<\_______EOF
2636 /* glibconfig.h
2637 *
2638 * This is a generated file. Please modify 'configure.ac'
2639 */
2641 #ifndef __GLIBCONFIG_H__
2642 #define __GLIBCONFIG_H__
2644 #include <glib/gmacros.h>
2646 _______EOF
2648 echo '#include <limits.h>' >> $outfile
2649 echo '#include <float.h>' >> $outfile
2650 if test x$glib_values_h = xyes; then
2651 echo '#include <values.h>' >> $outfile
2652 fi
2653 if test "$glib_header_alloca_h" = "yes"; then
2654 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2655 fi
2656 if test x$glib_included_printf != xyes; then
2657 echo "
2658 /* Specifies that GLib's g_print*() functions wrap the
2659 * system printf functions. This is useful to know, for example,
2660 * when using glibc's register_printf_function().
2661 */" >> $outfile
2662 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2663 fi
2665 cat >> $outfile <<_______EOF
2667 G_BEGIN_DECLS
2669 #define G_MINFLOAT FLT_MIN
2670 #define G_MAXFLOAT FLT_MAX
2671 #define G_MINDOUBLE DBL_MIN
2672 #define G_MAXDOUBLE DBL_MAX
2673 #define G_MINSHORT SHRT_MIN
2674 #define G_MAXSHORT SHRT_MAX
2675 #define G_MAXUSHORT USHRT_MAX
2676 #define G_MININT INT_MIN
2677 #define G_MAXINT INT_MAX
2678 #define G_MAXUINT UINT_MAX
2679 #define G_MINLONG LONG_MIN
2680 #define G_MAXLONG LONG_MAX
2681 #define G_MAXULONG ULONG_MAX
2683 _______EOF
2686 ### this should always be true in a modern C/C++ compiler
2687 ### and is statically asserted by glib-init.c
2688 cat >>$outfile <<_______EOF
2689 typedef signed char gint8;
2690 typedef unsigned char guint8;
2691 _______EOF
2694 if test -n "$gint16"; then
2695 cat >>$outfile <<_______EOF
2696 typedef signed $gint16 gint16;
2697 typedef unsigned $gint16 guint16;
2698 #define G_GINT16_MODIFIER $gint16_modifier
2699 #define G_GINT16_FORMAT $gint16_format
2700 #define G_GUINT16_FORMAT $guint16_format
2701 _______EOF
2702 fi
2705 if test -n "$gint32"; then
2706 cat >>$outfile <<_______EOF
2707 typedef signed $gint32 gint32;
2708 typedef unsigned $gint32 guint32;
2709 #define G_GINT32_MODIFIER $gint32_modifier
2710 #define G_GINT32_FORMAT $gint32_format
2711 #define G_GUINT32_FORMAT $guint32_format
2712 _______EOF
2713 fi
2715 cat >>$outfile <<_______EOF
2716 #define G_HAVE_GINT64 1 /* deprecated, always true */
2718 ${glib_extension}typedef signed $gint64 gint64;
2719 ${glib_extension}typedef unsigned $gint64 guint64;
2721 #define G_GINT64_CONSTANT(val) $gint64_constant
2722 #define G_GUINT64_CONSTANT(val) $guint64_constant
2723 _______EOF
2725 if test x$gint64_format != x ; then
2726 cat >>$outfile <<_______EOF
2727 #define G_GINT64_MODIFIER $gint64_modifier
2728 #define G_GINT64_FORMAT $gint64_format
2729 #define G_GUINT64_FORMAT $guint64_format
2730 _______EOF
2731 else
2732 cat >>$outfile <<_______EOF
2733 #undef G_GINT64_MODIFIER
2734 #undef G_GINT64_FORMAT
2735 #undef G_GUINT64_FORMAT
2736 _______EOF
2737 fi
2739 cat >>$outfile <<_______EOF
2741 #define GLIB_SIZEOF_VOID_P $glib_void_p
2742 #define GLIB_SIZEOF_LONG $glib_long
2743 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2744 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2746 _______EOF
2748 cat >>$outfile <<_______EOF
2749 typedef signed $glib_ssize_type_define gssize;
2750 typedef unsigned $glib_size_type_define gsize;
2751 #define G_GSIZE_MODIFIER $gsize_modifier
2752 #define G_GSSIZE_MODIFIER $gssize_modifier
2753 #define G_GSIZE_FORMAT $gsize_format
2754 #define G_GSSIZE_FORMAT $gssize_format
2756 #define G_MAXSIZE G_MAXU$glib_msize_type
2757 #define G_MINSSIZE G_MIN$glib_mssize_type
2758 #define G_MAXSSIZE G_MAX$glib_mssize_type
2760 typedef gint64 goffset;
2761 #define G_MINOFFSET G_MININT64
2762 #define G_MAXOFFSET G_MAXINT64
2764 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2765 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2766 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2768 #define G_POLLFD_FORMAT $g_pollfd_format
2770 _______EOF
2772 if test -z "$glib_unknown_void_p"; then
2773 cat >>$outfile <<_______EOF
2775 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2776 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2778 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2779 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2781 typedef signed $glib_intptr_type_define gintptr;
2782 typedef unsigned $glib_intptr_type_define guintptr;
2784 #define G_GINTPTR_MODIFIER $gintptr_modifier
2785 #define G_GINTPTR_FORMAT $gintptr_format
2786 #define G_GUINTPTR_FORMAT $guintptr_format
2787 _______EOF
2788 else
2789 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2790 fi
2794 cat >>$outfile <<_______EOF
2795 #ifndef G_DISABLE_DEPRECATED
2796 #define g_ATEXIT(proc) (atexit (proc))
2797 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2798 #endif
2799 $glib_defines
2800 $glib_os
2801 $glib_static_compilation
2803 $glib_vacopy
2805 _______EOF
2807 if test x$g_have_iso_c_varargs = xyes ; then
2808 cat >>$outfile <<_______EOF
2809 #ifndef __cplusplus
2810 # define G_HAVE_ISO_VARARGS 1
2811 #endif
2812 _______EOF
2813 fi
2814 if test x$g_have_iso_cxx_varargs = xyes ; then
2815 cat >>$outfile <<_______EOF
2816 #ifdef __cplusplus
2817 # define G_HAVE_ISO_VARARGS 1
2818 #endif
2819 _______EOF
2820 fi
2821 if test x$g_have_gnuc_varargs = xyes ; then
2822 cat >>$outfile <<_______EOF
2824 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2825 * is passed ISO vararg support is turned off, and there is no work
2826 * around to turn it on, so we unconditionally turn it off.
2827 */
2828 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2829 # undef G_HAVE_ISO_VARARGS
2830 #endif
2832 #define G_HAVE_GNUC_VARARGS 1
2833 _______EOF
2834 fi
2836 case x$g_stack_grows in
2837 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2838 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2839 esac
2842 echo >>$outfile
2843 if test x$g_have_eilseq = xno; then
2844 cat >>$outfile <<_______EOF
2845 #ifndef EILSEQ
2846 /* On some pre-C99 systems, EILSEQ is not defined.
2847 * The correspondence between this and the corresponding definition
2848 * in libiconv is essential.
2849 */
2850 # define EILSEQ ENOENT
2851 #endif
2852 _______EOF
2854 fi
2856 if test x$g_have_gnuc_visibility = xyes; then
2857 cat >>$outfile <<_______EOF
2858 #define G_HAVE_GNUC_VISIBILITY 1
2859 _______EOF
2860 fi
2861 cat >>$outfile <<_______EOF
2862 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2863 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2864 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2865 #define G_GNUC_INTERNAL __hidden
2866 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2867 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2868 #else
2869 #define G_GNUC_INTERNAL
2870 #endif
2871 _______EOF
2873 echo >>$outfile
2874 cat >>$outfile <<_______EOF
2875 #define G_THREADS_ENABLED
2876 #define G_THREADS_IMPL_$g_threads_impl_def
2877 _______EOF
2879 if test x"$g_memory_barrier_needed" != xno; then
2880 echo >>$outfile
2881 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2882 fi
2883 if test x"$g_atomic_lock_free" = xyes; then
2884 echo >>$outfile
2885 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2886 fi
2887 echo >>$outfile
2888 g_bit_sizes="16 32 64"
2889 for bits in $g_bit_sizes; do
2890 cat >>$outfile <<_______EOF
2891 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2892 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2893 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2894 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2895 _______EOF
2896 done
2898 cat >>$outfile <<_______EOF
2899 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2900 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2901 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2902 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2903 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2904 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2905 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2906 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2907 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2908 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2909 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2910 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2911 #define G_BYTE_ORDER $g_byte_order
2913 #define GLIB_SYSDEF_POLLIN =$g_pollin
2914 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2915 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2916 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2917 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2918 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2920 #define G_MODULE_SUFFIX "$g_module_suffix"
2922 typedef $g_pid_type GPid;
2923 #define G_PID_FORMAT $g_pid_format
2925 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2926 #define GLIB_SYSDEF_AF_INET $g_af_inet
2927 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2929 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2930 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2931 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2933 G_END_DECLS
2935 #endif /* __GLIBCONFIG_H__ */
2936 _______EOF
2939 if cmp -s $outfile glib/glibconfig.h; then
2940 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2941 rm -f $outfile
2942 else
2943 mv $outfile glib/glibconfig.h
2944 fi
2945 ],[
2947 # Note that if two cases are the same, case goes with the first one.
2948 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2949 # on variable expansion in case labels. Look at the generated config.status
2950 # for a hint.
2952 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2953 glib_header_alloca_h="$ac_cv_working_alloca_h"
2954 else
2955 glib_header_alloca_h="$ac_cv_header_alloca_h"
2956 fi
2958 if test x$enable_included_printf = xyes ; then
2959 glib_included_printf=yes
2960 fi
2962 case 2 in
2963 $ac_cv_sizeof_short)
2964 gint16=short
2965 gint16_modifier='"h"'
2966 gint16_format='"hi"'
2967 guint16_format='"hu"'
2968 ;;
2969 $ac_cv_sizeof_int)
2970 gint16=int
2971 gint16_modifier='""'
2972 gint16_format='"i"'
2973 guint16_format='"u"'
2974 ;;
2975 esac
2976 case 4 in
2977 $ac_cv_sizeof_short)
2978 gint32=short
2979 gint32_modifier='"h"'
2980 gint32_format='"hi"'
2981 guint32_format='"hu"'
2982 ;;
2983 $ac_cv_sizeof_int)
2984 gint32=int
2985 gint32_modifier='""'
2986 gint32_format='"i"'
2987 guint32_format='"u"'
2988 ;;
2989 $ac_cv_sizeof_long)
2990 gint32=long
2991 gint32_modifier='"l"'
2992 gint32_format='"li"'
2993 guint32_format='"lu"'
2994 ;;
2995 esac
2996 case 8 in
2997 $ac_cv_sizeof_int)
2998 gint64=int
2999 gint64_modifier='""'
3000 gint64_format='"i"'
3001 guint64_format='"u"'
3002 glib_extension=
3003 gint64_constant='(val)'
3004 guint64_constant='(val)'
3005 ;;
3006 $ac_cv_sizeof_long)
3007 gint64=long
3008 gint64_modifier='"l"'
3009 gint64_format='"li"'
3010 guint64_format='"lu"'
3011 glib_extension=
3012 gint64_constant='(val##L)'
3013 guint64_constant='(val##UL)'
3014 ;;
3015 $ac_cv_sizeof_long_long)
3016 gint64='long long'
3017 if test -n "$glib_cv_long_long_format"; then
3018 gint64_modifier='"'$glib_cv_long_long_format'"'
3019 gint64_format='"'$glib_cv_long_long_format'i"'
3020 guint64_format='"'$glib_cv_long_long_format'u"'
3021 fi
3022 glib_extension='G_GNUC_EXTENSION '
3023 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3024 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3025 ;;
3026 $ac_cv_sizeof___int64)
3027 gint64='__int64'
3028 if test -n "$glib_cv_long_long_format"; then
3029 gint64_modifier='"'$glib_cv_long_long_format'"'
3030 gint64_format='"'$glib_cv_long_long_format'i"'
3031 guint64_format='"'$glib_cv_long_long_format'u"'
3032 fi
3033 glib_extension=
3034 gint64_constant='(val##i64)'
3035 guint64_constant='(val##ui64)'
3036 ;;
3037 esac
3038 glib_size_t=$ac_cv_sizeof_size_t
3039 glib_ssize_t=$ac_cv_sizeof_ssize_t
3040 glib_size_type_define="$glib_size_type"
3041 glib_ssize_type_define="$glib_ssize_type"
3042 glib_void_p=$ac_cv_sizeof_void_p
3043 glib_long=$ac_cv_sizeof_long
3045 case "$glib_size_type" in
3046 short)
3047 gsize_modifier='"h"'
3048 gsize_format='"hu"'
3049 glib_msize_type='SHRT'
3050 ;;
3051 int)
3052 gsize_modifier='""'
3053 gsize_format='"u"'
3054 glib_msize_type='INT'
3055 ;;
3056 long)
3057 gsize_modifier='"l"'
3058 gsize_format='"lu"'
3059 glib_msize_type='LONG'
3060 ;;
3061 "long long"|__int64)
3062 gsize_modifier='"I64"'
3063 gsize_format='"I64u"'
3064 glib_msize_type='INT64'
3065 ;;
3066 esac
3068 case "$glib_ssize_type" in
3069 short)
3070 gssize_modifier='"h"'
3071 gssize_format='"hi"'
3072 glib_mssize_type='SHRT'
3073 ;;
3074 int)
3075 gssize_modifier='""'
3076 gssize_format='"i"'
3077 glib_mssize_type='INT'
3078 ;;
3079 long)
3080 gssize_modifier='"l"'
3081 gssize_format='"li"'
3082 glib_mssize_type='LONG'
3083 ;;
3084 "long long"|__int64)
3085 gssize_modifier='"I64"'
3086 gssize_format='"I64i"'
3087 glib_mssize_type='INT64'
3088 ;;
3089 esac
3091 gintbits=`expr $ac_cv_sizeof_int \* 8`
3092 glongbits=`expr $ac_cv_sizeof_long \* 8`
3093 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3094 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3096 case $ac_cv_sizeof_void_p in
3097 $ac_cv_sizeof_int)
3098 glib_intptr_type_define=int
3099 gintptr_modifier='""'
3100 gintptr_format='"i"'
3101 guintptr_format='"u"'
3102 glib_gpi_cast='(gint)'
3103 glib_gpui_cast='(guint)'
3104 ;;
3105 $ac_cv_sizeof_long)
3106 glib_intptr_type_define=long
3107 gintptr_modifier='"l"'
3108 gintptr_format='"li"'
3109 guintptr_format='"lu"'
3110 glib_gpi_cast='(glong)'
3111 glib_gpui_cast='(gulong)'
3112 ;;
3113 $ac_cv_sizeof_long_long)
3114 glib_intptr_type_define='long long'
3115 gintptr_modifier='"I64"'
3116 gintptr_format='"I64i"'
3117 guintptr_format='"I64u"'
3118 glib_gpi_cast='(gint64)'
3119 glib_gpui_cast='(guint64)'
3120 ;;
3121 $ac_cv_sizeof___int64)
3122 glib_intptr_type_define=__int64
3123 gintptr_modifier='"I64"'
3124 gintptr_format='"I64i"'
3125 guintptr_format='"I64u"'
3126 glib_gpi_cast='(gint64)'
3127 glib_gpui_cast='(guint64)'
3128 ;;
3129 *)
3130 glib_unknown_void_p=yes
3131 ;;
3132 esac
3135 glib_defines="
3136 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3137 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3138 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3139 "
3141 case xyes in
3142 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3143 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3144 *) glib_vacopy=''
3145 esac
3147 if test x$glib_cv_va_val_copy = xno; then
3148 glib_vacopy="\$glib_vacopy
3149 #define G_VA_COPY_AS_ARRAY 1"
3150 fi
3152 g_have_gnuc_varargs=$g_have_gnuc_varargs
3153 g_have_iso_c_varargs=$g_have_iso_c_varargs
3154 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3156 g_have_gnuc_visibility=$g_have_gnuc_visibility
3157 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3159 if test x$ac_cv_c_bigendian = xyes; then
3160 g_byte_order=G_BIG_ENDIAN
3161 g_bs_native=BE
3162 g_bs_alien=LE
3163 else
3164 g_byte_order=G_LITTLE_ENDIAN
3165 g_bs_native=LE
3166 g_bs_alien=BE
3167 fi
3169 g_pollin=$glib_cv_value_POLLIN
3170 g_pollout=$glib_cv_value_POLLOUT
3171 g_pollpri=$glib_cv_value_POLLPRI
3172 g_pollhup=$glib_cv_value_POLLHUP
3173 g_pollerr=$glib_cv_value_POLLERR
3174 g_pollnval=$glib_cv_value_POLLNVAL
3176 # If a family is not found on the system, define that family to
3177 # a negative value, picking a different one for each undefined
3178 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3179 # This is needed because glib-mkenums doesn't handle optional
3180 # values in enums, and thus we have to have all existing values
3181 # defined in the enum.
3182 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3183 g_af_unix=$glib_cv_value_AF_UNIX
3184 else
3185 g_af_unix=-1
3186 fi
3187 g_af_inet=$glib_cv_value_AF_INET
3188 g_af_inet6=$glib_cv_value_AF_INET6
3190 g_msg_peek=$glib_cv_value_MSG_PEEK
3191 g_msg_oob=$glib_cv_value_MSG_OOB
3192 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3194 g_stack_grows=$glib_cv_stack_grows
3196 g_have_eilseq=$have_eilseq
3198 g_threads_impl_def=$g_threads_impl
3200 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3201 g_memory_barrier_needed="$glib_memory_barrier_needed"
3202 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3204 g_module_suffix="$glib_gmodule_suffix"
3205 g_pid_type="$glib_pid_type"
3206 g_pid_format="\"$glib_pid_format\""
3207 g_pollfd_format="\"$glib_pollfd_format\""
3209 case $host in
3210 *-*-cygwin*)
3211 glib_os="#define G_OS_UNIX
3212 #define G_PLATFORM_WIN32
3213 #define G_WITH_CYGWIN"
3214 ;;
3215 *-*-mingw*)
3216 glib_os="#define G_OS_WIN32
3217 #define G_PLATFORM_WIN32"
3218 ;;
3219 *)
3220 glib_os="#define G_OS_UNIX"
3221 ;;
3222 esac
3223 glib_static_compilation=""
3224 if test x$glib_win32_static_compilation = xyes; then
3225 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3226 #define GOBJECT_STATIC_COMPILATION 1"
3227 fi
3228 ])
3230 # Redo enough to get guint32 and guint64 for the alignment checks below
3231 case 4 in
3232 $ac_cv_sizeof_short)
3233 gint32=short
3234 ;;
3235 $ac_cv_sizeof_int)
3236 gint32=int
3237 ;;
3238 $ac_cv_sizeof_long)
3239 gint32=long
3240 ;;
3241 esac
3242 case 8 in
3243 $ac_cv_sizeof_int)
3244 gint64=int
3245 ;;
3246 $ac_cv_sizeof_long)
3247 gint64=long
3248 ;;
3249 $ac_cv_sizeof_long_long)
3250 gint64='long long'
3251 ;;
3252 $ac_cv_sizeof___int64)
3253 gint64='__int64'
3254 ;;
3255 esac
3257 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3258 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3259 typedef unsigned $gint32 guint32;])
3260 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3261 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3262 typedef unsigned $gint64 guint64;])
3263 AC_CHECK_TYPE([unsigned long])
3264 AC_CHECK_ALIGNOF([unsigned long])
3266 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3267 #
3268 # 1.2.14 required for dbus_message_set_serial
3269 PKG_CHECK_MODULES(DBUS1,
3270 dbus-1 >= 1.2.14,
3271 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3272 have_dbus1=no)
3273 AC_SUBST(DBUS1_CFLAGS)
3274 AC_SUBST(DBUS1_LIBS)
3275 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3277 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3278 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3280 dnl
3281 dnl Check for -Bsymbolic-functions linker flag used to avoid
3282 dnl intra-library PLT jumps, if available.
3283 dnl
3285 AC_ARG_ENABLE(Bsymbolic,
3286 [AS_HELP_STRING([--disable-Bsymbolic],
3287 [avoid linking with -Bsymbolic])],,
3288 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3289 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3290 LDFLAGS=-Wl,-Bsymbolic-functions
3291 LIBS=
3292 AC_TRY_LINK([], [return 0],
3293 AC_MSG_RESULT(yes)
3294 enable_Bsymbolic=yes,
3295 AC_MSG_RESULT(no)
3296 enable_Bsymbolic=no)
3297 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3299 if test "x${enable_Bsymbolic}" = "xyes"; then
3300 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3301 fi
3303 dnl
3304 dnl Check for -z,nodelete linker flag: the type system assumes that
3305 dnl libgobject stays loaded for the lifetime of the process.
3306 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3307 dnl we also try to check for the --fatal-warnings linker flag if
3308 dnl auto-detecting.
3309 dnl
3311 AC_ARG_ENABLE([znodelete],
3312 [AS_HELP_STRING([--disable-znodelete],
3313 [avoid linking with -z,nodelete])],,
3314 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3315 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3316 LDFLAGS=-Wl,--fatal-warnings
3317 LIBS=
3318 AC_TRY_LINK([], [return 0],
3319 AC_MSG_RESULT(yes)
3320 [ldflags_fatal=-Wl,--fatal-warnings],
3321 AC_MSG_RESULT(no)
3322 ldflags_fatal=)
3323 AC_MSG_CHECKING([for -z,nodelete linker flag])
3324 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3325 AC_TRY_LINK([], [return 0],
3326 AC_MSG_RESULT(yes)
3327 enable_znodelete=yes,
3328 AC_MSG_RESULT(no)
3329 enable_znodelete=no)
3330 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3332 if test "x${enable_znodelete}" = "xyes"; then
3333 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3334 fi
3336 AC_SUBST(GLIB_LINK_FLAGS)
3338 dnl
3339 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3340 dnl visibility attributes for symbol export control
3341 dnl
3342 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3343 case "$host" in
3344 *-*-mingw*)
3345 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3346 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3347 [defines how to decorate public symbols while building])
3348 CFLAGS="${CFLAGS} -fvisibility=hidden"
3349 ;;
3350 *)
3351 dnl on other compilers, check if we can do -fvisibility=hidden
3352 SAVED_CFLAGS="${CFLAGS}"
3353 CFLAGS="-fvisibility=hidden"
3354 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3355 AC_TRY_COMPILE([], [return 0],
3356 AC_MSG_RESULT(yes)
3357 enable_fvisibility_hidden=yes,
3358 AC_MSG_RESULT(no)
3359 enable_fvisibility_hidden=no)
3360 CFLAGS="${SAVED_CFLAGS}"
3362 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3363 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3364 [defines how to decorate public symbols while building])
3365 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3366 ])
3367 ;;
3368 esac
3369 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3371 dnl Compiler flags; macro originates from systemd
3372 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3373 AC_ARG_ENABLE(compile-warnings,
3374 [AS_HELP_STRING([--disable-compile-warnings],
3375 [Don't use builtin compiler warnings])],,
3376 enable_compile_warnings=yes)
3377 AS_IF([test "x$enable_compile_warnings" = xyes], [
3378 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3379 -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3380 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3381 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3382 -Werror=format=2 -Werror=missing-include-dirs])
3383 ])
3384 AC_SUBST(GLIB_WARN_CFLAGS)
3386 #
3387 # Define variables corresponding to the correct include paths to use for
3388 # in-tree building.
3389 #
3391 # for config.h:
3392 config_h_INCLUDES='-I$(top_builddir)'
3393 AC_SUBST(config_h_INCLUDES)
3395 # glib:
3396 # config.h
3397 # $(top_builddir)/glib: for glibconfig.h
3398 # $(top_srcdir)/glib: for glib.h
3399 # $(top_srcdir): for everything
3400 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3401 AC_SUBST(glib_INCLUDES)
3403 # gobject:
3404 # same as glib
3405 gobject_INCLUDES='$(glib_INCLUDES)'
3406 AC_SUBST(gobject_INCLUDES)
3408 # gmodule:
3409 # glib includes
3410 # $(top_srcdir)/gmodule: for gmodule.h
3411 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3412 AC_SUBST(gmodule_INCLUDES)
3414 # gio:
3415 # same as gmodule
3416 gio_INCLUDES='$(gmodule_INCLUDES)'
3417 AC_SUBST(gio_INCLUDES)
3420 AC_CONFIG_FILES([
3421 glib-2.0.pc
3422 gmodule-2.0.pc
3423 gmodule-export-2.0.pc
3424 gmodule-no-export-2.0.pc
3425 gthread-2.0.pc
3426 gobject-2.0.pc
3427 gio-2.0.pc
3428 gio-unix-2.0.pc
3429 gio-windows-2.0.pc
3430 glib-zip
3431 glib-gettextize
3432 Makefile
3433 build/Makefile
3434 build/win32/Makefile
3435 build/win32/dirent/Makefile
3436 build/win32/vs9/Makefile
3437 build/win32/vs9/glib-version-paths.vsprops
3438 build/win32/vs10/Makefile
3439 build/win32/vs10/glib-version-paths.props
3440 build/win32/vs11/Makefile
3441 build/win32/vs12/Makefile
3442 build/win32/vs14/Makefile
3443 glib/Makefile
3444 glib/libcharset/Makefile
3445 glib/gnulib/Makefile
3446 glib/pcre/Makefile
3447 glib/update-pcre/Makefile
3448 glib/tests/Makefile
3449 gmodule/Makefile
3450 gmodule/gmoduleconf.h
3451 gobject/Makefile
3452 gobject/glib-mkenums
3453 gobject/tests/Makefile
3454 gthread/Makefile
3455 gio/Makefile
3456 gio/gdbus-2.0/codegen/Makefile
3457 gio/gdbus-2.0/codegen/config.py
3458 gio/gnetworking.h
3459 gio/xdgmime/Makefile
3460 gio/inotify/Makefile
3461 gio/kqueue/Makefile
3462 gio/fam/Makefile
3463 gio/win32/Makefile
3464 gio/tests/Makefile
3465 gio/tests/gdbus-object-manager-example/Makefile
3466 gio/tests/services/Makefile
3467 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3468 gio/tests/modules/Makefile
3469 po/Makefile.in
3470 docs/Makefile
3471 docs/reference/Makefile
3472 docs/reference/glib/Makefile
3473 docs/reference/glib/version.xml
3474 docs/reference/gobject/Makefile
3475 docs/reference/gobject/version.xml
3476 docs/reference/gio/Makefile
3477 docs/reference/gio/version.xml
3478 tests/Makefile
3479 tests/gobject/Makefile
3480 tests/refcount/Makefile
3481 m4macros/Makefile
3482 ])
3484 AC_CONFIG_COMMANDS([chmod-scripts],
3485 [chmod 0755 glib-zip
3486 chmod 0755 glib-gettextize
3487 chmod 0755 gobject/glib-mkenums])
3489 # we want to invoke this macro solely so that the config.status script
3490 # and automake generated makefiles know about these generated files.
3491 # They are only needed to distcheck the package
3492 if false; then
3493 AC_CONFIG_FILES([
3494 INSTALL
3495 README
3496 config.h.win32
3497 glib/glibconfig.h.win32
3498 glib/makefile.msc
3499 glib/glib.rc
3500 gmodule/makefile.msc
3501 gmodule/gmodule.rc
3502 gobject/makefile.msc
3503 gobject/gobject.rc
3504 gthread/makefile.msc
3505 gthread/gthread.rc
3506 gio/gio.rc
3507 tests/makefile.msc
3508 ])
3509 fi
3511 AC_OUTPUT