| blob | 594d9e35ed9959bd35d8598c9bc4890d5cb285b4 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [53])
34 m4_define([glib_micro_version], [6])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_cv_stack_grows=no
131 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
132 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
133 # (Sorry, I don't know exactly what is the problem, but it is related to
134 # floating point formatting and decimal point vs. comma.)
135 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
136 # rigorous enough to notice, though.
137 # So preset the autoconf cache variables.
138 ac_cv_func_vsnprintf_c99=no
139 ac_cv_func_snprintf_c99=no
140 case "$host" in
141 x86_64-*-*)
142 LIB_EXE_MACHINE_FLAG=X64
143 glib_pollfd_format='%#I64x'
144 ;;
145 esac
147 AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
148 ;;
149 *)
150 glib_native_win32=no
151 glib_pid_type=int
152 glib_pid_format='i'
153 glib_pollfd_format='%d'
154 ;;
155 esac
156 case $host in
157 *-*-linux*)
158 glib_os_linux=yes
159 ;;
160 esac
162 AC_MSG_RESULT([$glib_native_win32])
164 AC_MSG_CHECKING([for the Android])
165 case $host in
166 *android*)
167 glib_native_android="yes"
168 ;;
169 *)
170 glib_native_android="no"
171 ;;
172 esac
173 AC_MSG_RESULT([$glib_native_android])
175 AC_SUBST(LIB_EXE_MACHINE_FLAG)
177 glib_have_carbon=no
178 AC_MSG_CHECKING([for Mac OS X Carbon support])
179 AC_TRY_CPP([
180 #include <Carbon/Carbon.h>
181 #include <CoreServices/CoreServices.h>
182 ], glib_have_carbon=yes)
184 AC_MSG_RESULT([$glib_have_carbon])
186 glib_have_cocoa=no
187 AC_MSG_CHECKING([for Mac OS X Cocoa support])
188 AC_TRY_CPP([
189 #include <Cocoa/Cocoa.h>
190 #ifdef GNUSTEP_BASE_VERSION
191 #error "Detected GNUstep, not Cocoa"
192 #endif
193 ], glib_have_cocoa=yes)
195 AC_MSG_RESULT([$glib_have_cocoa])
197 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
198 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
199 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
200 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
201 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
202 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
204 AS_IF([test "$glib_native_win32" = "yes"], [
205 AC_CHECK_TOOL(WINDRES, windres, no)
206 if test "$WINDRES" = no; then
207 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
208 fi
209 AC_CHECK_TOOL(NM, nm, no)
210 if test "$NM" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
212 fi
213 AC_CHECK_TOOL(RANLIB, ranlib, :)
214 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
215 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
216 ])
217 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
219 AS_IF([test "x$glib_have_carbon" = "xyes"], [
220 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
221 CARBON_LIBS="-Wl,-framework,Carbon"
222 LDFLAGS="$LDFLAGS $CARBON_LIBS"
223 ], [CARBON_LIBS=""])
225 AC_SUBST([CARBON_LIBS])
226 ac_cv_have_os_x_9_or_later="no"
227 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
228 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
229 COCOA_LIBS="-Wl,-framework,Foundation"
230 LDFLAGS="$LDFLAGS $COCOA_LIBS"
231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
232 #include <AvailabilityMacros.h>
233 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
234 #error Compiling for minimum OS X version before 10.9
235 #endif
236 ]])],[ac_cv_have_os_x_9_or_later="yes"])
237 ], [COCOA_LIBS=""])
238 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
239 AC_SUBST([COCOA_LIBS])
241 dnl declare --enable-* args and collect ac_help strings
242 AC_ARG_ENABLE(debug,
243 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
244 [turn on debugging @<:@default=glib_debug_default@:>@]),,
245 enable_debug=glib_debug_default)
247 AC_ARG_ENABLE(gc_friendly,
248 [AS_HELP_STRING([--enable-gc-friendly],
249 [turn on garbage collector friendliness [default=no]])],,
250 [enable_gc_friendly=no])
251 AC_ARG_ENABLE(mem_pools,
252 [AS_HELP_STRING([--disable-mem-pools],
253 [disable all glib memory pools])],,
254 [disable_mem_pools=no])
255 AC_ARG_ENABLE(rebuilds,
256 [AS_HELP_STRING([--disable-rebuilds],
257 [disable all source autogeneration rules])],,
258 [enable_rebuilds=yes])
260 GLIB_TESTS
262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
264 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
265 AC_MSG_RESULT([yes])
266 ], [ AC_MSG_RESULT([no]) ])
268 AC_MSG_CHECKING([whether to disable memory pools])
269 AS_IF([test "x$disable_mem_pools" = "xno"], [
270 AC_MSG_RESULT([no])
271 ], [
272 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
273 AC_MSG_RESULT([yes])
274 ])
276 dnl location to install runtime libraries, e.g. ../../lib to install
277 dnl to /lib if libdir is /usr/lib
278 AC_ARG_WITH(runtime-libdir,
279 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
280 [install runtime libraries relative to libdir])],
281 [],
282 [with_runtime_libdir=""])
283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
289 AC_LANG_SAVE
290 AC_LANG_CPLUSPLUS
291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
293 AC_LANG_RESTORE
295 AM_PROG_CC_C_O
296 AC_PROG_INSTALL
298 AC_SYS_LARGEFILE
300 PKG_PROG_PKG_CONFIG(0.16)
302 if test "x$enable_debug" = "xyes"; then
303 if test "x$cflags_set" != "x" ; then
304 case " $CFLAGS " in
305 *[[\ \ ]]-g[[\ \ ]]*) ;;
306 *) CFLAGS="$CFLAGS -g" ;;
307 esac
308 fi
309 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
310 else
311 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
313 if test "x$enable_debug" = "xno"; then
314 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
315 fi
316 fi
318 # Ensure MSVC-compatible struct packing convention is used when
319 # compiling for Win32 with gcc.
320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
321 # gcc2 uses "-fnative-struct".
322 if test x"$glib_native_win32" = xyes; then
323 if test x"$GCC" = xyes; then
324 msnative_struct=''
325 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
326 if test -z "$ac_cv_prog_CC"; then
327 our_gcc="$CC"
328 else
329 our_gcc="$ac_cv_prog_CC"
330 fi
331 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
332 2.)
333 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
334 msnative_struct='-fnative-struct'
335 fi
336 ;;
337 *)
338 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
339 msnative_struct='-mms-bitfields'
340 fi
341 ;;
342 esac
343 if test x"$msnative_struct" = x ; then
344 AC_MSG_RESULT([no way])
345 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
346 else
347 CFLAGS="$CFLAGS $msnative_struct"
348 AC_MSG_RESULT([${msnative_struct}])
349 fi
350 fi
351 fi
352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
353 AC_SUBST(GLIB_EXTRA_CFLAGS)
355 AC_EXEEXT
357 # define a MAINT-like variable REBUILD which is set if Perl
358 # and awk are found, so autogenerated sources can be rebuilt
359 AC_PROG_AWK
360 AC_CHECK_PROGS(PERL, [perl5 perl])
361 # We would like indent, but don't require it.
362 AC_CHECK_PROG(INDENT, indent, indent)
363 REBUILD=\#
364 if test "x$enable_rebuilds" = "xyes" && \
365 test -n "$PERL" && \
366 $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
367 test -n "$AWK" ; then
368 REBUILD=
369 fi
370 AC_SUBST(REBUILD)
372 # Need full path to Perl for glib-mkenums
373 #
374 if test "x$PERL" != x ; then
375 AC_PATH_PROG(PERL_PATH, [$PERL])
376 fi
377 if test "x$PERL_PATH" = x ; then
378 PERL_PATH="/usr/bin/env perl"
379 fi
380 AC_SUBST(PERL_PATH)
382 # option to specify python interpreter to use; this just sets $PYTHON, so that
383 # we will fallback to reading $PYTHON if --with-python is not given, and
384 # python.m4 will get the expected input
385 AC_ARG_WITH(python,
386 AS_HELP_STRING([--with-python=PATH],
387 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
388 [PYTHON="$withval"], [])
389 if test x"$PYTHON" = xyes; then
390 AC_MSG_ERROR([--with-python option requires a path or program argument])
391 fi
392 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
395 dnl ***********************
396 dnl *** Tests for iconv ***
397 dnl ***********************
398 dnl
399 dnl We do this before the gettext checks, to avoid distortion
401 dnl On Windows we use a native implementation
403 AS_IF([ test x"$glib_native_win32" = xyes], [
404 with_libiconv=native
405 ], [
406 AC_ARG_WITH(libiconv,
407 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
408 [use the libiconv library])],,
409 [with_libiconv=maybe])
411 found_iconv=no
412 case $with_libiconv in
413 maybe)
414 # Check in the C library first
415 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
416 # Check if we have GNU libiconv
417 if test $found_iconv = "no"; then
418 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
419 fi
420 # Check if we have a iconv in -liconv, possibly from vendor
421 if test $found_iconv = "no"; then
422 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
423 fi
424 ;;
425 no)
426 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
427 ;;
428 gnu|yes)
429 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
430 ;;
431 native)
432 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
433 ;;
434 esac
436 if test "x$found_iconv" = "xno" ; then
437 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
438 fi
439 ])
441 dnl
442 dnl zlib support
443 dnl
444 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
445 AS_IF([test "x$found_zlib" = "xno"], [
446 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
447 if test "x$found_zlib" = "xno" ; then
448 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
449 fi
450 ZLIB_LIBS='-lz'
451 AC_SUBST(ZLIB_LIBS)
452 ])
454 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
455 AC_SUBST(LIBFFI_CFLAGS)
456 AC_SUBST(LIBFFI_LIBS)
458 dnl
459 dnl gettext support
460 dnl
462 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
463 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
464 GLIB_GNU_GETTEXT
466 if test "$gt_cv_have_gettext" != "yes" ; then
467 AC_MSG_ERROR([
468 *** You must have either have gettext support in your C library, or use the
469 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
470 ])
471 fi
473 LIBS="$INTLLIBS $LIBS"
475 GETTEXT_PACKAGE=glib20
476 AC_SUBST(GETTEXT_PACKAGE)
477 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
478 [Define the gettext package to be used])
480 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
482 dnl
483 dnl Now we are done with gettext checks, figure out ICONV_LIBS
484 dnl
486 AS_IF([test x"$glib_native_win32" != xyes], [
487 if test x$with_libiconv != xno ; then
488 case " $INTLLIBS " in
489 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
490 *) ICONV_LIBS="-liconv" ;;
491 esac
492 fi
493 ])
494 AC_SUBST(ICONV_LIBS)
496 case $with_libiconv in
497 gnu)
498 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
499 ;;
500 native)
501 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
502 ;;
503 esac
505 dnl Initialize libtool
506 LT_PREREQ([2.2])
507 LT_INIT([disable-static win32-dll])
508 dnl when using libtool 2.x create libtool early, because it's used in configure
509 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
512 AS_IF([test "$glib_native_win32" = "yes"], [
513 if test x$enable_static = xyes -a x$enable_shared = xyes; then
514 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
515 fi
516 if test x$enable_static = xyes; then
517 glib_win32_static_compilation=yes
518 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
519 #define GOBJECT_STATIC_COMPILATION 1"
520 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
521 fi
522 ])
523 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
525 # Checks for library functions.
526 AC_FUNC_ALLOCA
527 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
528 AC_CHECK_FUNCS(timegm gmtime_r)
529 AC_FUNC_STRERROR_R()
531 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
532 [AC_TRY_LINK([#include <unistd.h>
533 extern int __libc_enable_secure;],
534 [return __libc_enable_secure;],
535 glib_cv_have_libc_enable_secure=yes,
536 glib_cv_have_libc_enable_secure=no)])
537 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
538 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
539 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
540 ])
542 AC_CHECK_SIZEOF(char)
543 AC_CHECK_SIZEOF(short)
544 AC_CHECK_SIZEOF(long)
545 AC_CHECK_SIZEOF(int)
546 AC_CHECK_SIZEOF(void *)
547 AC_CHECK_SIZEOF(long long)
548 AC_CHECK_SIZEOF(__int64)
550 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
551 [AC_TRY_LINK([#include <signal.h>
552 #include <sys/types.h>
553 sig_atomic_t val = 42;],
554 [return val == 42 ? 0 : 1],
555 ac_cv_type_sig_atomic_t=yes,
556 ac_cv_type_sig_atomic_t=no)])
557 if test x$ac_cv_type_sig_atomic_t = xyes; then
558 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
559 [Define if you have the 'sig_atomic_t' type.])
560 fi
562 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
563 :
564 else
565 AC_MSG_ERROR([
566 *** GLib requires a 64 bit type. You might want to consider
567 *** using the GNU C compiler.
568 ])
569 fi
571 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
572 # long long is a 64 bit integer.
573 AC_MSG_CHECKING(for format to printf and scanf a guint64)
574 AC_CACHE_VAL(glib_cv_long_long_format,[
575 for format in ll q I64; do
576 AC_TRY_RUN([#include <stdio.h>
577 int main()
578 {
579 long long b, a = -0x3AFAFAFAFAFAFAFALL;
580 char buffer[1000];
581 sprintf (buffer, "%${format}u", a);
582 sscanf (buffer, "%${format}u", &b);
583 exit (b!=a);
584 }
585 ],
586 [glib_cv_long_long_format=${format}
587 break],
588 [],[:])
589 done])
590 AS_IF([ test -n "$glib_cv_long_long_format"], [
591 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
592 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
593 if test x"$glib_cv_long_long_format" = xI64; then
594 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
595 fi
596 ], [AC_MSG_RESULT(none)])
597 ],[ test x$ac_cv_sizeof___int64 = x8], [
598 # __int64 is a 64 bit integer.
599 AC_MSG_CHECKING(for format to printf and scanf a guint64)
600 # We know this is MSVCRT.DLL, and what the formats are
601 glib_cv_long_long_format=I64
602 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
603 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
604 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
605 ])
607 AC_C_CONST
609 dnl
610 dnl check in which direction the stack grows
611 dnl
612 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
613 AC_TRY_RUN([
614 volatile int *a = 0, *b = 0;
615 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
616 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
617 ],
618 glib_cv_stack_grows=yes
619 ,
620 glib_cv_stack_grows=no
621 ,)
622 ])
624 # check for flavours of varargs macros
625 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
626 AC_TRY_COMPILE([],[
627 int a(int p1, int p2, int p3);
628 #define call_a(...) a(1,__VA_ARGS__)
629 call_a(2,3);
630 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
631 AC_MSG_RESULT($g_have_iso_c_varargs)
633 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
634 AS_IF([test "$CXX" = ""], [
635 dnl No C++ compiler
636 g_have_iso_cxx_varargs=no
637 else
638 AC_LANG_CPLUSPLUS
639 AC_TRY_COMPILE([],[
640 int a(int p1, int p2, int p3);
641 #define call_a(...) a(1,__VA_ARGS__)
642 call_a(2,3);
643 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
644 AC_LANG_C
645 ])
646 AC_MSG_RESULT($g_have_iso_cxx_varargs)
648 AC_MSG_CHECKING(for GNUC varargs macros)
649 AC_TRY_COMPILE([],[
650 int a(int p1, int p2, int p3);
651 #define call_a(params...) a(1,params)
652 call_a(2,3);
653 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
654 AC_MSG_RESULT($g_have_gnuc_varargs)
656 # check for GNUC visibility support
657 AC_MSG_CHECKING(for GNUC visibility attribute)
658 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
659 void
660 __attribute__ ((visibility ("hidden")))
661 f_hidden (void)
662 {
663 }
664 void
665 __attribute__ ((visibility ("internal")))
666 f_internal (void)
667 {
668 }
669 void
670 __attribute__ ((visibility ("protected")))
671 f_protected (void)
672 {
673 }
674 void
675 __attribute__ ((visibility ("default")))
676 f_default (void)
677 {
678 }
679 int main (void)
680 {
681 f_hidden();
682 f_internal();
683 f_protected();
684 f_default();
685 return 0;
686 }
687 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
688 AC_MSG_RESULT($g_have_gnuc_visibility)
689 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
691 AC_MSG_CHECKING([whether using Sun Studio C compiler])
692 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
693 #else
694 # include "error: this is not Sun Studio."
695 #endif
696 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
697 AC_MSG_RESULT($g_have_sunstudio_visibility)
698 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
700 # check for bytesex stuff
701 AC_C_BIGENDIAN
702 if test x$ac_cv_c_bigendian = xuniversal ; then
703 AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
704 fi
707 # check for header files
708 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
709 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
710 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
711 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
712 AC_CHECK_HEADERS([linux/magic.h])
713 AC_CHECK_HEADERS([termios.h])
715 # Some versions of MSC lack these
716 AC_CHECK_HEADERS([dirent.h sys/time.h])
718 # We don't care about this, but we need to keep including it in
719 # glibconfig.h for backward compatibility
720 AC_CHECK_HEADERS([values.h])
722 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
723 [#if HAVE_SYS_PARAM_H
724 #include <sys/param.h>
725 #endif
726 ])
727 AC_CHECK_FUNCS(sysctlbyname)
729 AC_HEADER_MAJOR
730 AC_CHECK_HEADERS([xlocale.h])
732 # check for structure fields
733 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
734 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
735 #include <sys/stat.h>
736 #ifdef G_OS_UNIX
737 #include <unistd.h>
738 #endif
739 #ifdef HAVE_SYS_STATFS_H
740 #include <sys/statfs.h>
741 #endif
742 #ifdef HAVE_SYS_PARAM_H
743 #include <sys/param.h>
744 #endif
745 #ifdef HAVE_SYS_MOUNT_H
746 #include <sys/mount.h>
747 #endif])
748 # struct statvfs.f_basetype is available on Solaris but not for Linux.
749 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
750 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
751 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
753 AC_STRUCT_DIRENT_D_TYPE
755 # Checks for libcharset
756 AM_LANGINFO_CODESET
757 gl_GLIBC21
759 # check additional type sizes
760 AC_CHECK_SIZEOF(size_t)
762 dnl Try to figure out whether gsize should be long or int
763 AC_MSG_CHECKING([for the appropriate definition for size_t])
765 case $ac_cv_sizeof_size_t in
766 $ac_cv_sizeof_short)
767 glib_size_type=short
768 ;;
769 $ac_cv_sizeof_int)
770 glib_size_type=int
771 ;;
772 $ac_cv_sizeof_long)
773 glib_size_type=long
774 ;;
775 $ac_cv_sizeof_long_long)
776 glib_size_type='long long'
777 ;;
778 $ac_cv_sizeof__int64)
779 glib_size_type='__int64'
780 ;;
781 *) AC_MSG_ERROR([No type matching size_t in size])
782 ;;
783 esac
785 dnl If int/long are the same size, we see which one produces
786 dnl warnings when used in the location as size_t. (This matters
787 dnl on AIX with xlc)
788 dnl
789 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
790 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
791 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
792 #if defined(_AIX) && !defined(__GNUC__)
793 #pragma options langlvl=stdc89
794 #endif
795 #include <stddef.h>
796 int main ()
797 {
798 size_t s = 1;
799 unsigned int *size_int = &s;
800 return (int)*size_int;
801 }
802 ]])],glib_size_type=int,
803 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
804 #if defined(_AIX) && !defined(__GNUC__)
805 #pragma options langlvl=stdc89
806 #endif
807 #include <stddef.h>
808 int main ()
809 {
810 size_t s = 1;
811 unsigned long *size_long = &s;
812 return (int)*size_long;
813 }
814 ]])],glib_size_type=long)])
815 ])
817 AC_MSG_RESULT(unsigned $glib_size_type)
819 AC_CHECK_SIZEOF(ssize_t)
821 dnl Try to figure out whether gssize should be long or int
822 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
824 case $ac_cv_sizeof_ssize_t in
825 $ac_cv_sizeof_short)
826 glib_ssize_type=short
827 ;;
828 $ac_cv_sizeof_int)
829 glib_ssize_type=int
830 ;;
831 $ac_cv_sizeof_long)
832 glib_ssize_type=long
833 ;;
834 $ac_cv_sizeof_long_long)
835 glib_ssize_type='long long'
836 ;;
837 $ac_cv_sizeof__int64)
838 glib_ssize_type='__int64'
839 ;;
840 *) AC_MSG_ERROR([No type matching ssize_t in size])
841 ;;
842 esac
844 dnl If int/long are the same size, we see which one produces
845 dnl warnings when used in the location as ssize_t. (This matters
846 dnl on Android where ssize_t is long and size_t is unsigned int)
847 dnl
848 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
849 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
850 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
851 #if defined(_AIX) && !defined(__GNUC__)
852 #pragma options langlvl=stdc89
853 #endif
854 #include <stddef.h>
855 #ifdef HAVE_INTTYPES_H
856 # include <inttypes.h>
857 #endif
858 #ifdef HAVE_STDINT_H
859 # include <stdint.h>
860 #endif
861 #include <sys/types.h>
862 int main ()
863 {
864 ssize_t s = 1;
865 int *size_int = &s;
866 return (int)*size_int;
867 }
868 ]])],glib_ssize_type=int,
869 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
870 #if defined(_AIX) && !defined(__GNUC__)
871 #pragma options langlvl=stdc89
872 #endif
873 #include <stddef.h>
874 #ifdef HAVE_INTTYPES_H
875 # include <inttypes.h>
876 #endif
877 #ifdef HAVE_STDINT_H
878 # include <stdint.h>
879 #endif
880 #include <sys/types.h>
881 int main ()
882 {
883 ssize_t s = 1;
884 long *size_long = &s;
885 return (int)*size_long;
886 }
887 ]])],glib_ssize_type=long)])
888 ])
890 AC_MSG_RESULT($glib_ssize_type)
892 # Check for some functions
893 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
894 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
895 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
896 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
897 AC_CHECK_FUNCS(splice)
898 AC_CHECK_FUNCS(prlimit)
900 # To avoid finding a compatibility unusable statfs, which typically
901 # successfully compiles, but warns to use the newer statvfs interface:
902 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
903 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
905 AC_MSG_CHECKING([whether to use statfs or statvfs])
906 # Some systems have both statfs and statvfs, pick the most "native" for these
907 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
908 [
909 # on solaris and irix, statfs doesn't even have the f_bavail field
910 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
911 [ac_cv_func_statfs=no],
912 # else, at least on linux, statfs is the actual syscall
913 [ac_cv_func_statvfs=no])
914 ])
916 AS_IF([test x$ac_cv_func_statfs = xyes],
917 [
918 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
919 AC_MSG_RESULT([statfs])
920 ],
921 [test x$ac_cv_func_statvfs = xyes],
922 [
923 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
924 AC_MSG_RESULT([statvfs])
925 ],
926 [ AC_MSG_RESULT([neither])])
928 AC_CHECK_HEADERS(crt_externs.h)
929 AC_CHECK_FUNCS(_NSGetEnviron)
931 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
933 # Internet address families
934 if test $glib_native_win32 = yes; then
935 glib_inet_includes=["
936 #include <winsock2.h>
937 "]
938 else
939 glib_inet_includes=["
940 #include <sys/types.h>
941 #include <sys/socket.h>
942 "]
943 fi
945 glib_failed=false
946 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
947 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
948 # winsock defines this even though it doesn't support it
949 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
950 if $glib_failed ; then
951 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
952 fi
954 glib_failed=false
955 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
956 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
957 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
958 if $glib_failed ; then
959 AC_MSG_ERROR([Could not determine values for MSG_* constants])
960 fi
962 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
964 AS_IF([test $glib_native_win32 = yes], [
965 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
966 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
967 # they aren't present at run-time (on Windows 2000).
968 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
969 AC_SUBST(WSPIAPI_INCLUDE)
970 ], [
971 # Android does not have C_IN in public headers, we define it wherever necessary
972 AS_IF([test $glib_native_android != yes], [
973 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
974 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
975 #include <arpa/nameser.h>],
976 [int qclass = C_IN;])],
977 [AC_MSG_RESULT([no])],
978 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
979 #include <arpa/nameser.h>
980 #include <arpa/nameser_compat.h>],
981 [int qclass = C_IN;])],
982 [AC_MSG_RESULT([yes])
983 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
984 [AC_MSG_ERROR([could not compile test program either way])])])])
985 AC_SUBST(NAMESER_COMPAT_INCLUDE)
987 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
988 NETWORK_LIBS=""
989 AC_MSG_CHECKING([for res_query])
990 AC_TRY_LINK([#include <sys/types.h>
991 #include <netinet/in.h>
992 #include <arpa/nameser.h>
993 #include <resolv.h>
994 ],[
995 res_query("test", 0, 0, (void *)0, 0);
996 ],[AC_MSG_RESULT([yes])],
997 [save_libs="$LIBS"
998 LIBS="-lresolv $LIBS"
999 AC_TRY_LINK([#include <sys/types.h>
1000 #include <netinet/in.h>
1001 #include <arpa/nameser.h>
1002 #include <resolv.h>
1003 ],[
1004 res_query("test", 0, 0, (void *)0, 0);
1005 ],[AC_MSG_RESULT([in -lresolv])
1006 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1007 [LIBS="-lbind $save_libs"
1008 AC_TRY_LINK([#include <resolv.h>],
1009 [res_query("test", 0, 0, (void *)0, 0);],
1010 [AC_MSG_RESULT([in -lbind])
1011 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1012 [AC_MSG_ERROR(not found)])])
1013 LIBS="$save_libs"])
1014 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1015 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1016 [AC_MSG_ERROR(Could not find socket())]))
1017 save_libs="$LIBS"
1018 LIBS="$LIBS $NETWORK_LIBS"
1019 AC_MSG_CHECKING([for res_init])
1020 AC_TRY_LINK([#include <sys/types.h>
1021 #include <netinet/in.h>
1022 #include <arpa/nameser.h>
1023 #include <resolv.h>
1024 ],[
1025 res_init();
1026 ],[AC_MSG_RESULT([yes])
1027 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1028 ],[AC_MSG_RESULT([no])])
1029 LIBS="$save_libs"
1030 ])
1031 AC_SUBST(NETWORK_LIBS)
1033 AC_CHECK_HEADER([linux/netlink.h],
1034 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1035 [#include <sys/socket.h>])
1036 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1038 AC_CHECK_TYPE([struct ip_mreqn], [
1039 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1040 [#include <netinet/in.h>])
1042 case $host in
1043 *-*-solaris* )
1044 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1045 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1046 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1047 ;;
1048 esac
1050 dnl
1051 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1052 dnl
1053 AS_IF([test "$ac_cv_func_statfs" = yes], [
1054 AC_MSG_CHECKING([number of arguments to statfs()])
1055 AC_TRY_COMPILE([#include <unistd.h>
1056 #ifdef HAVE_SYS_PARAM_H
1057 #include <sys/param.h>
1058 #endif
1059 #ifdef HAVE_SYS_VFS_H
1060 #include <sys/vfs.h>
1061 #endif
1062 #ifdef HAVE_SYS_MOUNT_H
1063 #include <sys/mount.h>
1064 #endif
1065 #ifdef HAVE_SYS_STATFS_H
1066 #include <sys/statfs.h>
1067 #endif], [struct statfs st;
1068 statfs("/", &st);],[
1069 AC_MSG_RESULT([2])
1070 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1071 AC_TRY_COMPILE([#include <unistd.h>
1072 #ifdef HAVE_SYS_PARAM_H
1073 #include <sys/param.h>
1074 #endif
1075 #ifdef HAVE_SYS_VFS_H
1076 #include <sys/vfs.h>
1077 #endif
1078 #ifdef HAVE_SYS_MOUNT_H
1079 #include <sys/mount.h>
1080 #endif
1081 #ifdef HAVE_SYS_STATFS_H
1082 #include <sys/statfs.h>
1083 #endif], [struct statfs st;
1084 statfs("/", &st, sizeof (st), 0);],[
1085 AC_MSG_RESULT([4])
1086 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1087 AC_MSG_RESULT(unknown)
1088 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1089 ])
1091 dnl
1092 dnl open takes O_DIRECTORY as an option
1093 dnl
1094 AC_MSG_CHECKING([open() option O_DIRECTORY])
1095 AC_TRY_COMPILE([#include <fcntl.h>
1096 #include <sys/types.h>
1097 #include <sys/stat.h>],
1098 [open(0, O_DIRECTORY, 0);],[
1099 AC_MSG_RESULT([yes])
1100 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1101 AC_MSG_RESULT([no])])
1103 #
1104 # Check whether to use an included printf
1105 #
1106 AC_FUNC_VSNPRINTF_C99
1107 AC_FUNC_PRINTF_UNIX98
1109 AC_ARG_ENABLE(included-printf,
1110 [AS_HELP_STRING([--enable-included-printf],
1111 [use included printf [default=auto]])],
1112 enable_included_printf="$enableval")
1114 need_included_printf=no
1115 if test "x$enable_included_printf" = "xyes" ; then
1116 need_included_printf=yes
1117 fi
1118 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1119 need_included_printf=yes
1120 fi
1121 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1122 need_included_printf=yes
1123 fi
1124 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1125 test -z "$glib_cv_long_long_format" ; then
1126 need_included_printf=yes
1127 fi
1129 if test "x$enable_included_printf" = "xno" &&
1130 test "x$need_included_printf" = "xyes" ; then
1131 AC_MSG_ERROR([
1132 *** Your C library's printf doesn't appear to have the features that
1133 *** GLib needs, but you specified --enable-included-printf=no.])
1134 fi
1136 enable_included_printf=$need_included_printf
1138 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1139 AS_IF([test "$enable_included_printf" != "yes"], [
1140 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1141 ], [
1142 if test -z "$glib_cv_long_long_format" ; then
1143 glib_cv_long_long_format="ll"
1144 fi
1145 AC_DEFINE(HAVE_VASPRINTF,1)
1146 ])
1148 # Checks needed for gnulib vasnprintf
1149 bh_C_SIGNED
1150 jm_AC_TYPE_LONG_LONG
1151 gt_TYPE_LONGDOUBLE
1152 gt_TYPE_WCHAR_T
1153 gt_TYPE_WINT_T
1154 AC_TYPE_SIZE_T
1155 AC_CHECK_TYPES(ptrdiff_t)
1156 jm_AC_TYPE_INTMAX_T
1157 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1158 AC_FUNC_SNPRINTF_C99
1160 # Check if <sys/select.h> needs to be included for fd_set
1161 AC_MSG_CHECKING([for fd_set])
1162 AC_TRY_COMPILE([#include <sys/types.h>],
1163 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1164 AS_IF([test "$gtk_ok" = "yes"], [
1165 AC_MSG_RESULT([yes, found in sys/types.h])
1166 ], [
1167 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1168 if test "$gtk_ok" = "yes"; then
1169 # *** FIXME: give it a different name
1170 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1171 AC_MSG_RESULT([yes, found in sys/select.h])
1172 else
1173 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1174 AC_MSG_RESULT(no)
1175 fi
1176 ])
1178 dnl Check for nl_langinfo and CODESET
1179 AC_LANG_SAVE
1180 AC_LANG_C
1181 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1182 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1183 [char *codeset = nl_langinfo (CODESET);])],
1184 [glib_cv_langinfo_codeset=yes],
1185 [glib_cv_langinfo_codeset=no])])
1186 if test x$glib_cv_langinfo_codeset = xyes; then
1187 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1188 fi
1190 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1191 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1192 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1193 [char *str;
1194 str = nl_langinfo (PM_STR);
1195 str = nl_langinfo (D_T_FMT);
1196 str = nl_langinfo (D_FMT);
1197 str = nl_langinfo (T_FMT);
1198 str = nl_langinfo (T_FMT_AMPM);
1199 str = nl_langinfo (MON_1);
1200 str = nl_langinfo (ABMON_12);
1201 str = nl_langinfo (DAY_1);
1202 str = nl_langinfo (ABDAY_7);])],
1203 [glib_cv_langinfo_time=yes],
1204 [glib_cv_langinfo_time=no])])
1205 if test x$glib_cv_langinfo_time = xyes; then
1206 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1207 fi
1209 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1210 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1211 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1212 [char *str;
1213 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1214 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1215 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1216 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1217 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1218 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1219 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1220 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1222 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1223 [glib_cv_langinfo_outdigit=yes],
1224 [glib_cv_langinfo_outdigit=no])])
1225 if test x$glib_cv_langinfo_outdigit = xyes; then
1226 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1227 fi
1228 AC_LANG_RESTORE
1230 dnl ****************************************
1231 dnl *** posix_memalign ***
1232 dnl ****************************************
1233 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1234 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1235 glib_cv_compliant_posix_memalign=0
1236 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1237 AC_TRY_RUN([
1238 #define _XOPEN_SOURCE 600
1239 #include <stdlib.h> /* posix_memalign() should be defined here */
1240 /* some systems break if #include <malloc.h> used */
1241 static void test_memalign (size_t boundary, size_t size) {
1242 void *mem = 0;
1243 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1244 exit (1);
1245 else
1246 free (mem);
1247 }
1248 int main() {
1249 test_memalign ( 128, 128 - 2 * sizeof (void*));
1250 test_memalign ( 256, 256 - 2 * sizeof (void*));
1251 test_memalign ( 512, 512 - 2 * sizeof (void*));
1252 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1253 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1254 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1255 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1256 test_memalign (16384, 16384 - 2 * sizeof (void*));
1257 test_memalign (32768, 32768 - 2 * sizeof (void*));
1258 exit (0); /* success */
1259 }
1260 ],
1261 [glib_cv_compliant_posix_memalign=1], [], [:])
1262 :
1263 fi
1264 ])
1265 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1266 AC_MSG_RESULT(yes)
1267 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1268 ], [
1269 AC_MSG_RESULT(no)
1270 ])
1273 dnl ****************************************
1274 dnl *** strlcpy/strlcat ***
1275 dnl ****************************************
1276 # Check for strlcpy
1277 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1278 AC_TRY_RUN([#include <stdlib.h>
1279 #include <string.h>
1280 int main() {
1281 char p[10];
1282 (void) strlcpy (p, "hi", 10);
1283 if (strlcat (p, "bye", 0) != 3)
1284 return 1;
1285 return 0;
1286 }], glib_cv_have_strlcpy=yes,
1287 glib_cv_have_strlcpy=no,
1288 glib_cv_have_strlcpy=no)])
1289 if test "$glib_cv_have_strlcpy" = "yes"; then
1290 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1291 fi
1294 dnl **********************
1295 dnl *** va_copy checks ***
1296 dnl **********************
1297 dnl we currently check for all three va_copy possibilities, so we get
1298 dnl all results in config.log for bug reports.
1299 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1300 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1301 #include <stdlib.h>
1302 void f (int i, ...) {
1303 va_list args1, args2;
1304 va_start (args1, i);
1305 va_copy (args2, args1);
1306 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1307 exit (1);
1308 va_end (args1); va_end (args2);
1309 }
1310 int main() {
1311 f (0, 42);
1312 return 0;
1313 }]])],
1314 [glib_cv_va_copy=yes],
1315 [glib_cv_va_copy=no])
1316 ])
1317 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1318 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1319 #include <stdlib.h>
1320 void f (int i, ...) {
1321 va_list args1, args2;
1322 va_start (args1, i);
1323 __va_copy (args2, args1);
1324 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1325 exit (1);
1326 va_end (args1); va_end (args2);
1327 }
1328 int main() {
1329 f (0, 42);
1330 return 0;
1331 }]])],
1332 [glib_cv___va_copy=yes],
1333 [glib_cv___va_copy=no])
1334 ])
1336 if test "x$glib_cv_va_copy" = "xyes"; then
1337 g_va_copy_func=va_copy
1338 else if test "x$glib_cv___va_copy" = "xyes"; then
1339 g_va_copy_func=__va_copy
1340 fi
1341 fi
1343 if test -n "$g_va_copy_func"; then
1344 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1345 fi
1347 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1348 AC_TRY_RUN([#include <stdarg.h>
1349 #include <stdlib.h>
1350 void f (int i, ...) {
1351 va_list args1, args2;
1352 va_start (args1, i);
1353 args2 = args1;
1354 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1355 exit (1);
1356 va_end (args1); va_end (args2);
1357 }
1358 int main() {
1359 f (0, 42);
1360 return 0;
1361 }],
1362 [glib_cv_va_val_copy=yes],
1363 [glib_cv_va_val_copy=no],
1364 [glib_cv_va_val_copy=yes])
1365 ])
1367 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1368 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1369 ])
1371 dnl ***********************
1372 dnl *** g_module checks ***
1373 dnl ***********************
1374 G_MODULE_LIBS=
1375 G_MODULE_LIBS_EXTRA=
1376 G_MODULE_PLUGIN_LIBS=
1377 if test x"$glib_native_win32" = xyes; then
1378 dnl No use for this on Win32
1379 G_MODULE_LDFLAGS=
1380 else
1381 export SED
1382 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1383 fi
1384 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1385 G_MODULE_NEED_USCORE=0
1386 G_MODULE_BROKEN_RTLD_GLOBAL=0
1387 G_MODULE_HAVE_DLERROR=0
1388 dnl *** force native WIN32 shared lib loader
1389 if test -z "$G_MODULE_IMPL"; then
1390 case "$host" in
1391 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1392 esac
1393 fi
1394 dnl *** force native AIX library loader
1395 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1396 if test -z "$G_MODULE_IMPL"; then
1397 case "$host" in
1398 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1399 esac
1400 fi
1401 dnl *** dlopen() and dlsym() in system libraries
1402 AS_IF([ test -z "$G_MODULE_IMPL"], [
1403 AC_CHECK_FUNC(dlopen,
1404 [AC_CHECK_FUNC(dlsym,
1405 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1406 [])
1407 ])
1408 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1409 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1410 AC_CHECK_FUNC(NSLinkModule,
1411 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1412 G_MODULE_NEED_USCORE=1],
1413 [])
1414 ])
1415 dnl *** dlopen() and dlsym() in libdl
1416 AS_IF([ test -z "$G_MODULE_IMPL"], [
1417 AC_CHECK_LIB(dl, dlopen,
1418 [AC_CHECK_LIB(dl, dlsym,
1419 [G_MODULE_LIBS=-ldl
1420 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1421 [])
1422 ])
1423 dnl *** additional checks for G_MODULE_IMPL_DL
1424 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1425 LIBS_orig="$LIBS"
1426 LDFLAGS_orig="$LDFLAGS"
1427 LIBS="$G_MODULE_LIBS $LIBS"
1428 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1429 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1430 echo "void glib_plugin_test(void) { }" > plugin.c
1431 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1432 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1433 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1434 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1435 -shrext ".o" -avoid-version plugin.lo \
1436 -rpath /dont/care >/dev/null 2>&1
1437 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1438 glib_cv_rtldglobal_broken,[
1439 AC_TRY_RUN([
1440 #include <dlfcn.h>
1441 #ifndef RTLD_GLOBAL
1442 # define RTLD_GLOBAL 0
1443 #endif
1444 #ifndef RTLD_LAZY
1445 # define RTLD_LAZY 0
1446 #endif
1447 int glib_plugin_test;
1448 int main () {
1449 void *handle, *global, *local;
1450 global = &glib_plugin_test;
1451 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1452 if (!handle) return 0;
1453 local = dlsym (handle, "glib_plugin_test");
1454 return global == local;
1455 } ],
1456 [glib_cv_rtldglobal_broken=no],
1457 [glib_cv_rtldglobal_broken=yes],
1458 [glib_cv_rtldglobal_broken=no])
1459 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1460 rmdir ${objdir} 2>/dev/null
1461 ])
1462 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1463 G_MODULE_BROKEN_RTLD_GLOBAL=1
1464 else
1465 G_MODULE_BROKEN_RTLD_GLOBAL=0
1466 fi
1467 dnl *** check whether we need preceeding underscores
1468 AC_CACHE_CHECK([for preceeding underscore in symbols],
1469 glib_cv_uscore,[
1470 AC_TRY_RUN([#include <dlfcn.h>
1471 int glib_underscore_test (void) { return 42; }
1472 int main() {
1473 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1474 handle = dlopen ((void*)0, 0);
1475 if (handle) {
1476 f1 = dlsym (handle, "glib_underscore_test");
1477 f2 = dlsym (handle, "_glib_underscore_test");
1478 } return (!f2 || f1);
1479 }],
1480 [glib_cv_uscore=yes],
1481 [glib_cv_uscore=no],
1482 [])
1483 rm -f plugin.c plugin.$ac_objext plugin.lo
1484 ])
1485 GLIB_ASSERT_SET(glib_cv_uscore)
1486 if test "x$glib_cv_uscore" = "xyes"; then
1487 G_MODULE_NEED_USCORE=1
1488 else
1489 G_MODULE_NEED_USCORE=0
1490 fi
1492 AC_CHECK_DECL([RTLD_LAZY],
1493 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1494 [], [[#include <dlfcn.h>]])
1495 AC_CHECK_DECL([RTLD_NOW],
1496 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1497 [], [[#include <dlfcn.h>]])
1498 AC_CHECK_DECL([RTLD_GLOBAL],
1499 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1500 [], [[#include <dlfcn.h>]])
1502 LDFLAGS="$LDFLAGS_orig"
1503 dnl *** check for having dlerror()
1504 AC_CHECK_FUNC(dlerror,
1505 [G_MODULE_HAVE_DLERROR=1],
1506 [G_MODULE_HAVE_DLERROR=0])
1507 LIBS="$LIBS_orig"
1508 ])
1509 dnl *** done, have we got an implementation?
1510 if test -z "$G_MODULE_IMPL"; then
1511 G_MODULE_IMPL=0
1512 G_MODULE_SUPPORTED=false
1513 else
1514 G_MODULE_SUPPORTED=true
1515 fi
1517 AC_MSG_CHECKING(for the suffix of module shared libraries)
1518 export SED
1519 module=yes eval std_shrext=$shrext_cmds
1520 # chop the initial dot
1521 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1522 AC_MSG_RESULT(.$glib_gmodule_suffix)
1523 # any reason it may fail?
1524 if test "x$glib_gmodule_suffix" = x; then
1525 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1526 fi
1528 AC_SUBST(G_MODULE_SUPPORTED)
1529 AC_SUBST(G_MODULE_IMPL)
1530 AC_SUBST(G_MODULE_LIBS)
1531 AC_SUBST(G_MODULE_LIBS_EXTRA)
1532 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1533 AC_SUBST(G_MODULE_LDFLAGS)
1534 AC_SUBST(G_MODULE_HAVE_DLERROR)
1535 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1536 AC_SUBST(G_MODULE_NEED_USCORE)
1537 AC_SUBST(GLIB_DEBUG_FLAGS)
1539 dnl **********************
1540 dnl *** g_spawn checks ***
1541 dnl **********************
1543 AC_MSG_CHECKING(for gspawn implementation)
1544 case "$host" in
1545 *-*-mingw*)
1546 GSPAWN=gspawn-win32.lo
1547 ;;
1548 *)
1549 GSPAWN=gspawn.lo
1550 ;;
1551 esac
1552 AC_MSG_RESULT($GSPAWN)
1553 AC_SUBST(GSPAWN)
1555 dnl *************************
1556 dnl *** GIOChannel checks ***
1557 dnl *************************
1559 AC_MSG_CHECKING(for GIOChannel implementation)
1560 case "$host" in
1561 *-*-mingw*)
1562 GIO=giowin32.lo
1563 ;;
1564 *)
1565 GIO=giounix.lo
1566 ;;
1567 esac
1568 AC_MSG_RESULT($GIO)
1569 AC_SUBST(GIO)
1571 dnl *********************************
1572 dnl *** Directory for GIO modules ***
1573 dnl *********************************
1575 AC_ARG_WITH(gio-module-dir,
1576 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1577 [load gio modules from this directory [LIBDIR/gio/modules]])],
1578 [],
1579 [with_gio_module_dir='${libdir}/gio/modules'])
1580 GIO_MODULE_DIR=$with_gio_module_dir
1581 AC_SUBST(GIO_MODULE_DIR)
1583 dnl **********************************
1584 dnl *** Check for libselinux (GIO) ***
1585 dnl **********************************
1586 AC_ARG_ENABLE(selinux,
1587 AS_HELP_STRING([--disable-selinux],
1588 [build without selinux support]))
1589 msg_selinux=no
1590 SELINUX_LIBS=
1591 AS_IF([ test "x$enable_selinux" != "xno"], [
1593 AC_CHECK_LIB(selinux, is_selinux_enabled,
1594 [AC_CHECK_HEADERS(selinux/selinux.h,
1595 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1596 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1597 SELINUX_LIBS="-lselinux"
1598 msg_selinux=yes])
1599 ])
1600 ])
1601 ])
1602 AC_SUBST(SELINUX_LIBS)
1604 dnl *****************************
1605 dnl ** Check for inotify (GIO) **
1606 dnl *****************************
1607 inotify_support=no
1608 AC_CHECK_HEADERS([sys/inotify.h],
1609 [
1610 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1611 ])
1613 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1615 dnl ****************************
1616 dnl ** Check for kqueue (GIO) **
1617 dnl ****************************
1618 kqueue_support=no
1619 AC_CHECK_HEADERS([sys/event.h],
1620 [
1621 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1622 ])
1624 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1626 dnl ****************************
1627 dnl *** Checks for FAM (GIO) ***
1628 dnl ****************************
1630 should_disable_fam=no
1632 AC_ARG_ENABLE(fam,
1633 AS_HELP_STRING([--disable-fam],
1634 [don't use fam for file system monitoring]),
1635 [
1636 if test "x$enable_fam" = "xno"; then
1637 should_disable_fam=yes
1638 fi
1639 ]
1640 )
1641 fam_support=no
1642 FAM_LIBS=
1643 if test "x$should_disable_fam" = "xno"; then
1644 AC_CHECK_LIB(fam, FAMOpen,
1645 [AC_CHECK_HEADERS(fam.h,
1646 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1647 AC_CHECK_LIB(fam, FAMNoExists,
1648 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1649 FAM_LIBS="-lfam"]
1650 fam_support=yes,
1651 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1652 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1653 AC_SUBST(FAM_LIBS)
1654 fi
1655 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1658 dnl *****************************
1659 dnl *** Check for xattr (GIO) ***
1660 dnl *****************************
1661 AC_ARG_ENABLE(xattr,
1662 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1663 msg_xattr=no
1664 XATTR_LIBS=
1665 AS_IF([ test "x$enable_xattr" != "xno"], [
1667 dnl either glibc or libattr can provide xattr support
1669 dnl for both of them, we check for getxattr being in
1670 dnl the library and a valid xattr header.
1672 dnl try glibc
1673 AC_CHECK_LIB(c, getxattr,
1674 [AC_CHECK_HEADERS(sys/xattr.h,
1675 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1676 msg_xattr=yes])
1677 ])
1679 AS_IF([ test "x$msg_xattr" != "xyes"], [
1680 dnl failure. try libattr
1681 AC_CHECK_LIB(attr, getxattr,
1682 [AC_CHECK_HEADERS(attr/xattr.h,
1683 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1684 XATTR_LIBS="-lattr"
1685 msg_xattr=yes])
1686 ])
1687 ])
1689 AS_IF([ test "x$msg_xattr" = "xyes"], [
1690 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1691 AC_TRY_COMPILE([
1692 #include <stdio.h>
1693 #ifdef HAVE_SYS_TYPES_H
1694 #include <sys/types.h>
1695 #endif
1696 #ifdef HAVE_SYS_XATTR_H
1697 #include <sys/xattr.h>
1698 #elif HAVE_ATTR_XATTR_H
1699 #include <attr/xattr.h>
1700 #endif
1701 ],
1702 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1703 [
1704 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1705 AC_MSG_RESULT([yes])
1706 ],
1707 [AC_MSG_RESULT([no])]
1708 )
1709 ])
1710 ])
1711 AC_SUBST(XATTR_LIBS)
1713 dnl ************************
1714 dnl *** check for libelf ***
1715 dnl ************************
1716 AC_ARG_ENABLE(libelf,
1717 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1718 AS_IF([ test "x$enable_libelf" != "xno"],[
1719 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1720 AS_IF([ test $have_libelf = maybe ], [
1721 glib_save_LIBS=$LIBS
1722 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1723 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1724 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1725 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1726 LIBS=$glib_save_LIBS
1728 if test $have_libelf != no; then
1729 LIBELF_LIBS=-lelf
1730 have_libelf=yes
1731 fi
1732 ])
1733 ])
1735 if test x$have_libelf = xyes; then
1736 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1737 fi
1739 dnl ************************
1740 dnl *** check for libmount ***
1741 dnl ************************
1743 dnl The fallback code doesn't really implement the same behaviors - e.g.
1744 dnl so on linux we want to require libmount unless specifically disabled
1745 dnl
1746 enable_libmount_default=${glib_os_linux:-no}
1747 AC_ARG_ENABLE(libmount,
1748 [AS_HELP_STRING([--enable-libmount],
1749 [build with libmount support [default for Linux]])],,
1750 [enable_libmount=$enable_libmount_default])
1751 AS_IF([ test "x$enable_libmount" = "xyes"],[
1752 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.28], [have_libmount=yes], [have_libmount=maybe])
1753 AS_IF([ test $have_libmount = maybe ], [
1754 glib_save_LIBS=$LIBS
1755 AC_CHECK_HEADER([libmount/libmount.h], [:], [have_libmount=no])
1757 # Check for a recent enough libmount
1758 AC_CHECK_LIB([mount], [mnt_unref_table], [:], [have_libmount=no])
1759 LIBS=$glib_save_LIBS
1761 if test $have_libmount != no; then
1762 LIBMOUNT_LIBS=-lmount
1763 have_libmount=yes
1764 fi
1765 ])
1766 if test $have_libmount = no ; then
1767 AC_MSG_ERROR([*** Could not find libmount])
1768 fi
1769 ])
1771 if test x$have_libmount = xyes; then
1772 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1773 fi
1774 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1776 dnl ****************************************
1777 dnl *** platform dependent source checks ***
1778 dnl ****************************************
1780 AC_MSG_CHECKING(for platform-dependent source)
1781 case "$host" in
1782 *-*-cygwin*|*-*-mingw*)
1783 PLATFORMDEP=gwin32.lo
1784 ;;
1785 *)
1786 PLATFORMDEP=
1787 ;;
1788 esac
1789 AC_MSG_RESULT($PLATFORMDEP)
1790 AC_SUBST(PLATFORMDEP)
1792 AC_MSG_CHECKING([whether to compile timeloop])
1793 case "$host" in
1794 *-*-cygwin*|*-*-mingw*|*-*-minix)
1795 enable_timeloop=no
1796 ;;
1797 *)
1798 enable_timeloop=yes
1799 ;;
1800 esac
1801 AC_MSG_RESULT($enable_timeloop)
1802 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1804 AC_MSG_CHECKING([if building for some Win32 platform])
1805 case "$host" in
1806 *-*-mingw*|*-*-cygwin*)
1807 platform_win32=yes
1808 ;;
1809 *)
1810 platform_win32=no
1811 ;;
1812 esac
1813 AC_MSG_RESULT($platform_win32)
1814 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1816 dnl ***********************
1817 dnl *** g_thread checks ***
1818 dnl ***********************
1820 AC_ARG_WITH(threads,
1821 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1822 [specify a thread implementation to use])],
1823 [],
1824 [with_threads=yes])
1826 dnl error and warning message
1827 dnl *************************
1829 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1831 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1832 platform (normally it's "_REENTRANT"). I'll not use any flag on
1833 compilation now, but then your programs might not work.
1834 Please provide information on how it is done on your system."
1836 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1837 "
1839 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1840 provide information on your thread implementation."
1842 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1843 functions will not be MT-safe during their first call because
1844 there is no working 'getpwuid_r' on your system."
1846 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1847 because there is no 'localtime_r' on your system."
1849 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1850 linking threaded applications. As GLib cannot do that
1851 automatically, you will get an linkg error everytime you are
1852 not using the right compiler. In that case you have to relink
1853 with the right compiler. Ususally just '_r' is appended
1854 to the compiler name."
1856 dnl determination of thread implementation
1857 dnl ***************************************
1859 AC_MSG_CHECKING(for thread implementation)
1861 have_threads=no
1862 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1863 AS_IF([ test "x$have_threads" = xno], [
1864 AC_TRY_COMPILE([#include <pthread.h>],
1865 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1866 have_threads=posix)
1867 ])
1868 # Tru64Unix requires -pthread to find pthread.h. See #103020
1869 if test "x$have_threads" = xno; then
1870 glib_save_CPPFLAGS="$CPPFLAGS"
1871 CPPFLAGS="$CPPFLAGS -pthread"
1872 AC_TRY_COMPILE([#include <pthread.h>],
1873 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1874 have_threads=posix)
1875 CPPFLAGS="$glib_save_CPPFLAGS"
1876 fi
1877 ])
1878 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1879 case $host in
1880 *-*-mingw*)
1881 have_threads=win32
1882 ;;
1883 esac
1884 fi
1886 if test "x$have_threads" = xno; then
1887 AC_MSG_RESULT(none available)
1888 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1889 else
1890 AC_MSG_RESULT($have_threads)
1891 fi
1894 dnl determination of G_THREAD_CFLAGS
1895 dnl ********************************
1897 G_THREAD_LIBS=
1898 G_THREAD_LIBS_EXTRA=
1899 G_THREAD_CFLAGS=
1901 dnl
1902 dnl Test program for basic POSIX threads functionality
1903 dnl
1904 m4_define([glib_thread_test],[
1905 #include <pthread.h>
1906 int check_me = 0;
1907 void* func(void* data) {check_me = 42; return &check_me;}
1908 int main()
1909 { pthread_t t;
1910 void *ret;
1911 pthread_create (&t, $1, func, 0);
1912 pthread_join (t, &ret);
1913 return (check_me != 42 || ret != &check_me);
1914 }])
1916 AS_IF([ test x"$have_threads" = xposix], [
1917 # First we test for posix, whether -pthread or -pthreads do the trick as
1918 # both CPPFLAG and LIBS.
1919 # One of them does for most gcc versions and some other platforms/compilers
1920 # too and could be considered as the canonical way to go.
1921 case $host in
1922 *-*-cygwin*|*-*-darwin*)
1923 # skip cygwin and darwin -pthread or -pthreads test
1924 ;;
1925 *-solaris*)
1926 # These compiler/linker flags work with both Sun Studio and gcc
1927 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1928 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1929 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1930 G_THREAD_LIBS="-lpthread -lthread"
1931 ;;
1932 *)
1933 for flag in pthread pthreads mt; do
1934 glib_save_CFLAGS="$CFLAGS"
1935 CFLAGS="$CFLAGS -$flag"
1936 AC_TRY_RUN(glib_thread_test(0),
1937 glib_flag_works=yes,
1938 glib_flag_works=no,
1939 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1940 glib_flag_works=yes,
1941 glib_flag_works=no)])
1942 CFLAGS="$glib_save_CFLAGS"
1943 if test $glib_flag_works = yes ; then
1944 G_THREAD_CFLAGS=-$flag
1945 G_THREAD_LIBS=-$flag
1946 break;
1947 fi
1948 done
1949 ;;
1950 esac
1951 ])
1953 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1955 # The canonical -pthread[s] does not work. Try something different.
1957 case $host in
1958 *-aix*)
1959 if test x"$GCC" = xyes; then
1960 # GCC 3.0 and above needs -pthread.
1961 # Should be coverd by the case above.
1962 # GCC 2.x and below needs -mthreads
1963 G_THREAD_CFLAGS="-mthreads"
1964 G_THREAD_LIBS=$G_THREAD_CFLAGS
1965 else
1966 # We are probably using the aix compiler. Normaly a
1967 # program would have to be compiled with the _r variant
1968 # of the corresponding compiler, but we as GLib cannot
1969 # do that: but the good news is that for compiling the
1970 # only difference is the added -D_THREAD_SAFE compile
1971 # option. This is according to the "C for AIX User's
1972 # Guide".
1973 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1974 fi
1975 ;;
1976 *-sysv5uw7*) # UnixWare 7
1977 # We are not using gcc with -pthread. Catched above.
1978 G_THREAD_CFLAGS="-Kthread"
1979 G_THREAD_LIBS=$G_THREAD_CFLAGS
1980 ;;
1981 *-mingw*)
1982 # No flag needed when using MSVCRT.DLL
1983 G_THREAD_CFLAGS=""
1984 ;;
1985 *)
1986 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1987 ;;
1988 esac
1989 ])
1991 # if we are not finding the localtime_r function, then we probably are
1992 # not using the proper multithread flag
1994 glib_save_CPPFLAGS="$CPPFLAGS"
1995 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1997 # First we test, whether localtime_r is declared in time.h
1998 # directly. Then we test whether a macro localtime_r exists, in
1999 # which case localtime_r in the test program is replaced and thus
2000 # if we still find localtime_r in the output, it is not defined as
2001 # a macro.
2003 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2004 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2005 localtime_r(a,b)],
2006 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2008 CPPFLAGS="$glib_save_CPPFLAGS"
2010 AC_MSG_CHECKING(thread related cflags)
2011 AC_MSG_RESULT($G_THREAD_CFLAGS)
2012 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2014 dnl determination of G_THREAD_LIBS
2015 dnl ******************************
2017 AS_IF([test x$have_threads = xposix], [
2018 glib_save_CPPFLAGS="$CPPFLAGS"
2019 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2020 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2021 case $host in
2022 *-aix*)
2023 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2024 # probably using the aix compiler.
2025 AC_MSG_WARN($AIX_COMPILE_INFO)
2026 ;;
2027 *)
2028 G_THREAD_LIBS=error
2029 glib_save_LIBS="$LIBS"
2030 for thread_lib in "" pthread pthread32 pthreads thread; do
2031 if test x"$thread_lib" = x; then
2032 add_thread_lib=""
2033 IN=""
2034 else
2035 add_thread_lib="-l$thread_lib"
2036 IN=" in -l$thread_lib"
2037 fi
2038 if test x"$have_threads" = xposix; then
2039 defattr=0
2040 else
2041 defattr=pthread_attr_default
2042 fi
2044 LIBS="$add_thread_lib $glib_save_LIBS"
2046 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2047 AC_TRY_RUN(glib_thread_test($defattr),
2048 glib_result=yes,
2049 glib_result=no,
2050 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2051 glib_result=yes,
2052 glib_result=no)])
2053 AC_MSG_RESULT($glib_result)
2055 if test "$glib_result" = "yes" ; then
2056 G_THREAD_LIBS="$add_thread_lib"
2057 break
2058 fi
2059 done
2060 if test "x$G_THREAD_LIBS" = xerror; then
2061 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2062 fi
2063 LIBS="$glib_save_LIBS"
2064 ;;
2065 esac
2066 ])
2068 g_threads_impl="POSIX"
2069 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2070 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2071 CPPFLAGS="$glib_save_CPPFLAGS"
2072 ], [test x$have_threads = xwin32], [
2073 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2074 g_threads_impl="WIN32"
2075 ], [
2076 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2077 g_threads_impl="NONE"
2078 G_THREAD_LIBS=error
2079 ])
2080 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2081 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2082 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2084 if test "x$G_THREAD_LIBS" = xerror; then
2085 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2086 fi
2088 AC_MSG_CHECKING(thread related libraries)
2089 AC_MSG_RESULT($G_THREAD_LIBS)
2091 dnl check for mt safe function variants and some posix functions
2092 dnl ************************************************************
2094 glib_save_LIBS="$LIBS"
2095 # we are not doing the following for now, as this might require glib
2096 # to always be linked with the thread libs on some platforms.
2097 # LIBS="$LIBS $G_THREAD_LIBS"
2098 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2100 LIBS="$G_THREAD_LIBS $LIBS"
2101 AS_IF([ test x"$have_threads" = xposix], [
2102 glib_save_CPPFLAGS="$CPPFLAGS"
2103 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2104 # This is not AC_CHECK_FUNC to also work with function
2105 # name mangling in header files.
2106 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2107 AC_LINK_IFELSE(
2108 [AC_LANG_PROGRAM(
2109 [#include <pthread.h>],
2110 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2111 [AC_MSG_RESULT(yes)
2112 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2113 [Have function pthread_attr_setstacksize])],
2114 [AC_MSG_RESULT(no)])
2115 AC_MSG_CHECKING(for pthread_condattr_setclock)
2116 AC_LINK_IFELSE(
2117 [AC_LANG_PROGRAM(
2118 [#include <pthread.h>],
2119 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2120 [AC_MSG_RESULT(yes)
2121 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2122 [Have function pthread_condattr_setclock])],
2123 [AC_MSG_RESULT(no)])
2124 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2125 AC_LINK_IFELSE(
2126 [AC_LANG_PROGRAM(
2127 [#include <pthread.h>],
2128 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2129 [AC_MSG_RESULT(yes)
2130 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2131 [Have function pthread_cond_timedwait_relative_np])],
2132 [AC_MSG_RESULT(no)])
2133 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2134 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2135 AC_LINK_IFELSE(
2136 [AC_LANG_PROGRAM(
2137 [#include <pthread.h>],
2138 [pthread_setname_np("example")])],
2139 [AC_MSG_RESULT(yes)
2140 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2141 [Have function pthread_setname_np(const char*)])],
2142 [AC_MSG_RESULT(no)])
2143 dnl Sets thread names on Solaris 11.3 & higher
2144 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2145 AC_LINK_IFELSE(
2146 [AC_LANG_PROGRAM(
2147 [#include <pthread.h>],
2148 [pthread_setname_np(pthread_self(), "example")])],
2149 [AC_MSG_RESULT(yes)
2150 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2151 [Have function pthread_setname_np(pthread_t, const char*)])],
2152 [AC_MSG_RESULT(no)])
2153 CPPFLAGS="$glib_save_CPPFLAGS"
2154 ])
2156 LIBS="$glib_save_LIBS"
2158 # now spit out all the warnings.
2159 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2160 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2161 fi
2162 if test "$ac_cv_func_localtime_r" != "yes"; then
2163 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2164 fi
2166 #
2167 # Hack to deal with:
2168 #
2169 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2170 # building shared libraries with linux.
2171 # b) FreeBSD doesn't do this either.
2172 #
2173 case $host in
2174 *android*)
2175 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2176 ;;
2177 *-*-freebsd*|*-*-linux*)
2178 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2179 ;;
2180 *)
2181 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2182 ;;
2183 esac
2185 AC_SUBST(G_THREAD_CFLAGS)
2186 AC_SUBST(G_THREAD_LIBS)
2187 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2188 AC_SUBST(G_THREAD_LIBS_EXTRA)
2190 AC_CHECK_FUNCS(clock_gettime, [], [
2191 AC_CHECK_LIB(rt, clock_gettime, [
2192 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2193 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2194 ])
2195 ])
2198 dnl ************************
2199 dnl *** g_atomic_* tests ***
2200 dnl ************************
2202 dnl We need to decide at configure time if GLib will use real atomic
2203 dnl operations ("lock free") or emulated ones with a mutex. This is
2204 dnl because we must put this information in glibconfig.h so we know if
2205 dnl it is safe or not to inline using compiler intrinsics directly from
2206 dnl the header.
2207 dnl
2208 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2209 dnl user is interested in knowing if they can use the atomic ops across
2210 dnl processes.
2211 dnl
2212 dnl We can currently support the atomic ops natively when building GLib
2213 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2214 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2215 dnl we are using GCC (and not mingw*).
2216 dnl
2217 dnl Note that the atomic ops are only available with GCC on x86 when
2218 dnl using -march=i486 or higher. If we detect that the atomic ops are
2219 dnl not available but would be available given the right flags, we want
2220 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2221 dnl that then to silently fall back on emulated atomic ops just because
2222 dnl the user had the wrong build environment.
2224 dnl We may add other compilers here in the future...
2226 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2227 case $host in
2228 *-*-mingw*)
2229 glib_cv_g_atomic_lock_free=yes
2230 ;;
2231 *)
2232 AC_TRY_LINK([],
2233 [volatile int atomic = 2;\
2234 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2235 [glib_cv_g_atomic_lock_free=yes],
2236 [glib_cv_g_atomic_lock_free=no])
2237 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2238 SAVE_CFLAGS="${CFLAGS}"
2239 CFLAGS="-march=i486"
2240 AC_TRY_LINK([],
2241 [volatile int atomic = 2;\
2242 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2243 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2244 [])
2245 CFLAGS="${SAVE_CFLAGS}"
2246 fi
2247 ;;
2248 esac])
2251 case $host in
2252 *-*-mingw*)
2253 ;;
2254 *)
2255 # Some compilers support atomic operations but do not define
2256 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2257 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2258 AC_TRY_LINK([],
2259 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2260 [],
2261 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2262 fi
2263 ;;
2264 esac
2266 dnl We need a more robust approach here...
2267 case $host_cpu in
2268 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2269 glib_memory_barrier_needed=no
2270 ;;
2271 sparc*|alpha*|powerpc*|ia64)
2272 glib_memory_barrier_needed=yes
2273 ;;
2274 *)
2275 glib_memory_barrier_needed=yes
2276 ;;
2277 esac
2279 dnl ************************
2280 dnl ** Check for futex(2) **
2281 dnl ************************
2282 AC_CACHE_CHECK(for futex(2) system call,
2283 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2284 #include <linux/futex.h>
2285 #include <sys/syscall.h>
2286 #include <unistd.h>
2287 ],[
2288 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2289 ])],glib_cv_futex=yes,glib_cv_futex=no))
2290 if test x"$glib_cv_futex" = xyes; then
2291 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2292 fi
2294 AC_CACHE_CHECK(for eventfd(2) system call,
2295 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2296 #include <sys/eventfd.h>
2297 #include <unistd.h>
2298 ],[
2299 eventfd (0, EFD_CLOEXEC);
2300 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2301 if test x"$glib_cv_eventfd" = x"yes"; then
2302 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2303 fi
2304 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2306 dnl ****************************************
2307 dnl *** GLib POLL* compatibility defines ***
2308 dnl ****************************************
2310 glib_poll_includes=["
2311 #include <sys/types.h>
2312 #include <poll.h>
2313 "]
2315 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2316 test $ac_cv_func_poll = yes ], [
2317 glib_failed=false
2318 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2319 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2320 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2321 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2322 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2323 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2324 if $glib_failed ; then
2325 AC_MSG_ERROR([Could not determine values for POLL* constants])
2326 fi
2327 ], [
2328 glib_cv_value_POLLIN=1
2329 glib_cv_value_POLLOUT=4
2330 glib_cv_value_POLLPRI=2
2331 glib_cv_value_POLLERR=8
2332 glib_cv_value_POLLHUP=16
2333 glib_cv_value_POLLNVAL=32
2334 ])
2336 AC_MSG_CHECKING([for broken poll])
2337 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2338 #include <stdlib.h>
2339 #include <fcntl.h>
2340 #include <poll.h>
2341 int main(void) {
2342 struct pollfd fds[1];
2343 int fd;
2344 fd = open("/dev/null", 1);
2345 fds[0].fd = fd;
2346 fds[0].events = POLLIN;
2347 fds[0].revents = 0;
2348 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2349 exit(1); /* Does not work for devices -- fail */
2350 }
2351 exit(0);
2352 }]])],
2353 [broken_poll=no],
2354 [broken_poll=yes
2355 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2356 [broken_poll="no (cross compiling)"])
2357 AC_MSG_RESULT($broken_poll)
2359 dnl *********************
2360 dnl *** GRegex checks ***
2361 dnl *********************
2363 PCRE_REQUIRED_VERSION=8.13
2365 # Check if we should use the internal or the system-supplied pcre
2366 AC_ARG_WITH(pcre,
2367 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2368 [whether to use system PCRE [default=system]])],
2369 [],
2370 [with_pcre=system])
2372 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2374 AS_IF([ test "x$with_pcre" = xsystem], [
2375 PKG_CHECK_MODULES(PCRE,
2376 libpcre >= $PCRE_REQUIRED_VERSION)
2377 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2378 glib_save_CFLAGS="$CFLAGS"
2379 glib_save_LIBS="$LIBS"
2380 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2381 AC_TRY_RUN([#include <pcre.h>
2382 int main () {
2383 int support;
2384 pcre_config (PCRE_CONFIG_UTF8, &support);
2385 if (!support)
2386 return 1;
2387 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2388 if (!support)
2389 return 1;
2390 return 0;
2391 }],
2392 glib_cv_pcre_has_unicode=yes,
2393 glib_cv_pcre_has_unicode=no,
2394 glib_cv_pcre_has_unicode=yes)
2395 CFLAGS="$glib_save_CFLAGS"
2396 LIBS="$glib_save_LIBS"
2397 ])
2398 if test "$glib_cv_pcre_has_unicode" = "no"; then
2399 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2400 fi
2401 AC_SUBST(PCRE_CFLAGS)
2402 AC_SUBST(PCRE_LIBS)
2403 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2404 PCRE_REQUIRES=libpcre
2405 AC_SUBST(PCRE_REQUIRES)
2406 ], [
2407 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2408 AS_IF([ test x"$GCC" = xyes], [
2409 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2410 save_CFLAGS="$CFLAGS"
2411 CFLAGS="$CFLAGS -Wno-pointer-sign"
2412 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2413 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2414 CFLAGS="$save_CFLAGS"
2415 ])
2416 ])
2417 AC_SUBST(PCRE_WARN_CFLAGS)
2419 dnl **********************
2420 dnl *** Win32 API libs ***
2421 dnl **********************
2423 case $host in
2424 *-*-cygwin*)
2425 G_LIBS_EXTRA="-luser32 -lkernel32"
2426 ;;
2427 *-*-mingw*)
2428 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2429 ;;
2430 *)
2431 G_LIBS_EXTRA=""
2432 ;;
2433 esac
2434 AC_SUBST(G_LIBS_EXTRA)
2436 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2437 dnl since we need it for g_iconv()
2439 AC_MSG_CHECKING([for EILSEQ])
2440 AC_TRY_COMPILE([
2441 #include <errno.h>
2442 ],
2443 [
2444 int error = EILSEQ;
2445 ], have_eilseq=yes, have_eilseq=no);
2446 AC_MSG_RESULT($have_eilseq)
2448 dnl Add a conditional we can use when cross-compiling, so we avoid running
2449 dnl binaries
2450 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2452 dnl **************************
2453 dnl *** Checks for gtk-doc ***
2454 dnl **************************
2455 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2456 # it on it's own line.
2457 m4_ifdef([GTK_DOC_CHECK], [
2458 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2459 ],[
2460 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2461 ])
2463 AC_ARG_ENABLE(man,
2464 [AS_HELP_STRING([--enable-man],
2465 [generate man pages [default=auto]])],,
2466 enable_man=maybe)
2468 AS_IF([test "$enable_man" != no], [
2469 AC_PATH_PROG([XSLTPROC], [xsltproc])
2470 AS_IF([test -z "$XSLTPROC"], [
2471 AS_IF([test "$enable_man" = yes], [
2472 AC_MSG_ERROR([xsltproc is required for --enable-man])
2473 ])
2474 enable_man=no
2475 ])
2476 ])
2478 AS_IF([ test "$enable_man" != no ], [
2479 dnl check for DocBook DTD in the local catalog
2480 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2481 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2482 AS_IF([test "$have_docbook_dtd" != yes], [
2483 AS_IF([test "$enable_man" = yes ], [
2484 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2485 ])
2486 enable_man=no
2487 ])
2488 ])
2490 AS_IF([test "$enable_man" != no], [
2491 dnl check for DocBook XSL stylesheets in the local catalog
2492 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2493 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2494 AS_IF([ test "$have_docbook_style" != yes ], [
2495 AS_IF([ test "$enable_man" = yes ], [
2496 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2497 ])
2498 enable_man=no
2499 ])
2500 ])
2502 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2504 AC_MSG_CHECKING([whether to generate man pages])
2505 AS_IF([ test "$enable_man" != no ], [
2506 AC_MSG_RESULT([yes])
2507 ], [
2508 AC_MSG_RESULT([no])
2509 ])
2511 dnl
2512 dnl Tracing
2513 dnl
2515 AC_ARG_ENABLE([dtrace],
2516 [AS_HELP_STRING([--enable-dtrace],
2517 [include tracing support for dtrace])])
2518 have_dtrace=no
2519 AC_MSG_CHECKING([whether to include dtrace tracing support])
2520 AS_IF([ test "x$enable_dtrace" != xno], [
2521 if test x$glib_have_carbon = xyes; then
2522 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2523 else
2524 AC_MSG_RESULT([yes])
2525 AC_CHECK_PROGS(DTRACE, dtrace)
2526 if test -z "$DTRACE"; then
2527 if test "x$enable_dtrace" = xyes; then
2528 AC_MSG_ERROR([dtrace not found])
2529 fi
2530 else
2531 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2532 [if test "x$enable_dtrace" = xyes; then
2533 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2534 fi])
2535 fi
2536 fi
2537 ], [
2538 AC_MSG_RESULT([no])
2539 ])
2540 if test "x$have_dtrace" = xyes; then
2541 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2542 fi
2543 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2545 AC_MSG_CHECKING([whether to include systemtap tracing support])
2546 AC_ARG_ENABLE([systemtap],
2547 [AS_HELP_STRING([--enable-systemtap],
2548 [include tracing support for systemtap])])
2549 have_systemtap=no
2550 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2551 have_systemtap=yes
2552 fi
2553 AC_MSG_RESULT(${have_systemtap})
2555 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2557 AC_ARG_WITH([tapset-install-dir],
2558 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2559 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2560 [if test "x${withval}" = x; then
2561 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2562 else
2563 ABS_TAPSET_DIR="${withval}"
2564 fi],
2565 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2566 AC_SUBST(ABS_TAPSET_DIR)
2568 dnl ************************************
2569 dnl *** Enable lcov coverage reports ***
2570 dnl ************************************
2572 AC_ARG_ENABLE(coverage,
2573 AS_HELP_STRING([--enable-coverage],
2574 [enable coverage testing with gcov]),
2575 [use_gcov=$enableval], [use_gcov=no])
2577 AS_IF([ test "x$use_gcov" = "xyes"], [
2578 dnl we need gcc:
2579 if test "$GCC" != "yes"; then
2580 AC_MSG_ERROR([GCC is required for --enable-coverage])
2581 fi
2583 dnl Check if ccache is being used
2584 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2585 case `$SHTOOL path $CC` in
2586 *ccache*[)] gcc_ccache=yes;;
2587 *[)] gcc_ccache=no;;
2588 esac
2590 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2591 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2592 fi
2594 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2595 AC_CHECK_PROG(LTP, lcov, lcov)
2596 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2598 AS_IF([ test "$LTP" ], [
2599 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2600 glib_cv_ltp_version=invalid
2601 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2602 for ltp_check_version in $ltp_version_list; do
2603 if test "$ltp_version" = "$ltp_check_version"; then
2604 glib_cv_ltp_version="$ltp_check_version (ok)"
2605 fi
2606 done
2607 ])
2608 ], [
2609 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2610 AC_MSG_ERROR([$ltp_msg])
2611 ])
2613 case $glib_cv_ltp_version in
2614 ""|invalid[)]
2615 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2616 AC_MSG_ERROR([$ltp_msg])
2617 LTP="exit 0;"
2618 ;;
2619 esac
2621 if test -z "$LTP_GENHTML"; then
2622 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2623 fi
2625 dnl Remove all optimization flags from CFLAGS
2626 changequote({,})
2627 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2628 changequote([,])
2630 dnl Add the special gcc flags
2631 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2632 LDFLAGS="$LDFLAGS -lgcov"
2633 ])
2635 dnl ******************************
2636 dnl *** output the whole stuff ***
2637 dnl ******************************
2639 dnl this section will only be run if config.status is invoked with no
2640 dnl arguments, or with "glib/glibconfig.h" as an argument.
2641 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2642 [
2643 outfile=glib/glibconfig.h-tmp
2644 cat > $outfile <<\_______EOF
2645 /* glibconfig.h
2646 *
2647 * This is a generated file. Please modify 'configure.ac'
2648 */
2650 #ifndef __GLIBCONFIG_H__
2651 #define __GLIBCONFIG_H__
2653 #include <glib/gmacros.h>
2655 _______EOF
2657 echo '#include <limits.h>' >> $outfile
2658 echo '#include <float.h>' >> $outfile
2659 if test x$glib_values_h = xyes; then
2660 echo '#include <values.h>' >> $outfile
2661 fi
2662 if test "$glib_header_alloca_h" = "yes"; then
2663 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2664 fi
2665 if test x$glib_included_printf != xyes; then
2666 echo "
2667 /* Specifies that GLib's g_print*() functions wrap the
2668 * system printf functions. This is useful to know, for example,
2669 * when using glibc's register_printf_function().
2670 */" >> $outfile
2671 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2672 fi
2674 cat >> $outfile <<_______EOF
2676 G_BEGIN_DECLS
2678 #define G_MINFLOAT FLT_MIN
2679 #define G_MAXFLOAT FLT_MAX
2680 #define G_MINDOUBLE DBL_MIN
2681 #define G_MAXDOUBLE DBL_MAX
2682 #define G_MINSHORT SHRT_MIN
2683 #define G_MAXSHORT SHRT_MAX
2684 #define G_MAXUSHORT USHRT_MAX
2685 #define G_MININT INT_MIN
2686 #define G_MAXINT INT_MAX
2687 #define G_MAXUINT UINT_MAX
2688 #define G_MINLONG LONG_MIN
2689 #define G_MAXLONG LONG_MAX
2690 #define G_MAXULONG ULONG_MAX
2692 _______EOF
2695 ### this should always be true in a modern C/C++ compiler
2696 ### and is statically asserted by glib-init.c
2697 cat >>$outfile <<_______EOF
2698 typedef signed char gint8;
2699 typedef unsigned char guint8;
2700 _______EOF
2703 if test -n "$gint16"; then
2704 cat >>$outfile <<_______EOF
2705 typedef signed $gint16 gint16;
2706 typedef unsigned $gint16 guint16;
2707 #define G_GINT16_MODIFIER $gint16_modifier
2708 #define G_GINT16_FORMAT $gint16_format
2709 #define G_GUINT16_FORMAT $guint16_format
2710 _______EOF
2711 fi
2714 if test -n "$gint32"; then
2715 cat >>$outfile <<_______EOF
2716 typedef signed $gint32 gint32;
2717 typedef unsigned $gint32 guint32;
2718 #define G_GINT32_MODIFIER $gint32_modifier
2719 #define G_GINT32_FORMAT $gint32_format
2720 #define G_GUINT32_FORMAT $guint32_format
2721 _______EOF
2722 fi
2724 cat >>$outfile <<_______EOF
2725 #define G_HAVE_GINT64 1 /* deprecated, always true */
2727 ${glib_extension}typedef signed $gint64 gint64;
2728 ${glib_extension}typedef unsigned $gint64 guint64;
2730 #define G_GINT64_CONSTANT(val) $gint64_constant
2731 #define G_GUINT64_CONSTANT(val) $guint64_constant
2732 _______EOF
2734 if test x$gint64_format != x ; then
2735 cat >>$outfile <<_______EOF
2736 #define G_GINT64_MODIFIER $gint64_modifier
2737 #define G_GINT64_FORMAT $gint64_format
2738 #define G_GUINT64_FORMAT $guint64_format
2739 _______EOF
2740 else
2741 cat >>$outfile <<_______EOF
2742 #undef G_GINT64_MODIFIER
2743 #undef G_GINT64_FORMAT
2744 #undef G_GUINT64_FORMAT
2745 _______EOF
2746 fi
2748 cat >>$outfile <<_______EOF
2750 #define GLIB_SIZEOF_VOID_P $glib_void_p
2751 #define GLIB_SIZEOF_LONG $glib_long
2752 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2753 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2755 _______EOF
2757 cat >>$outfile <<_______EOF
2758 typedef signed $glib_ssize_type_define gssize;
2759 typedef unsigned $glib_size_type_define gsize;
2760 #define G_GSIZE_MODIFIER $gsize_modifier
2761 #define G_GSSIZE_MODIFIER $gssize_modifier
2762 #define G_GSIZE_FORMAT $gsize_format
2763 #define G_GSSIZE_FORMAT $gssize_format
2765 #define G_MAXSIZE G_MAXU$glib_msize_type
2766 #define G_MINSSIZE G_MIN$glib_mssize_type
2767 #define G_MAXSSIZE G_MAX$glib_mssize_type
2769 typedef gint64 goffset;
2770 #define G_MINOFFSET G_MININT64
2771 #define G_MAXOFFSET G_MAXINT64
2773 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2774 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2775 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2777 #define G_POLLFD_FORMAT $g_pollfd_format
2779 _______EOF
2781 if test -z "$glib_unknown_void_p"; then
2782 cat >>$outfile <<_______EOF
2784 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2785 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2787 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2788 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2790 typedef signed $glib_intptr_type_define gintptr;
2791 typedef unsigned $glib_intptr_type_define guintptr;
2793 #define G_GINTPTR_MODIFIER $gintptr_modifier
2794 #define G_GINTPTR_FORMAT $gintptr_format
2795 #define G_GUINTPTR_FORMAT $guintptr_format
2796 _______EOF
2797 else
2798 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2799 fi
2803 cat >>$outfile <<_______EOF
2804 #ifndef G_DISABLE_DEPRECATED
2805 #define g_ATEXIT(proc) (atexit (proc))
2806 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2807 #endif
2808 $glib_defines
2809 $glib_os
2810 $glib_static_compilation
2812 $glib_vacopy
2814 _______EOF
2816 if test x$g_have_iso_c_varargs = xyes ; then
2817 cat >>$outfile <<_______EOF
2818 #ifndef __cplusplus
2819 # define G_HAVE_ISO_VARARGS 1
2820 #endif
2821 _______EOF
2822 fi
2823 if test x$g_have_iso_cxx_varargs = xyes ; then
2824 cat >>$outfile <<_______EOF
2825 #ifdef __cplusplus
2826 # define G_HAVE_ISO_VARARGS 1
2827 #endif
2828 _______EOF
2829 fi
2830 if test x$g_have_gnuc_varargs = xyes ; then
2831 cat >>$outfile <<_______EOF
2833 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2834 * is passed ISO vararg support is turned off, and there is no work
2835 * around to turn it on, so we unconditionally turn it off.
2836 */
2837 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2838 # undef G_HAVE_ISO_VARARGS
2839 #endif
2841 #define G_HAVE_GNUC_VARARGS 1
2842 _______EOF
2843 fi
2845 case x$g_stack_grows in
2846 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2847 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2848 esac
2851 echo >>$outfile
2852 if test x$g_have_eilseq = xno; then
2853 cat >>$outfile <<_______EOF
2854 #ifndef EILSEQ
2855 /* On some pre-C99 systems, EILSEQ is not defined.
2856 * The correspondence between this and the corresponding definition
2857 * in libiconv is essential.
2858 */
2859 # define EILSEQ ENOENT
2860 #endif
2861 _______EOF
2863 fi
2865 if test x$g_have_gnuc_visibility = xyes; then
2866 cat >>$outfile <<_______EOF
2867 #define G_HAVE_GNUC_VISIBILITY 1
2868 _______EOF
2869 fi
2870 cat >>$outfile <<_______EOF
2871 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2872 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2873 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2874 #define G_GNUC_INTERNAL __hidden
2875 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2876 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2877 #else
2878 #define G_GNUC_INTERNAL
2879 #endif
2880 _______EOF
2882 echo >>$outfile
2883 cat >>$outfile <<_______EOF
2884 #define G_THREADS_ENABLED
2885 #define G_THREADS_IMPL_$g_threads_impl_def
2886 _______EOF
2888 if test x"$g_memory_barrier_needed" != xno; then
2889 echo >>$outfile
2890 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2891 fi
2892 if test x"$g_atomic_lock_free" = xyes; then
2893 echo >>$outfile
2894 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2895 fi
2896 echo >>$outfile
2897 g_bit_sizes="16 32 64"
2898 for bits in $g_bit_sizes; do
2899 cat >>$outfile <<_______EOF
2900 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2901 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2902 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2903 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2904 _______EOF
2905 done
2907 cat >>$outfile <<_______EOF
2908 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2909 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2910 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2911 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2912 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2913 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2914 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2915 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2916 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2917 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2918 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2919 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2920 #define G_BYTE_ORDER $g_byte_order
2922 #define GLIB_SYSDEF_POLLIN =$g_pollin
2923 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2924 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2925 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2926 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2927 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2929 #define G_MODULE_SUFFIX "$g_module_suffix"
2931 typedef $g_pid_type GPid;
2932 #define G_PID_FORMAT $g_pid_format
2934 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2935 #define GLIB_SYSDEF_AF_INET $g_af_inet
2936 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2938 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2939 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2940 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2942 G_END_DECLS
2944 #endif /* __GLIBCONFIG_H__ */
2945 _______EOF
2948 if cmp -s $outfile glib/glibconfig.h; then
2949 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2950 rm -f $outfile
2951 else
2952 mv $outfile glib/glibconfig.h
2953 fi
2954 ],[
2956 # Note that if two cases are the same, case goes with the first one.
2957 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2958 # on variable expansion in case labels. Look at the generated config.status
2959 # for a hint.
2961 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2962 glib_header_alloca_h="$ac_cv_working_alloca_h"
2963 else
2964 glib_header_alloca_h="$ac_cv_header_alloca_h"
2965 fi
2967 if test x$enable_included_printf = xyes ; then
2968 glib_included_printf=yes
2969 fi
2971 case 2 in
2972 $ac_cv_sizeof_short)
2973 gint16=short
2974 gint16_modifier='"h"'
2975 gint16_format='"hi"'
2976 guint16_format='"hu"'
2977 ;;
2978 $ac_cv_sizeof_int)
2979 gint16=int
2980 gint16_modifier='""'
2981 gint16_format='"i"'
2982 guint16_format='"u"'
2983 ;;
2984 esac
2985 case 4 in
2986 $ac_cv_sizeof_short)
2987 gint32=short
2988 gint32_modifier='"h"'
2989 gint32_format='"hi"'
2990 guint32_format='"hu"'
2991 ;;
2992 $ac_cv_sizeof_int)
2993 gint32=int
2994 gint32_modifier='""'
2995 gint32_format='"i"'
2996 guint32_format='"u"'
2997 ;;
2998 $ac_cv_sizeof_long)
2999 gint32=long
3000 gint32_modifier='"l"'
3001 gint32_format='"li"'
3002 guint32_format='"lu"'
3003 ;;
3004 esac
3005 case 8 in
3006 $ac_cv_sizeof_int)
3007 gint64=int
3008 gint64_modifier='""'
3009 gint64_format='"i"'
3010 guint64_format='"u"'
3011 glib_extension=
3012 gint64_constant='(val)'
3013 guint64_constant='(val)'
3014 ;;
3015 $ac_cv_sizeof_long)
3016 gint64=long
3017 gint64_modifier='"l"'
3018 gint64_format='"li"'
3019 guint64_format='"lu"'
3020 glib_extension=
3021 gint64_constant='(val##L)'
3022 guint64_constant='(val##UL)'
3023 ;;
3024 $ac_cv_sizeof_long_long)
3025 gint64='long long'
3026 if test -n "$glib_cv_long_long_format"; then
3027 gint64_modifier='"'$glib_cv_long_long_format'"'
3028 gint64_format='"'$glib_cv_long_long_format'i"'
3029 guint64_format='"'$glib_cv_long_long_format'u"'
3030 fi
3031 glib_extension='G_GNUC_EXTENSION '
3032 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3033 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3034 ;;
3035 $ac_cv_sizeof___int64)
3036 gint64='__int64'
3037 if test -n "$glib_cv_long_long_format"; then
3038 gint64_modifier='"'$glib_cv_long_long_format'"'
3039 gint64_format='"'$glib_cv_long_long_format'i"'
3040 guint64_format='"'$glib_cv_long_long_format'u"'
3041 fi
3042 glib_extension=
3043 gint64_constant='(val##i64)'
3044 guint64_constant='(val##ui64)'
3045 ;;
3046 esac
3047 glib_size_t=$ac_cv_sizeof_size_t
3048 glib_ssize_t=$ac_cv_sizeof_ssize_t
3049 glib_size_type_define="$glib_size_type"
3050 glib_ssize_type_define="$glib_ssize_type"
3051 glib_void_p=$ac_cv_sizeof_void_p
3052 glib_long=$ac_cv_sizeof_long
3054 case "$glib_size_type" in
3055 short)
3056 gsize_modifier='"h"'
3057 gsize_format='"hu"'
3058 glib_msize_type='SHRT'
3059 ;;
3060 int)
3061 gsize_modifier='""'
3062 gsize_format='"u"'
3063 glib_msize_type='INT'
3064 ;;
3065 long)
3066 gsize_modifier='"l"'
3067 gsize_format='"lu"'
3068 glib_msize_type='LONG'
3069 ;;
3070 "long long"|__int64)
3071 gsize_modifier='"I64"'
3072 gsize_format='"I64u"'
3073 glib_msize_type='INT64'
3074 ;;
3075 esac
3077 case "$glib_ssize_type" in
3078 short)
3079 gssize_modifier='"h"'
3080 gssize_format='"hi"'
3081 glib_mssize_type='SHRT'
3082 ;;
3083 int)
3084 gssize_modifier='""'
3085 gssize_format='"i"'
3086 glib_mssize_type='INT'
3087 ;;
3088 long)
3089 gssize_modifier='"l"'
3090 gssize_format='"li"'
3091 glib_mssize_type='LONG'
3092 ;;
3093 "long long"|__int64)
3094 gssize_modifier='"I64"'
3095 gssize_format='"I64i"'
3096 glib_mssize_type='INT64'
3097 ;;
3098 esac
3100 gintbits=`expr $ac_cv_sizeof_int \* 8`
3101 glongbits=`expr $ac_cv_sizeof_long \* 8`
3102 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3103 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3105 case $ac_cv_sizeof_void_p in
3106 $ac_cv_sizeof_int)
3107 glib_intptr_type_define=int
3108 gintptr_modifier='""'
3109 gintptr_format='"i"'
3110 guintptr_format='"u"'
3111 glib_gpi_cast='(gint)'
3112 glib_gpui_cast='(guint)'
3113 ;;
3114 $ac_cv_sizeof_long)
3115 glib_intptr_type_define=long
3116 gintptr_modifier='"l"'
3117 gintptr_format='"li"'
3118 guintptr_format='"lu"'
3119 glib_gpi_cast='(glong)'
3120 glib_gpui_cast='(gulong)'
3121 ;;
3122 $ac_cv_sizeof_long_long)
3123 glib_intptr_type_define='long long'
3124 gintptr_modifier='"I64"'
3125 gintptr_format='"I64i"'
3126 guintptr_format='"I64u"'
3127 glib_gpi_cast='(gint64)'
3128 glib_gpui_cast='(guint64)'
3129 ;;
3130 $ac_cv_sizeof___int64)
3131 glib_intptr_type_define=__int64
3132 gintptr_modifier='"I64"'
3133 gintptr_format='"I64i"'
3134 guintptr_format='"I64u"'
3135 glib_gpi_cast='(gint64)'
3136 glib_gpui_cast='(guint64)'
3137 ;;
3138 *)
3139 glib_unknown_void_p=yes
3140 ;;
3141 esac
3144 glib_defines="
3145 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3146 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3147 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3148 "
3150 case xyes in
3151 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3152 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3153 *) glib_vacopy=''
3154 esac
3156 if test x$glib_cv_va_val_copy = xno; then
3157 glib_vacopy="\$glib_vacopy
3158 #define G_VA_COPY_AS_ARRAY 1"
3159 fi
3161 g_have_gnuc_varargs=$g_have_gnuc_varargs
3162 g_have_iso_c_varargs=$g_have_iso_c_varargs
3163 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3165 g_have_gnuc_visibility=$g_have_gnuc_visibility
3166 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3168 if test x$ac_cv_c_bigendian = xyes; then
3169 g_byte_order=G_BIG_ENDIAN
3170 g_bs_native=BE
3171 g_bs_alien=LE
3172 else
3173 g_byte_order=G_LITTLE_ENDIAN
3174 g_bs_native=LE
3175 g_bs_alien=BE
3176 fi
3178 g_pollin=$glib_cv_value_POLLIN
3179 g_pollout=$glib_cv_value_POLLOUT
3180 g_pollpri=$glib_cv_value_POLLPRI
3181 g_pollhup=$glib_cv_value_POLLHUP
3182 g_pollerr=$glib_cv_value_POLLERR
3183 g_pollnval=$glib_cv_value_POLLNVAL
3185 # If a family is not found on the system, define that family to
3186 # a negative value, picking a different one for each undefined
3187 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3188 # This is needed because glib-mkenums doesn't handle optional
3189 # values in enums, and thus we have to have all existing values
3190 # defined in the enum.
3191 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3192 g_af_unix=$glib_cv_value_AF_UNIX
3193 else
3194 g_af_unix=-1
3195 fi
3196 g_af_inet=$glib_cv_value_AF_INET
3197 g_af_inet6=$glib_cv_value_AF_INET6
3199 g_msg_peek=$glib_cv_value_MSG_PEEK
3200 g_msg_oob=$glib_cv_value_MSG_OOB
3201 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3203 g_stack_grows=$glib_cv_stack_grows
3205 g_have_eilseq=$have_eilseq
3207 g_threads_impl_def=$g_threads_impl
3209 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3210 g_memory_barrier_needed="$glib_memory_barrier_needed"
3211 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3213 g_module_suffix="$glib_gmodule_suffix"
3214 g_pid_type="$glib_pid_type"
3215 g_pid_format="\"$glib_pid_format\""
3216 g_pollfd_format="\"$glib_pollfd_format\""
3218 case $host in
3219 *-*-cygwin*)
3220 glib_os="#define G_OS_UNIX
3221 #define G_PLATFORM_WIN32
3222 #define G_WITH_CYGWIN"
3223 ;;
3224 *-*-mingw*)
3225 glib_os="#define G_OS_WIN32
3226 #define G_PLATFORM_WIN32"
3227 ;;
3228 *)
3229 glib_os="#define G_OS_UNIX"
3230 ;;
3231 esac
3232 glib_static_compilation=""
3233 if test x$glib_win32_static_compilation = xyes; then
3234 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3235 #define GOBJECT_STATIC_COMPILATION 1"
3236 fi
3237 ])
3239 # Redo enough to get guint32 and guint64 for the alignment checks below
3240 case 4 in
3241 $ac_cv_sizeof_short)
3242 gint32=short
3243 ;;
3244 $ac_cv_sizeof_int)
3245 gint32=int
3246 ;;
3247 $ac_cv_sizeof_long)
3248 gint32=long
3249 ;;
3250 esac
3251 case 8 in
3252 $ac_cv_sizeof_int)
3253 gint64=int
3254 ;;
3255 $ac_cv_sizeof_long)
3256 gint64=long
3257 ;;
3258 $ac_cv_sizeof_long_long)
3259 gint64='long long'
3260 ;;
3261 $ac_cv_sizeof___int64)
3262 gint64='__int64'
3263 ;;
3264 esac
3266 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3267 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3268 typedef unsigned $gint32 guint32;])
3269 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3270 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3271 typedef unsigned $gint64 guint64;])
3272 AC_CHECK_TYPE([unsigned long])
3273 AC_CHECK_ALIGNOF([unsigned long])
3275 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3276 #
3277 # 1.2.14 required for dbus_message_set_serial
3278 PKG_CHECK_MODULES(DBUS1,
3279 dbus-1 >= 1.2.14,
3280 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3281 have_dbus1=no)
3282 AC_SUBST(DBUS1_CFLAGS)
3283 AC_SUBST(DBUS1_LIBS)
3284 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3286 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3287 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3289 # Check whether MSVC toolset is explicitly set
3290 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3291 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3293 dnl
3294 dnl Check for -Bsymbolic-functions linker flag used to avoid
3295 dnl intra-library PLT jumps, if available.
3296 dnl
3298 AC_ARG_ENABLE(Bsymbolic,
3299 [AS_HELP_STRING([--disable-Bsymbolic],
3300 [avoid linking with -Bsymbolic])],,
3301 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3302 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3303 LDFLAGS=-Wl,-Bsymbolic-functions
3304 LIBS=
3305 AC_TRY_LINK([], [return 0],
3306 AC_MSG_RESULT(yes)
3307 enable_Bsymbolic=yes,
3308 AC_MSG_RESULT(no)
3309 enable_Bsymbolic=no)
3310 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3312 if test "x${enable_Bsymbolic}" = "xyes"; then
3313 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3314 fi
3316 dnl
3317 dnl Check for -z,nodelete linker flag: the type system assumes that
3318 dnl libgobject stays loaded for the lifetime of the process.
3319 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3320 dnl we also try to check for the --fatal-warnings linker flag if
3321 dnl auto-detecting.
3322 dnl
3324 AC_ARG_ENABLE([znodelete],
3325 [AS_HELP_STRING([--disable-znodelete],
3326 [avoid linking with -z,nodelete])],,
3327 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3328 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3329 LDFLAGS=-Wl,--fatal-warnings
3330 LIBS=
3331 AC_TRY_LINK([], [return 0],
3332 AC_MSG_RESULT(yes)
3333 [ldflags_fatal=-Wl,--fatal-warnings],
3334 AC_MSG_RESULT(no)
3335 ldflags_fatal=)
3336 AC_MSG_CHECKING([for -z,nodelete linker flag])
3337 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3338 AC_TRY_LINK([], [return 0],
3339 AC_MSG_RESULT(yes)
3340 enable_znodelete=yes,
3341 AC_MSG_RESULT(no)
3342 enable_znodelete=no)
3343 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3345 if test "x${enable_znodelete}" = "xyes"; then
3346 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3347 fi
3349 AC_SUBST(GLIB_LINK_FLAGS)
3351 dnl
3352 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3353 dnl visibility attributes for symbol export control
3354 dnl
3355 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3356 case "$host" in
3357 *-*-mingw*)
3358 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3359 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3360 [defines how to decorate public symbols while building])
3361 CFLAGS="${CFLAGS} -fvisibility=hidden"
3362 ;;
3363 *)
3364 dnl on other compilers, check if we can do -fvisibility=hidden
3365 SAVED_CFLAGS="${CFLAGS}"
3366 CFLAGS="-fvisibility=hidden"
3367 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3368 AC_TRY_COMPILE([], [return 0],
3369 AC_MSG_RESULT(yes)
3370 enable_fvisibility_hidden=yes,
3371 AC_MSG_RESULT(no)
3372 enable_fvisibility_hidden=no)
3373 CFLAGS="${SAVED_CFLAGS}"
3375 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3376 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3377 [defines how to decorate public symbols while building])
3378 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3379 ])
3380 ;;
3381 esac
3382 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3384 dnl Compiler flags; macro originates from systemd
3385 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3386 AC_ARG_ENABLE(compile-warnings,
3387 [AS_HELP_STRING([--disable-compile-warnings],
3388 [Don't use builtin compiler warnings])],,
3389 enable_compile_warnings=yes)
3390 AS_IF([test "x$enable_compile_warnings" != xno], [
3391 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3392 -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3393 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3394 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3395 -Werror=format=2 -Werror=missing-include-dirs])
3396 ])
3397 AC_SUBST(GLIB_WARN_CFLAGS)
3399 #
3400 # Define variables corresponding to the correct include paths to use for
3401 # in-tree building.
3402 #
3404 # for config.h:
3405 config_h_INCLUDES='-I$(top_builddir)'
3406 AC_SUBST(config_h_INCLUDES)
3408 # glib:
3409 # config.h
3410 # $(top_builddir)/glib: for glibconfig.h
3411 # $(top_srcdir)/glib: for glib.h
3412 # $(top_srcdir): for everything
3413 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3414 AC_SUBST(glib_INCLUDES)
3416 # gobject:
3417 # same as glib
3418 gobject_INCLUDES='$(glib_INCLUDES)'
3419 AC_SUBST(gobject_INCLUDES)
3421 # gmodule:
3422 # glib includes
3423 # $(top_srcdir)/gmodule: for gmodule.h
3424 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3425 AC_SUBST(gmodule_INCLUDES)
3427 # gio:
3428 # same as gmodule
3429 gio_INCLUDES='$(gmodule_INCLUDES)'
3430 AC_SUBST(gio_INCLUDES)
3433 AC_CONFIG_FILES([
3434 glib-2.0.pc
3435 gmodule-2.0.pc
3436 gmodule-export-2.0.pc
3437 gmodule-no-export-2.0.pc
3438 gthread-2.0.pc
3439 gobject-2.0.pc
3440 gio-2.0.pc
3441 gio-unix-2.0.pc
3442 gio-windows-2.0.pc
3443 glib-zip
3444 glib-gettextize
3445 Makefile
3446 build/Makefile
3447 build/win32/Makefile
3448 build/win32/dirent/Makefile
3449 win32/Makefile
3450 win32/vs9/Makefile
3451 win32/vs9/glib-version-paths.vsprops
3452 win32/vs10/Makefile
3453 win32/vs10/glib-version-paths.props
3454 win32/vs11/Makefile
3455 win32/vs12/Makefile
3456 win32/vs14/Makefile
3457 win32/vs15/Makefile
3458 glib/Makefile
3459 glib/libcharset/Makefile
3460 glib/gnulib/Makefile
3461 glib/pcre/Makefile
3462 glib/update-pcre/Makefile
3463 glib/tests/Makefile
3464 gmodule/Makefile
3465 gmodule/gmoduleconf.h
3466 gobject/Makefile
3467 gobject/glib-genmarshal
3468 gobject/glib-mkenums
3469 gobject/tests/Makefile
3470 gthread/Makefile
3471 gio/Makefile
3472 gio/gdbus-2.0/codegen/Makefile
3473 gio/gdbus-2.0/codegen/config.py
3474 gio/gnetworking.h
3475 gio/xdgmime/Makefile
3476 gio/inotify/Makefile
3477 gio/kqueue/Makefile
3478 gio/fam/Makefile
3479 gio/win32/Makefile
3480 gio/tests/Makefile
3481 gio/tests/gdbus-object-manager-example/Makefile
3482 gio/tests/services/Makefile
3483 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3484 gio/tests/modules/Makefile
3485 po/Makefile.in
3486 docs/Makefile
3487 docs/reference/Makefile
3488 docs/reference/glib/Makefile
3489 docs/reference/glib/version.xml
3490 docs/reference/gobject/Makefile
3491 docs/reference/gobject/version.xml
3492 docs/reference/gio/Makefile
3493 docs/reference/gio/version.xml
3494 tests/Makefile
3495 tests/gobject/Makefile
3496 tests/refcount/Makefile
3497 m4macros/Makefile
3498 ])
3500 AC_CONFIG_COMMANDS([chmod-scripts],
3501 [chmod 0755 glib-zip
3502 chmod 0755 glib-gettextize
3503 chmod 0755 gobject/glib-genmarshal
3504 chmod 0755 gobject/glib-mkenums])
3506 # we want to invoke this macro solely so that the config.status script
3507 # and automake generated makefiles know about these generated files.
3508 # They are only needed to distcheck the package
3509 if false; then
3510 AC_CONFIG_FILES([
3511 INSTALL
3512 README
3513 config.h.win32
3514 glib/glibconfig.h.win32
3515 glib/glib.rc
3516 gmodule/gmodule.rc
3517 gobject/gobject.rc
3518 gthread/gthread.rc
3519 gio/gio.rc
3520 ])
3521 fi
3523 AC_OUTPUT