gio/gdbus-2.0/codegen/meson.build

   1 gdbus_codegen_files = [
   2   '__init__.py',
   3   'codegen.py',
   4   'codegen_main.py',
   5   'codegen_docbook.py',
   6   'dbustypes.py',
   7   'parser.py',
   8   'utils.py',
   9 ]
  10
  11 gdbus_codegen_conf = configuration_data()
  12 gdbus_codegen_conf.set('VERSION', glib_version)
  13 gdbus_codegen_conf.set('PYTHON', python_name)
  14 gdbus_codegen_conf.set('DATADIR', glib_datadir)
  15
  16 # Install gdbus-codegen executable
  17 gdbus_codegen = configure_file(input : 'gdbus-codegen.in',
  18   output : 'gdbus-codegen',
  19   install : true,
  20   install_dir : get_option('bindir'),
  21   configuration : gdbus_codegen_conf
  22 )
  23   # Provide tools for others when we're a subproject and they use the Meson GNOME module
  24 meson.override_find_program('gdbus-codegen', gdbus_codegen)
  25
  26 codegen_dir = join_paths(get_option('datadir'), 'glib-2.0/codegen')
  27
  28 gdbus_codegen_built_files = []
  29 gdbus_codegen_built_files += configure_file(input : 'config.py.in',
  30                                             output : 'config.py',
  31                                             install : true,
  32                                             install_dir : codegen_dir,
  33                                             configuration : gdbus_codegen_conf)
  34
  35 foreach f : gdbus_codegen_files
  36   # Copy these into the builddir so that gdbus-codegen can be used uninstalled
  37   # and then install it too so that it can be used after installation
  38   gdbus_codegen_built_files += configure_file(input : f, output : f,
  39                                               install : true,
  40                                               install_dir : codegen_dir,
  41                                               copy : true)
  42 endforeach