| blob | 1563ca12430853ef7825f165026b9b425df413d6 |
1 dnl ***********************************
2 dnl *** include special GLib macros ***
3 dnl ***********************************
5 define(glib_configure_in)
6 builtin(include, acglib.m4)dnl
7 builtin(include, glib/libcharset/codeset.m4)dnl
8 builtin(include, glib/libcharset/glibc21.m4)dnl
9 builtin(include, m4macros/glib-gettext.m4)dnl
11 # require autoconf 2.53
12 AC_PREREQ(2.53)
14 # Process this file with autoconf to produce a configure script.
15 AC_INIT(glib/glib.h)
17 # Save this value here, since automake will set cflags later
18 cflags_set=${CFLAGS+set}
20 #
21 # The following version number definitions apply to GLib, GModule, GObject
22 # and GThread as a whole, so if changes occoured in any of them, they are all
23 # treated with the same interface and binary age.
24 #
25 # Making releases:
26 # GLIB_MICRO_VERSION += 1;
27 # GLIB_INTERFACE_AGE += 1;
28 # GLIB_BINARY_AGE += 1;
29 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
30 # if backwards compatibility has been broken,
31 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
32 #
33 m4_define([glib_major_version], [2])
34 m4_define([glib_minor_version], [2])
35 m4_define([glib_micro_version], [2])
36 m4_define([glib_interface_age], [2])
38 # if the minor version number is odd, then we want debugging. Otherwise
39 # we only want minimal debugging support.
40 m4_define([glib_debug_default],
41 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
43 GLIB_MAJOR_VERSION=glib_major_version
44 GLIB_MINOR_VERSION=glib_minor_version
45 GLIB_MICRO_VERSION=glib_micro_version
46 GLIB_INTERFACE_AGE=glib_interface_age
47 GLIB_BINARY_AGE=`expr 100 '*' $GLIB_MINOR_VERSION + $GLIB_MICRO_VERSION`
48 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
50 AC_SUBST(GLIB_MAJOR_VERSION)
51 AC_SUBST(GLIB_MINOR_VERSION)
52 AC_SUBST(GLIB_MICRO_VERSION)
53 AC_SUBST(GLIB_VERSION)
54 AC_SUBST(GLIB_INTERFACE_AGE)
55 AC_SUBST(GLIB_BINARY_AGE)
57 # libtool versioning
58 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
59 LT_CURRENT=`expr 100 '*' $GLIB_MINOR_VERSION + $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
60 LT_REVISION=$GLIB_INTERFACE_AGE
61 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
62 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
63 AC_SUBST(LT_RELEASE)
64 AC_SUBST(LT_CURRENT)
65 AC_SUBST(LT_REVISION)
66 AC_SUBST(LT_AGE)
67 AC_SUBST(LT_CURRENT_MINUS_AGE)
69 VERSION=$GLIB_VERSION
70 PACKAGE=glib
72 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
74 # Specify a configuration file
75 AM_CONFIG_HEADER(config.h)
77 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
78 [Define to the GLIB major version])
79 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
80 [Define to the GLIB minor version])
81 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
82 [Define to the GLIB micro version])
83 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
84 [Define to the GLIB interface age])
85 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
86 [Define to the GLIB binary age])
88 dnl Initialize maintainer mode
89 AM_MAINTAINER_MODE
91 AC_CANONICAL_HOST
93 AC_MSG_CHECKING(for the BeOS)
94 case $host in
95 *-*-beos*)
96 glib_native_beos="yes"
97 ;;
98 *)
99 glib_native_beos="no"
100 ;;
101 esac
102 AC_MSG_RESULT([$glib_native_beos])
104 dnl
106 AC_MSG_CHECKING([for Win32])
107 case "$host" in
108 *-*-mingw*)
109 glib_native_win32=yes
110 G_LIB_WIN32_RESOURCE=glib-win32res.lo
111 G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
112 G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
113 G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
114 GLIB_DEF=glib.def
115 GMODULE_DEF=gmodule.def
116 GOBJECT_DEF=gobject.def
117 GTHREAD_DEF=gthread.def
118 TESTGMODULE_EXP=testgmodule.exp
119 ;;
120 *)
121 glib_native_win32=no
122 G_LIB_WIN32_RESOURCE=
123 G_MODULE_WIN32_RESOURCE=
124 G_OBJECT_WIN32_RESOURCE=
125 G_THREAD_WIN32_RESOURCE=
126 GLIB_DEF=
127 GMODULE_DEF=
128 GOBJECT_DEF=
129 GTHREAD_DEF=
130 TESTGMODULE_EXP=
131 ;;
132 esac
133 AC_MSG_RESULT([$glib_native_win32])
134 AM_CONDITIONAL(OS_WIN32, test "$glib_native_win32" = "yes")
135 AC_SUBST(G_LIB_WIN32_RESOURCE)
136 AC_SUBST(G_MODULE_WIN32_RESOURCE)
137 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
138 AC_SUBST(G_THREAD_WIN32_RESOURCE)
139 AC_SUBST(GLIB_DEF)
140 AC_SUBST(GMODULE_DEF)
141 AC_SUBST(GOBJECT_DEF)
142 AC_SUBST(GTHREAD_DEF)
143 AC_SUBST(TESTGMODULE_EXP)
145 if test "$glib_native_win32" = "yes"; then
146 AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
147 fi
148 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
150 dnl declare --enable-* args and collect ac_help strings
151 AC_ARG_ENABLE(debug, [ --enable-debug=[no/minimum/yes] turn on debugging @<:@default=glib_debug_default@:>@],,enable_debug=glib_debug_default)
152 AC_ARG_ENABLE(gc_friendly, [ --enable-gc-friendly turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
153 AC_ARG_ENABLE(mem_pools, [ --disable-mem-pools disable all glib memory pools],,disable_mem_pools=no)
154 AC_ARG_ENABLE(ansi, [ --enable-ansi turn on strict ansi [default=no]],
155 , enable_ansi=no)
156 AC_ARG_ENABLE(threads, [ --enable-threads turn on basic thread support [default=yes]
157 ([=no] will override --with-threads)],,enable_threads=yes)
158 AC_ARG_ENABLE(rebuilds, [ --disable-rebuilds disable all source autogeneration rules],,enable_rebuilds=yes)
160 if test "x$enable_threads" != "xyes"; then
161 enable_threads=no
162 fi
164 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
165 [Whether glib was compiled with debugging enabled])
167 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
168 if test "x$enable_gc_friendly" = "xyes"; then
169 AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
170 AC_SUBST(ENABLE_GC_FRIENDLY)
171 AC_MSG_RESULT(yes)
172 else
173 AC_MSG_RESULT(no)
174 fi
176 AC_MSG_CHECKING(whether to disable memory pools)
177 if test "x$disable_mem_pools" = "xno"; then
178 AC_MSG_RESULT(no)
179 else
180 AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
181 AC_SUBST(DISABLE_MEM_POOLS)
182 AC_MSG_RESULT(yes)
183 fi
185 dnl Checks for programs.
186 AC_PROG_CC
188 dnl Check for a working C++ compiler, but do not bail out, if none is found.
189 AC_CHECK_PROGS(CXX, $CCC c++ g++ gcc CC cxx cc++ cl, gcc)
190 AC_LANG_SAVE
191 AC_LANG_CPLUSPLUS
192 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
193 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
194 AC_LANG_RESTORE
196 AM_PROG_CC_STDC
197 AC_PROG_INSTALL
199 AC_SYS_LARGEFILE
201 #
202 # Find pkg-config
203 #
204 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
205 if test x$PKG_CONFIG = xno ; then
206 AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
207 fi
209 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
210 :
211 else
212 AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
213 fi
215 if test "x$enable_debug" = "xyes"; then
216 if test x$cflags_set != xset ; then
217 case " $CFLAGS " in
218 *[[\ \ ]]-g[[\ \ ]]*) ;;
219 *) CFLAGS="$CFLAGS -g" ;;
220 esac
221 fi
223 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
224 else
225 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
227 if test "x$enable_debug" = "xno"; then
228 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
229 fi
230 fi
232 # Ensure MSVC-compatible struct packing convention is used when
233 # compiling for Win32 with gcc.
234 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
235 # gcc2 uses "-fnative-struct".
236 if test x"$glib_native_win32" = xyes; then
237 if test x"$GCC" = xyes; then
238 msnative_struct=''
239 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
240 if test -z "$ac_cv_prog_CC"; then
241 our_gcc="$CC"
242 else
243 our_gcc="$ac_cv_prog_CC"
244 fi
245 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
246 2.)
247 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
248 msnative_struct='-fnative-struct'
249 fi
250 ;;
251 *)
252 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
253 msnative_struct='-mms-bitfields'
254 fi
255 ;;
256 esac
257 if test x"$msnative_struct" = x ; then
258 AC_MSG_RESULT([no way])
259 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
260 else
261 CFLAGS="$CFLAGS $msnative_struct"
262 AC_MSG_RESULT([${msnative_struct}])
263 fi
264 fi
265 fi
267 AC_CYGWIN
268 AC_EXEEXT
270 # define a MAINT-like variable REBUILD which is set if Perl
271 # and awk are found, so autogenerated sources can be rebuilt
272 AC_PROG_AWK
273 AC_CHECK_PROGS(PERL, perl5 perl)
274 # We would like indent, but don't require it.
275 AC_CHECK_PROG(INDENT, indent, indent)
276 REBUILD=\#
277 if test "x$enable_rebuilds" = "xyes" && \
278 test -n "$PERL" && \
279 $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
280 test -n "$AWK" ; then
281 REBUILD=
282 fi
283 AC_SUBST(REBUILD)
285 # Need full path to Perl for glib-mkenums
286 #
287 if test "x$PERL" != x ; then
288 AC_PATH_PROG(PERL_PATH, $PERL)
289 else
290 PERL_PATH="/usr/bin/env perl"
291 fi
292 AC_SUBST(PERL_PATH)
294 dnl ***********************
295 dnl *** Tests for iconv ***
296 dnl ***********************
297 dnl
298 dnl We do this before the gettext checks, to avoid distortion
300 AC_ARG_WITH(libiconv, [ --with-libiconv=[no/gnu/native] use the libiconv library ],,with_libiconv=maybe)
302 found_iconv=no
303 case $with_libiconv in
304 maybe)
305 # Check in the C library first
306 AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
307 # Check if we have GNU libiconv
308 if test $found_iconv = "no"; then
309 AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=gnu; found_iconv=yes)
310 fi
311 # Check if we have a iconv in -liconv, possibly from vendor
312 if test $found_iconv = "no"; then
313 AC_CHECK_LIB(iconv, iconv_open, with_libiconv=native; found_iconv=yes)
314 fi
315 ;;
316 no)
317 AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
318 ;;
319 gnu|yes)
320 AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=gnu; found_iconv=yes)
321 ;;
322 native)
323 AC_CHECK_LIB(iconv, iconv_open, with_libiconv=native; found_iconv=yes)
324 ;;
325 esac
327 if test "x$found_iconv" = "xno" ; then
328 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
329 fi
331 dnl
332 dnl gettext support
333 dnl
335 ALL_LINGUAS="am az be bg bn ca cs cy da de el es et eu fa fi fr gl he hi id it ja ko li lv mk ml mn ms nl nn no pl pt pt_BR ro ru sk sl sq sr sr@Latn sv ta tr uk vi yi zh_CN zh_TW"
336 GLIB_GNU_GETTEXT
338 if test "$gt_cv_have_gettext" != "yes" ; then
339 AC_MSG_ERROR([
340 *** You must have either have gettext support in your C library, or use the
341 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
342 ])
343 fi
345 LIBS="$INTLLIBS $LIBS"
347 GETTEXT_PACKAGE=glib20
348 AC_SUBST(GETTEXT_PACKAGE)
349 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
350 [Define the gettext package to be used])
352 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
354 dnl
355 dnl Now we are done with gettext checks, figure out ICONV_LIBS
356 dnl
358 if test x$with_libiconv != xno ; then
359 case " $INTLLIBS " in
360 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
361 *) ICONV_LIBS="-liconv" ;;
362 esac
363 fi
364 AC_SUBST(ICONV_LIBS)
366 case $with_libiconv in
367 gnu)
368 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
369 ;;
370 native)
371 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
372 ;;
373 esac
375 dnl Initialize libtool
376 AM_DISABLE_STATIC
377 AC_LIBTOOL_WIN32_DLL
378 AM_PROG_LIBTOOL
380 if test "x$GCC" = "xyes"; then
381 case " $CFLAGS " in
382 *[[\ \ ]]-Wall[[\ \ ]]*) ;;
383 *) CFLAGS="$CFLAGS -Wall" ;;
384 esac
386 if test "x$enable_ansi" = "xyes"; then
387 case " $CFLAGS " in
388 *[[\ \ ]]-ansi[[\ \ ]]*) ;;
389 *) CFLAGS="$CFLAGS -ansi" ;;
390 esac
392 case " $CFLAGS " in
393 *[[\ \ ]]-pedantic[[\ \ ]]*) ;;
394 *) CFLAGS="$CFLAGS -pedantic" ;;
395 esac
396 fi
397 fi
399 dnl
400 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
401 dnl
402 if test $cross_compiling != yes ; then
403 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
404 glib_save_LIBS=$LIBS
405 LIBS="$LIBS -lm"
406 AC_TRY_RUN([#include <math.h>
407 int main (void) { return (log(1) != log(1.)); }],
408 AC_MSG_RESULT(none needed),
409 glib_save_CFLAGS=$CFLAGS
410 CFLAGS="$CFLAGS -std1"
411 AC_TRY_RUN([#include <math.h>
412 int main (void) { return (log(1) != log(1.)); }],
413 AC_MSG_RESULT(-std1),
414 AC_MSG_RESULT()
415 CFLAGS=$glib_save_CFLAGS
416 AC_MSG_WARN(
417 [No ANSI prototypes found in library. (-std1 didn't work.)])
418 )
419 )
420 LIBS=$glib_save_LIBS
421 fi
423 dnl NeXTStep cc seems to need this
424 AC_MSG_CHECKING([for extra flags for POSIX compliance])
425 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
426 AC_MSG_RESULT(none needed),
427 glib_save_CFLAGS=$CFLAGS
428 CFLAGS="$CFLAGS -posix"
429 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
430 AC_MSG_RESULT(-posix),
431 AC_MSG_RESULT()
432 CFLAGS=$glib_save_CFLAGS
433 AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
435 # Checks for header files.
436 AC_HEADER_STDC
438 # Checks for library functions.
439 AC_FUNC_VPRINTF
441 AC_FUNC_ALLOCA
443 AC_CHECK_FUNCS(atexit on_exit)
445 AC_CHECK_SIZEOF(char)
446 AC_CHECK_SIZEOF(short)
447 AC_CHECK_SIZEOF(long)
448 AC_CHECK_SIZEOF(int)
449 AC_CHECK_SIZEOF(void *)
450 AC_CHECK_SIZEOF(long long)
451 AC_CHECK_SIZEOF(__int64)
453 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
454 :
455 else
456 AC_MSG_ERROR([
457 *** GLib requires a 64 bit type. You might want to consider
458 *** using the GNU C compiler.
459 ])
460 fi
462 if test x$ac_cv_sizeof_long_long = x8; then
463 # long long is a 64 bit integer.
464 AC_MSG_CHECKING(for format to printf and scanf a guint64)
465 AC_CACHE_VAL(glib_cv_long_long_format,[
466 for format in ll q I64; do
467 AC_TRY_RUN([#include <stdio.h>
468 int main()
469 {
470 long long b, a = -0x3AFAFAFAFAFAFAFALL;
471 char buffer[1000];
472 sprintf (buffer, "%${format}u", a);
473 sscanf (buffer, "%${format}u", &b);
474 exit (b!=a);
475 }
476 ],
477 [glib_cv_long_long_format=${format}
478 break],
479 [],[:])
480 done])
481 if test -n "$glib_cv_long_long_format"; then
482 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
483 else
484 AC_MSG_RESULT(none)
485 fi
486 elif test x$ac_cv_sizeof___int64 = x8; then
487 # __int64 is a 64 bit integer.
488 AC_MSG_CHECKING(for format to printf and scanf a guint64)
489 # We know this is MSVC, and what the formats are
490 glib_cv_long_long_format=I64
491 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
492 fi
494 dnl long doubles were not used, and a portability problem
495 dnl AC_C_LONG_DOUBLE
496 AC_C_CONST
498 dnl ok, here we try to check whether the systems prototypes for
499 dnl malloc and friends actually match the prototypes provided
500 dnl by gmem.h (keep in sync). i currently only know how to check
501 dnl this reliably with gcc (-Werror), improvements for other
502 dnl compilers are apprechiated.
503 SANE_MALLOC_PROTOS=no
504 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
505 glib_save_CFLAGS=$CFLAGS
506 if test "x$GCC" = "xyes"; then
507 CFLAGS="$CFLAGS -Werror"
508 AC_TRY_COMPILE([#include <stdlib.h>], [
509 void* (*my_calloc_p) (size_t, size_t) = calloc;
510 void* (*my_malloc_p) (size_t) = malloc;
511 void (*my_free_p) (void*) = free;
512 void* (*my_realloc_p) (void*, size_t) = realloc;
513 my_calloc_p = 0;
514 my_malloc_p = 0;
515 my_free_p = 0;
516 my_realloc_p = 0;
517 ],
518 AC_DEFINE(SANE_MALLOC_PROTOS, 1,
519 [Define if you have correct malloc prototypes])
520 SANE_MALLOC_PROTOS=yes)
521 fi
522 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
523 CFLAGS=$glib_save_CFLAGS
525 dnl
526 dnl check in which direction the stack grows
527 dnl
528 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
529 AC_TRY_RUN([
530 volatile int *a = 0, *b = 0;
531 void foo (void);
532 int main () { volatile int y = 7; a = &y; foo (); return b > a; }
533 void foo (void) { volatile int x = 5; b = &x; }
534 ],
535 glib_cv_stack_grows=no
536 ,
537 glib_cv_stack_grows=yes
538 ,)
539 ])
541 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
542 dnl truely know which ones of `inline', `__inline' and `__inline__' are
543 dnl actually supported.
544 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
545 AC_COMPILE_IFELSE([
546 __inline int foo () { return 0; }
547 int main () { return foo (); }
548 ],
549 glib_cv_has__inline=yes
550 ,
551 glib_cv_has__inline=no
552 ,)
553 ])
554 case x$glib_cv_has__inline in
555 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
556 esac
557 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
558 AC_COMPILE_IFELSE([
559 __inline__ int foo () { return 0; }
560 int main () { return foo (); }
561 ],
562 glib_cv_has__inline__=yes
563 ,
564 glib_cv_has__inline__=no
565 ,)
566 ])
567 case x$glib_cv_has__inline__ in
568 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
569 esac
570 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
571 AC_COMPILE_IFELSE([
572 #undef inline
573 inline int foo () { return 0; }
574 int main () { return foo (); }
575 ],
576 glib_cv_hasinline=yes
577 ,
578 glib_cv_hasinline=no
579 ,)
580 ])
581 case x$glib_cv_hasinline in
582 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
583 esac
585 # check for flavours of varargs macros
586 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
587 AC_TRY_COMPILE([],[
588 int a(int p1, int p2, int p3);
589 #define call_a(...) a(1,__VA_ARGS__)
590 call_a(2,3);
591 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
592 AC_MSG_RESULT($g_have_iso_c_varargs)
594 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
595 if test "$CXX" = ""; then
596 dnl No C++ compiler
597 g_have_iso_cxx_varargs=no
598 else
599 AC_LANG_CPLUSPLUS
600 AC_TRY_COMPILE([],[
601 int a(int p1, int p2, int p3);
602 #define call_a(...) a(1,__VA_ARGS__)
603 call_a(2,3);
604 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
605 AC_LANG_C
606 fi
607 AC_MSG_RESULT($g_have_iso_cxx_varargs)
609 AC_MSG_CHECKING(for GNUC varargs macros)
610 AC_TRY_COMPILE([],[
611 int a(int p1, int p2, int p3);
612 #define call_a(params...) a(1,params)
613 call_a(2,3);
614 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
615 AC_MSG_RESULT($g_have_gnuc_varargs)
617 # check for bytesex stuff
618 AC_C_BIGENDIAN
620 # check for header files
621 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
622 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
624 # Checks for libcharset
625 jm_LANGINFO_CODESET
626 jm_GLIBC21
627 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
628 AC_CHECK_FUNCS(setlocale)
630 AC_MSG_CHECKING(whether make is GNU Make)
631 STRIP_BEGIN=
632 STRIP_END=
633 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
634 STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
635 STRIP_END=')'
636 AC_MSG_RESULT(yes)
637 else
638 AC_MSG_RESULT(no)
639 fi
640 STRIP_DUMMY=
641 AC_SUBST(STRIP_DUMMY)
642 AC_SUBST(STRIP_BEGIN)
643 AC_SUBST(STRIP_END)
645 # check additional type sizes
646 AC_CHECK_SIZEOF(size_t)
648 dnl Try to figure out whether gsize, gssize should be long or int
649 AC_MSG_CHECKING([for the appropriate definition for size_t])
651 case $ac_cv_sizeof_size_t in
652 $ac_cv_sizeof_short)
653 glib_size_type=short
654 ;;
655 $ac_cv_sizeof_int)
656 glib_size_type=int
657 ;;
658 $ac_cv_sizeof_long)
659 glib_size_type=long
660 ;;
661 *) AC_MSG_ERROR([No type matching size_t in size])
662 ;;
663 esac
665 dnl If int/long are the same size, we see which one produces
666 dnl warnings when used in the location as size_t. (This matters
667 dnl on AIX with xlc)
668 dnl
669 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
670 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
671 GLIB_CHECK_COMPILE_WARNINGS([
672 #include <stddef.h>
673 int main ()
674 {
675 size_t s = 1;
676 unsigned int *size_int = &s;
677 return (int)*size_int;
678 }
679 ],glib_size_type=int,
680 [GLIB_CHECK_COMPILE_WARNINGS([
681 #include <stddef.h>
682 int main ()
683 {
684 size_t s = 1;
685 unsigned long *size_long = &s;
686 return (int)*size_long;
687 }
688 ],glib_size_type=long)])
689 fi
691 AC_MSG_RESULT(unsigned $glib_size_type)
693 # Check for some functions
694 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf unsetenv getc_unlocked)
696 AC_FUNC_VSNPRINTF_C99
697 AC_FUNC_PRINTF_UNIX98
699 #
700 # Check whether to use trio printf
701 #
703 AC_ARG_ENABLE(included-printf, [ --enable-included-printf use included printf [default=auto]], enable_trio="$enableval")
705 need_trio=no
706 if test "x$enable_trio" = "xyes" ; then
707 need_trio=yes
708 fi
709 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
710 need_trio=yes
711 fi
712 if test "$ac_cv_func_printf_unix98" != "yes" ; then
713 need_trio=yes
714 fi
715 if test "x$ac_cv_sizeof_long_long" = "x8" &&
716 test -z "$glib_cv_long_long_format" ; then
717 need_trio=yes
718 fi
720 if test "x$enable_trio" = "xno" &&
721 test "x$need_trio" = "xyes" ; then
722 AC_MSG_ERROR([
723 *** Your C library's printf doesn't appear to have the features that
724 *** GLib needs, but you specified --enable-included-printf=no.])
725 fi
727 enable_trio=$need_trio
729 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_trio" != "yes")
730 if test "$enable_trio" != "yes" ; then
731 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
732 else
733 glib_cv_long_long_format="ll"
734 AC_DEFINE(HAVE_VASPRINTF,1)
735 AC_DEFINE(HAVE_C99_VSNPRINTF,1)
736 AC_DEFINE(HAVE_UNIX98_PRINTF,1)
737 if test "$glib_native_win32" != "yes" ; then
738 TRIO_LIBS=-lm
739 fi
740 fi
741 AC_SUBST(TRIO_LIBS)
743 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
744 # The check is borrowed from the PERL Configure script.
745 if test "$ac_cv_func_memmove" != "yes"; then
746 AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
747 glib_cv_working_bcopy,[AC_TRY_RUN([
748 int main() {
749 char buf[128], abc[128], *b;
750 int len, off, align;
751 bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
752 for (align = 7; align >= 0; align--) {
753 for (len = 36; len; len--) {
754 b = buf+align; bcopy(abc, b, len);
755 for (off = 1; off <= len; off++) {
756 bcopy(b, b+off, len); bcopy(b+off, b, len);
757 if (bcmp(b, abc, len)) return(1);
758 }
759 }
760 }
761 return(0);
762 }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
764 GLIB_ASSERT_SET(glib_cv_working_bcopy)
765 if test "$glib_cv_working_bcopy" = "yes"; then
766 AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
767 fi
768 fi
770 # Check for sys_errlist
771 AC_MSG_CHECKING(for sys_errlist)
772 AC_TRY_LINK(, [
773 extern char *sys_errlist[];
774 extern int sys_nerr;
775 sys_errlist[sys_nerr-1][0] = 0;
776 ], glib_ok=yes, glib_ok=no)
777 AC_MSG_RESULT($glib_ok)
778 if test "$glib_ok" = "no"; then
779 AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
780 fi
782 # Check for sys_siglist
783 AC_MSG_CHECKING(for sys_siglist)
784 AC_TRY_LINK(, [
785 extern char *sys_siglist[];
786 exit (sys_siglist[0]);
787 ], glib_ok=yes, glib_ok=no)
788 AC_MSG_RESULT($glib_ok)
789 if test "$glib_ok" = "no"; then
790 AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
791 fi
793 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
794 AC_MSG_CHECKING(for sys_siglist declaration)
795 AC_TRY_COMPILE([#include <signal.h>], [
796 strlen (sys_siglist[0]);
797 ], glib_ok=yes, glib_ok=no)
798 AC_MSG_RESULT($glib_ok)
799 if test "$glib_ok" = "no"; then
800 AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
801 fi
803 # Check if <sys/select.h> needs to be included for fd_set
804 AC_MSG_CHECKING([for fd_set])
805 AC_TRY_COMPILE([#include <sys/types.h>],
806 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
807 if test "$gtk_ok" = "yes"; then
808 AC_MSG_RESULT([yes, found in sys/types.h])
809 else
810 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
811 if test "$gtk_ok" = "yes"; then
812 # *** FIXME: give it a different name
813 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
814 AC_MSG_RESULT([yes, found in sys/select.h])
815 else
816 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
817 AC_MSG_RESULT(no)
818 fi
819 fi
821 dnl *** check for sane realloc() ***
822 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
823 AC_TRY_RUN([#include <stdlib.h>
824 int main() {
825 return realloc (0, sizeof (int)) == 0;
826 }],
827 [glib_cv_sane_realloc=yes],
828 [glib_cv_sane_realloc=no],
829 [glib_cv_sane_realloc=yes])
830 ])
831 if test x$glib_cv_sane_realloc = xyes; then
832 AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
833 fi
835 dnl Check for nl_langinfo and CODESET
837 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
838 AC_TRY_COMPILE([#include <langinfo.h>],
839 [char *codeset = nl_langinfo (CODESET);],
840 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
841 have_codeset=yes,
842 have_codeset=no)
843 AC_MSG_RESULT($have_codeset)
846 dnl ****************************************
847 dnl *** strlcpy/strlcat ***
848 dnl ****************************************
849 # Check for strlcpy
850 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
851 AC_TRY_RUN([#include <stdlib.h>
852 #include <string.h>
853 int main() {
854 char p[10];
855 (void) strlcpy (p, "hi", 10);
856 if (strlcat (p, "bye", 0) != 3)
857 return 1;
858 return 0;
859 }], glib_cv_have_strlcpy=yes,
860 glib_cv_have_strlcpy=no,
861 glib_cv_have_strlcpy=no)])
862 if test "$glib_cv_have_strlcpy" = "yes"; then
863 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
864 fi
867 dnl **********************
868 dnl *** va_copy checks ***
869 dnl **********************
870 dnl we currently check for all three va_copy possibilities, so we get
871 dnl all results in config.log for bug reports.
872 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
873 AC_LINK_IFELSE([#include <stdarg.h>
874 void f (int i, ...) {
875 va_list args1, args2;
876 va_start (args1, i);
877 va_copy (args2, args1);
878 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
879 exit (1);
880 va_end (args1); va_end (args2);
881 }
882 int main() {
883 f (0, 42);
884 return 0;
885 }],
886 [glib_cv_va_copy=yes],
887 [glib_cv_va_copy=no])
888 ])
889 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
890 AC_LINK_IFELSE([#include <stdarg.h>
891 void f (int i, ...) {
892 va_list args1, args2;
893 va_start (args1, i);
894 __va_copy (args2, args1);
895 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
896 exit (1);
897 va_end (args1); va_end (args2);
898 }
899 int main() {
900 f (0, 42);
901 return 0;
902 }],
903 [glib_cv___va_copy=yes],
904 [glib_cv___va_copy=no])
905 ])
907 if test "x$glib_cv_va_copy" = "xyes"; then
908 g_va_copy_func=va_copy
909 else if test "x$glib_cv___va_copy" = "xyes"; then
910 g_va_copy_func=__va_copy
911 fi
912 fi
914 if test -n "$g_va_copy_func"; then
915 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
916 fi
918 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
919 AC_TRY_RUN([#include <stdarg.h>
920 void f (int i, ...) {
921 va_list args1, args2;
922 va_start (args1, i);
923 args2 = args1;
924 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
925 exit (1);
926 va_end (args1); va_end (args2);
927 }
928 int main() {
929 f (0, 42);
930 return 0;
931 }],
932 [glib_cv_va_val_copy=yes],
933 [glib_cv_va_val_copy=no],
934 [glib_cv_va_val_copy=yes])
935 ])
937 if test "x$glib_cv_va_val_copy" = "xno"; then
938 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
939 fi
941 dnl ***********************
942 dnl *** g_module checks ***
943 dnl ***********************
944 G_MODULE_LIBS=
945 G_MODULE_LIBS_EXTRA=
946 G_MODULE_PLUGIN_LIBS=
947 if test x"$glib_native_win32" = xyes; then
948 dnl No use for this on Win32
949 G_MODULE_LDFLAGS=
950 else
951 G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
952 fi
953 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
954 G_MODULE_NEED_USCORE=0
955 G_MODULE_BROKEN_RTLD_GLOBAL=0
956 G_MODULE_HAVE_DLERROR=0
957 dnl *** force native WIN32 shared lib loader
958 if test -z "$G_MODULE_IMPL"; then
959 case "$host" in
960 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
961 esac
962 fi
963 dnl *** dlopen() and dlsym() in system libraries
964 if test -z "$G_MODULE_IMPL"; then
965 AC_CHECK_FUNC(dlopen,
966 [AC_CHECK_FUNC(dlsym,
967 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
968 [])
969 fi
970 dnl *** load_image (BeOS)
971 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
972 AC_CHECK_LIB(root, load_image,
973 [G_MODULE_LIBS="-lbe -lroot -lglib"
974 G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
975 G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
976 G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
977 [])
978 fi
979 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
980 if test -z "$G_MODULE_IMPL"; then
981 AC_CHECK_FUNC(NSLinkModule,
982 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
983 G_MODULE_NEED_USCORE=1],
984 [])
985 fi
986 dnl *** dlopen() and dlsym() in libdl
987 if test -z "$G_MODULE_IMPL"; then
988 AC_CHECK_LIB(dl, dlopen,
989 [AC_CHECK_LIB(dl, dlsym,
990 [G_MODULE_LIBS=-ldl
991 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
992 [])
993 fi
994 dnl *** shl_load() in libdld (HP-UX)
995 if test -z "$G_MODULE_IMPL"; then
996 AC_CHECK_LIB(dld, shl_load,
997 [G_MODULE_LIBS=-ldld
998 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
999 [])
1000 fi
1001 dnl *** additional checks for G_MODULE_IMPL_DL
1002 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1003 LIBS_orig="$LIBS"
1004 LDFLAGS_orig="$LDFLAGS"
1005 LIBS="$G_MODULE_LIBS $LIBS"
1006 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1007 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1008 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1009 glib_cv_rtldglobal_broken,[
1010 AC_TRY_RUN([
1011 #include <dlfcn.h>
1012 #ifndef RTLD_GLOBAL
1013 # define RTLD_GLOBAL 0
1014 #endif
1015 #ifndef RTLD_LAZY
1016 # define RTLD_LAZY 0
1017 #endif
1018 int pthread_create;
1019 int main () {
1020 void *handle, *global, *local;
1021 global = &pthread_create;
1022 handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
1023 if (!handle) return 0;
1024 local = dlsym (handle, "pthread_create");
1025 return global == local;
1026 } ],
1027 [glib_cv_rtldglobal_broken=no],
1028 [glib_cv_rtldglobal_broken=yes],
1029 [glib_cv_rtldglobal_broken=no])
1030 rm -f plugin.c plugin.o plugin.lo
1031 ])
1032 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1033 G_MODULE_BROKEN_RTLD_GLOBAL=1
1034 else
1035 G_MODULE_BROKEN_RTLD_GLOBAL=0
1036 fi
1037 dnl *** check whether we need preceeding underscores
1038 AC_CACHE_CHECK([for preceeding underscore in symbols],
1039 glib_cv_uscore,[
1040 AC_TRY_RUN([#include <dlfcn.h>
1041 int glib_underscore_test (void) { return 42; }
1042 int main() {
1043 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1044 handle = dlopen ((void*)0, 0);
1045 if (handle) {
1046 f1 = dlsym (handle, "glib_underscore_test");
1047 f2 = dlsym (handle, "_glib_underscore_test");
1048 } return (!f2 || f1);
1049 }],
1050 [glib_cv_uscore=yes],
1051 [glib_cv_uscore=no],
1052 [])
1053 rm -f plugin.c plugin.$ac_objext plugin.lo
1054 ])
1055 GLIB_ASSERT_SET(glib_cv_uscore)
1056 if test "x$glib_cv_uscore" = "xyes"; then
1057 G_MODULE_NEED_USCORE=1
1058 else
1059 G_MODULE_NEED_USCORE=0
1060 fi
1062 LDFLAGS="$LDFLAGS_orig"
1063 dnl *** check for having dlerror()
1064 AC_CHECK_FUNC(dlerror,
1065 [G_MODULE_HAVE_DLERROR=1],
1066 [G_MODULE_HAVE_DLERROR=0])
1067 LIBS="$LIBS_orig"
1068 fi
1069 dnl *** done, have we got an implementation?
1070 if test -z "$G_MODULE_IMPL"; then
1071 G_MODULE_IMPL=0
1072 G_MODULE_SUPPORTED=false
1073 else
1074 G_MODULE_SUPPORTED=true
1075 fi
1077 AC_MSG_CHECKING(for the suffix of shared libraries)
1078 case "$host_os" in
1079 hpux9* | hpux10* | hpux11*) # taken from ltconfig
1080 glib_gmodule_suffix='sl'
1081 ;;
1082 cygwin* | mingw*)
1083 glib_gmodule_suffix='dll'
1084 ;;
1085 *)
1086 glib_gmodule_suffix='so'
1087 ;;
1088 esac
1089 AC_MSG_RESULT(.$glib_gmodule_suffix)
1091 AC_SUBST(G_MODULE_SUPPORTED)
1092 AC_SUBST(G_MODULE_IMPL)
1093 AC_SUBST(G_MODULE_LIBS)
1094 AC_SUBST(G_MODULE_LIBS_EXTRA)
1095 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1096 AC_SUBST(G_MODULE_LDFLAGS)
1097 AC_SUBST(G_MODULE_HAVE_DLERROR)
1098 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1099 AC_SUBST(G_MODULE_NEED_USCORE)
1100 AC_SUBST(GLIB_DEBUG_FLAGS)
1102 dnl **********************
1103 dnl *** g_spawn checks ***
1104 dnl **********************
1106 AC_MSG_CHECKING(for gspawn implementation)
1107 case "$host" in
1108 *-*-mingw*)
1109 GSPAWN=gspawn-win32.lo
1110 ;;
1111 *)
1112 GSPAWN=gspawn.lo
1113 ;;
1114 esac
1115 AC_MSG_RESULT($GSPAWN)
1116 AC_SUBST(GSPAWN)
1118 dnl *************************
1119 dnl *** GIOChannel checks ***
1120 dnl *************************
1122 AC_MSG_CHECKING(for GIOChannel implementation)
1123 case "$host" in
1124 *-*-mingw*)
1125 GIO=giowin32.lo
1126 ;;
1127 *)
1128 GIO=giounix.lo
1129 ;;
1130 esac
1131 AC_MSG_RESULT($GIO)
1132 AC_SUBST(GIO)
1134 dnl ****************************************
1135 dnl *** platform dependent source checks ***
1136 dnl ****************************************
1138 AC_MSG_CHECKING(for platform-dependent source)
1139 case "$host" in
1140 *-*-cygwin*|*-*-mingw*)
1141 PLATFORMDEP=gwin32.lo
1142 ;;
1143 *)
1144 PLATFORMDEP=
1145 ;;
1146 esac
1147 AC_MSG_RESULT($PLATFORMDEP)
1148 AC_SUBST(PLATFORMDEP)
1150 AC_MSG_CHECKING([whether to compile timeloop])
1151 case "$host" in
1152 *-*-cygwin*|*-*-mingw*)
1153 enable_timeloop=no
1154 ;;
1155 *)
1156 enable_timeloop=yes
1157 ;;
1158 esac
1159 AC_MSG_RESULT($enable_timeloop)
1160 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1162 AC_MSG_CHECKING([if building for some Win32 platform])
1163 case "$host" in
1164 *-*-mingw*|*-*-cygwin*)
1165 platform_win32=yes
1166 ;;
1167 *)
1168 platform_win32=no
1169 ;;
1170 esac
1171 AC_MSG_RESULT($platform_win32)
1172 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1174 dnl ***********************
1175 dnl *** g_thread checks ***
1176 dnl ***********************
1178 AC_ARG_WITH(threads, [ --with-threads=[none/posix/dce/solaris/win32] specify a thread implementation to use],
1179 if test "x$with_threads" = x; then
1180 want_threads=yes
1181 else
1182 want_threads=$with_threads
1183 fi,
1184 want_threads=yes)
1185 if test "x$enable_threads" = "xno"; then
1186 want_threads=no
1187 fi
1189 dnl error and warning message
1190 dnl *************************
1192 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1193 computer. GLib will not have a default thread implementation."
1195 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1196 platform (normally it's "_REENTRANT"). I'll not use any flag on
1197 compilation now, but then your programs might not work.
1198 Please provide information on how it is done on your system."
1200 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1201 "
1203 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1204 provide information on your thread implementation.
1205 You can also run 'configure --disable-threads'
1206 to compile without thread support."
1208 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1209 functions will not be MT-safe during their first call because
1210 there is no working 'getpwuid_r' on your system."
1212 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1213 because there is no 'localtime_r' on your system."
1215 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1216 crude surrogate will be used. If you happen to know a
1217 yield function for your system, please inform the GLib
1218 developers."
1220 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1221 threads on your system. Thus threads can only have the default
1222 priority. If you happen to know these main/max
1223 priorities, please inform the GLib developers."
1225 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1226 linking threaded applications. As GLib cannot do that
1227 automatically, you will get an linkg error everytime you are
1228 not using the right compiler. In that case you have to relink
1229 with the right compiler. Ususally just '_r' is appended
1230 to the compiler name."
1232 dnl determination of thread implementation
1233 dnl ***************************************
1235 # have_threads=no means no thread support
1236 # have_threads=none means no default thread implementation
1238 have_threads=no
1239 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1240 case $host in
1241 *-*-solaris*)
1242 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1243 ;;
1244 esac
1245 fi
1246 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1247 || test "x$want_threads" = xdce; then
1248 # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1249 # -U_OSF_SOURCE is for Digital UNIX 4.0d
1250 GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1251 glib_save_CPPFLAGS="$CPPFLAGS"
1252 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1253 if test "x$have_threads" = xno; then
1254 AC_TRY_COMPILE([#include <pthread.h>],
1255 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1256 have_threads=posix)
1257 fi
1258 if test "x$have_threads" = xno; then
1259 AC_TRY_COMPILE([#include <pthread.h>],
1260 [pthread_mutex_t m;
1261 pthread_mutex_init (&m, pthread_mutexattr_default);],
1262 have_threads=dce)
1263 fi
1264 # Tru64Unix requires -pthread to find pthread.h. See #103020
1265 CPPFLAGS="$CPPFLAGS -pthread"
1266 if test "x$have_threads" = xno; then
1267 AC_TRY_COMPILE([#include <pthread.h>],
1268 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1269 have_threads=posix)
1270 fi
1271 CPPFLAGS="$glib_save_CPPFLAGS"
1272 fi
1273 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1274 case $host in
1275 *-*-mingw*)
1276 have_threads=win32
1277 ;;
1278 esac
1279 fi
1280 if test "x$want_threads" = xnone; then
1281 have_threads=none
1282 fi
1284 AC_MSG_CHECKING(for thread implementation)
1286 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1287 AC_MSG_RESULT(none available)
1288 AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1289 else
1290 AC_MSG_RESULT($have_threads)
1291 fi
1294 dnl determination of G_THREAD_CFLAGS
1295 dnl ********************************
1297 G_THREAD_LIBS=
1298 G_THREAD_LIBS_EXTRA=
1299 G_THREAD_CFLAGS=
1301 dnl
1302 dnl Test program for basic POSIX threads functionality
1303 dnl
1304 m4_define([glib_thread_test],[
1305 #include <pthread.h>
1306 int check_me = 0;
1307 void* func(void* data) {check_me = 42; return &check_me;}
1308 int main()
1309 { pthread_t t;
1310 void *ret;
1311 pthread_create (&t, $1, func, 0);
1312 pthread_join (t, &ret);
1313 exit (check_me != 42 || ret != &check_me);
1314 }])
1316 dnl
1317 dnl Test program for sched_get_priority_min()
1318 dnl
1319 m4_define([glib_sched_priority_test],[
1320 #include <sched.h>
1321 #include <errno.h>
1322 int main() {
1323 errno = 0;
1324 return sched_get_priority_min(SCHED_OTHER)==-1
1325 && errno != 0;
1326 }])
1328 if test x"$have_threads" != xno; then
1330 if test x"$have_threads" = xposix; then
1331 # First we test for posix, whether -pthread or -pthreads do the trick as
1332 # both CPPFLAG and LIBS.
1333 # One of them does for most gcc versions and some other platforms/compilers
1334 # too and could be considered as the canonical way to go.
1335 for flag in pthread pthreads; do
1336 glib_save_CFLAGS="$CFLAGS"
1337 CFLAGS="$CFLAGS -$flag"
1338 AC_TRY_RUN(glib_thread_test(0),
1339 glib_flag_works=yes,
1340 glib_flag_works=no,
1341 [AC_LINK_IFELSE(glib_thread_test(0),
1342 glib_flag_works=yes,
1343 glib_flag_works=no)])
1344 CFLAGS="$glib_save_CFLAGS"
1345 if test $glib_flag_works = yes ; then
1346 G_THREAD_CFLAGS=-$flag
1347 G_THREAD_LIBS=-$flag
1348 fi
1349 done
1350 fi
1352 if test x"$G_THREAD_CFLAGS" = x; then
1354 # The canonical -pthread[s] does not work. Try something different.
1356 case $host in
1357 *-aix*)
1358 if test x"$GCC" = xyes; then
1359 # GCC 3.0 and above needs -pthread.
1360 # Should be coverd by the case above.
1361 # GCC 2.x and below needs -mthreads
1362 G_THREAD_CFLAGS="-mthreads"
1363 G_THREAD_LIBS=$G_THREAD_CFLAGS
1364 else
1365 # We are probably using the aix compiler. Normaly a
1366 # program would have to be compiled with the _r variant
1367 # of the corresponding compiler, but we as GLib cannot
1368 # do that: but the good news is that for compiling the
1369 # only difference is the added -D_THREAD_SAFE compile
1370 # option. This is according to the "C for AIX User's
1371 # Guide".
1372 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1373 fi
1374 ;;
1375 *-dg-dgux*) # DG/UX
1376 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1377 ;;
1378 *-osf*)
1379 # So we are using dce threads. posix threads are already
1380 # catched above.
1381 G_THREAD_CFLAGS="-threads"
1382 G_THREAD_LIBS=$G_THREAD_CFLAGS
1383 ;;
1384 *-solaris*)
1385 if test x"$GCC" = xyes; then
1386 # We are using solaris threads. posix threads are
1387 # already catched above.
1388 G_THREAD_CFLAGS="-threads"
1389 else
1390 G_THREAD_CFLAGS="-mt"
1391 fi
1392 G_THREAD_LIBS=$G_THREAD_CFLAGS
1393 ;;
1394 *-sysv5uw7*) # UnixWare 7
1395 # We are not using gcc with -pthread. Catched above.
1396 G_THREAD_CFLAGS="-Kthread"
1397 G_THREAD_LIBS=$G_THREAD_CFLAGS
1398 ;;
1399 *)
1400 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1401 ;;
1402 esac
1404 fi
1406 # if we are not finding the localtime_r function, then we probably are
1407 # not using the proper multithread flag
1409 glib_save_CPPFLAGS="$CPPFLAGS"
1410 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1412 # First we test, whether localtime_r is declared in time.h
1413 # directly. Then we test whether a macro localtime_r exists, in
1414 # which case localtime_r in the test program is replaced and thus
1415 # if we still find localtime_r in the output, it is not defined as
1416 # a macro.
1418 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1419 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1420 localtime_r(a,b)],
1421 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1423 CPPFLAGS="$glib_save_CPPFLAGS"
1425 AC_MSG_CHECKING(thread related cflags)
1426 AC_MSG_RESULT($G_THREAD_CFLAGS)
1427 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1428 fi
1430 dnl determination of G_THREAD_LIBS
1431 dnl ******************************
1433 mutex_has_default=no
1434 case $have_threads in
1435 posix|dce)
1436 glib_save_CPPFLAGS="$CPPFLAGS"
1437 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1438 if test x"$G_THREAD_LIBS" = x; then
1439 case $host in
1440 *-aix*)
1441 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1442 # probably using the aix compiler.
1443 AC_MSG_WARN($AIX_COMPILE_INFO)
1444 ;;
1445 *)
1446 G_THREAD_LIBS=error
1447 glib_save_LIBS="$LIBS"
1448 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1449 if test x"$thread_lib" = x; then
1450 add_thread_lib=""
1451 IN=""
1452 else
1453 add_thread_lib="-l$thread_lib"
1454 IN=" in -l$thread_lib"
1455 fi
1456 if test x"$have_threads" = xposix; then
1457 defattr=0
1458 else
1459 defattr=pthread_attr_default
1460 fi
1462 LIBS="$add_thread_lib $glib_save_LIBS"
1464 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1465 AC_TRY_RUN(glib_thread_test($defattr),
1466 glib_result=yes,
1467 glib_result=no,
1468 [AC_LINK_IFELSE(glib_thread_test($defattr),
1469 glib_result=yes,
1470 glib_result=no)])
1471 AC_MSG_RESULT($glib_result)
1473 if test "$glib_result" = "yes" ; then
1474 G_THREAD_LIBS="$add_thread_lib"
1475 break
1476 fi
1477 done
1478 if test "x$G_THREAD_LIBS" = xerror; then
1479 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1480 fi
1481 LIBS="$glib_save_LIBS"
1482 ;;
1483 esac
1484 fi
1486 glib_save_LIBS="$LIBS"
1487 for thread_lib in "" rt rte; do
1488 if test x"$thread_lib" = x; then
1489 add_thread_lib=""
1490 IN=""
1491 else
1492 add_thread_lib="-l$thread_lib"
1493 IN=" in -l$thread_lib"
1494 fi
1495 LIBS="$add_thread_lib $glib_save_LIBS"
1497 AC_MSG_CHECKING(for sched_get_priority_min$IN)
1498 AC_TRY_RUN(glib_sched_priority_test,
1499 glib_result=yes,
1500 glib_result=no,
1501 [AC_LINK_IFELSE(glib_sched_priority_test,
1502 glib_result=yes,
1503 glib_result=no)])
1504 AC_MSG_RESULT($glib_result)
1506 if test "$glib_result" = "yes" ; then
1507 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1508 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1509 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1510 break
1511 fi
1512 done
1513 LIBS="$glib_save_LIBS"
1514 mutex_has_default=yes
1515 mutex_default_type='pthread_mutex_t'
1516 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1517 mutex_header_file='pthread.h'
1518 if test "x$have_threads" = "xposix"; then
1519 g_threads_impl="POSIX"
1520 else
1521 g_threads_impl="DCE"
1522 have_threads="posix"
1523 fi
1524 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1525 CPPFLAGS="$glib_save_CPPFLAGS"
1526 ;;
1527 solaris)
1528 mutex_has_default=yes
1529 mutex_default_type='mutex_t'
1530 mutex_default_init="DEFAULTMUTEX"
1531 mutex_header_file='thread.h'
1532 g_threads_impl="SOLARIS"
1533 ;;
1534 win32)
1535 g_threads_impl="WIN32"
1536 ;;
1537 none|no)
1538 g_threads_impl="NONE"
1539 ;;
1540 *)
1541 g_threads_impl="NONE"
1542 G_THREAD_LIBS=error
1543 ;;
1544 esac
1546 if test "x$G_THREAD_LIBS" = xerror; then
1547 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1548 fi
1550 case $host in
1551 *-*-beos*)
1552 G_THREAD_LIBS="-lbe -lroot -lglib "
1553 G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1554 ;;
1555 *)
1556 ;;
1557 esac
1559 AC_MSG_CHECKING(thread related libraries)
1560 AC_MSG_RESULT($G_THREAD_LIBS)
1562 dnl check for mt safe function variants and some posix functions
1563 dnl ************************************************************
1565 if test x"$have_threads" != xno; then
1566 glib_save_LIBS="$LIBS"
1567 # we are not doing the following for now, as this might require glib
1568 # to always be linked with the thread libs on some platforms.
1569 # LIBS="$LIBS $G_THREAD_LIBS"
1570 AC_CHECK_FUNCS(localtime_r)
1571 if test "$ac_cv_header_pwd_h" = "yes"; then
1572 AC_CACHE_CHECK([for posix getpwuid_r],
1573 ac_cv_func_posix_getpwuid_r,
1574 [AC_TRY_RUN([
1575 #include <errno.h>
1576 #include <pwd.h>
1577 int main () {
1578 char buffer[10000];
1579 struct passwd pwd, *pwptr = &pwd;
1580 int error;
1581 errno = 0;
1582 error = getpwuid_r (0, &pwd, buffer,
1583 sizeof (buffer), &pwptr);
1584 return (error < 0 && errno == ENOSYS)
1585 || error == ENOSYS;
1586 } ],
1587 [ac_cv_func_posix_getpwuid_r=yes],
1588 [ac_cv_func_posix_getpwuid_r=no])])
1589 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1590 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1591 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1592 [Have POSIX function getpwuid_r])
1593 else
1594 AC_CACHE_CHECK([for nonposix getpwuid_r],
1595 ac_cv_func_nonposix_getpwuid_r,
1596 [AC_TRY_LINK([#include <pwd.h>],
1597 [char buffer[10000];
1598 struct passwd pwd;
1599 getpwuid_r (0, &pwd, buffer,
1600 sizeof (buffer));],
1601 [ac_cv_func_nonposix_getpwuid_r=yes],
1602 [ac_cv_func_nonposix_getpwuid_r=no])])
1603 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1604 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1605 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1606 [Have non-POSIX function getpwuid_r])
1607 fi
1608 fi
1609 fi
1610 LIBS="$G_THREAD_LIBS $LIBS"
1611 if test x"$have_threads" = xposix; then
1612 glib_save_CPPFLAGS="$CPPFLAGS"
1613 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1614 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1615 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1616 # This is not AC_CHECK_FUNC to also work with function
1617 # name mangling in header files.
1618 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1619 AC_TRY_LINK([#include <pthread.h>],
1620 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1621 [AC_MSG_RESULT(yes)
1622 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1623 [Have function pthread_attr_setstacksize])],
1624 [AC_MSG_RESULT(no)])
1625 AC_MSG_CHECKING(for minimal/maximal thread priority)
1626 if test x"$posix_priority_min" = x; then
1627 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1628 PX_PRIO_MIN],,[
1629 posix_priority_min=PX_PRIO_MIN
1630 posix_priority_max=PX_PRIO_MAX])
1631 fi
1632 if test x"$posix_priority_min" = x; then
1633 # AIX
1634 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1635 PTHREAD_PRIO_MIN],,[
1636 posix_priority_min=PTHREAD_PRIO_MIN
1637 posix_priority_max=PTHREAD_PRIO_MAX])
1638 fi
1639 if test x"$posix_priority_min" = x; then
1640 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1641 PRI_OTHER_MIN],,[
1642 posix_priority_min=PRI_OTHER_MIN
1643 posix_priority_max=PRI_OTHER_MAX])
1644 fi
1645 if test x"$posix_priority_min" = x; then
1646 AC_MSG_RESULT(none found)
1647 AC_MSG_WARN($POSIX_NO_PRIORITIES)
1648 posix_priority_min=-1
1649 posix_priority_max=-1
1650 else
1651 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1652 AC_MSG_CHECKING(for pthread_setschedparam)
1653 AC_TRY_LINK([#include <pthread.h>],
1654 [pthread_t t; pthread_setschedparam(&t, 0, NULL)],
1655 [AC_MSG_RESULT(yes)
1656 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1657 AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1658 [AC_MSG_RESULT(no)
1659 AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1660 fi
1661 posix_yield_func=none
1662 AC_MSG_CHECKING(for posix yield function)
1663 for yield_func in sched_yield pthread_yield_np pthread_yield \
1664 thr_yield; do
1665 AC_TRY_LINK([#include <pthread.h>],
1666 [$yield_func()],
1667 [posix_yield_func="$yield_func"
1668 break])
1669 done
1670 if test x"$posix_yield_func" = xnone; then
1671 AC_MSG_RESULT(none found)
1672 AC_MSG_WARN($POSIX_NO_YIELD)
1673 posix_yield_func="g_usleep(1000)"
1674 else
1675 AC_MSG_RESULT($posix_yield_func)
1676 posix_yield_func="$posix_yield_func()"
1677 fi
1678 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1679 CPPFLAGS="$glib_save_CPPFLAGS"
1681 AC_CACHE_CHECK([whether to use the PID niceness surrogate for thread priorities],
1682 glib_cv_use_pid_surrogate,
1683 [AC_TRY_RUN([
1684 #include <pthread.h>
1685 #include <sys/types.h>
1686 #include <unistd.h>
1687 pid_t other_pid = 0;
1689 void* func(void* data) {other_pid = getpid();}
1690 main()
1691 { pthread_t t;
1692 void *ret;
1693 pthread_create (&t, 0, func, NULL);
1694 pthread_join (t, &ret);
1695 exit (getpid()==other_pid ||
1696 $posix_priority_min != $posix_priority_max);
1697 } ],
1698 [glib_cv_use_pid_surrogate=yes],
1699 [glib_cv_use_pid_surrogate=no],
1700 [])])
1701 GLIB_ASSERT_SET(glib_cv_use_pid_surrogate)
1702 if test "$glib_cv_use_pid_surrogate" = "yes" ; then
1703 AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1704 [whether to use the PID niceness surrogate for thread priorities])
1705 fi
1707 elif test x"$have_threads" = xwin32; then
1708 # It's a pointer to a private struct
1709 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1710 elif test x"$have_threads" = xsolaris; then
1711 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1712 fi
1714 LIBS="$glib_save_LIBS"
1716 # now spit out all the warnings.
1717 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1718 test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1719 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1720 fi
1721 if test "$ac_cv_func_localtime_r" != "yes"; then
1722 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1723 fi
1724 fi
1726 if test x"$glib_cv_sizeof_system_thread" = x; then
1727 # use a pointer as a fallback.
1728 GLIB_SIZEOF(,void *, system_thread)
1729 fi
1731 #
1732 # Hack to deal with:
1733 #
1734 # a) GCC < 3.3 for Linux doesn't include -lpthread when
1735 # building shared libraries with linux.
1736 # b) libtool doesn't recognize -pthread as a library dependency.
1737 #
1738 case $host in
1739 *-*-linux*)
1740 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1741 ;;
1742 *)
1743 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-Wc,-pthread/`"
1744 ;;
1745 esac
1747 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1748 [Source file containing theread implementation])
1749 AC_SUBST(G_THREAD_CFLAGS)
1750 AC_SUBST(G_THREAD_LIBS)
1751 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1752 AC_SUBST(G_THREAD_LIBS_EXTRA)
1754 dnl **********************************************
1755 dnl *** GDefaultMutex setup and initialization ***
1756 dnl **********************************************
1757 dnl
1758 dnl if mutex_has_default = yes, we also got
1759 dnl mutex_default_type, mutex_default_init and mutex_header_file
1760 if test $mutex_has_default = yes ; then
1761 glib_save_CPPFLAGS="$CPPFLAGS"
1762 glib_save_LIBS="$LIBS"
1763 LIBS="$G_THREAD_LIBS $LIBS"
1764 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1765 GLIB_SIZEOF([#include <$mutex_header_file>],
1766 $mutex_default_type,
1767 gmutex)
1768 GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1769 $mutex_default_type,
1770 gmutex,
1771 $glib_cv_sizeof_gmutex,
1772 $mutex_default_init)
1773 if test x"$glib_cv_byte_contents_gmutex" = xno; then
1774 mutex_has_default=no
1775 fi
1776 CPPFLAGS="$glib_save_CPPFLAGS"
1777 LIBS="$glib_save_LIBS"
1778 fi
1780 dnl ****************************************
1781 dnl *** GLib POLL* compatibility defines ***
1782 dnl ****************************************
1784 glib_poll_includes=["
1785 #include <sys/types.h>
1786 #include <sys/poll.h>
1787 "]
1789 if test $ac_cv_header_sys_types_h = yes &&
1790 test $ac_cv_header_sys_poll_h = yes ; then
1791 glib_failed=false
1792 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1793 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1794 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
1795 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
1796 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
1797 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
1798 if $glib_failed ; then
1799 AC_MSG_ERROR([Could not determine values for POLL* constants])
1800 fi
1801 else
1802 glib_cv_value_POLLIN=1
1803 glib_cv_value_POLLOUT=4
1804 glib_cv_value_POLLPRI=2
1805 glib_cv_value_POLLERR=8
1806 glib_cv_value_POLLHUP=16
1807 glib_cv_value_POLLNVAL=32
1808 fi
1810 dnl **********************
1811 dnl *** Win32 API libs ***
1812 dnl **********************
1814 case $host in
1815 *-*-cygwin*)
1816 G_LIBS_EXTRA="-luser32 -lkernel32"
1817 ;;
1818 *-*-mingw*)
1819 G_LIBS_EXTRA="-lwsock32"
1820 ;;
1821 *)
1822 G_LIBS_EXTRA=""
1823 ;;
1824 esac
1825 AC_SUBST(G_LIBS_EXTRA)
1827 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1828 dnl since we need it for g_iconv()
1830 AC_MSG_CHECKING([for EILSEQ])
1831 AC_TRY_COMPILE([
1832 #include <errno.h>
1833 ],
1834 [
1835 int error = EILSEQ;
1836 ], have_eilseq=yes, have_eilseq=no);
1837 AC_MSG_RESULT($have_eilseq)
1839 dnl ******************************************************************
1840 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
1841 dnl ******************************************************************
1843 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1845 if test $cross_compiling = yes; then
1846 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
1847 if test x$GLIB_GENMARSHAL = xno; then
1848 AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
1849 fi
1850 fi
1852 dnl **************************
1853 dnl *** Checks for gtk-doc ***
1854 dnl **************************
1856 AC_ARG_WITH(html-dir, [ --with-html-dir=PATH path to installed docs])
1858 if test "x$with_html_dir" = "x" ; then
1859 HTML_DIR='${datadir}/gtk-doc/html'
1860 else
1861 HTML_DIR=$with_html_dir
1862 fi
1864 AC_SUBST(HTML_DIR)
1866 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1868 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1870 gtk_doc_min_version=0.10
1871 if $GTKDOC ; then
1872 gtk_doc_version=`gtkdoc-mkdb --version`
1873 AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1875 IFS="${IFS= }"; gtk_save_IFS="$IFS"; IFS="."
1876 set $gtk_doc_version
1877 for min in $gtk_doc_min_version ; do
1878 cur=$1; shift
1879 if test -z $min ; then break; fi
1880 if test -z $cur ; then GTKDOC=false; break; fi
1881 if test $cur -gt $min ; then break ; fi
1882 if test $cur -lt $min ; then GTKDOC=false; break ; fi
1883 done
1884 IFS="$gtk_save_IFS"
1886 if $GTKDOC ; then
1887 AC_MSG_RESULT(yes)
1888 else
1889 AC_MSG_RESULT(no)
1890 fi
1891 fi
1893 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1894 AC_SUBST(HAVE_GTK_DOC)
1896 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1897 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1899 dnl Let people disable the gtk-doc stuff.
1900 AC_ARG_ENABLE(gtk-doc, [ --enable-gtk-doc use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=no)
1902 if test x$enable_gtk_doc = xyes ; then
1903 if test x$GTKDOC = xtrue ; then
1904 enable_gtk_doc=yes
1905 else
1906 enable_gtk_doc=no
1907 fi
1908 fi
1910 dnl NOTE: We need to use a separate automake conditional for this
1911 dnl to make this work with the tarballs.
1912 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1914 dnl ******************************
1915 dnl *** output the whole stuff ***
1916 dnl ******************************
1918 AC_OUTPUT_COMMANDS([
1920 ## Generate `glibconfig.h' in two cases
1921 ## 1. `config.status' is run either explicitly, or via configure.
1922 ## Esp. not when it is run in `Makefile' to generate makefiles and
1923 ## config.h
1924 ## 2. CONFIG_OTHER is set explicitly
1925 ##
1926 ## Case 1 is difficult. We know that `automake' sets one of
1927 ## CONFIG_FILES or CONFIG_HEADERS to empty. This heuristic works
1928 ## only when AM_CONFIG_HEADER is set, however.
1930 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1931 # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1932 CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1933 fi
1934 case "$CONFIG_OTHER" in
1935 *glibconfig.h*)
1936 echo creating glibconfig.h
1937 outfile=glibconfig.h-tmp
1938 cat > $outfile <<\_______EOF
1939 /* glibconfig.h
1940 *
1941 * This is a generated file. Please modify 'configure.in'
1942 */
1944 #ifndef __G_LIBCONFIG_H__
1945 #define __G_LIBCONFIG_H__
1947 #include <glib/gmacros.h>
1949 _______EOF
1951 if test x$glib_limits_h = xyes; then
1952 echo '#include <limits.h>' >> $outfile
1953 fi
1954 if test x$glib_float_h = xyes; then
1955 echo '#include <float.h>' >> $outfile
1956 fi
1957 if test x$glib_values_h = xyes; then
1958 echo '#include <values.h>' >> $outfile
1959 fi
1960 if test "$glib_header_alloca_h" = "yes"; then
1961 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1962 fi
1963 if test x$glib_sys_poll_h = xyes; then
1964 echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1965 fi
1967 cat >> $outfile <<_______EOF
1969 G_BEGIN_DECLS
1971 #define G_MINFLOAT $glib_mf
1972 #define G_MAXFLOAT $glib_Mf
1973 #define G_MINDOUBLE $glib_md
1974 #define G_MAXDOUBLE $glib_Md
1975 #define G_MINSHORT $glib_ms
1976 #define G_MAXSHORT $glib_Ms
1977 #define G_MAXUSHORT $glib_Mus
1978 #define G_MININT $glib_mi
1979 #define G_MAXINT $glib_Mi
1980 #define G_MAXUINT $glib_Mui
1981 #define G_MINLONG $glib_ml
1982 #define G_MAXLONG $glib_Ml
1983 #define G_MAXULONG $glib_Mul
1985 #define G_MININT64 G_GINT64_CONSTANT(0x8000000000000000)
1986 #define G_MAXINT64 G_GINT64_CONSTANT(0x7fffffffffffffff)
1987 #define G_MAXUINT64 G_GINT64_CONSTANT(0xffffffffffffffffU)
1989 _______EOF
1992 ### this should always be true in a modern C/C++ compiler
1993 cat >>$outfile <<_______EOF
1994 typedef signed char gint8;
1995 typedef unsigned char guint8;
1996 _______EOF
1999 if test -n "$gint16"; then
2000 cat >>$outfile <<_______EOF
2001 typedef signed $gint16 gint16;
2002 typedef unsigned $gint16 guint16;
2003 #define G_GINT16_FORMAT $gint16_format
2004 #define G_GUINT16_FORMAT $guint16_format
2005 _______EOF
2006 fi
2009 if test -n "$gint32"; then
2010 cat >>$outfile <<_______EOF
2011 typedef signed $gint32 gint32;
2012 typedef unsigned $gint32 guint32;
2013 #define G_GINT32_FORMAT $gint32_format
2014 #define G_GUINT32_FORMAT $guint32_format
2015 _______EOF
2016 fi
2018 cat >>$outfile <<_______EOF
2019 #define G_HAVE_GINT64 1 /* deprecated, always true */
2021 ${glib_extension}typedef signed $gint64 gint64;
2022 ${glib_extension}typedef unsigned $gint64 guint64;
2024 #define G_GINT64_CONSTANT(val) $gint64_constant
2025 _______EOF
2027 if test x$gint64_format != x ; then
2028 cat >>$outfile <<_______EOF
2029 #define G_GINT64_FORMAT $gint64_format
2030 #define G_GUINT64_FORMAT $guint64_format
2031 _______EOF
2032 else
2033 cat >>$outfile <<_______EOF
2034 #undef G_GINT64_FORMAT
2035 #undef G_GUINT64_FORMAT
2036 _______EOF
2037 fi
2039 cat >>$outfile <<_______EOF
2041 #define GLIB_SIZEOF_VOID_P $glib_void_p
2042 #define GLIB_SIZEOF_LONG $glib_long
2043 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2045 _______EOF
2047 echo "typedef signed $glib_size_type_define gssize;" >> $outfile
2048 echo "typedef unsigned $glib_size_type_define gsize;" >> $outfile
2050 if test -z "$glib_unknown_void_p"; then
2051 cat >>$outfile <<_______EOF
2053 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2054 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2056 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2057 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2058 _______EOF
2059 else
2060 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2061 fi
2065 cat >>$outfile <<_______EOF
2066 $glib_atexit
2067 $glib_memmove
2068 $glib_defines
2069 $glib_os
2071 $glib_vacopy
2073 #ifdef __cplusplus
2074 #define G_HAVE_INLINE 1
2075 #else /* !__cplusplus */
2076 $glib_inline
2077 #endif /* !__cplusplus */
2079 _______EOF
2081 if test x$g_have_iso_c_varargs = xyes ; then
2082 cat >>$outfile <<_______EOF
2083 #ifndef __cplusplus
2084 # define G_HAVE_ISO_VARARGS 1
2085 #endif
2086 _______EOF
2087 fi
2088 if test x$g_have_iso_cxx_varargs = xyes ; then
2089 cat >>$outfile <<_______EOF
2090 #ifdef __cplusplus
2091 # define G_HAVE_ISO_VARARGS 1
2092 #endif
2093 _______EOF
2094 fi
2095 if test x$g_have_gnuc_varargs = xyes ; then
2096 cat >>$outfile <<_______EOF
2098 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2099 * is passed ISO vararg support is turned off, and there is no work
2100 * around to turn it on, so we unconditionally turn it off.
2101 */
2102 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2103 # undef G_HAVE_ISO_VARARGS
2104 #endif
2106 #define G_HAVE_GNUC_VARARGS 1
2107 _______EOF
2108 fi
2110 case x$g_stack_grows in
2111 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2112 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2113 esac
2116 echo >>$outfile
2117 if test x$g_have_eilseq = xno; then
2118 cat >>$outfile <<_______EOF
2119 #ifndef EILSEQ
2120 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2121 * The correspondence between this and the corresponding definition
2122 * in libiconv is essential.
2123 */
2124 # define EILSEQ ENOENT
2125 #endif
2126 _______EOF
2128 fi
2130 echo >>$outfile
2131 if test x$g_mutex_has_default = xyes; then
2132 cat >>$outfile <<_______EOF
2133 $g_enable_threads_def G_THREADS_ENABLED
2134 #define G_THREADS_IMPL_$g_threads_impl_def
2135 typedef struct _GStaticMutex GStaticMutex;
2136 struct _GStaticMutex
2137 {
2138 struct _GMutex *runtime_mutex;
2139 union {
2140 char pad[$g_mutex_sizeof];
2141 double dummy_double;
2142 void *dummy_pointer;
2143 long dummy_long;
2144 } static_mutex;
2145 };
2146 #define G_STATIC_MUTEX_INIT { NULL, { { $g_mutex_contents} } }
2147 #define g_static_mutex_get_mutex(mutex) \
2148 (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
2149 g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
2150 _______EOF
2151 else
2152 cat >>$outfile <<_______EOF
2153 $g_enable_threads_def G_THREADS_ENABLED
2154 #define G_THREADS_IMPL_$g_threads_impl_def
2155 typedef struct _GMutex* GStaticMutex;
2156 #define G_STATIC_MUTEX_INIT NULL
2157 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
2158 _______EOF
2159 fi
2161 cat >>$outfile <<_______EOF
2162 /* This represents a system thread as used by the implementation. An
2163 * alien implementaion, as loaded by g_thread_init can only count on
2164 * "sizeof (gpointer)" bytes to store their info. We however need more
2165 * for some of our native implementations. */
2166 typedef union _GSystemThread GSystemThread;
2167 union _GSystemThread
2168 {
2169 char data[$g_system_thread_sizeof];
2170 double dummy_double;
2171 void *dummy_pointer;
2172 long dummy_long;
2173 };
2174 _______EOF
2176 echo >>$outfile
2177 g_bit_sizes="16 32 64"
2178 for bits in $g_bit_sizes; do
2179 cat >>$outfile <<_______EOF
2180 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2181 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2182 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2183 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2184 _______EOF
2185 done
2187 cat >>$outfile <<_______EOF
2188 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2189 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2190 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2191 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2192 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2193 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2194 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2195 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2196 #define G_BYTE_ORDER $g_byte_order
2198 #define GLIB_SYSDEF_POLLIN =$g_pollin
2199 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2200 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2201 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2202 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2203 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2205 #define G_MODULE_SUFFIX "$g_module_suffix"
2207 G_END_DECLS
2209 #endif /* GLIBCONFIG_H */
2210 _______EOF
2213 if cmp -s $outfile glibconfig.h; then
2214 echo glibconfig.h is unchanged
2215 rm -f $outfile
2216 else
2217 mv $outfile glibconfig.h
2218 fi ;;
2219 esac
2220 ],[
2222 # Note that if two cases are the same, case goes with the first one.
2223 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2224 # on variable expansion in case labels. Look at the generated config.status
2225 # for a hint.
2227 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2228 glib_header_alloca_h="$ac_cv_working_alloca_h"
2229 else
2230 glib_header_alloca_h="$ac_cv_header_alloca_h"
2231 fi
2233 case xyes in
2234 x$ac_cv_header_float_h)
2235 glib_float_h=yes
2236 glib_mf=FLT_MIN glib_Mf=FLT_MAX
2237 glib_md=DBL_MIN glib_Md=DBL_MAX
2238 ;;
2239 x$ac_cv_header_values_h)
2240 glib_values_h=yes
2241 glib_mf=MINFLOAT glib_Mf=MAXFLOAT
2242 glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2243 ;;
2244 esac
2246 case xyes in
2247 x$ac_cv_header_limits_h)
2248 glib_limits_h=yes
2249 glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2250 glib_mi=INT_MIN glib_Mi=INT_MAX glib_Mui=UINT_MAX
2251 glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2252 ;;
2253 x$ac_cv_header_values_h)
2254 glib_values_h=yes
2255 glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2256 glib_mi=MININT glib_Mi=MAXINT glib_Mui="(((guint)G_MAXINT)*2+1)"
2257 glib_ml=MINLONG glib_Ml=MAXLONG glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2258 ;;
2259 esac
2261 if test x$ac_cv_header_sys_poll_h = xyes ; then
2262 glib_sys_poll_h=yes
2263 fi
2265 case 2 in
2266 $ac_cv_sizeof_short)
2267 gint16=short
2268 gint16_format='"hi"'
2269 guint16_format='"hu"'
2270 ;;
2271 $ac_cv_sizeof_int)
2272 gint16=int
2273 gint16_format='"i"'
2274 guint16_format='"u"'
2275 ;;
2276 esac
2277 case 4 in
2278 $ac_cv_sizeof_short)
2279 gint32=short
2280 gint32_format='"hi"'
2281 guint32_format='"hu"'
2282 ;;
2283 $ac_cv_sizeof_int)
2284 gint32=int
2285 gint32_format='"i"'
2286 guint32_format='"u"'
2287 ;;
2288 $ac_cv_sizeof_long)
2289 gint32=long
2290 gint32_format='"li"'
2291 guint32_format='"lu"'
2292 ;;
2293 esac
2294 case 8 in
2295 $ac_cv_sizeof_int)
2296 gint64=int
2297 gint64_format='"i"'
2298 guint64_format='"u"'
2299 glib_extension=
2300 gint64_constant='(val)'
2301 ;;
2302 $ac_cv_sizeof_long)
2303 gint64=long
2304 gint64_format='"li"'
2305 guint64_format='"lu"'
2306 glib_extension=
2307 gint64_constant='(val##L)'
2308 ;;
2309 $ac_cv_sizeof_long_long)
2310 gint64='long long'
2311 if test -n "$glib_cv_long_long_format"; then
2312 gint64_format='"'$glib_cv_long_long_format'i"'
2313 guint64_format='"'$glib_cv_long_long_format'u"'
2314 fi
2315 glib_extension='G_GNUC_EXTENSION '
2316 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2317 ;;
2318 $ac_cv_sizeof___int64)
2319 gint64='__int64'
2320 if test -n "$glib_cv_long_long_format"; then
2321 gint64_format='"'$glib_cv_long_long_format'i"'
2322 guint64_format='"'$glib_cv_long_long_format'u"'
2323 fi
2324 glib_extension=
2325 gint64_constant='(val##i64)'
2326 ;;
2327 esac
2328 glib_size_t=$ac_cv_sizeof_size_t
2329 glib_size_type_define=$glib_size_type
2330 glib_void_p=$ac_cv_sizeof_long
2331 glib_long=$ac_cv_sizeof_void_p
2333 gintbits=`expr $ac_cv_sizeof_int \* 8`
2334 glongbits=`expr $ac_cv_sizeof_long \* 8`
2337 case $ac_cv_sizeof_void_p in
2338 $ac_cv_sizeof_int) glib_gpi_cast='' glib_gpui_cast='' ;;
2339 $ac_cv_sizeof_long) glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2340 *) glib_unknown_void_p=yes ;;
2341 esac
2344 case xyes in
2345 x$ac_cv_func_atexit)
2346 glib_atexit="
2347 #ifdef NeXT /* @#%@! NeXTStep */
2348 # define g_ATEXIT(proc) (!atexit (proc))
2349 #else
2350 # define g_ATEXIT(proc) (atexit (proc))
2351 #endif"
2352 ;;
2353 x$ac_cv_func_on_exit)
2354 glib_atexit="
2355 #define g_ATEXIT(proc) (on_exit ((void (*)(int, void*))(proc), NULL))"
2356 ;;
2357 esac
2359 case xyes in
2360 x$ac_cv_func_memmove)
2361 glib_memmove='
2362 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2363 ;;
2364 x$glib_cv_working_bcopy)
2365 glib_memmove="
2366 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2367 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2368 ;;
2369 *)
2370 glib_memmove="
2371 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2372 * so we have to roll our own copy routine. */
2373 void g_memmove (void* dest, const void * src, unsigned long len);"
2374 ;;
2375 esac
2377 glib_defines="
2378 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2379 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2380 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2381 "
2383 case xyes in
2384 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
2385 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
2386 *) glib_vacopy=''
2387 esac
2389 if test x$glib_cv_va_val_copy = xno; then
2390 glib_vacopy="\$glib_vacopy
2391 #define G_VA_COPY_AS_ARRAY 1"
2392 fi
2394 if test x$glib_cv_hasinline = xyes; then
2395 glib_inline='#define G_HAVE_INLINE 1'
2396 fi
2397 if test x$glib_cv_has__inline = xyes; then
2398 glib_inline="\$glib_inline
2399 #define G_HAVE___INLINE 1"
2400 fi
2401 if test x$glib_cv_has__inline__ = xyes; then
2402 glib_inline="\$glib_inline
2403 #define G_HAVE___INLINE__ 1"
2404 fi
2406 g_have_gnuc_varargs=$g_have_gnuc_varargs
2407 g_have_iso_c_varargs=$g_have_iso_c_varargs
2408 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2410 case xyes in
2411 x$ac_cv_c_bigendian)
2412 g_byte_order=G_BIG_ENDIAN
2413 g_bs_native=BE
2414 g_bs_alien=LE
2415 ;;
2416 *)
2417 g_byte_order=G_LITTLE_ENDIAN
2418 g_bs_native=LE
2419 g_bs_alien=BE
2420 ;;
2421 esac
2423 g_pollin=$glib_cv_value_POLLIN
2424 g_pollout=$glib_cv_value_POLLOUT
2425 g_pollpri=$glib_cv_value_POLLPRI
2426 g_pollhup=$glib_cv_value_POLLHUP
2427 g_pollerr=$glib_cv_value_POLLERR
2428 g_pollnval=$glib_cv_value_POLLNVAL
2430 g_stack_grows=$glib_cv_stack_grows
2432 g_have_eilseq=$have_eilseq
2434 case x$have_threads in
2435 xno) g_enable_threads_def="#undef";;
2436 *) g_enable_threads_def="#define";;
2437 esac
2439 g_threads_impl_def=$g_threads_impl
2441 g_mutex_has_default="$mutex_has_default"
2442 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2443 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2444 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2446 g_module_suffix="$glib_gmodule_suffix"
2448 case $host in
2449 *-*-beos*)
2450 glib_os="#define G_OS_BEOS"
2451 ;;
2452 *-*-cygwin*)
2453 glib_os="#define G_OS_UNIX
2454 #define G_PLATFORM_WIN32
2455 #define G_WITH_CYGWIN"
2456 ;;
2457 *-*-mingw*)
2458 glib_os="#define G_OS_WIN32
2459 #define G_PLATFORM_WIN32"
2460 ;;
2461 *)
2462 glib_os="#define G_OS_UNIX"
2463 ;;
2464 esac
2465 ])
2467 AC_OUTPUT([
2468 glib-2.0.pc
2469 glib-2.0-uninstalled.pc
2470 gmodule-2.0.pc
2471 gmodule-2.0-uninstalled.pc
2472 gthread-2.0.pc
2473 gthread-2.0-uninstalled.pc
2474 gobject-2.0.pc
2475 gobject-2.0-uninstalled.pc
2476 glib-zip
2477 glib-gettextize
2478 Makefile
2479 build/Makefile
2480 build/win32/Makefile
2481 build/win32/dirent/Makefile
2482 glib/Makefile
2483 glib/libcharset/Makefile
2484 glib/trio/Makefile
2485 gmodule/gmoduleconf.h
2486 gmodule/Makefile
2487 gobject/Makefile
2488 gobject/glib-mkenums
2489 gthread/Makefile
2490 po/Makefile.in
2491 docs/Makefile
2492 docs/reference/Makefile
2493 docs/reference/glib/Makefile
2494 docs/reference/glib/version.xml
2495 docs/reference/gobject/Makefile
2496 docs/reference/gobject/version.xml
2497 tests/Makefile
2498 m4macros/Makefile
2499 ],[
2500 chmod 0755 glib-zip
2501 chmod 0755 glib-gettextize
2502 chmod 0755 gobject/glib-mkenums
2503 ])