| blob | 00436a2cbd587917427910dec2e7b8bddd51bfe0 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [53])
34 m4_define([glib_micro_version], [2])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_cv_stack_grows=no
131 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
132 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
133 # (Sorry, I don't know exactly what is the problem, but it is related to
134 # floating point formatting and decimal point vs. comma.)
135 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
136 # rigorous enough to notice, though.
137 # So preset the autoconf cache variables.
138 ac_cv_func_vsnprintf_c99=no
139 ac_cv_func_snprintf_c99=no
140 case "$host" in
141 x86_64-*-*)
142 LIB_EXE_MACHINE_FLAG=X64
143 glib_pollfd_format='%#I64x'
144 ;;
145 esac
147 AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
148 ;;
149 *)
150 glib_native_win32=no
151 glib_pid_type=int
152 glib_pid_format='i'
153 glib_pollfd_format='%d'
154 ;;
155 esac
156 case $host in
157 *-*-linux*)
158 glib_os_linux=yes
159 ;;
160 esac
162 AC_MSG_RESULT([$glib_native_win32])
164 AC_MSG_CHECKING([for the Android])
165 case $host in
166 *android*)
167 glib_native_android="yes"
168 ;;
169 *)
170 glib_native_android="no"
171 ;;
172 esac
173 AC_MSG_RESULT([$glib_native_android])
175 AC_SUBST(LIB_EXE_MACHINE_FLAG)
177 glib_have_carbon=no
178 AC_MSG_CHECKING([for Mac OS X Carbon support])
179 AC_TRY_CPP([
180 #include <Carbon/Carbon.h>
181 #include <CoreServices/CoreServices.h>
182 ], glib_have_carbon=yes)
184 AC_MSG_RESULT([$glib_have_carbon])
186 glib_have_cocoa=no
187 AC_MSG_CHECKING([for Mac OS X Cocoa support])
188 AC_TRY_CPP([
189 #include <Cocoa/Cocoa.h>
190 #ifdef GNUSTEP_BASE_VERSION
191 #error "Detected GNUstep, not Cocoa"
192 #endif
193 ], glib_have_cocoa=yes)
195 AC_MSG_RESULT([$glib_have_cocoa])
197 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
198 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
199 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
200 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
201 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
202 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
204 AS_IF([test "$glib_native_win32" = "yes"], [
205 AC_CHECK_TOOL(WINDRES, windres, no)
206 if test "$WINDRES" = no; then
207 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
208 fi
209 AC_CHECK_TOOL(NM, nm, no)
210 if test "$NM" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
212 fi
213 AC_CHECK_TOOL(RANLIB, ranlib, :)
214 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
215 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
216 ])
217 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
219 AS_IF([test "x$glib_have_carbon" = "xyes"], [
220 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
221 CARBON_LIBS="-Wl,-framework,Carbon"
222 LDFLAGS="$LDFLAGS $CARBON_LIBS"
223 ], [CARBON_LIBS=""])
225 AC_SUBST([CARBON_LIBS])
226 ac_cv_have_os_x_9_or_later="no"
227 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
228 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
229 COCOA_LIBS="-Wl,-framework,Foundation"
230 LDFLAGS="$LDFLAGS $COCOA_LIBS"
231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
232 #include <AvailabilityMacros.h>
233 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
234 #error Compiling for minimum OS X version before 10.9
235 #endif
236 ]])],[ac_cv_have_os_x_9_or_later="yes"])
237 ], [COCOA_LIBS=""])
238 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
239 AC_SUBST([COCOA_LIBS])
241 dnl declare --enable-* args and collect ac_help strings
242 AC_ARG_ENABLE(debug,
243 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
244 [turn on debugging @<:@default=glib_debug_default@:>@]),,
245 enable_debug=glib_debug_default)
247 AC_ARG_ENABLE(gc_friendly,
248 [AS_HELP_STRING([--enable-gc-friendly],
249 [turn on garbage collector friendliness [default=no]])],,
250 [enable_gc_friendly=no])
251 AC_ARG_ENABLE(mem_pools,
252 [AS_HELP_STRING([--disable-mem-pools],
253 [disable all glib memory pools])],,
254 [disable_mem_pools=no])
255 AC_ARG_ENABLE(rebuilds,
256 [AS_HELP_STRING([--disable-rebuilds],
257 [disable all source autogeneration rules])],,
258 [enable_rebuilds=yes])
260 GLIB_TESTS
262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
264 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
265 AC_MSG_RESULT([yes])
266 ], [ AC_MSG_RESULT([no]) ])
268 AC_MSG_CHECKING([whether to disable memory pools])
269 AS_IF([test "x$disable_mem_pools" = "xno"], [
270 AC_MSG_RESULT([no])
271 ], [
272 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
273 AC_MSG_RESULT([yes])
274 ])
276 dnl location to install runtime libraries, e.g. ../../lib to install
277 dnl to /lib if libdir is /usr/lib
278 AC_ARG_WITH(runtime-libdir,
279 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
280 [install runtime libraries relative to libdir])],
281 [],
282 [with_runtime_libdir=""])
283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
289 AC_LANG_SAVE
290 AC_LANG_CPLUSPLUS
291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
293 AC_LANG_RESTORE
295 AM_PROG_CC_C_O
296 AC_PROG_INSTALL
298 AC_SYS_LARGEFILE
300 PKG_PROG_PKG_CONFIG(0.16)
302 if test "x$enable_debug" = "xyes"; then
303 if test "x$cflags_set" != "x" ; then
304 case " $CFLAGS " in
305 *[[\ \ ]]-g[[\ \ ]]*) ;;
306 *) CFLAGS="$CFLAGS -g" ;;
307 esac
308 fi
309 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
310 else
311 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
313 if test "x$enable_debug" = "xno"; then
314 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
315 fi
316 fi
318 # Ensure MSVC-compatible struct packing convention is used when
319 # compiling for Win32 with gcc.
320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
321 # gcc2 uses "-fnative-struct".
322 if test x"$glib_native_win32" = xyes; then
323 if test x"$GCC" = xyes; then
324 msnative_struct=''
325 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
326 if test -z "$ac_cv_prog_CC"; then
327 our_gcc="$CC"
328 else
329 our_gcc="$ac_cv_prog_CC"
330 fi
331 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
332 2.)
333 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
334 msnative_struct='-fnative-struct'
335 fi
336 ;;
337 *)
338 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
339 msnative_struct='-mms-bitfields'
340 fi
341 ;;
342 esac
343 if test x"$msnative_struct" = x ; then
344 AC_MSG_RESULT([no way])
345 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
346 else
347 CFLAGS="$CFLAGS $msnative_struct"
348 AC_MSG_RESULT([${msnative_struct}])
349 fi
350 fi
351 fi
352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
353 AC_SUBST(GLIB_EXTRA_CFLAGS)
355 AC_EXEEXT
357 # define a MAINT-like variable REBUILD which is set if Perl
358 # and awk are found, so autogenerated sources can be rebuilt
359 AC_PROG_AWK
360 AC_CHECK_PROGS(PERL, [perl5 perl])
361 # We would like indent, but don't require it.
362 AC_CHECK_PROG(INDENT, indent, indent)
363 REBUILD=\#
364 if test "x$enable_rebuilds" = "xyes" && \
365 test -n "$PERL" && \
366 $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
367 test -n "$AWK" ; then
368 REBUILD=
369 fi
370 AC_SUBST(REBUILD)
372 # Need full path to Perl for glib-mkenums
373 #
374 if test "x$PERL" != x ; then
375 AC_PATH_PROG(PERL_PATH, [$PERL])
376 fi
377 if test "x$PERL_PATH" = x ; then
378 PERL_PATH="/usr/bin/env perl"
379 fi
380 AC_SUBST(PERL_PATH)
382 # option to specify python interpreter to use; this just sets $PYTHON, so that
383 # we will fallback to reading $PYTHON if --with-python is not given, and
384 # python.m4 will get the expected input
385 AC_ARG_WITH(python,
386 AS_HELP_STRING([--with-python=PATH],
387 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
388 [PYTHON="$withval"], [])
389 if test x"$PYTHON" = xyes; then
390 AC_MSG_ERROR([--with-python option requires a path or program argument])
391 fi
392 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
395 dnl ***********************
396 dnl *** Tests for iconv ***
397 dnl ***********************
398 dnl
399 dnl We do this before the gettext checks, to avoid distortion
401 dnl On Windows we use a native implementation
403 AS_IF([ test x"$glib_native_win32" = xyes], [
404 with_libiconv=native
405 ], [
406 AC_ARG_WITH(libiconv,
407 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
408 [use the libiconv library])],,
409 [with_libiconv=maybe])
411 found_iconv=no
412 case $with_libiconv in
413 maybe)
414 # Check in the C library first
415 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
416 # Check if we have GNU libiconv
417 if test $found_iconv = "no"; then
418 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
419 fi
420 # Check if we have a iconv in -liconv, possibly from vendor
421 if test $found_iconv = "no"; then
422 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
423 fi
424 ;;
425 no)
426 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
427 ;;
428 gnu|yes)
429 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
430 ;;
431 native)
432 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
433 ;;
434 esac
436 if test "x$found_iconv" = "xno" ; then
437 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
438 fi
439 ])
441 dnl
442 dnl zlib support
443 dnl
444 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
445 AS_IF([test "x$found_zlib" = "xno"], [
446 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
447 if test "x$found_zlib" = "xno" ; then
448 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
449 fi
450 ZLIB_LIBS='-lz'
451 AC_SUBST(ZLIB_LIBS)
452 ])
454 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
455 AC_SUBST(LIBFFI_CFLAGS)
456 AC_SUBST(LIBFFI_LIBS)
458 dnl
459 dnl gettext support
460 dnl
462 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
463 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
464 GLIB_GNU_GETTEXT
466 if test "$gt_cv_have_gettext" != "yes" ; then
467 AC_MSG_ERROR([
468 *** You must have either have gettext support in your C library, or use the
469 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
470 ])
471 fi
473 LIBS="$INTLLIBS $LIBS"
475 GETTEXT_PACKAGE=glib20
476 AC_SUBST(GETTEXT_PACKAGE)
477 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
478 [Define the gettext package to be used])
480 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
482 dnl
483 dnl Now we are done with gettext checks, figure out ICONV_LIBS
484 dnl
486 AS_IF([test x"$glib_native_win32" != xyes], [
487 if test x$with_libiconv != xno ; then
488 case " $INTLLIBS " in
489 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
490 *) ICONV_LIBS="-liconv" ;;
491 esac
492 fi
493 ])
494 AC_SUBST(ICONV_LIBS)
496 case $with_libiconv in
497 gnu)
498 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
499 ;;
500 native)
501 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
502 ;;
503 esac
505 dnl Initialize libtool
506 LT_PREREQ([2.2])
507 LT_INIT([disable-static win32-dll])
508 dnl when using libtool 2.x create libtool early, because it's used in configure
509 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
512 AS_IF([test "$glib_native_win32" = "yes"], [
513 if test x$enable_static = xyes -a x$enable_shared = xyes; then
514 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
515 fi
516 if test x$enable_static = xyes; then
517 glib_win32_static_compilation=yes
518 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
519 #define GOBJECT_STATIC_COMPILATION 1"
520 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
521 fi
522 ])
523 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
525 # Checks for library functions.
526 AC_FUNC_ALLOCA
527 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
528 AC_CHECK_FUNCS(timegm gmtime_r strerror_r)
530 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
531 [AC_TRY_LINK([#include <unistd.h>
532 extern int __libc_enable_secure;],
533 [return __libc_enable_secure;],
534 glib_cv_have_libc_enable_secure=yes,
535 glib_cv_have_libc_enable_secure=no)])
536 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
537 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
538 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
539 ])
541 AC_CHECK_SIZEOF(char)
542 AC_CHECK_SIZEOF(short)
543 AC_CHECK_SIZEOF(long)
544 AC_CHECK_SIZEOF(int)
545 AC_CHECK_SIZEOF(void *)
546 AC_CHECK_SIZEOF(long long)
547 AC_CHECK_SIZEOF(__int64)
549 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
550 [AC_TRY_LINK([#include <signal.h>
551 #include <sys/types.h>
552 sig_atomic_t val = 42;],
553 [return val == 42 ? 0 : 1],
554 ac_cv_type_sig_atomic_t=yes,
555 ac_cv_type_sig_atomic_t=no)])
556 if test x$ac_cv_type_sig_atomic_t = xyes; then
557 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
558 [Define if you have the 'sig_atomic_t' type.])
559 fi
561 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
562 :
563 else
564 AC_MSG_ERROR([
565 *** GLib requires a 64 bit type. You might want to consider
566 *** using the GNU C compiler.
567 ])
568 fi
570 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
571 # long long is a 64 bit integer.
572 AC_MSG_CHECKING(for format to printf and scanf a guint64)
573 AC_CACHE_VAL(glib_cv_long_long_format,[
574 for format in ll q I64; do
575 AC_TRY_RUN([#include <stdio.h>
576 int main()
577 {
578 long long b, a = -0x3AFAFAFAFAFAFAFALL;
579 char buffer[1000];
580 sprintf (buffer, "%${format}u", a);
581 sscanf (buffer, "%${format}u", &b);
582 exit (b!=a);
583 }
584 ],
585 [glib_cv_long_long_format=${format}
586 break],
587 [],[:])
588 done])
589 AS_IF([ test -n "$glib_cv_long_long_format"], [
590 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
591 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
592 if test x"$glib_cv_long_long_format" = xI64; then
593 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
594 fi
595 ], [AC_MSG_RESULT(none)])
596 ],[ test x$ac_cv_sizeof___int64 = x8], [
597 # __int64 is a 64 bit integer.
598 AC_MSG_CHECKING(for format to printf and scanf a guint64)
599 # We know this is MSVCRT.DLL, and what the formats are
600 glib_cv_long_long_format=I64
601 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
602 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
603 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
604 ])
606 AC_C_CONST
608 dnl
609 dnl check in which direction the stack grows
610 dnl
611 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
612 AC_TRY_RUN([
613 volatile int *a = 0, *b = 0;
614 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
615 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
616 ],
617 glib_cv_stack_grows=yes
618 ,
619 glib_cv_stack_grows=no
620 ,)
621 ])
623 # check for flavours of varargs macros
624 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
625 AC_TRY_COMPILE([],[
626 int a(int p1, int p2, int p3);
627 #define call_a(...) a(1,__VA_ARGS__)
628 call_a(2,3);
629 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
630 AC_MSG_RESULT($g_have_iso_c_varargs)
632 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
633 AS_IF([test "$CXX" = ""], [
634 dnl No C++ compiler
635 g_have_iso_cxx_varargs=no
636 else
637 AC_LANG_CPLUSPLUS
638 AC_TRY_COMPILE([],[
639 int a(int p1, int p2, int p3);
640 #define call_a(...) a(1,__VA_ARGS__)
641 call_a(2,3);
642 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
643 AC_LANG_C
644 ])
645 AC_MSG_RESULT($g_have_iso_cxx_varargs)
647 AC_MSG_CHECKING(for GNUC varargs macros)
648 AC_TRY_COMPILE([],[
649 int a(int p1, int p2, int p3);
650 #define call_a(params...) a(1,params)
651 call_a(2,3);
652 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
653 AC_MSG_RESULT($g_have_gnuc_varargs)
655 # check for GNUC visibility support
656 AC_MSG_CHECKING(for GNUC visibility attribute)
657 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
658 void
659 __attribute__ ((visibility ("hidden")))
660 f_hidden (void)
661 {
662 }
663 void
664 __attribute__ ((visibility ("internal")))
665 f_internal (void)
666 {
667 }
668 void
669 __attribute__ ((visibility ("protected")))
670 f_protected (void)
671 {
672 }
673 void
674 __attribute__ ((visibility ("default")))
675 f_default (void)
676 {
677 }
678 int main (void)
679 {
680 f_hidden();
681 f_internal();
682 f_protected();
683 f_default();
684 return 0;
685 }
686 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
687 AC_MSG_RESULT($g_have_gnuc_visibility)
688 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
690 AC_MSG_CHECKING([whether using Sun Studio C compiler])
691 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
692 #else
693 # include "error: this is not Sun Studio."
694 #endif
695 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
696 AC_MSG_RESULT($g_have_sunstudio_visibility)
697 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
699 # check for bytesex stuff
700 AC_C_BIGENDIAN
701 if test x$ac_cv_c_bigendian = xuniversal ; then
702 AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
703 fi
706 # check for header files
707 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
708 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
709 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
710 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
711 AC_CHECK_HEADERS([linux/magic.h])
712 AC_CHECK_HEADERS([termios.h])
714 # Some versions of MSC lack these
715 AC_CHECK_HEADERS([dirent.h sys/time.h])
717 # We don't care about this, but we need to keep including it in
718 # glibconfig.h for backward compatibility
719 AC_CHECK_HEADERS([values.h])
721 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
722 [#if HAVE_SYS_PARAM_H
723 #include <sys/param.h>
724 #endif
725 ])
726 AC_CHECK_FUNCS(sysctlbyname)
728 AC_HEADER_MAJOR
729 AC_CHECK_HEADERS([xlocale.h])
731 # check for structure fields
732 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
733 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
734 #include <sys/stat.h>
735 #ifdef G_OS_UNIX
736 #include <unistd.h>
737 #endif
738 #ifdef HAVE_SYS_STATFS_H
739 #include <sys/statfs.h>
740 #endif
741 #ifdef HAVE_SYS_PARAM_H
742 #include <sys/param.h>
743 #endif
744 #ifdef HAVE_SYS_MOUNT_H
745 #include <sys/mount.h>
746 #endif])
747 # struct statvfs.f_basetype is available on Solaris but not for Linux.
748 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
749 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
750 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
752 AC_STRUCT_DIRENT_D_TYPE
754 # Checks for libcharset
755 AM_LANGINFO_CODESET
756 gl_GLIBC21
758 # check additional type sizes
759 AC_CHECK_SIZEOF(size_t)
761 dnl Try to figure out whether gsize should be long or int
762 AC_MSG_CHECKING([for the appropriate definition for size_t])
764 case $ac_cv_sizeof_size_t in
765 $ac_cv_sizeof_short)
766 glib_size_type=short
767 ;;
768 $ac_cv_sizeof_int)
769 glib_size_type=int
770 ;;
771 $ac_cv_sizeof_long)
772 glib_size_type=long
773 ;;
774 $ac_cv_sizeof_long_long)
775 glib_size_type='long long'
776 ;;
777 $ac_cv_sizeof__int64)
778 glib_size_type='__int64'
779 ;;
780 *) AC_MSG_ERROR([No type matching size_t in size])
781 ;;
782 esac
784 dnl If int/long are the same size, we see which one produces
785 dnl warnings when used in the location as size_t. (This matters
786 dnl on AIX with xlc)
787 dnl
788 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
789 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
790 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
791 #if defined(_AIX) && !defined(__GNUC__)
792 #pragma options langlvl=stdc89
793 #endif
794 #include <stddef.h>
795 int main ()
796 {
797 size_t s = 1;
798 unsigned int *size_int = &s;
799 return (int)*size_int;
800 }
801 ]])],glib_size_type=int,
802 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
803 #if defined(_AIX) && !defined(__GNUC__)
804 #pragma options langlvl=stdc89
805 #endif
806 #include <stddef.h>
807 int main ()
808 {
809 size_t s = 1;
810 unsigned long *size_long = &s;
811 return (int)*size_long;
812 }
813 ]])],glib_size_type=long)])
814 ])
816 AC_MSG_RESULT(unsigned $glib_size_type)
818 AC_CHECK_SIZEOF(ssize_t)
820 dnl Try to figure out whether gssize should be long or int
821 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
823 case $ac_cv_sizeof_ssize_t in
824 $ac_cv_sizeof_short)
825 glib_ssize_type=short
826 ;;
827 $ac_cv_sizeof_int)
828 glib_ssize_type=int
829 ;;
830 $ac_cv_sizeof_long)
831 glib_ssize_type=long
832 ;;
833 $ac_cv_sizeof_long_long)
834 glib_ssize_type='long long'
835 ;;
836 $ac_cv_sizeof__int64)
837 glib_ssize_type='__int64'
838 ;;
839 *) AC_MSG_ERROR([No type matching ssize_t in size])
840 ;;
841 esac
843 dnl If int/long are the same size, we see which one produces
844 dnl warnings when used in the location as ssize_t. (This matters
845 dnl on Android where ssize_t is long and size_t is unsigned int)
846 dnl
847 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
848 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
849 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
850 #if defined(_AIX) && !defined(__GNUC__)
851 #pragma options langlvl=stdc89
852 #endif
853 #include <stddef.h>
854 #ifdef HAVE_INTTYPES_H
855 # include <inttypes.h>
856 #endif
857 #ifdef HAVE_STDINT_H
858 # include <stdint.h>
859 #endif
860 #include <sys/types.h>
861 int main ()
862 {
863 ssize_t s = 1;
864 int *size_int = &s;
865 return (int)*size_int;
866 }
867 ]])],glib_ssize_type=int,
868 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
869 #if defined(_AIX) && !defined(__GNUC__)
870 #pragma options langlvl=stdc89
871 #endif
872 #include <stddef.h>
873 #ifdef HAVE_INTTYPES_H
874 # include <inttypes.h>
875 #endif
876 #ifdef HAVE_STDINT_H
877 # include <stdint.h>
878 #endif
879 #include <sys/types.h>
880 int main ()
881 {
882 ssize_t s = 1;
883 long *size_long = &s;
884 return (int)*size_long;
885 }
886 ]])],glib_ssize_type=long)])
887 ])
889 AC_MSG_RESULT($glib_ssize_type)
891 # Check for some functions
892 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
893 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
894 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
895 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
896 AC_CHECK_FUNCS(splice)
897 AC_CHECK_FUNCS(prlimit)
899 # To avoid finding a compatibility unusable statfs, which typically
900 # successfully compiles, but warns to use the newer statvfs interface:
901 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
902 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
904 AC_MSG_CHECKING([whether to use statfs or statvfs])
905 # Some systems have both statfs and statvfs, pick the most "native" for these
906 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
907 [
908 # on solaris and irix, statfs doesn't even have the f_bavail field
909 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
910 [ac_cv_func_statfs=no],
911 # else, at least on linux, statfs is the actual syscall
912 [ac_cv_func_statvfs=no])
913 ])
915 AS_IF([test x$ac_cv_func_statfs = xyes],
916 [
917 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
918 AC_MSG_RESULT([statfs])
919 ],
920 [test x$ac_cv_func_statvfs = xyes],
921 [
922 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
923 AC_MSG_RESULT([statvfs])
924 ],
925 [ AC_MSG_RESULT([neither])])
927 AC_CHECK_HEADERS(crt_externs.h)
928 AC_CHECK_FUNCS(_NSGetEnviron)
930 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
932 # Internet address families
933 if test $glib_native_win32 = yes; then
934 glib_inet_includes=["
935 #include <winsock2.h>
936 "]
937 else
938 glib_inet_includes=["
939 #include <sys/types.h>
940 #include <sys/socket.h>
941 "]
942 fi
944 glib_failed=false
945 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
946 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
947 # winsock defines this even though it doesn't support it
948 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
949 if $glib_failed ; then
950 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
951 fi
953 glib_failed=false
954 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
955 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
956 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
957 if $glib_failed ; then
958 AC_MSG_ERROR([Could not determine values for MSG_* constants])
959 fi
961 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
963 AS_IF([test $glib_native_win32 = yes], [
964 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
965 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
966 # they aren't present at run-time (on Windows 2000).
967 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
968 AC_SUBST(WSPIAPI_INCLUDE)
969 ], [
970 # Android does not have C_IN in public headers, we define it wherever necessary
971 AS_IF([test $glib_native_android != yes], [
972 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
973 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
974 #include <arpa/nameser.h>],
975 [int qclass = C_IN;])],
976 [AC_MSG_RESULT([no])],
977 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
978 #include <arpa/nameser.h>
979 #include <arpa/nameser_compat.h>],
980 [int qclass = C_IN;])],
981 [AC_MSG_RESULT([yes])
982 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
983 [AC_MSG_ERROR([could not compile test program either way])])])])
984 AC_SUBST(NAMESER_COMPAT_INCLUDE)
986 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
987 NETWORK_LIBS=""
988 AC_MSG_CHECKING([for res_query])
989 AC_TRY_LINK([#include <sys/types.h>
990 #include <netinet/in.h>
991 #include <arpa/nameser.h>
992 #include <resolv.h>
993 ],[
994 res_query("test", 0, 0, (void *)0, 0);
995 ],[AC_MSG_RESULT([yes])],
996 [save_libs="$LIBS"
997 LIBS="-lresolv $LIBS"
998 AC_TRY_LINK([#include <sys/types.h>
999 #include <netinet/in.h>
1000 #include <arpa/nameser.h>
1001 #include <resolv.h>
1002 ],[
1003 res_query("test", 0, 0, (void *)0, 0);
1004 ],[AC_MSG_RESULT([in -lresolv])
1005 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1006 [LIBS="-lbind $save_libs"
1007 AC_TRY_LINK([#include <resolv.h>],
1008 [res_query("test", 0, 0, (void *)0, 0);],
1009 [AC_MSG_RESULT([in -lbind])
1010 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1011 [AC_MSG_ERROR(not found)])])
1012 LIBS="$save_libs"])
1013 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1014 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1015 [AC_MSG_ERROR(Could not find socket())]))
1016 save_libs="$LIBS"
1017 LIBS="$LIBS $NETWORK_LIBS"
1018 AC_MSG_CHECKING([for res_init])
1019 AC_TRY_LINK([#include <sys/types.h>
1020 #include <netinet/in.h>
1021 #include <arpa/nameser.h>
1022 #include <resolv.h>
1023 ],[
1024 res_init();
1025 ],[AC_MSG_RESULT([yes])
1026 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1027 ],[AC_MSG_RESULT([no])])
1028 LIBS="$save_libs"
1029 ])
1030 AC_SUBST(NETWORK_LIBS)
1032 AC_CHECK_HEADER([linux/netlink.h],
1033 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1034 [#include <sys/socket.h>])
1035 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1037 AC_CHECK_TYPE([struct ip_mreqn], [
1038 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1039 [#include <netinet/in.h>])
1041 case $host in
1042 *-*-solaris* )
1043 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1044 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1045 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1046 ;;
1047 esac
1049 dnl
1050 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1051 dnl
1052 AS_IF([test "$ac_cv_func_statfs" = yes], [
1053 AC_MSG_CHECKING([number of arguments to statfs()])
1054 AC_TRY_COMPILE([#include <unistd.h>
1055 #ifdef HAVE_SYS_PARAM_H
1056 #include <sys/param.h>
1057 #endif
1058 #ifdef HAVE_SYS_VFS_H
1059 #include <sys/vfs.h>
1060 #endif
1061 #ifdef HAVE_SYS_MOUNT_H
1062 #include <sys/mount.h>
1063 #endif
1064 #ifdef HAVE_SYS_STATFS_H
1065 #include <sys/statfs.h>
1066 #endif], [struct statfs st;
1067 statfs("/", &st);],[
1068 AC_MSG_RESULT([2])
1069 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1070 AC_TRY_COMPILE([#include <unistd.h>
1071 #ifdef HAVE_SYS_PARAM_H
1072 #include <sys/param.h>
1073 #endif
1074 #ifdef HAVE_SYS_VFS_H
1075 #include <sys/vfs.h>
1076 #endif
1077 #ifdef HAVE_SYS_MOUNT_H
1078 #include <sys/mount.h>
1079 #endif
1080 #ifdef HAVE_SYS_STATFS_H
1081 #include <sys/statfs.h>
1082 #endif], [struct statfs st;
1083 statfs("/", &st, sizeof (st), 0);],[
1084 AC_MSG_RESULT([4])
1085 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1086 AC_MSG_RESULT(unknown)
1087 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1088 ])
1090 dnl
1091 dnl open takes O_DIRECTORY as an option
1092 dnl
1093 AC_MSG_CHECKING([open() option O_DIRECTORY])
1094 AC_TRY_COMPILE([#include <fcntl.h>
1095 #include <sys/types.h>
1096 #include <sys/stat.h>],
1097 [open(0, O_DIRECTORY, 0);],[
1098 AC_MSG_RESULT([yes])
1099 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1100 AC_MSG_RESULT([no])])
1102 #
1103 # Check whether to use an included printf
1104 #
1105 AC_FUNC_VSNPRINTF_C99
1106 AC_FUNC_PRINTF_UNIX98
1108 AC_ARG_ENABLE(included-printf,
1109 [AS_HELP_STRING([--enable-included-printf],
1110 [use included printf [default=auto]])],
1111 enable_included_printf="$enableval")
1113 need_included_printf=no
1114 if test "x$enable_included_printf" = "xyes" ; then
1115 need_included_printf=yes
1116 fi
1117 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1118 need_included_printf=yes
1119 fi
1120 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1121 need_included_printf=yes
1122 fi
1123 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1124 test -z "$glib_cv_long_long_format" ; then
1125 need_included_printf=yes
1126 fi
1128 if test "x$enable_included_printf" = "xno" &&
1129 test "x$need_included_printf" = "xyes" ; then
1130 AC_MSG_ERROR([
1131 *** Your C library's printf doesn't appear to have the features that
1132 *** GLib needs, but you specified --enable-included-printf=no.])
1133 fi
1135 enable_included_printf=$need_included_printf
1137 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1138 AS_IF([test "$enable_included_printf" != "yes"], [
1139 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1140 ], [
1141 if test -z "$glib_cv_long_long_format" ; then
1142 glib_cv_long_long_format="ll"
1143 fi
1144 AC_DEFINE(HAVE_VASPRINTF,1)
1145 ])
1147 # Checks needed for gnulib vasnprintf
1148 bh_C_SIGNED
1149 jm_AC_TYPE_LONG_LONG
1150 gt_TYPE_LONGDOUBLE
1151 gt_TYPE_WCHAR_T
1152 gt_TYPE_WINT_T
1153 AC_TYPE_SIZE_T
1154 AC_CHECK_TYPES(ptrdiff_t)
1155 jm_AC_TYPE_INTMAX_T
1156 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1157 AC_FUNC_SNPRINTF_C99
1159 # Check if <sys/select.h> needs to be included for fd_set
1160 AC_MSG_CHECKING([for fd_set])
1161 AC_TRY_COMPILE([#include <sys/types.h>],
1162 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1163 AS_IF([test "$gtk_ok" = "yes"], [
1164 AC_MSG_RESULT([yes, found in sys/types.h])
1165 ], [
1166 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1167 if test "$gtk_ok" = "yes"; then
1168 # *** FIXME: give it a different name
1169 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1170 AC_MSG_RESULT([yes, found in sys/select.h])
1171 else
1172 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1173 AC_MSG_RESULT(no)
1174 fi
1175 ])
1177 dnl Check for nl_langinfo and CODESET
1178 AC_LANG_SAVE
1179 AC_LANG_C
1180 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1181 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1182 [char *codeset = nl_langinfo (CODESET);])],
1183 [glib_cv_langinfo_codeset=yes],
1184 [glib_cv_langinfo_codeset=no])])
1185 if test x$glib_cv_langinfo_codeset = xyes; then
1186 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1187 fi
1189 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1190 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1191 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1192 [char *str;
1193 str = nl_langinfo (PM_STR);
1194 str = nl_langinfo (D_T_FMT);
1195 str = nl_langinfo (D_FMT);
1196 str = nl_langinfo (T_FMT);
1197 str = nl_langinfo (T_FMT_AMPM);
1198 str = nl_langinfo (MON_1);
1199 str = nl_langinfo (ABMON_12);
1200 str = nl_langinfo (DAY_1);
1201 str = nl_langinfo (ABDAY_7);])],
1202 [glib_cv_langinfo_time=yes],
1203 [glib_cv_langinfo_time=no])])
1204 if test x$glib_cv_langinfo_time = xyes; then
1205 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1206 fi
1208 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1209 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1210 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1211 [char *str;
1212 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1213 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1214 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1215 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1216 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1217 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1218 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1219 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1220 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1222 [glib_cv_langinfo_outdigit=yes],
1223 [glib_cv_langinfo_outdigit=no])])
1224 if test x$glib_cv_langinfo_outdigit = xyes; then
1225 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1226 fi
1227 AC_LANG_RESTORE
1229 dnl ****************************************
1230 dnl *** posix_memalign ***
1231 dnl ****************************************
1232 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1233 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1234 glib_cv_compliant_posix_memalign=0
1235 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1236 AC_TRY_RUN([
1237 #define _XOPEN_SOURCE 600
1238 #include <stdlib.h> /* posix_memalign() should be defined here */
1239 /* some systems break if #include <malloc.h> used */
1240 static void test_memalign (size_t boundary, size_t size) {
1241 void *mem = 0;
1242 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1243 exit (1);
1244 else
1245 free (mem);
1246 }
1247 int main() {
1248 test_memalign ( 128, 128 - 2 * sizeof (void*));
1249 test_memalign ( 256, 256 - 2 * sizeof (void*));
1250 test_memalign ( 512, 512 - 2 * sizeof (void*));
1251 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1252 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1253 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1254 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1255 test_memalign (16384, 16384 - 2 * sizeof (void*));
1256 test_memalign (32768, 32768 - 2 * sizeof (void*));
1257 exit (0); /* success */
1258 }
1259 ],
1260 [glib_cv_compliant_posix_memalign=1], [], [:])
1261 :
1262 fi
1263 ])
1264 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1265 AC_MSG_RESULT(yes)
1266 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1267 ], [
1268 AC_MSG_RESULT(no)
1269 ])
1272 dnl ****************************************
1273 dnl *** strlcpy/strlcat ***
1274 dnl ****************************************
1275 # Check for strlcpy
1276 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1277 AC_TRY_RUN([#include <stdlib.h>
1278 #include <string.h>
1279 int main() {
1280 char p[10];
1281 (void) strlcpy (p, "hi", 10);
1282 if (strlcat (p, "bye", 0) != 3)
1283 return 1;
1284 return 0;
1285 }], glib_cv_have_strlcpy=yes,
1286 glib_cv_have_strlcpy=no,
1287 glib_cv_have_strlcpy=no)])
1288 if test "$glib_cv_have_strlcpy" = "yes"; then
1289 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1290 fi
1293 dnl **********************
1294 dnl *** va_copy checks ***
1295 dnl **********************
1296 dnl we currently check for all three va_copy possibilities, so we get
1297 dnl all results in config.log for bug reports.
1298 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1299 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1300 #include <stdlib.h>
1301 void f (int i, ...) {
1302 va_list args1, args2;
1303 va_start (args1, i);
1304 va_copy (args2, args1);
1305 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1306 exit (1);
1307 va_end (args1); va_end (args2);
1308 }
1309 int main() {
1310 f (0, 42);
1311 return 0;
1312 }]])],
1313 [glib_cv_va_copy=yes],
1314 [glib_cv_va_copy=no])
1315 ])
1316 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1317 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1318 #include <stdlib.h>
1319 void f (int i, ...) {
1320 va_list args1, args2;
1321 va_start (args1, i);
1322 __va_copy (args2, args1);
1323 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1324 exit (1);
1325 va_end (args1); va_end (args2);
1326 }
1327 int main() {
1328 f (0, 42);
1329 return 0;
1330 }]])],
1331 [glib_cv___va_copy=yes],
1332 [glib_cv___va_copy=no])
1333 ])
1335 if test "x$glib_cv_va_copy" = "xyes"; then
1336 g_va_copy_func=va_copy
1337 else if test "x$glib_cv___va_copy" = "xyes"; then
1338 g_va_copy_func=__va_copy
1339 fi
1340 fi
1342 if test -n "$g_va_copy_func"; then
1343 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1344 fi
1346 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1347 AC_TRY_RUN([#include <stdarg.h>
1348 #include <stdlib.h>
1349 void f (int i, ...) {
1350 va_list args1, args2;
1351 va_start (args1, i);
1352 args2 = args1;
1353 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1354 exit (1);
1355 va_end (args1); va_end (args2);
1356 }
1357 int main() {
1358 f (0, 42);
1359 return 0;
1360 }],
1361 [glib_cv_va_val_copy=yes],
1362 [glib_cv_va_val_copy=no],
1363 [glib_cv_va_val_copy=yes])
1364 ])
1366 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1367 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1368 ])
1370 dnl ***********************
1371 dnl *** g_module checks ***
1372 dnl ***********************
1373 G_MODULE_LIBS=
1374 G_MODULE_LIBS_EXTRA=
1375 G_MODULE_PLUGIN_LIBS=
1376 if test x"$glib_native_win32" = xyes; then
1377 dnl No use for this on Win32
1378 G_MODULE_LDFLAGS=
1379 else
1380 export SED
1381 G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1382 fi
1383 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1384 G_MODULE_NEED_USCORE=0
1385 G_MODULE_BROKEN_RTLD_GLOBAL=0
1386 G_MODULE_HAVE_DLERROR=0
1387 dnl *** force native WIN32 shared lib loader
1388 if test -z "$G_MODULE_IMPL"; then
1389 case "$host" in
1390 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1391 esac
1392 fi
1393 dnl *** force native AIX library loader
1394 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1395 if test -z "$G_MODULE_IMPL"; then
1396 case "$host" in
1397 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1398 esac
1399 fi
1400 dnl *** dlopen() and dlsym() in system libraries
1401 AS_IF([ test -z "$G_MODULE_IMPL"], [
1402 AC_CHECK_FUNC(dlopen,
1403 [AC_CHECK_FUNC(dlsym,
1404 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1405 [])
1406 ])
1407 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1408 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1409 AC_CHECK_FUNC(NSLinkModule,
1410 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1411 G_MODULE_NEED_USCORE=1],
1412 [])
1413 ])
1414 dnl *** dlopen() and dlsym() in libdl
1415 AS_IF([ test -z "$G_MODULE_IMPL"], [
1416 AC_CHECK_LIB(dl, dlopen,
1417 [AC_CHECK_LIB(dl, dlsym,
1418 [G_MODULE_LIBS=-ldl
1419 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1420 [])
1421 ])
1422 dnl *** additional checks for G_MODULE_IMPL_DL
1423 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1424 LIBS_orig="$LIBS"
1425 LDFLAGS_orig="$LDFLAGS"
1426 LIBS="$G_MODULE_LIBS $LIBS"
1427 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1428 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1429 echo "void glib_plugin_test(void) { }" > plugin.c
1430 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1431 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1432 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1433 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1434 -shrext ".o" -avoid-version plugin.lo \
1435 -rpath /dont/care >/dev/null 2>&1
1436 eval `./libtool --config | grep ^objdir`
1437 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1438 glib_cv_rtldglobal_broken,[
1439 AC_TRY_RUN([
1440 #include <dlfcn.h>
1441 #ifndef RTLD_GLOBAL
1442 # define RTLD_GLOBAL 0
1443 #endif
1444 #ifndef RTLD_LAZY
1445 # define RTLD_LAZY 0
1446 #endif
1447 int glib_plugin_test;
1448 int main () {
1449 void *handle, *global, *local;
1450 global = &glib_plugin_test;
1451 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1452 if (!handle) return 0;
1453 local = dlsym (handle, "glib_plugin_test");
1454 return global == local;
1455 } ],
1456 [glib_cv_rtldglobal_broken=no],
1457 [glib_cv_rtldglobal_broken=yes],
1458 [glib_cv_rtldglobal_broken=no])
1459 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1460 rmdir ${objdir} 2>/dev/null
1461 ])
1462 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1463 G_MODULE_BROKEN_RTLD_GLOBAL=1
1464 else
1465 G_MODULE_BROKEN_RTLD_GLOBAL=0
1466 fi
1467 dnl *** check whether we need preceeding underscores
1468 AC_CACHE_CHECK([for preceeding underscore in symbols],
1469 glib_cv_uscore,[
1470 AC_TRY_RUN([#include <dlfcn.h>
1471 int glib_underscore_test (void) { return 42; }
1472 int main() {
1473 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1474 handle = dlopen ((void*)0, 0);
1475 if (handle) {
1476 f1 = dlsym (handle, "glib_underscore_test");
1477 f2 = dlsym (handle, "_glib_underscore_test");
1478 } return (!f2 || f1);
1479 }],
1480 [glib_cv_uscore=yes],
1481 [glib_cv_uscore=no],
1482 [])
1483 rm -f plugin.c plugin.$ac_objext plugin.lo
1484 ])
1485 GLIB_ASSERT_SET(glib_cv_uscore)
1486 if test "x$glib_cv_uscore" = "xyes"; then
1487 G_MODULE_NEED_USCORE=1
1488 else
1489 G_MODULE_NEED_USCORE=0
1490 fi
1492 AC_CHECK_DECL([RTLD_LAZY],
1493 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1494 [], [[#include <dlfcn.h>]])
1495 AC_CHECK_DECL([RTLD_NOW],
1496 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1497 [], [[#include <dlfcn.h>]])
1498 AC_CHECK_DECL([RTLD_GLOBAL],
1499 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1500 [], [[#include <dlfcn.h>]])
1502 LDFLAGS="$LDFLAGS_orig"
1503 dnl *** check for having dlerror()
1504 AC_CHECK_FUNC(dlerror,
1505 [G_MODULE_HAVE_DLERROR=1],
1506 [G_MODULE_HAVE_DLERROR=0])
1507 LIBS="$LIBS_orig"
1508 ])
1509 dnl *** done, have we got an implementation?
1510 if test -z "$G_MODULE_IMPL"; then
1511 G_MODULE_IMPL=0
1512 G_MODULE_SUPPORTED=false
1513 else
1514 G_MODULE_SUPPORTED=true
1515 fi
1517 AC_MSG_CHECKING(for the suffix of module shared libraries)
1518 export SED
1519 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1520 eval $shrext_cmds
1521 module=yes eval std_shrext=$shrext_cmds
1522 # chop the initial dot
1523 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1524 AC_MSG_RESULT(.$glib_gmodule_suffix)
1525 # any reason it may fail?
1526 if test "x$glib_gmodule_suffix" = x; then
1527 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1528 fi
1530 AC_SUBST(G_MODULE_SUPPORTED)
1531 AC_SUBST(G_MODULE_IMPL)
1532 AC_SUBST(G_MODULE_LIBS)
1533 AC_SUBST(G_MODULE_LIBS_EXTRA)
1534 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1535 AC_SUBST(G_MODULE_LDFLAGS)
1536 AC_SUBST(G_MODULE_HAVE_DLERROR)
1537 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1538 AC_SUBST(G_MODULE_NEED_USCORE)
1539 AC_SUBST(GLIB_DEBUG_FLAGS)
1541 dnl **********************
1542 dnl *** g_spawn checks ***
1543 dnl **********************
1545 AC_MSG_CHECKING(for gspawn implementation)
1546 case "$host" in
1547 *-*-mingw*)
1548 GSPAWN=gspawn-win32.lo
1549 ;;
1550 *)
1551 GSPAWN=gspawn.lo
1552 ;;
1553 esac
1554 AC_MSG_RESULT($GSPAWN)
1555 AC_SUBST(GSPAWN)
1557 dnl *************************
1558 dnl *** GIOChannel checks ***
1559 dnl *************************
1561 AC_MSG_CHECKING(for GIOChannel implementation)
1562 case "$host" in
1563 *-*-mingw*)
1564 GIO=giowin32.lo
1565 ;;
1566 *)
1567 GIO=giounix.lo
1568 ;;
1569 esac
1570 AC_MSG_RESULT($GIO)
1571 AC_SUBST(GIO)
1573 dnl *********************************
1574 dnl *** Directory for GIO modules ***
1575 dnl *********************************
1577 AC_ARG_WITH(gio-module-dir,
1578 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1579 [load gio modules from this directory [LIBDIR/gio/modules]])],
1580 [],
1581 [with_gio_module_dir='${libdir}/gio/modules'])
1582 GIO_MODULE_DIR=$with_gio_module_dir
1583 AC_SUBST(GIO_MODULE_DIR)
1585 dnl **********************************
1586 dnl *** Check for libselinux (GIO) ***
1587 dnl **********************************
1588 AC_ARG_ENABLE(selinux,
1589 AS_HELP_STRING([--disable-selinux],
1590 [build without selinux support]))
1591 msg_selinux=no
1592 SELINUX_LIBS=
1593 AS_IF([ test "x$enable_selinux" != "xno"], [
1595 AC_CHECK_LIB(selinux, is_selinux_enabled,
1596 [AC_CHECK_HEADERS(selinux/selinux.h,
1597 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1598 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1599 SELINUX_LIBS="-lselinux"
1600 msg_selinux=yes])
1601 ])
1602 ])
1603 ])
1604 AC_SUBST(SELINUX_LIBS)
1606 dnl *****************************
1607 dnl ** Check for inotify (GIO) **
1608 dnl *****************************
1609 inotify_support=no
1610 AC_CHECK_HEADERS([sys/inotify.h],
1611 [
1612 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1613 ])
1615 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1617 dnl ****************************
1618 dnl ** Check for kqueue (GIO) **
1619 dnl ****************************
1620 kqueue_support=no
1621 AC_CHECK_HEADERS([sys/event.h],
1622 [
1623 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1624 ])
1626 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1628 dnl ****************************
1629 dnl *** Checks for FAM (GIO) ***
1630 dnl ****************************
1632 should_disable_fam=no
1634 AC_ARG_ENABLE(fam,
1635 AS_HELP_STRING([--disable-fam],
1636 [don't use fam for file system monitoring]),
1637 [
1638 if test "x$enable_fam" = "xno"; then
1639 should_disable_fam=yes
1640 fi
1641 ]
1642 )
1643 fam_support=no
1644 FAM_LIBS=
1645 if test "x$should_disable_fam" = "xno"; then
1646 AC_CHECK_LIB(fam, FAMOpen,
1647 [AC_CHECK_HEADERS(fam.h,
1648 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1649 AC_CHECK_LIB(fam, FAMNoExists,
1650 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1651 FAM_LIBS="-lfam"]
1652 fam_support=yes,
1653 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1654 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1655 AC_SUBST(FAM_LIBS)
1656 fi
1657 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1660 dnl *****************************
1661 dnl *** Check for xattr (GIO) ***
1662 dnl *****************************
1663 AC_ARG_ENABLE(xattr,
1664 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1665 msg_xattr=no
1666 XATTR_LIBS=
1667 AS_IF([ test "x$enable_xattr" != "xno"], [
1669 dnl either glibc or libattr can provide xattr support
1671 dnl for both of them, we check for getxattr being in
1672 dnl the library and a valid xattr header.
1674 dnl try glibc
1675 AC_CHECK_LIB(c, getxattr,
1676 [AC_CHECK_HEADERS(sys/xattr.h,
1677 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1678 msg_xattr=yes])
1679 ])
1681 AS_IF([ test "x$msg_xattr" != "xyes"], [
1682 dnl failure. try libattr
1683 AC_CHECK_LIB(attr, getxattr,
1684 [AC_CHECK_HEADERS(attr/xattr.h,
1685 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1686 XATTR_LIBS="-lattr"
1687 msg_xattr=yes])
1688 ])
1689 ])
1691 AS_IF([ test "x$msg_xattr" = "xyes"], [
1692 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1693 AC_TRY_COMPILE([
1694 #include <stdio.h>
1695 #ifdef HAVE_SYS_TYPES_H
1696 #include <sys/types.h>
1697 #endif
1698 #ifdef HAVE_SYS_XATTR_H
1699 #include <sys/xattr.h>
1700 #elif HAVE_ATTR_XATTR_H
1701 #include <attr/xattr.h>
1702 #endif
1703 ],
1704 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1705 [
1706 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1707 AC_MSG_RESULT([yes])
1708 ],
1709 [AC_MSG_RESULT([no])]
1710 )
1711 ])
1712 ])
1713 AC_SUBST(XATTR_LIBS)
1715 dnl ************************
1716 dnl *** check for libelf ***
1717 dnl ************************
1718 AC_ARG_ENABLE(libelf,
1719 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1720 AS_IF([ test "x$enable_libelf" != "xno"],[
1721 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1722 AS_IF([ test $have_libelf = maybe ], [
1723 glib_save_LIBS=$LIBS
1724 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1725 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1726 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1727 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1728 LIBS=$glib_save_LIBS
1730 if test $have_libelf != no; then
1731 LIBELF_LIBS=-lelf
1732 have_libelf=yes
1733 fi
1734 ])
1735 ])
1737 if test x$have_libelf = xyes; then
1738 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1739 fi
1741 dnl ************************
1742 dnl *** check for libmount ***
1743 dnl ************************
1745 dnl The fallback code doesn't really implement the same behaviors - e.g.
1746 dnl so on linux we want to require libmount unless specifically disabled
1747 dnl
1748 enable_libmount_default=${glib_os_linux:-no}
1749 AC_ARG_ENABLE(libmount,
1750 [AS_HELP_STRING([--enable-libmount],
1751 [build with libmount support [default for Linux]])],,
1752 [enable_libmount=$enable_libmount_default])
1753 AS_IF([ test "x$enable_libmount" = "xyes"],[
1754 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.28], [have_libmount=yes], [have_libmount=maybe])
1755 AS_IF([ test $have_libmount = maybe ], [
1756 glib_save_LIBS=$LIBS
1757 AC_CHECK_HEADER([libmount/libmount.h], [:], [have_libmount=no])
1759 # Check for a recent enough libmount
1760 AC_CHECK_LIB([mount], [mnt_unref_table], [:], [have_libmount=no])
1761 LIBS=$glib_save_LIBS
1763 if test $have_libmount != no; then
1764 LIBMOUNT_LIBS=-lmount
1765 have_libmount=yes
1766 fi
1767 ])
1768 if test $have_libmount = no ; then
1769 AC_MSG_ERROR([*** Could not find libmount])
1770 fi
1771 ])
1773 if test x$have_libmount = xyes; then
1774 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1775 fi
1776 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1778 dnl ****************************************
1779 dnl *** platform dependent source checks ***
1780 dnl ****************************************
1782 AC_MSG_CHECKING(for platform-dependent source)
1783 case "$host" in
1784 *-*-cygwin*|*-*-mingw*)
1785 PLATFORMDEP=gwin32.lo
1786 ;;
1787 *)
1788 PLATFORMDEP=
1789 ;;
1790 esac
1791 AC_MSG_RESULT($PLATFORMDEP)
1792 AC_SUBST(PLATFORMDEP)
1794 AC_MSG_CHECKING([whether to compile timeloop])
1795 case "$host" in
1796 *-*-cygwin*|*-*-mingw*|*-*-minix)
1797 enable_timeloop=no
1798 ;;
1799 *)
1800 enable_timeloop=yes
1801 ;;
1802 esac
1803 AC_MSG_RESULT($enable_timeloop)
1804 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1806 AC_MSG_CHECKING([if building for some Win32 platform])
1807 case "$host" in
1808 *-*-mingw*|*-*-cygwin*)
1809 platform_win32=yes
1810 ;;
1811 *)
1812 platform_win32=no
1813 ;;
1814 esac
1815 AC_MSG_RESULT($platform_win32)
1816 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1818 dnl ***********************
1819 dnl *** g_thread checks ***
1820 dnl ***********************
1822 AC_ARG_WITH(threads,
1823 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1824 [specify a thread implementation to use])],
1825 [],
1826 [with_threads=yes])
1828 dnl error and warning message
1829 dnl *************************
1831 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1833 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1834 platform (normally it's "_REENTRANT"). I'll not use any flag on
1835 compilation now, but then your programs might not work.
1836 Please provide information on how it is done on your system."
1838 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1839 "
1841 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1842 provide information on your thread implementation."
1844 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1845 functions will not be MT-safe during their first call because
1846 there is no working 'getpwuid_r' on your system."
1848 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1849 because there is no 'localtime_r' on your system."
1851 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1852 linking threaded applications. As GLib cannot do that
1853 automatically, you will get an linkg error everytime you are
1854 not using the right compiler. In that case you have to relink
1855 with the right compiler. Ususally just '_r' is appended
1856 to the compiler name."
1858 dnl determination of thread implementation
1859 dnl ***************************************
1861 AC_MSG_CHECKING(for thread implementation)
1863 have_threads=no
1864 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1865 AS_IF([ test "x$have_threads" = xno], [
1866 AC_TRY_COMPILE([#include <pthread.h>],
1867 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1868 have_threads=posix)
1869 ])
1870 # Tru64Unix requires -pthread to find pthread.h. See #103020
1871 if test "x$have_threads" = xno; then
1872 glib_save_CPPFLAGS="$CPPFLAGS"
1873 CPPFLAGS="$CPPFLAGS -pthread"
1874 AC_TRY_COMPILE([#include <pthread.h>],
1875 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1876 have_threads=posix)
1877 CPPFLAGS="$glib_save_CPPFLAGS"
1878 fi
1879 ])
1880 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1881 case $host in
1882 *-*-mingw*)
1883 have_threads=win32
1884 ;;
1885 esac
1886 fi
1888 if test "x$have_threads" = xno; then
1889 AC_MSG_RESULT(none available)
1890 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1891 else
1892 AC_MSG_RESULT($have_threads)
1893 fi
1896 dnl determination of G_THREAD_CFLAGS
1897 dnl ********************************
1899 G_THREAD_LIBS=
1900 G_THREAD_LIBS_EXTRA=
1901 G_THREAD_CFLAGS=
1903 dnl
1904 dnl Test program for basic POSIX threads functionality
1905 dnl
1906 m4_define([glib_thread_test],[
1907 #include <pthread.h>
1908 int check_me = 0;
1909 void* func(void* data) {check_me = 42; return &check_me;}
1910 int main()
1911 { pthread_t t;
1912 void *ret;
1913 pthread_create (&t, $1, func, 0);
1914 pthread_join (t, &ret);
1915 return (check_me != 42 || ret != &check_me);
1916 }])
1918 AS_IF([ test x"$have_threads" = xposix], [
1919 # First we test for posix, whether -pthread or -pthreads do the trick as
1920 # both CPPFLAG and LIBS.
1921 # One of them does for most gcc versions and some other platforms/compilers
1922 # too and could be considered as the canonical way to go.
1923 case $host in
1924 *-*-cygwin*|*-*-darwin*)
1925 # skip cygwin and darwin -pthread or -pthreads test
1926 ;;
1927 *-solaris*)
1928 # These compiler/linker flags work with both Sun Studio and gcc
1929 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1930 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1931 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1932 G_THREAD_LIBS="-lpthread -lthread"
1933 ;;
1934 *)
1935 for flag in pthread pthreads mt; do
1936 glib_save_CFLAGS="$CFLAGS"
1937 CFLAGS="$CFLAGS -$flag"
1938 AC_TRY_RUN(glib_thread_test(0),
1939 glib_flag_works=yes,
1940 glib_flag_works=no,
1941 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1942 glib_flag_works=yes,
1943 glib_flag_works=no)])
1944 CFLAGS="$glib_save_CFLAGS"
1945 if test $glib_flag_works = yes ; then
1946 G_THREAD_CFLAGS=-$flag
1947 G_THREAD_LIBS=-$flag
1948 break;
1949 fi
1950 done
1951 ;;
1952 esac
1953 ])
1955 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1957 # The canonical -pthread[s] does not work. Try something different.
1959 case $host in
1960 *-aix*)
1961 if test x"$GCC" = xyes; then
1962 # GCC 3.0 and above needs -pthread.
1963 # Should be coverd by the case above.
1964 # GCC 2.x and below needs -mthreads
1965 G_THREAD_CFLAGS="-mthreads"
1966 G_THREAD_LIBS=$G_THREAD_CFLAGS
1967 else
1968 # We are probably using the aix compiler. Normaly a
1969 # program would have to be compiled with the _r variant
1970 # of the corresponding compiler, but we as GLib cannot
1971 # do that: but the good news is that for compiling the
1972 # only difference is the added -D_THREAD_SAFE compile
1973 # option. This is according to the "C for AIX User's
1974 # Guide".
1975 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1976 fi
1977 ;;
1978 *-sysv5uw7*) # UnixWare 7
1979 # We are not using gcc with -pthread. Catched above.
1980 G_THREAD_CFLAGS="-Kthread"
1981 G_THREAD_LIBS=$G_THREAD_CFLAGS
1982 ;;
1983 *-mingw*)
1984 # No flag needed when using MSVCRT.DLL
1985 G_THREAD_CFLAGS=""
1986 ;;
1987 *)
1988 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1989 ;;
1990 esac
1991 ])
1993 # if we are not finding the localtime_r function, then we probably are
1994 # not using the proper multithread flag
1996 glib_save_CPPFLAGS="$CPPFLAGS"
1997 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1999 # First we test, whether localtime_r is declared in time.h
2000 # directly. Then we test whether a macro localtime_r exists, in
2001 # which case localtime_r in the test program is replaced and thus
2002 # if we still find localtime_r in the output, it is not defined as
2003 # a macro.
2005 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2006 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2007 localtime_r(a,b)],
2008 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2010 CPPFLAGS="$glib_save_CPPFLAGS"
2012 AC_MSG_CHECKING(thread related cflags)
2013 AC_MSG_RESULT($G_THREAD_CFLAGS)
2014 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2016 dnl determination of G_THREAD_LIBS
2017 dnl ******************************
2019 AS_IF([test x$have_threads = xposix], [
2020 glib_save_CPPFLAGS="$CPPFLAGS"
2021 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2022 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2023 case $host in
2024 *-aix*)
2025 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2026 # probably using the aix compiler.
2027 AC_MSG_WARN($AIX_COMPILE_INFO)
2028 ;;
2029 *)
2030 G_THREAD_LIBS=error
2031 glib_save_LIBS="$LIBS"
2032 for thread_lib in "" pthread pthread32 pthreads thread; do
2033 if test x"$thread_lib" = x; then
2034 add_thread_lib=""
2035 IN=""
2036 else
2037 add_thread_lib="-l$thread_lib"
2038 IN=" in -l$thread_lib"
2039 fi
2040 if test x"$have_threads" = xposix; then
2041 defattr=0
2042 else
2043 defattr=pthread_attr_default
2044 fi
2046 LIBS="$add_thread_lib $glib_save_LIBS"
2048 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2049 AC_TRY_RUN(glib_thread_test($defattr),
2050 glib_result=yes,
2051 glib_result=no,
2052 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2053 glib_result=yes,
2054 glib_result=no)])
2055 AC_MSG_RESULT($glib_result)
2057 if test "$glib_result" = "yes" ; then
2058 G_THREAD_LIBS="$add_thread_lib"
2059 break
2060 fi
2061 done
2062 if test "x$G_THREAD_LIBS" = xerror; then
2063 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2064 fi
2065 LIBS="$glib_save_LIBS"
2066 ;;
2067 esac
2068 ])
2070 g_threads_impl="POSIX"
2071 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2072 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2073 CPPFLAGS="$glib_save_CPPFLAGS"
2074 ], [test x$have_threads = xwin32], [
2075 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2076 g_threads_impl="WIN32"
2077 ], [
2078 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2079 g_threads_impl="NONE"
2080 G_THREAD_LIBS=error
2081 ])
2082 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2083 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2084 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2086 if test "x$G_THREAD_LIBS" = xerror; then
2087 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2088 fi
2090 AC_MSG_CHECKING(thread related libraries)
2091 AC_MSG_RESULT($G_THREAD_LIBS)
2093 dnl check for mt safe function variants and some posix functions
2094 dnl ************************************************************
2096 glib_save_LIBS="$LIBS"
2097 # we are not doing the following for now, as this might require glib
2098 # to always be linked with the thread libs on some platforms.
2099 # LIBS="$LIBS $G_THREAD_LIBS"
2100 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2102 LIBS="$G_THREAD_LIBS $LIBS"
2103 AS_IF([ test x"$have_threads" = xposix], [
2104 glib_save_CPPFLAGS="$CPPFLAGS"
2105 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2106 # This is not AC_CHECK_FUNC to also work with function
2107 # name mangling in header files.
2108 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2109 AC_LINK_IFELSE(
2110 [AC_LANG_PROGRAM(
2111 [#include <pthread.h>],
2112 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2113 [AC_MSG_RESULT(yes)
2114 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2115 [Have function pthread_attr_setstacksize])],
2116 [AC_MSG_RESULT(no)])
2117 AC_MSG_CHECKING(for pthread_condattr_setclock)
2118 AC_LINK_IFELSE(
2119 [AC_LANG_PROGRAM(
2120 [#include <pthread.h>],
2121 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2122 [AC_MSG_RESULT(yes)
2123 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2124 [Have function pthread_condattr_setclock])],
2125 [AC_MSG_RESULT(no)])
2126 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2127 AC_LINK_IFELSE(
2128 [AC_LANG_PROGRAM(
2129 [#include <pthread.h>],
2130 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2131 [AC_MSG_RESULT(yes)
2132 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2133 [Have function pthread_cond_timedwait_relative_np])],
2134 [AC_MSG_RESULT(no)])
2135 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2136 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2137 AC_LINK_IFELSE(
2138 [AC_LANG_PROGRAM(
2139 [#include <pthread.h>],
2140 [pthread_setname_np("example")])],
2141 [AC_MSG_RESULT(yes)
2142 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2143 [Have function pthread_setname_np(const char*)])],
2144 [AC_MSG_RESULT(no)])
2145 dnl Sets thread names on Solaris 11.3 & higher
2146 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2147 AC_LINK_IFELSE(
2148 [AC_LANG_PROGRAM(
2149 [#include <pthread.h>],
2150 [pthread_setname_np(pthread_self(), "example")])],
2151 [AC_MSG_RESULT(yes)
2152 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2153 [Have function pthread_setname_np(pthread_t, const char*)])],
2154 [AC_MSG_RESULT(no)])
2155 CPPFLAGS="$glib_save_CPPFLAGS"
2156 ])
2158 LIBS="$glib_save_LIBS"
2160 # now spit out all the warnings.
2161 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2162 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2163 fi
2164 if test "$ac_cv_func_localtime_r" != "yes"; then
2165 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2166 fi
2168 #
2169 # Hack to deal with:
2170 #
2171 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2172 # building shared libraries with linux.
2173 # b) FreeBSD doesn't do this either.
2174 #
2175 case $host in
2176 *android*)
2177 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2178 ;;
2179 *-*-freebsd*|*-*-linux*)
2180 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2181 ;;
2182 *)
2183 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2184 ;;
2185 esac
2187 AC_SUBST(G_THREAD_CFLAGS)
2188 AC_SUBST(G_THREAD_LIBS)
2189 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2190 AC_SUBST(G_THREAD_LIBS_EXTRA)
2192 AC_CHECK_FUNCS(clock_gettime, [], [
2193 AC_CHECK_LIB(rt, clock_gettime, [
2194 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2195 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2196 ])
2197 ])
2200 dnl ************************
2201 dnl *** g_atomic_* tests ***
2202 dnl ************************
2204 dnl We need to decide at configure time if GLib will use real atomic
2205 dnl operations ("lock free") or emulated ones with a mutex. This is
2206 dnl because we must put this information in glibconfig.h so we know if
2207 dnl it is safe or not to inline using compiler intrinsics directly from
2208 dnl the header.
2209 dnl
2210 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2211 dnl user is interested in knowing if they can use the atomic ops across
2212 dnl processes.
2213 dnl
2214 dnl We can currently support the atomic ops natively when building GLib
2215 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2216 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2217 dnl we are using GCC (and not mingw*).
2218 dnl
2219 dnl Note that the atomic ops are only available with GCC on x86 when
2220 dnl using -march=i486 or higher. If we detect that the atomic ops are
2221 dnl not available but would be available given the right flags, we want
2222 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2223 dnl that then to silently fall back on emulated atomic ops just because
2224 dnl the user had the wrong build environment.
2226 dnl We may add other compilers here in the future...
2228 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2229 case $host in
2230 *-*-mingw*)
2231 glib_cv_g_atomic_lock_free=yes
2232 ;;
2233 *)
2234 AC_TRY_LINK([],
2235 [volatile int atomic = 2;\
2236 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2237 [glib_cv_g_atomic_lock_free=yes],
2238 [glib_cv_g_atomic_lock_free=no])
2239 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2240 SAVE_CFLAGS="${CFLAGS}"
2241 CFLAGS="-march=i486"
2242 AC_TRY_LINK([],
2243 [volatile int atomic = 2;\
2244 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2245 [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2246 [])
2247 CFLAGS="${SAVE_CFLAGS}"
2248 fi
2249 ;;
2250 esac])
2253 case $host in
2254 *-*-mingw*)
2255 ;;
2256 *)
2257 # Some compilers support atomic operations but do not define
2258 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2259 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2260 AC_TRY_LINK([],
2261 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2262 [],
2263 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2264 fi
2265 ;;
2266 esac
2268 dnl We need a more robust approach here...
2269 case $host_cpu in
2270 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2271 glib_memory_barrier_needed=no
2272 ;;
2273 sparc*|alpha*|powerpc*|ia64)
2274 glib_memory_barrier_needed=yes
2275 ;;
2276 *)
2277 glib_memory_barrier_needed=yes
2278 ;;
2279 esac
2281 dnl ************************
2282 dnl ** Check for futex(2) **
2283 dnl ************************
2284 AC_CACHE_CHECK(for futex(2) system call,
2285 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2286 #include <linux/futex.h>
2287 #include <sys/syscall.h>
2288 #include <unistd.h>
2289 ],[
2290 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2291 ])],glib_cv_futex=yes,glib_cv_futex=no))
2292 if test x"$glib_cv_futex" = xyes; then
2293 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2294 fi
2296 AC_CACHE_CHECK(for eventfd(2) system call,
2297 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2298 #include <sys/eventfd.h>
2299 #include <unistd.h>
2300 ],[
2301 eventfd (0, EFD_CLOEXEC);
2302 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2303 if test x"$glib_cv_eventfd" = x"yes"; then
2304 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2305 fi
2306 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2308 dnl ****************************************
2309 dnl *** GLib POLL* compatibility defines ***
2310 dnl ****************************************
2312 glib_poll_includes=["
2313 #include <sys/types.h>
2314 #include <poll.h>
2315 "]
2317 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2318 test $ac_cv_func_poll = yes ], [
2319 glib_failed=false
2320 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2321 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2322 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2323 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2324 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2325 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2326 if $glib_failed ; then
2327 AC_MSG_ERROR([Could not determine values for POLL* constants])
2328 fi
2329 ], [
2330 glib_cv_value_POLLIN=1
2331 glib_cv_value_POLLOUT=4
2332 glib_cv_value_POLLPRI=2
2333 glib_cv_value_POLLERR=8
2334 glib_cv_value_POLLHUP=16
2335 glib_cv_value_POLLNVAL=32
2336 ])
2338 AC_MSG_CHECKING([for broken poll])
2339 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2340 #include <stdlib.h>
2341 #include <fcntl.h>
2342 #include <poll.h>
2343 int main(void) {
2344 struct pollfd fds[1];
2345 int fd;
2346 fd = open("/dev/null", 1);
2347 fds[0].fd = fd;
2348 fds[0].events = POLLIN;
2349 fds[0].revents = 0;
2350 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2351 exit(1); /* Does not work for devices -- fail */
2352 }
2353 exit(0);
2354 }]])],
2355 [broken_poll=no],
2356 [broken_poll=yes
2357 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2358 [broken_poll="no (cross compiling)"])
2359 AC_MSG_RESULT($broken_poll)
2361 dnl *********************
2362 dnl *** GRegex checks ***
2363 dnl *********************
2365 PCRE_REQUIRED_VERSION=8.13
2367 # Check if we should use the internal or the system-supplied pcre
2368 AC_ARG_WITH(pcre,
2369 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2370 [whether to use system PCRE [default=system]])],
2371 [],
2372 [with_pcre=system])
2374 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2376 AS_IF([ test "x$with_pcre" = xsystem], [
2377 PKG_CHECK_MODULES(PCRE,
2378 libpcre >= $PCRE_REQUIRED_VERSION)
2379 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2380 glib_save_CFLAGS="$CFLAGS"
2381 glib_save_LIBS="$LIBS"
2382 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2383 AC_TRY_RUN([#include <pcre.h>
2384 int main () {
2385 int support;
2386 pcre_config (PCRE_CONFIG_UTF8, &support);
2387 if (!support)
2388 return 1;
2389 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2390 if (!support)
2391 return 1;
2392 return 0;
2393 }],
2394 glib_cv_pcre_has_unicode=yes,
2395 glib_cv_pcre_has_unicode=no,
2396 glib_cv_pcre_has_unicode=yes)
2397 CFLAGS="$glib_save_CFLAGS"
2398 LIBS="$glib_save_LIBS"
2399 ])
2400 if test "$glib_cv_pcre_has_unicode" = "no"; then
2401 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2402 fi
2403 AC_SUBST(PCRE_CFLAGS)
2404 AC_SUBST(PCRE_LIBS)
2405 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2406 PCRE_REQUIRES=libpcre
2407 AC_SUBST(PCRE_REQUIRES)
2408 ], [
2409 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2410 AS_IF([ test x"$GCC" = xyes], [
2411 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2412 save_CFLAGS="$CFLAGS"
2413 CFLAGS="$CFLAGS -Wno-pointer-sign"
2414 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2415 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2416 CFLAGS="$save_CFLAGS"
2417 ])
2418 ])
2419 AC_SUBST(PCRE_WARN_CFLAGS)
2421 dnl **********************
2422 dnl *** Win32 API libs ***
2423 dnl **********************
2425 case $host in
2426 *-*-cygwin*)
2427 G_LIBS_EXTRA="-luser32 -lkernel32"
2428 ;;
2429 *-*-mingw*)
2430 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2431 ;;
2432 *)
2433 G_LIBS_EXTRA=""
2434 ;;
2435 esac
2436 AC_SUBST(G_LIBS_EXTRA)
2438 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2439 dnl since we need it for g_iconv()
2441 AC_MSG_CHECKING([for EILSEQ])
2442 AC_TRY_COMPILE([
2443 #include <errno.h>
2444 ],
2445 [
2446 int error = EILSEQ;
2447 ], have_eilseq=yes, have_eilseq=no);
2448 AC_MSG_RESULT($have_eilseq)
2450 dnl Add a conditional we can use when cross-compiling, so we avoid running
2451 dnl binaries
2452 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2454 dnl **************************
2455 dnl *** Checks for gtk-doc ***
2456 dnl **************************
2457 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2458 # it on it's own line.
2459 m4_ifdef([GTK_DOC_CHECK], [
2460 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2461 ],[
2462 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2463 ])
2465 AC_ARG_ENABLE(man,
2466 [AS_HELP_STRING([--enable-man],
2467 [generate man pages [default=auto]])],,
2468 enable_man=maybe)
2470 AS_IF([test "$enable_man" != no], [
2471 AC_PATH_PROG([XSLTPROC], [xsltproc])
2472 AS_IF([test -z "$XSLTPROC"], [
2473 AS_IF([test "$enable_man" = yes], [
2474 AC_MSG_ERROR([xsltproc is required for --enable-man])
2475 ])
2476 enable_man=no
2477 ])
2478 ])
2480 AS_IF([ test "$enable_man" != no ], [
2481 dnl check for DocBook DTD in the local catalog
2482 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2483 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2484 AS_IF([test "$have_docbook_dtd" != yes], [
2485 AS_IF([test "$enable_man" = yes ], [
2486 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2487 ])
2488 enable_man=no
2489 ])
2490 ])
2492 AS_IF([test "$enable_man" != no], [
2493 dnl check for DocBook XSL stylesheets in the local catalog
2494 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2495 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2496 AS_IF([ test "$have_docbook_style" != yes ], [
2497 AS_IF([ test "$enable_man" = yes ], [
2498 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2499 ])
2500 enable_man=no
2501 ])
2502 ])
2504 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2506 AC_MSG_CHECKING([whether to generate man pages])
2507 AS_IF([ test "$enable_man" != no ], [
2508 AC_MSG_RESULT([yes])
2509 ], [
2510 AC_MSG_RESULT([no])
2511 ])
2513 dnl
2514 dnl Tracing
2515 dnl
2517 AC_ARG_ENABLE([dtrace],
2518 [AS_HELP_STRING([--enable-dtrace],
2519 [include tracing support for dtrace])])
2520 have_dtrace=no
2521 AC_MSG_CHECKING([whether to include dtrace tracing support])
2522 AS_IF([ test "x$enable_dtrace" != xno], [
2523 if test x$glib_have_carbon = xyes; then
2524 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2525 else
2526 AC_MSG_RESULT([yes])
2527 AC_CHECK_PROGS(DTRACE, dtrace)
2528 if test -z "$DTRACE"; then
2529 if test "x$enable_dtrace" = xyes; then
2530 AC_MSG_ERROR([dtrace not found])
2531 fi
2532 else
2533 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2534 [if test "x$enable_dtrace" = xyes; then
2535 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2536 fi])
2537 fi
2538 fi
2539 ], [
2540 AC_MSG_RESULT([no])
2541 ])
2542 if test "x$have_dtrace" = xyes; then
2543 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2544 fi
2545 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2547 AC_MSG_CHECKING([whether to include systemtap tracing support])
2548 AC_ARG_ENABLE([systemtap],
2549 [AS_HELP_STRING([--enable-systemtap],
2550 [include tracing support for systemtap])])
2551 have_systemtap=no
2552 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2553 have_systemtap=yes
2554 fi
2555 AC_MSG_RESULT(${have_systemtap})
2557 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2559 AC_ARG_WITH([tapset-install-dir],
2560 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2561 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2562 [if test "x${withval}" = x; then
2563 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2564 else
2565 ABS_TAPSET_DIR="${withval}"
2566 fi],
2567 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2568 AC_SUBST(ABS_TAPSET_DIR)
2570 dnl ************************************
2571 dnl *** Enable lcov coverage reports ***
2572 dnl ************************************
2574 AC_ARG_ENABLE(coverage,
2575 AS_HELP_STRING([--enable-coverage],
2576 [enable coverage testing with gcov]),
2577 [use_gcov=$enableval], [use_gcov=no])
2579 AS_IF([ test "x$use_gcov" = "xyes"], [
2580 dnl we need gcc:
2581 if test "$GCC" != "yes"; then
2582 AC_MSG_ERROR([GCC is required for --enable-coverage])
2583 fi
2585 dnl Check if ccache is being used
2586 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2587 case `$SHTOOL path $CC` in
2588 *ccache*[)] gcc_ccache=yes;;
2589 *[)] gcc_ccache=no;;
2590 esac
2592 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2593 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2594 fi
2596 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2597 AC_CHECK_PROG(LTP, lcov, lcov)
2598 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2600 AS_IF([ test "$LTP" ], [
2601 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2602 glib_cv_ltp_version=invalid
2603 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2604 for ltp_check_version in $ltp_version_list; do
2605 if test "$ltp_version" = "$ltp_check_version"; then
2606 glib_cv_ltp_version="$ltp_check_version (ok)"
2607 fi
2608 done
2609 ])
2610 ], [
2611 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2612 AC_MSG_ERROR([$ltp_msg])
2613 ])
2615 case $glib_cv_ltp_version in
2616 ""|invalid[)]
2617 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2618 AC_MSG_ERROR([$ltp_msg])
2619 LTP="exit 0;"
2620 ;;
2621 esac
2623 if test -z "$LTP_GENHTML"; then
2624 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2625 fi
2627 dnl Remove all optimization flags from CFLAGS
2628 changequote({,})
2629 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2630 changequote([,])
2632 dnl Add the special gcc flags
2633 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2634 LDFLAGS="$LDFLAGS -lgcov"
2635 ])
2637 dnl ******************************
2638 dnl *** output the whole stuff ***
2639 dnl ******************************
2641 dnl this section will only be run if config.status is invoked with no
2642 dnl arguments, or with "glib/glibconfig.h" as an argument.
2643 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2644 [
2645 outfile=glib/glibconfig.h-tmp
2646 cat > $outfile <<\_______EOF
2647 /* glibconfig.h
2648 *
2649 * This is a generated file. Please modify 'configure.ac'
2650 */
2652 #ifndef __GLIBCONFIG_H__
2653 #define __GLIBCONFIG_H__
2655 #include <glib/gmacros.h>
2657 _______EOF
2659 echo '#include <limits.h>' >> $outfile
2660 echo '#include <float.h>' >> $outfile
2661 if test x$glib_values_h = xyes; then
2662 echo '#include <values.h>' >> $outfile
2663 fi
2664 if test "$glib_header_alloca_h" = "yes"; then
2665 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2666 fi
2667 if test x$glib_included_printf != xyes; then
2668 echo "
2669 /* Specifies that GLib's g_print*() functions wrap the
2670 * system printf functions. This is useful to know, for example,
2671 * when using glibc's register_printf_function().
2672 */" >> $outfile
2673 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2674 fi
2676 cat >> $outfile <<_______EOF
2678 G_BEGIN_DECLS
2680 #define G_MINFLOAT FLT_MIN
2681 #define G_MAXFLOAT FLT_MAX
2682 #define G_MINDOUBLE DBL_MIN
2683 #define G_MAXDOUBLE DBL_MAX
2684 #define G_MINSHORT SHRT_MIN
2685 #define G_MAXSHORT SHRT_MAX
2686 #define G_MAXUSHORT USHRT_MAX
2687 #define G_MININT INT_MIN
2688 #define G_MAXINT INT_MAX
2689 #define G_MAXUINT UINT_MAX
2690 #define G_MINLONG LONG_MIN
2691 #define G_MAXLONG LONG_MAX
2692 #define G_MAXULONG ULONG_MAX
2694 _______EOF
2697 ### this should always be true in a modern C/C++ compiler
2698 ### and is statically asserted by glib-init.c
2699 cat >>$outfile <<_______EOF
2700 typedef signed char gint8;
2701 typedef unsigned char guint8;
2702 _______EOF
2705 if test -n "$gint16"; then
2706 cat >>$outfile <<_______EOF
2707 typedef signed $gint16 gint16;
2708 typedef unsigned $gint16 guint16;
2709 #define G_GINT16_MODIFIER $gint16_modifier
2710 #define G_GINT16_FORMAT $gint16_format
2711 #define G_GUINT16_FORMAT $guint16_format
2712 _______EOF
2713 fi
2716 if test -n "$gint32"; then
2717 cat >>$outfile <<_______EOF
2718 typedef signed $gint32 gint32;
2719 typedef unsigned $gint32 guint32;
2720 #define G_GINT32_MODIFIER $gint32_modifier
2721 #define G_GINT32_FORMAT $gint32_format
2722 #define G_GUINT32_FORMAT $guint32_format
2723 _______EOF
2724 fi
2726 cat >>$outfile <<_______EOF
2727 #define G_HAVE_GINT64 1 /* deprecated, always true */
2729 ${glib_extension}typedef signed $gint64 gint64;
2730 ${glib_extension}typedef unsigned $gint64 guint64;
2732 #define G_GINT64_CONSTANT(val) $gint64_constant
2733 #define G_GUINT64_CONSTANT(val) $guint64_constant
2734 _______EOF
2736 if test x$gint64_format != x ; then
2737 cat >>$outfile <<_______EOF
2738 #define G_GINT64_MODIFIER $gint64_modifier
2739 #define G_GINT64_FORMAT $gint64_format
2740 #define G_GUINT64_FORMAT $guint64_format
2741 _______EOF
2742 else
2743 cat >>$outfile <<_______EOF
2744 #undef G_GINT64_MODIFIER
2745 #undef G_GINT64_FORMAT
2746 #undef G_GUINT64_FORMAT
2747 _______EOF
2748 fi
2750 cat >>$outfile <<_______EOF
2752 #define GLIB_SIZEOF_VOID_P $glib_void_p
2753 #define GLIB_SIZEOF_LONG $glib_long
2754 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2755 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2757 _______EOF
2759 cat >>$outfile <<_______EOF
2760 typedef signed $glib_ssize_type_define gssize;
2761 typedef unsigned $glib_size_type_define gsize;
2762 #define G_GSIZE_MODIFIER $gsize_modifier
2763 #define G_GSSIZE_MODIFIER $gssize_modifier
2764 #define G_GSIZE_FORMAT $gsize_format
2765 #define G_GSSIZE_FORMAT $gssize_format
2767 #define G_MAXSIZE G_MAXU$glib_msize_type
2768 #define G_MINSSIZE G_MIN$glib_mssize_type
2769 #define G_MAXSSIZE G_MAX$glib_mssize_type
2771 typedef gint64 goffset;
2772 #define G_MINOFFSET G_MININT64
2773 #define G_MAXOFFSET G_MAXINT64
2775 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2776 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2777 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2779 #define G_POLLFD_FORMAT $g_pollfd_format
2781 _______EOF
2783 if test -z "$glib_unknown_void_p"; then
2784 cat >>$outfile <<_______EOF
2786 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2787 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2789 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2790 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2792 typedef signed $glib_intptr_type_define gintptr;
2793 typedef unsigned $glib_intptr_type_define guintptr;
2795 #define G_GINTPTR_MODIFIER $gintptr_modifier
2796 #define G_GINTPTR_FORMAT $gintptr_format
2797 #define G_GUINTPTR_FORMAT $guintptr_format
2798 _______EOF
2799 else
2800 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2801 fi
2805 cat >>$outfile <<_______EOF
2806 #ifndef G_DISABLE_DEPRECATED
2807 #define g_ATEXIT(proc) (atexit (proc))
2808 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2809 #endif
2810 $glib_defines
2811 $glib_os
2812 $glib_static_compilation
2814 $glib_vacopy
2816 _______EOF
2818 if test x$g_have_iso_c_varargs = xyes ; then
2819 cat >>$outfile <<_______EOF
2820 #ifndef __cplusplus
2821 # define G_HAVE_ISO_VARARGS 1
2822 #endif
2823 _______EOF
2824 fi
2825 if test x$g_have_iso_cxx_varargs = xyes ; then
2826 cat >>$outfile <<_______EOF
2827 #ifdef __cplusplus
2828 # define G_HAVE_ISO_VARARGS 1
2829 #endif
2830 _______EOF
2831 fi
2832 if test x$g_have_gnuc_varargs = xyes ; then
2833 cat >>$outfile <<_______EOF
2835 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2836 * is passed ISO vararg support is turned off, and there is no work
2837 * around to turn it on, so we unconditionally turn it off.
2838 */
2839 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2840 # undef G_HAVE_ISO_VARARGS
2841 #endif
2843 #define G_HAVE_GNUC_VARARGS 1
2844 _______EOF
2845 fi
2847 case x$g_stack_grows in
2848 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2849 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2850 esac
2853 echo >>$outfile
2854 if test x$g_have_eilseq = xno; then
2855 cat >>$outfile <<_______EOF
2856 #ifndef EILSEQ
2857 /* On some pre-C99 systems, EILSEQ is not defined.
2858 * The correspondence between this and the corresponding definition
2859 * in libiconv is essential.
2860 */
2861 # define EILSEQ ENOENT
2862 #endif
2863 _______EOF
2865 fi
2867 if test x$g_have_gnuc_visibility = xyes; then
2868 cat >>$outfile <<_______EOF
2869 #define G_HAVE_GNUC_VISIBILITY 1
2870 _______EOF
2871 fi
2872 cat >>$outfile <<_______EOF
2873 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2874 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2875 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2876 #define G_GNUC_INTERNAL __hidden
2877 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2878 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2879 #else
2880 #define G_GNUC_INTERNAL
2881 #endif
2882 _______EOF
2884 echo >>$outfile
2885 cat >>$outfile <<_______EOF
2886 #define G_THREADS_ENABLED
2887 #define G_THREADS_IMPL_$g_threads_impl_def
2888 _______EOF
2890 if test x"$g_memory_barrier_needed" != xno; then
2891 echo >>$outfile
2892 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2893 fi
2894 if test x"$g_atomic_lock_free" = xyes; then
2895 echo >>$outfile
2896 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2897 fi
2898 echo >>$outfile
2899 g_bit_sizes="16 32 64"
2900 for bits in $g_bit_sizes; do
2901 cat >>$outfile <<_______EOF
2902 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2903 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2904 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2905 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2906 _______EOF
2907 done
2909 cat >>$outfile <<_______EOF
2910 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2911 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2912 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2913 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2914 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2915 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2916 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2917 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2918 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2919 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2920 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2921 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2922 #define G_BYTE_ORDER $g_byte_order
2924 #define GLIB_SYSDEF_POLLIN =$g_pollin
2925 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2926 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2927 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2928 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2929 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2931 #define G_MODULE_SUFFIX "$g_module_suffix"
2933 typedef $g_pid_type GPid;
2934 #define G_PID_FORMAT $g_pid_format
2936 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2937 #define GLIB_SYSDEF_AF_INET $g_af_inet
2938 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2940 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2941 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2942 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2944 G_END_DECLS
2946 #endif /* __GLIBCONFIG_H__ */
2947 _______EOF
2950 if cmp -s $outfile glib/glibconfig.h; then
2951 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2952 rm -f $outfile
2953 else
2954 mv $outfile glib/glibconfig.h
2955 fi
2956 ],[
2958 # Note that if two cases are the same, case goes with the first one.
2959 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2960 # on variable expansion in case labels. Look at the generated config.status
2961 # for a hint.
2963 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2964 glib_header_alloca_h="$ac_cv_working_alloca_h"
2965 else
2966 glib_header_alloca_h="$ac_cv_header_alloca_h"
2967 fi
2969 if test x$enable_included_printf = xyes ; then
2970 glib_included_printf=yes
2971 fi
2973 case 2 in
2974 $ac_cv_sizeof_short)
2975 gint16=short
2976 gint16_modifier='"h"'
2977 gint16_format='"hi"'
2978 guint16_format='"hu"'
2979 ;;
2980 $ac_cv_sizeof_int)
2981 gint16=int
2982 gint16_modifier='""'
2983 gint16_format='"i"'
2984 guint16_format='"u"'
2985 ;;
2986 esac
2987 case 4 in
2988 $ac_cv_sizeof_short)
2989 gint32=short
2990 gint32_modifier='"h"'
2991 gint32_format='"hi"'
2992 guint32_format='"hu"'
2993 ;;
2994 $ac_cv_sizeof_int)
2995 gint32=int
2996 gint32_modifier='""'
2997 gint32_format='"i"'
2998 guint32_format='"u"'
2999 ;;
3000 $ac_cv_sizeof_long)
3001 gint32=long
3002 gint32_modifier='"l"'
3003 gint32_format='"li"'
3004 guint32_format='"lu"'
3005 ;;
3006 esac
3007 case 8 in
3008 $ac_cv_sizeof_int)
3009 gint64=int
3010 gint64_modifier='""'
3011 gint64_format='"i"'
3012 guint64_format='"u"'
3013 glib_extension=
3014 gint64_constant='(val)'
3015 guint64_constant='(val)'
3016 ;;
3017 $ac_cv_sizeof_long)
3018 gint64=long
3019 gint64_modifier='"l"'
3020 gint64_format='"li"'
3021 guint64_format='"lu"'
3022 glib_extension=
3023 gint64_constant='(val##L)'
3024 guint64_constant='(val##UL)'
3025 ;;
3026 $ac_cv_sizeof_long_long)
3027 gint64='long long'
3028 if test -n "$glib_cv_long_long_format"; then
3029 gint64_modifier='"'$glib_cv_long_long_format'"'
3030 gint64_format='"'$glib_cv_long_long_format'i"'
3031 guint64_format='"'$glib_cv_long_long_format'u"'
3032 fi
3033 glib_extension='G_GNUC_EXTENSION '
3034 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3035 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3036 ;;
3037 $ac_cv_sizeof___int64)
3038 gint64='__int64'
3039 if test -n "$glib_cv_long_long_format"; then
3040 gint64_modifier='"'$glib_cv_long_long_format'"'
3041 gint64_format='"'$glib_cv_long_long_format'i"'
3042 guint64_format='"'$glib_cv_long_long_format'u"'
3043 fi
3044 glib_extension=
3045 gint64_constant='(val##i64)'
3046 guint64_constant='(val##ui64)'
3047 ;;
3048 esac
3049 glib_size_t=$ac_cv_sizeof_size_t
3050 glib_ssize_t=$ac_cv_sizeof_ssize_t
3051 glib_size_type_define="$glib_size_type"
3052 glib_ssize_type_define="$glib_ssize_type"
3053 glib_void_p=$ac_cv_sizeof_void_p
3054 glib_long=$ac_cv_sizeof_long
3056 case "$glib_size_type" in
3057 short)
3058 gsize_modifier='"h"'
3059 gsize_format='"hu"'
3060 glib_msize_type='SHRT'
3061 ;;
3062 int)
3063 gsize_modifier='""'
3064 gsize_format='"u"'
3065 glib_msize_type='INT'
3066 ;;
3067 long)
3068 gsize_modifier='"l"'
3069 gsize_format='"lu"'
3070 glib_msize_type='LONG'
3071 ;;
3072 "long long"|__int64)
3073 gsize_modifier='"I64"'
3074 gsize_format='"I64u"'
3075 glib_msize_type='INT64'
3076 ;;
3077 esac
3079 case "$glib_ssize_type" in
3080 short)
3081 gssize_modifier='"h"'
3082 gssize_format='"hi"'
3083 glib_mssize_type='SHRT'
3084 ;;
3085 int)
3086 gssize_modifier='""'
3087 gssize_format='"i"'
3088 glib_mssize_type='INT'
3089 ;;
3090 long)
3091 gssize_modifier='"l"'
3092 gssize_format='"li"'
3093 glib_mssize_type='LONG'
3094 ;;
3095 "long long"|__int64)
3096 gssize_modifier='"I64"'
3097 gssize_format='"I64i"'
3098 glib_mssize_type='INT64'
3099 ;;
3100 esac
3102 gintbits=`expr $ac_cv_sizeof_int \* 8`
3103 glongbits=`expr $ac_cv_sizeof_long \* 8`
3104 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3105 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3107 case $ac_cv_sizeof_void_p in
3108 $ac_cv_sizeof_int)
3109 glib_intptr_type_define=int
3110 gintptr_modifier='""'
3111 gintptr_format='"i"'
3112 guintptr_format='"u"'
3113 glib_gpi_cast='(gint)'
3114 glib_gpui_cast='(guint)'
3115 ;;
3116 $ac_cv_sizeof_long)
3117 glib_intptr_type_define=long
3118 gintptr_modifier='"l"'
3119 gintptr_format='"li"'
3120 guintptr_format='"lu"'
3121 glib_gpi_cast='(glong)'
3122 glib_gpui_cast='(gulong)'
3123 ;;
3124 $ac_cv_sizeof_long_long)
3125 glib_intptr_type_define='long long'
3126 gintptr_modifier='"I64"'
3127 gintptr_format='"I64i"'
3128 guintptr_format='"I64u"'
3129 glib_gpi_cast='(gint64)'
3130 glib_gpui_cast='(guint64)'
3131 ;;
3132 $ac_cv_sizeof___int64)
3133 glib_intptr_type_define=__int64
3134 gintptr_modifier='"I64"'
3135 gintptr_format='"I64i"'
3136 guintptr_format='"I64u"'
3137 glib_gpi_cast='(gint64)'
3138 glib_gpui_cast='(guint64)'
3139 ;;
3140 *)
3141 glib_unknown_void_p=yes
3142 ;;
3143 esac
3146 glib_defines="
3147 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3148 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3149 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3150 "
3152 case xyes in
3153 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3154 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3155 *) glib_vacopy=''
3156 esac
3158 if test x$glib_cv_va_val_copy = xno; then
3159 glib_vacopy="\$glib_vacopy
3160 #define G_VA_COPY_AS_ARRAY 1"
3161 fi
3163 g_have_gnuc_varargs=$g_have_gnuc_varargs
3164 g_have_iso_c_varargs=$g_have_iso_c_varargs
3165 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3167 g_have_gnuc_visibility=$g_have_gnuc_visibility
3168 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3170 if test x$ac_cv_c_bigendian = xyes; then
3171 g_byte_order=G_BIG_ENDIAN
3172 g_bs_native=BE
3173 g_bs_alien=LE
3174 else
3175 g_byte_order=G_LITTLE_ENDIAN
3176 g_bs_native=LE
3177 g_bs_alien=BE
3178 fi
3180 g_pollin=$glib_cv_value_POLLIN
3181 g_pollout=$glib_cv_value_POLLOUT
3182 g_pollpri=$glib_cv_value_POLLPRI
3183 g_pollhup=$glib_cv_value_POLLHUP
3184 g_pollerr=$glib_cv_value_POLLERR
3185 g_pollnval=$glib_cv_value_POLLNVAL
3187 # If a family is not found on the system, define that family to
3188 # a negative value, picking a different one for each undefined
3189 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3190 # This is needed because glib-mkenums doesn't handle optional
3191 # values in enums, and thus we have to have all existing values
3192 # defined in the enum.
3193 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3194 g_af_unix=$glib_cv_value_AF_UNIX
3195 else
3196 g_af_unix=-1
3197 fi
3198 g_af_inet=$glib_cv_value_AF_INET
3199 g_af_inet6=$glib_cv_value_AF_INET6
3201 g_msg_peek=$glib_cv_value_MSG_PEEK
3202 g_msg_oob=$glib_cv_value_MSG_OOB
3203 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3205 g_stack_grows=$glib_cv_stack_grows
3207 g_have_eilseq=$have_eilseq
3209 g_threads_impl_def=$g_threads_impl
3211 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3212 g_memory_barrier_needed="$glib_memory_barrier_needed"
3213 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3215 g_module_suffix="$glib_gmodule_suffix"
3216 g_pid_type="$glib_pid_type"
3217 g_pid_format="\"$glib_pid_format\""
3218 g_pollfd_format="\"$glib_pollfd_format\""
3220 case $host in
3221 *-*-cygwin*)
3222 glib_os="#define G_OS_UNIX
3223 #define G_PLATFORM_WIN32
3224 #define G_WITH_CYGWIN"
3225 ;;
3226 *-*-mingw*)
3227 glib_os="#define G_OS_WIN32
3228 #define G_PLATFORM_WIN32"
3229 ;;
3230 *)
3231 glib_os="#define G_OS_UNIX"
3232 ;;
3233 esac
3234 glib_static_compilation=""
3235 if test x$glib_win32_static_compilation = xyes; then
3236 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3237 #define GOBJECT_STATIC_COMPILATION 1"
3238 fi
3239 ])
3241 # Redo enough to get guint32 and guint64 for the alignment checks below
3242 case 4 in
3243 $ac_cv_sizeof_short)
3244 gint32=short
3245 ;;
3246 $ac_cv_sizeof_int)
3247 gint32=int
3248 ;;
3249 $ac_cv_sizeof_long)
3250 gint32=long
3251 ;;
3252 esac
3253 case 8 in
3254 $ac_cv_sizeof_int)
3255 gint64=int
3256 ;;
3257 $ac_cv_sizeof_long)
3258 gint64=long
3259 ;;
3260 $ac_cv_sizeof_long_long)
3261 gint64='long long'
3262 ;;
3263 $ac_cv_sizeof___int64)
3264 gint64='__int64'
3265 ;;
3266 esac
3268 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3269 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3270 typedef unsigned $gint32 guint32;])
3271 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3272 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3273 typedef unsigned $gint64 guint64;])
3274 AC_CHECK_TYPE([unsigned long])
3275 AC_CHECK_ALIGNOF([unsigned long])
3277 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3278 #
3279 # 1.2.14 required for dbus_message_set_serial
3280 PKG_CHECK_MODULES(DBUS1,
3281 dbus-1 >= 1.2.14,
3282 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3283 have_dbus1=no)
3284 AC_SUBST(DBUS1_CFLAGS)
3285 AC_SUBST(DBUS1_LIBS)
3286 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3288 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3289 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3291 # Check whether MSVC toolset is explicitly set
3292 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3293 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3295 dnl
3296 dnl Check for -Bsymbolic-functions linker flag used to avoid
3297 dnl intra-library PLT jumps, if available.
3298 dnl
3300 AC_ARG_ENABLE(Bsymbolic,
3301 [AS_HELP_STRING([--disable-Bsymbolic],
3302 [avoid linking with -Bsymbolic])],,
3303 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3304 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3305 LDFLAGS=-Wl,-Bsymbolic-functions
3306 LIBS=
3307 AC_TRY_LINK([], [return 0],
3308 AC_MSG_RESULT(yes)
3309 enable_Bsymbolic=yes,
3310 AC_MSG_RESULT(no)
3311 enable_Bsymbolic=no)
3312 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3314 if test "x${enable_Bsymbolic}" = "xyes"; then
3315 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3316 fi
3318 dnl
3319 dnl Check for -z,nodelete linker flag: the type system assumes that
3320 dnl libgobject stays loaded for the lifetime of the process.
3321 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3322 dnl we also try to check for the --fatal-warnings linker flag if
3323 dnl auto-detecting.
3324 dnl
3326 AC_ARG_ENABLE([znodelete],
3327 [AS_HELP_STRING([--disable-znodelete],
3328 [avoid linking with -z,nodelete])],,
3329 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3330 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3331 LDFLAGS=-Wl,--fatal-warnings
3332 LIBS=
3333 AC_TRY_LINK([], [return 0],
3334 AC_MSG_RESULT(yes)
3335 [ldflags_fatal=-Wl,--fatal-warnings],
3336 AC_MSG_RESULT(no)
3337 ldflags_fatal=)
3338 AC_MSG_CHECKING([for -z,nodelete linker flag])
3339 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3340 AC_TRY_LINK([], [return 0],
3341 AC_MSG_RESULT(yes)
3342 enable_znodelete=yes,
3343 AC_MSG_RESULT(no)
3344 enable_znodelete=no)
3345 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3347 if test "x${enable_znodelete}" = "xyes"; then
3348 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3349 fi
3351 AC_SUBST(GLIB_LINK_FLAGS)
3353 dnl
3354 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3355 dnl visibility attributes for symbol export control
3356 dnl
3357 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3358 case "$host" in
3359 *-*-mingw*)
3360 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3361 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3362 [defines how to decorate public symbols while building])
3363 CFLAGS="${CFLAGS} -fvisibility=hidden"
3364 ;;
3365 *)
3366 dnl on other compilers, check if we can do -fvisibility=hidden
3367 SAVED_CFLAGS="${CFLAGS}"
3368 CFLAGS="-fvisibility=hidden"
3369 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3370 AC_TRY_COMPILE([], [return 0],
3371 AC_MSG_RESULT(yes)
3372 enable_fvisibility_hidden=yes,
3373 AC_MSG_RESULT(no)
3374 enable_fvisibility_hidden=no)
3375 CFLAGS="${SAVED_CFLAGS}"
3377 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3378 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3379 [defines how to decorate public symbols while building])
3380 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3381 ])
3382 ;;
3383 esac
3384 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3386 dnl Compiler flags; macro originates from systemd
3387 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3388 AC_ARG_ENABLE(compile-warnings,
3389 [AS_HELP_STRING([--disable-compile-warnings],
3390 [Don't use builtin compiler warnings])],,
3391 enable_compile_warnings=yes)
3392 AS_IF([test "x$enable_compile_warnings" = xyes], [
3393 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3394 -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3395 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3396 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3397 -Werror=format=2 -Werror=missing-include-dirs])
3398 ])
3399 AC_SUBST(GLIB_WARN_CFLAGS)
3401 #
3402 # Define variables corresponding to the correct include paths to use for
3403 # in-tree building.
3404 #
3406 # for config.h:
3407 config_h_INCLUDES='-I$(top_builddir)'
3408 AC_SUBST(config_h_INCLUDES)
3410 # glib:
3411 # config.h
3412 # $(top_builddir)/glib: for glibconfig.h
3413 # $(top_srcdir)/glib: for glib.h
3414 # $(top_srcdir): for everything
3415 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3416 AC_SUBST(glib_INCLUDES)
3418 # gobject:
3419 # same as glib
3420 gobject_INCLUDES='$(glib_INCLUDES)'
3421 AC_SUBST(gobject_INCLUDES)
3423 # gmodule:
3424 # glib includes
3425 # $(top_srcdir)/gmodule: for gmodule.h
3426 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3427 AC_SUBST(gmodule_INCLUDES)
3429 # gio:
3430 # same as gmodule
3431 gio_INCLUDES='$(gmodule_INCLUDES)'
3432 AC_SUBST(gio_INCLUDES)
3435 AC_CONFIG_FILES([
3436 glib-2.0.pc
3437 gmodule-2.0.pc
3438 gmodule-export-2.0.pc
3439 gmodule-no-export-2.0.pc
3440 gthread-2.0.pc
3441 gobject-2.0.pc
3442 gio-2.0.pc
3443 gio-unix-2.0.pc
3444 gio-windows-2.0.pc
3445 glib-zip
3446 glib-gettextize
3447 Makefile
3448 build/Makefile
3449 build/win32/Makefile
3450 build/win32/dirent/Makefile
3451 win32/Makefile
3452 win32/vs9/Makefile
3453 win32/vs9/glib-version-paths.vsprops
3454 win32/vs10/Makefile
3455 win32/vs10/glib-version-paths.props
3456 win32/vs11/Makefile
3457 win32/vs12/Makefile
3458 win32/vs14/Makefile
3459 win32/vs15/Makefile
3460 glib/Makefile
3461 glib/libcharset/Makefile
3462 glib/gnulib/Makefile
3463 glib/pcre/Makefile
3464 glib/update-pcre/Makefile
3465 glib/tests/Makefile
3466 gmodule/Makefile
3467 gmodule/gmoduleconf.h
3468 gobject/Makefile
3469 gobject/glib-mkenums
3470 gobject/tests/Makefile
3471 gthread/Makefile
3472 gio/Makefile
3473 gio/gdbus-2.0/codegen/Makefile
3474 gio/gdbus-2.0/codegen/config.py
3475 gio/gnetworking.h
3476 gio/xdgmime/Makefile
3477 gio/inotify/Makefile
3478 gio/kqueue/Makefile
3479 gio/fam/Makefile
3480 gio/win32/Makefile
3481 gio/tests/Makefile
3482 gio/tests/gdbus-object-manager-example/Makefile
3483 gio/tests/services/Makefile
3484 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3485 gio/tests/modules/Makefile
3486 po/Makefile.in
3487 docs/Makefile
3488 docs/reference/Makefile
3489 docs/reference/glib/Makefile
3490 docs/reference/glib/version.xml
3491 docs/reference/gobject/Makefile
3492 docs/reference/gobject/version.xml
3493 docs/reference/gio/Makefile
3494 docs/reference/gio/version.xml
3495 tests/Makefile
3496 tests/gobject/Makefile
3497 tests/refcount/Makefile
3498 m4macros/Makefile
3499 ])
3501 AC_CONFIG_COMMANDS([chmod-scripts],
3502 [chmod 0755 glib-zip
3503 chmod 0755 glib-gettextize
3504 chmod 0755 gobject/glib-mkenums])
3506 # we want to invoke this macro solely so that the config.status script
3507 # and automake generated makefiles know about these generated files.
3508 # They are only needed to distcheck the package
3509 if false; then
3510 AC_CONFIG_FILES([
3511 INSTALL
3512 README
3513 config.h.win32
3514 glib/glibconfig.h.win32
3515 glib/makefile.msc
3516 glib/glib.rc
3517 gmodule/makefile.msc
3518 gmodule/gmodule.rc
3519 gobject/makefile.msc
3520 gobject/gobject.rc
3521 gthread/makefile.msc
3522 gthread/gthread.rc
3523 gio/gio.rc
3524 tests/makefile.msc
3525 ])
3526 fi
3528 AC_OUTPUT