gobject/meson.build

   1 gobject_install_headers = files(
   2   'gobject-autocleanups.h',
   3   'glib-types.h',
   4   'gbinding.h',
   5   'gboxed.h',
   6   'gclosure.h',
   7   'genums.h',
   8   'gmarshal.h',
   9   'gobject.h',
  10   'gparam.h',
  11   'gparamspecs.h',
  12   'gsignal.h',
  13   'gsourceclosure.h',
  14   'gtype.h',
  15   'gtypemodule.h',
  16   'gtypeplugin.h',
  17   'gvalue.h',
  18   'gvaluearray.h',
  19   'gvaluecollector.h',
  20   'gvaluetypes.h',
  21   'gobjectnotifyqueue.c', # sic
  22 )
  23 install_headers(gobject_install_headers, subdir : 'glib-2.0/gobject')
  24
  25 gobject_sources = files(
  26   'gatomicarray.c',
  27   'gbinding.c',
  28   'gboxed.c',
  29   'gclosure.c',
  30   'genums.c',
  31   'gmarshal.c',
  32   'gobject.c',
  33   'gparam.c',
  34   'gparamspecs.c',
  35   'gsignal.c',
  36   'gsourceclosure.c',
  37   'gtype.c',
  38   'gtypemodule.c',
  39   'gtypeplugin.c',
  40   'gvalue.c',
  41   'gvaluearray.c',
  42   'gvaluetransform.c',
  43   'gvaluetypes.c',
  44 )
  45
  46 if host_system == 'windows'
  47   gobject_win_rc = configure_file(
  48     input: 'gobject.rc.in',
  49     output: 'gobject.rc',
  50     configuration: glibconfig_conf,
  51   )
  52   gobject_win_res = windows.compile_resources(gobject_win_rc)
  53   gobject_sources += [gobject_win_res]
  54 endif
  55
  56 if enable_dtrace
  57   gobject_dtrace_obj = dtrace_obj_gen.process('gobject_probes.d')
  58   gobject_dtrace_hdr = dtrace_hdr_gen.process('gobject_probes.d')
  59 else
  60   gobject_dtrace_obj = []
  61   gobject_dtrace_hdr = []
  62 endif
  63
  64 libgobject = library('gobject-2.0',
  65   gobject_dtrace_obj, gobject_dtrace_hdr,
  66   sources : gobject_sources,
  67   version : library_version,
  68   soversion : soversion,
  69   install : true,
  70   include_directories : [configinc],
  71   dependencies : [libintl, libffi_dep, libglib_dep],
  72   c_args : ['-DG_LOG_DOMAIN="GLib-GObject"', '-DGOBJECT_COMPILATION'] + glib_hidden_visibility_args)
  73
  74 libgobject_dep = declare_dependency(link_with : libgobject,
  75   include_directories : gobjectinc)
  76
  77 python_tools = [
  78   'glib-genmarshal',
  79   'glib-mkenums',
  80 ]
  81
  82 python_tools_conf = configuration_data()
  83 python_tools_conf.set('VERSION', glib_version)
  84 python_tools_conf.set('PYTHON', python.path())
  85
  86 foreach tool: python_tools
  87   tool_bin = configure_file(
  88     input : tool + '.in',
  89     output : tool,
  90     configuration : python_tools_conf,
  91     install : true,
  92     install_dir : glib_bindir,
  93   )
  94
  95   # Set variables for later use
  96   set_variable(tool.underscorify(), tool_bin)
  97 endforeach
  98
  99 executable('gobject-query', 'gobject-query.c',
 100   install : true,
 101   c_args : ['-DHAVE_CONFIG_H=1'],
 102   dependencies : [libglib_dep, libgobject_dep])
 103
 104 install_data('gobject_gdb.py', install_dir : join_paths(glib_pkgdatadir, 'gdb'))
 105 gdb_conf = configuration_data()
 106 gdb_conf.set('datadir', glib_datadir)
 107 configure_file(
 108   input: 'libgobject-gdb.py.in',
 109   output: 'libgobject-2.0.so.@0@-gdb.py'.format(library_version),
 110   configuration: gdb_conf,
 111   install_dir: gdb_install_dir,
 112 )
 113
 114 if enable_systemtap
 115   gobject_stp = configure_file(input : 'gobject.stp.in',
 116     output : '@0@.stp'.format(libgobject.full_path().split('/').get(-1)),
 117     configuration : stp_cdata,
 118     install_dir : tapset_install_dir,
 119     install : true)
 120 endif
 121
 122 subdir('tests')