glib/tests/meson.build

   1 glib_tests = {
   2   'array-test' : {},
   3   'asyncqueue' : {},
   4   'atomic' : {
   5     'c_args' : cc.get_id() == 'gcc' ? ['-Wstrict-aliasing=2'] : [],
   6   },
   7   'autoptr' : {
   8     'skip' : cc.get_id() == 'msvc',
   9   },
  10   'base64' : {},
  11   'bitlock' : {},
  12   'bookmarkfile' : {},
  13   'bytes' : {},
  14   'cache' : {},
  15   'charset' : {},
  16   'checksum' : {},
  17   'collate' : {},
  18   'cond' : {},
  19   'convert' : {},
  20   'dataset' : {},
  21   'date' : {},
  22   'dir' : {},
  23   'environment' : {},
  24   'error' : {},
  25   'fileutils' : {},
  26   'gdatetime' : {},
  27   'guuid' : {},
  28   'gvariant' : {
  29     'suite' : ['slow'],
  30   },
  31   'gwakeup' : {
  32     'source' : ['gwakeuptest.c', '../gwakeup.c'],
  33   },
  34   'gwakeup-fallback' : {
  35     'skip' : not glib_conf.has('HAVE_EVENTFD'),
  36     'source' : ['gwakeuptest.c', '../gwakeup.c'],
  37     'c_args' : ['-DTEST_EVENTFD_FALLBACK'],
  38   },
  39   'hash' : {},
  40   'hmac' : {},
  41   'hook' : {},
  42   'hostutils' : {},
  43   'include' : {
  44     'skip' : host_machine.system() == 'windows',
  45   },
  46   'keyfile' : {},
  47   'list' : {},
  48   'logging' : {},
  49   'mainloop' : {},
  50   'mappedfile' : {},
  51   'markup' : {},
  52   'markup-parse' : {},
  53   'markup-collect' : {},
  54   'markup-escape' : {},
  55   'markup-subparser' : {},
  56   'mem-overflow' : {},
  57   'mutex' : {},
  58   'node' : {},
  59   'once' : {},
  60   'option-context' : {},
  61   'option-argv0' : {},
  62   'overflow' : {},
  63   'overflow-fallback' : {
  64     'source' : 'overflow.c',
  65     'c_args' : ['-D_GLIB_TEST_OVERFLOW_FALLBACK'],
  66   },
  67   'pattern' : {},
  68   'private' : {},
  69   'protocol' : {},
  70   'queue' : {},
  71   'rand' : {},
  72   'rcbox' : {},
  73   'rec-mutex' : {},
  74   'refcount' : {},
  75   'refcount-macro' : {
  76     'source' : 'refcount.c',
  77     'c_args' : ['-DG_DISABLE_CHECKS'],
  78   },
  79   'refstring' : {},
  80   'regex' : {
  81     'dependencies' : [pcre],
  82     'c_args' : use_pcre_static_flag ? ['-DPCRE_STATIC'] : [],
  83   },
  84   'rwlock' : {},
  85   'scannerapi' : {},
  86   'search-utils' : {},
  87   'sequence' : {
  88     'suite' : ['slow'],
  89   },
  90   'shell' : {},
  91   'slice' : {},
  92   'slist' : {},
  93   'sort' : {},
  94   'spawn-multithreaded' : {},
  95   'spawn-singlethread' : {},
  96   'strfuncs' : {},
  97   'string' : {},
  98   'testing' : {},
  99   'test-printf' : {},
 100   'thread' : {},
 101   'timeout' : {},
 102   'timer' : {},
 103   'tree' : {},
 104   'utf8-performance' : {},
 105   'utf8-pointer' : {},
 106   'utf8-validate' : {},
 107   'utf8-misc' : {},
 108   'utils' : {},
 109   'unicode' : {},
 110   'unix' : {
 111     'skip' : host_machine.system() == 'windows',
 112   },
 113   'uri' : {},
 114   '1bit-mutex' : {},
 115   '1bit-emufutex' : {
 116     'source' : '1bit-mutex.c',
 117     'c_args' : ['-DTEST_EMULATED_FUTEX'],
 118   },
 119   '642026' : {
 120     'suite' : ['slow'],
 121   },
 122   '642026-ec' : {
 123     'source' : '642026.c',
 124     'c_args' : ['-DG_ERRORCHECK_MUTEXES'],
 125     'suite' : ['slow'],
 126   },
 127 }
 128
 129 # Not entirely random of course, but at least it changes over time
 130 random_number = minor_version + meson.version().split('.').get(1).to_int()
 131
 132 test_env = environment()
 133 test_env.set('G_TEST_SRCDIR', meson.current_source_dir())
 134 test_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
 135 test_env.set('G_DEBUG', 'gc-friendly')
 136 test_env.set('MALLOC_CHECK_', '2')
 137 test_env.set('MALLOC_PERTURB_', '@0@'.format(random_number % 256))
 138
 139 test_deps = [libm, thread_dep, libglib_dep]
 140 test_cargs = ['-DG_LOG_DOMAIN="GLib"']
 141
 142 foreach test_name, extra_args : glib_tests
 143   # FIXME: This condition is ugly, meson should either have 'continue'
 144   # keyword (https://github.com/mesonbuild/meson/issues/3601), or support
 145   # mutable to dictionaries (https://github.com/mesonbuild/meson/pull/3820).
 146   if not extra_args.get('skip', false)
 147     source = extra_args.get('source', test_name + '.c')
 148
 149     exe = executable(test_name, source,
 150       c_args : test_cargs + extra_args.get('c_args', []),
 151       dependencies : test_deps + extra_args.get('dependencies', []),
 152       install: false,
 153     )
 154
 155     suite = ['glib'] + extra_args.get('suite', [])
 156     timeout = suite.contains('slow') ? 120 : 30
 157     test(test_name, exe, env : test_env, timeout : timeout, suite : suite)
 158   endif
 159 endforeach
 160
 161 # test-spawn-echo helper binary required by the spawn tests above
 162 executable('test-spawn-echo', 'test-spawn-echo.c',
 163   c_args : test_cargs,
 164   dependencies : test_deps,
 165   install : false,
 166 )
 167
 168 # some testing of gtester functionality
 169 if not meson.is_cross_build() and host_system != 'windows'
 170   xmllint = find_program('xmllint', required: false)
 171   if xmllint.found()
 172     tmpsample_xml = custom_target('tmpsample.xml',
 173       output : 'tmpsample.xml',
 174       command : [ gtester, '-k', '--quiet', '-o', '@OUTPUT@',
 175                   '--test-arg=--gtester-selftest', gtester])
 176
 177     test('gtester-xmllint-check', xmllint,
 178       args : ['--noout', tmpsample_xml],
 179       env : test_env,
 180       suite : ['glib'],
 181     )
 182   endif
 183 endif