| blob | 233002470c23883fe42aa4b61e37c211e6754233 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [56])
34 m4_define([glib_micro_version], [0])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 AC_ARG_ENABLE(gc_friendly,
252 [AS_HELP_STRING([--enable-gc-friendly],
253 [turn on garbage collector friendliness [default=no]])],,
254 [enable_gc_friendly=no])
255 AC_ARG_ENABLE(mem_pools,
256 [AS_HELP_STRING([--disable-mem-pools],
257 [disable all glib memory pools])],,
258 [disable_mem_pools=no])
260 GLIB_TESTS
262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
264 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
265 AC_MSG_RESULT([yes])
266 ], [ AC_MSG_RESULT([no]) ])
268 AC_MSG_CHECKING([whether to disable memory pools])
269 AS_IF([test "x$disable_mem_pools" = "xno"], [
270 AC_MSG_RESULT([no])
271 ], [
272 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
273 AC_MSG_RESULT([yes])
274 ])
276 dnl location to install runtime libraries, e.g. ../../lib to install
277 dnl to /lib if libdir is /usr/lib
278 AC_ARG_WITH(runtime-libdir,
279 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
280 [install runtime libraries relative to libdir])],
281 [],
282 [with_runtime_libdir=""])
283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
289 AC_LANG_SAVE
290 AC_LANG_CPLUSPLUS
291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
293 AC_LANG_RESTORE
295 AM_PROG_CC_C_O
296 AC_PROG_INSTALL
298 AC_SYS_LARGEFILE
300 PKG_PROG_PKG_CONFIG(0.16)
302 if test "x$enable_debug" = "xyes"; then
303 if test "x$cflags_set" != "x" ; then
304 case " $CFLAGS " in
305 *[[\ \ ]]-g[[\ \ ]]*) ;;
306 *) CFLAGS="$CFLAGS -g" ;;
307 esac
308 fi
309 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
310 else
311 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
313 if test "x$enable_debug" = "xno"; then
314 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
315 fi
316 fi
318 # Ensure MSVC-compatible struct packing convention is used when
319 # compiling for Win32 with gcc.
320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
321 # gcc2 uses "-fnative-struct".
322 if test x"$glib_native_win32" = xyes; then
323 if test x"$GCC" = xyes; then
324 msnative_struct=''
325 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
326 if test -z "$ac_cv_prog_CC"; then
327 our_gcc="$CC"
328 else
329 our_gcc="$ac_cv_prog_CC"
330 fi
331 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
332 2.)
333 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
334 msnative_struct='-fnative-struct'
335 fi
336 ;;
337 *)
338 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
339 msnative_struct='-mms-bitfields'
340 fi
341 ;;
342 esac
343 if test x"$msnative_struct" = x ; then
344 AC_MSG_RESULT([no way])
345 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
346 else
347 CFLAGS="$CFLAGS $msnative_struct"
348 AC_MSG_RESULT([${msnative_struct}])
349 fi
350 fi
351 fi
352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
353 AC_SUBST(GLIB_EXTRA_CFLAGS)
355 AC_EXEEXT
357 AC_PROG_AWK
358 AC_CHECK_PROGS(PERL, [perl5 perl])
360 # option to specify python interpreter to use; this just sets $PYTHON, so that
361 # we will fallback to reading $PYTHON if --with-python is not given, and
362 # python.m4 will get the expected input
363 AC_ARG_WITH(python,
364 AS_HELP_STRING([--with-python=PATH],
365 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
366 [PYTHON="$withval"], [])
367 if test x"$PYTHON" = xyes; then
368 AC_MSG_ERROR([--with-python option requires a path or program argument])
369 fi
370 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
373 dnl ***********************
374 dnl *** Tests for iconv ***
375 dnl ***********************
376 dnl
377 dnl We do this before the gettext checks, to avoid distortion
379 dnl On Windows we use a native implementation
381 AS_IF([ test x"$glib_native_win32" = xyes], [
382 with_libiconv=native
383 ], [
384 AC_ARG_WITH(libiconv,
385 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
386 [use the libiconv library])],,
387 [with_libiconv=maybe])
389 found_iconv=no
390 case $with_libiconv in
391 maybe)
392 # Check in the C library first
393 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
394 # Check if we have GNU libiconv
395 if test $found_iconv = "no"; then
396 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
397 fi
398 # Check if we have a iconv in -liconv, possibly from vendor
399 if test $found_iconv = "no"; then
400 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
401 fi
402 ;;
403 no)
404 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
405 ;;
406 gnu|yes)
407 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
408 ;;
409 native)
410 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
411 ;;
412 esac
414 if test "x$found_iconv" = "xno" ; then
415 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
416 fi
417 ])
419 dnl
420 dnl zlib support
421 dnl
422 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
423 AS_IF([test "x$found_zlib" = "xno"], [
424 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
425 if test "x$found_zlib" = "xno" ; then
426 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
427 fi
428 ZLIB_LIBS='-lz'
429 AC_SUBST(ZLIB_LIBS)
430 ])
432 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
433 AC_SUBST(LIBFFI_CFLAGS)
434 AC_SUBST(LIBFFI_LIBS)
436 dnl
437 dnl gettext support
438 dnl
440 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
441 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
442 GLIB_GNU_GETTEXT
444 if test "$gt_cv_have_gettext" != "yes" ; then
445 AC_MSG_ERROR([
446 *** You must have either have gettext support in your C library, or use the
447 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
448 ])
449 fi
451 LIBS="$INTLLIBS $LIBS"
453 GETTEXT_PACKAGE=glib20
454 AC_SUBST(GETTEXT_PACKAGE)
455 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
456 [Define the gettext package to be used])
458 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
460 dnl
461 dnl Now we are done with gettext checks, figure out ICONV_LIBS
462 dnl
464 AS_IF([test x"$glib_native_win32" != xyes], [
465 if test x$with_libiconv != xno ; then
466 case " $INTLLIBS " in
467 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
468 *) ICONV_LIBS="-liconv" ;;
469 esac
470 fi
471 ])
472 AC_SUBST(ICONV_LIBS)
474 case $with_libiconv in
475 gnu)
476 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
477 ;;
478 native)
479 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
480 ;;
481 esac
483 dnl Initialize libtool
484 LT_PREREQ([2.2])
485 LT_INIT([disable-static win32-dll])
486 dnl when using libtool 2.x create libtool early, because it's used in configure
487 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
490 AS_IF([test "$glib_native_win32" = "yes"], [
491 if test x$enable_static = xyes -a x$enable_shared = xyes; then
492 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
493 fi
494 if test x$enable_static = xyes; then
495 glib_win32_static_compilation=yes
496 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
497 #define GOBJECT_STATIC_COMPILATION 1"
498 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
499 fi
500 ])
501 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
503 # Checks for library functions.
504 AC_FUNC_ALLOCA
505 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
506 AC_CHECK_FUNCS(timegm gmtime_r)
507 AC_FUNC_STRERROR_R()
509 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
510 [AC_TRY_LINK([#include <unistd.h>
511 extern int __libc_enable_secure;],
512 [return __libc_enable_secure;],
513 glib_cv_have_libc_enable_secure=yes,
514 glib_cv_have_libc_enable_secure=no)])
515 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
516 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
517 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
518 ])
520 AC_CHECK_SIZEOF(char)
521 AC_CHECK_SIZEOF(short)
522 AC_CHECK_SIZEOF(long)
523 AC_CHECK_SIZEOF(int)
524 AC_CHECK_SIZEOF(void *)
525 AC_CHECK_SIZEOF(long long)
526 AC_CHECK_SIZEOF(__int64)
528 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
529 [AC_TRY_LINK([#include <signal.h>
530 #include <sys/types.h>
531 sig_atomic_t val = 42;],
532 [return val == 42 ? 0 : 1],
533 ac_cv_type_sig_atomic_t=yes,
534 ac_cv_type_sig_atomic_t=no)])
535 if test x$ac_cv_type_sig_atomic_t = xyes; then
536 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
537 [Define if you have the 'sig_atomic_t' type.])
538 fi
540 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
541 :
542 else
543 AC_MSG_ERROR([
544 *** GLib requires a 64 bit type. You might want to consider
545 *** using the GNU C compiler.
546 ])
547 fi
549 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
550 # long long is a 64 bit integer.
551 AC_MSG_CHECKING(for format to printf and scanf a guint64)
552 AC_CACHE_VAL(glib_cv_long_long_format,[
553 for format in ll q I64; do
554 AC_TRY_RUN([#include <stdio.h>
555 int main()
556 {
557 long long b, a = -0x3AFAFAFAFAFAFAFALL;
558 char buffer[1000];
559 sprintf (buffer, "%${format}u", a);
560 sscanf (buffer, "%${format}u", &b);
561 exit (b!=a);
562 }
563 ],
564 [glib_cv_long_long_format=${format}
565 break],
566 [],[:])
567 done])
568 AS_IF([ test -n "$glib_cv_long_long_format"], [
569 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
570 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
571 if test x"$glib_cv_long_long_format" = xI64; then
572 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
573 fi
574 ], [AC_MSG_RESULT(none)])
575 ],[ test x$ac_cv_sizeof___int64 = x8], [
576 # __int64 is a 64 bit integer.
577 AC_MSG_CHECKING(for format to printf and scanf a guint64)
578 # We know this is MSVCRT.DLL, and what the formats are
579 glib_cv_long_long_format=I64
580 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
581 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
582 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
583 ])
585 AC_C_CONST
587 dnl
588 dnl check in which direction the stack grows
589 dnl
590 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
591 AC_TRY_RUN([
592 volatile int *a = 0, *b = 0;
593 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
594 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
595 ],
596 glib_cv_stack_grows=yes
597 ,
598 glib_cv_stack_grows=no
599 ,)
600 ])
602 # check for flavours of varargs macros
603 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
604 AC_TRY_COMPILE([],[
605 int a(int p1, int p2, int p3);
606 #define call_a(...) a(1,__VA_ARGS__)
607 call_a(2,3);
608 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
609 AC_MSG_RESULT($g_have_iso_c_varargs)
611 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
612 AS_IF([test "$CXX" = ""], [
613 dnl No C++ compiler
614 g_have_iso_cxx_varargs=no
615 else
616 AC_LANG_CPLUSPLUS
617 AC_TRY_COMPILE([],[
618 int a(int p1, int p2, int p3);
619 #define call_a(...) a(1,__VA_ARGS__)
620 call_a(2,3);
621 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
622 AC_LANG_C
623 ])
624 AC_MSG_RESULT($g_have_iso_cxx_varargs)
626 AC_MSG_CHECKING(for GNUC varargs macros)
627 AC_TRY_COMPILE([],[
628 int a(int p1, int p2, int p3);
629 #define call_a(params...) a(1,params)
630 call_a(2,3);
631 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
632 AC_MSG_RESULT($g_have_gnuc_varargs)
634 # check for GNUC visibility support
635 AC_MSG_CHECKING(for GNUC visibility attribute)
636 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
637 void
638 __attribute__ ((visibility ("hidden")))
639 f_hidden (void)
640 {
641 }
642 void
643 __attribute__ ((visibility ("internal")))
644 f_internal (void)
645 {
646 }
647 void
648 __attribute__ ((visibility ("protected")))
649 f_protected (void)
650 {
651 }
652 void
653 __attribute__ ((visibility ("default")))
654 f_default (void)
655 {
656 }
657 int main (void)
658 {
659 f_hidden();
660 f_internal();
661 f_protected();
662 f_default();
663 return 0;
664 }
665 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
666 AC_MSG_RESULT($g_have_gnuc_visibility)
667 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
669 AC_MSG_CHECKING([whether using Sun Studio C compiler])
670 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
671 #else
672 # include "error: this is not Sun Studio."
673 #endif
674 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
675 AC_MSG_RESULT($g_have_sunstudio_visibility)
676 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
678 # check for bytesex stuff
679 AC_C_BIGENDIAN
680 if test x$ac_cv_c_bigendian = xuniversal ; then
681 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
682 fi
685 # check for header files
686 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
687 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
688 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
689 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
690 AC_CHECK_HEADERS([linux/magic.h])
691 AC_CHECK_HEADERS([termios.h])
693 # Some versions of MSC lack these
694 AC_CHECK_HEADERS([dirent.h sys/time.h])
696 # We don't care about this, but we need to keep including it in
697 # glibconfig.h for backward compatibility
698 AC_CHECK_HEADERS([values.h])
700 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
701 [#if HAVE_SYS_PARAM_H
702 #include <sys/param.h>
703 #endif
704 ])
705 AC_CHECK_FUNCS(sysctlbyname)
707 AC_HEADER_MAJOR
708 AC_CHECK_HEADERS([xlocale.h])
710 # check for structure fields
711 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
712 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
713 #include <sys/stat.h>
714 #ifdef G_OS_UNIX
715 #include <unistd.h>
716 #endif
717 #ifdef HAVE_SYS_STATFS_H
718 #include <sys/statfs.h>
719 #endif
720 #ifdef HAVE_SYS_PARAM_H
721 #include <sys/param.h>
722 #endif
723 #ifdef HAVE_SYS_MOUNT_H
724 #include <sys/mount.h>
725 #endif])
726 # struct statvfs.f_basetype is available on Solaris but not for Linux.
727 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
728 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
729 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
731 AC_STRUCT_DIRENT_D_TYPE
733 # Checks for libcharset
734 AM_LANGINFO_CODESET
735 gl_GLIBC21
736 AC_ARG_WITH(charsetalias-dir,
737 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
738 [],
739 [with_charsetalias_dir='${libdir}'])
740 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
741 AC_SUBST(GLIB_CHARSETALIAS_DIR)
743 # check additional type sizes
744 AC_CHECK_SIZEOF(size_t)
746 dnl Try to figure out whether gsize should be long or int
747 AC_MSG_CHECKING([for the appropriate definition for size_t])
749 case $ac_cv_sizeof_size_t in
750 $ac_cv_sizeof_short)
751 glib_size_type=short
752 ;;
753 $ac_cv_sizeof_int)
754 glib_size_type=int
755 ;;
756 $ac_cv_sizeof_long)
757 glib_size_type=long
758 ;;
759 $ac_cv_sizeof_long_long)
760 glib_size_type='long long'
761 ;;
762 $ac_cv_sizeof__int64)
763 glib_size_type='__int64'
764 ;;
765 *) AC_MSG_ERROR([No type matching size_t in size])
766 ;;
767 esac
769 dnl If int/long are the same size, we see which one produces
770 dnl warnings when used in the location as size_t. (This matters
771 dnl on AIX with xlc)
772 dnl
773 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
774 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
775 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
776 #if defined(_AIX) && !defined(__GNUC__)
777 #pragma options langlvl=stdc89
778 #endif
779 #include <stddef.h>
780 int main ()
781 {
782 size_t s = 1;
783 unsigned int *size_int = &s;
784 return (int)*size_int;
785 }
786 ]])],glib_size_type=int,
787 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
788 #if defined(_AIX) && !defined(__GNUC__)
789 #pragma options langlvl=stdc89
790 #endif
791 #include <stddef.h>
792 int main ()
793 {
794 size_t s = 1;
795 unsigned long *size_long = &s;
796 return (int)*size_long;
797 }
798 ]])],glib_size_type=long)])
799 ])
801 AC_MSG_RESULT(unsigned $glib_size_type)
803 AC_CHECK_SIZEOF(ssize_t)
805 dnl Try to figure out whether gssize should be long or int
806 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
808 case $ac_cv_sizeof_ssize_t in
809 $ac_cv_sizeof_short)
810 glib_ssize_type=short
811 ;;
812 $ac_cv_sizeof_int)
813 glib_ssize_type=int
814 ;;
815 $ac_cv_sizeof_long)
816 glib_ssize_type=long
817 ;;
818 $ac_cv_sizeof_long_long)
819 glib_ssize_type='long long'
820 ;;
821 $ac_cv_sizeof__int64)
822 glib_ssize_type='__int64'
823 ;;
824 *) AC_MSG_ERROR([No type matching ssize_t in size])
825 ;;
826 esac
828 dnl If int/long are the same size, we see which one produces
829 dnl warnings when used in the location as ssize_t. (This matters
830 dnl on Android where ssize_t is long and size_t is unsigned int)
831 dnl
832 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
833 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
834 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
835 #if defined(_AIX) && !defined(__GNUC__)
836 #pragma options langlvl=stdc89
837 #endif
838 #include <stddef.h>
839 #ifdef HAVE_INTTYPES_H
840 # include <inttypes.h>
841 #endif
842 #ifdef HAVE_STDINT_H
843 # include <stdint.h>
844 #endif
845 #include <sys/types.h>
846 int main ()
847 {
848 ssize_t s = 1;
849 int *size_int = &s;
850 return (int)*size_int;
851 }
852 ]])],glib_ssize_type=int,
853 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
854 #if defined(_AIX) && !defined(__GNUC__)
855 #pragma options langlvl=stdc89
856 #endif
857 #include <stddef.h>
858 #ifdef HAVE_INTTYPES_H
859 # include <inttypes.h>
860 #endif
861 #ifdef HAVE_STDINT_H
862 # include <stdint.h>
863 #endif
864 #include <sys/types.h>
865 int main ()
866 {
867 ssize_t s = 1;
868 long *size_long = &s;
869 return (int)*size_long;
870 }
871 ]])],glib_ssize_type=long)])
872 ])
874 AC_MSG_RESULT($glib_ssize_type)
876 # Check for some functions
877 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp)
878 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
879 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
880 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
881 AC_CHECK_FUNCS(splice)
882 AC_CHECK_FUNCS(prlimit)
884 # To avoid finding a compatibility unusable statfs, which typically
885 # successfully compiles, but warns to use the newer statvfs interface:
886 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
887 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
889 AC_MSG_CHECKING([whether to use statfs or statvfs])
890 # Some systems have both statfs and statvfs, pick the most "native" for these
891 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
892 [
893 # on solaris and irix, statfs doesn't even have the f_bavail field
894 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
895 [ac_cv_func_statfs=no],
896 # else, at least on linux, statfs is the actual syscall
897 [ac_cv_func_statvfs=no])
898 ])
900 AS_IF([test x$ac_cv_func_statfs = xyes],
901 [
902 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
903 AC_MSG_RESULT([statfs])
904 ],
905 [test x$ac_cv_func_statvfs = xyes],
906 [
907 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
908 AC_MSG_RESULT([statvfs])
909 ],
910 [ AC_MSG_RESULT([neither])])
912 AC_CHECK_HEADERS(crt_externs.h)
913 AC_CHECK_FUNCS(_NSGetEnviron)
915 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
917 # Internet address families
918 if test $glib_native_win32 = yes; then
919 glib_inet_includes=["
920 #include <winsock2.h>
921 "]
922 else
923 glib_inet_includes=["
924 #include <sys/types.h>
925 #include <sys/socket.h>
926 "]
927 fi
929 glib_failed=false
930 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
931 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
932 # winsock defines this even though it doesn't support it
933 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
934 if $glib_failed ; then
935 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
936 fi
938 glib_failed=false
939 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
940 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
941 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
942 if $glib_failed ; then
943 AC_MSG_ERROR([Could not determine values for MSG_* constants])
944 fi
946 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
948 AC_MSG_CHECKING([for SIOCGIFADDR])
949 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
950 [[
951 #include <sys/ioctl.h>
952 #include <net/if.h>
953 ]],
954 [[
955 struct ifreq ifr;
956 ioctl(0, SIOCGIFADDR, &ifr);
957 ]])], [
958 AC_MSG_RESULT(yes)
959 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
960 ], [
961 AC_MSG_RESULT(no)
962 ])
964 AS_IF([test $glib_native_win32 = yes], [
965 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
966 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
967 # they aren't present at run-time (on Windows 2000).
968 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
969 AC_SUBST(WSPIAPI_INCLUDE)
970 ], [
971 # Android does not have C_IN in public headers, we define it wherever necessary
972 AS_IF([test $glib_native_android != yes], [
973 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
974 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
975 #include <arpa/nameser.h>],
976 [int qclass = C_IN;])],
977 [AC_MSG_RESULT([no])],
978 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
979 #include <arpa/nameser.h>
980 #include <arpa/nameser_compat.h>],
981 [int qclass = C_IN;])],
982 [AC_MSG_RESULT([yes])
983 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
984 [AC_MSG_ERROR([could not compile test program either way])])])])
985 AC_SUBST(NAMESER_COMPAT_INCLUDE)
987 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
988 NETWORK_LIBS=""
989 AC_MSG_CHECKING([for res_query])
990 AC_TRY_LINK([#include <sys/types.h>
991 #include <netinet/in.h>
992 #include <arpa/nameser.h>
993 #include <resolv.h>
994 ],[
995 res_query("test", 0, 0, (void *)0, 0);
996 ],[AC_MSG_RESULT([yes])],
997 [save_libs="$LIBS"
998 LIBS="-lresolv $LIBS"
999 AC_TRY_LINK([#include <sys/types.h>
1000 #include <netinet/in.h>
1001 #include <arpa/nameser.h>
1002 #include <resolv.h>
1003 ],[
1004 res_query("test", 0, 0, (void *)0, 0);
1005 ],[AC_MSG_RESULT([in -lresolv])
1006 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1007 [LIBS="-lbind $save_libs"
1008 AC_TRY_LINK([#include <resolv.h>],
1009 [res_query("test", 0, 0, (void *)0, 0);],
1010 [AC_MSG_RESULT([in -lbind])
1011 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1012 [AC_MSG_ERROR(not found)])])
1013 LIBS="$save_libs"])
1014 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1015 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1016 [AC_MSG_ERROR(Could not find socket())]))
1017 save_libs="$LIBS"
1018 LIBS="$LIBS $NETWORK_LIBS"
1020 AC_MSG_CHECKING([for res_init])
1021 AC_TRY_LINK([#include <sys/types.h>
1022 #include <netinet/in.h>
1023 #include <arpa/nameser.h>
1024 #include <resolv.h>
1025 ],[
1026 res_init();
1027 ],[AC_MSG_RESULT([yes])
1028 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1029 ],[AC_MSG_RESULT([no])])
1031 AC_MSG_CHECKING([for res_nclose])
1032 AC_TRY_LINK([#include <sys/types.h>
1033 #include <netinet/in.h>
1034 #include <arpa/nameser.h>
1035 #include <resolv.h>
1036 ],[
1037 struct __res_state res;
1038 res_nclose(&res);
1039 ],[AC_MSG_RESULT([yes])
1040 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1041 ],[AC_MSG_RESULT([no])])
1043 AC_MSG_CHECKING([for res_ndestroy])
1044 AC_TRY_LINK([#include <sys/types.h>
1045 #include <netinet/in.h>
1046 #include <arpa/nameser.h>
1047 #include <resolv.h>
1048 ],[
1049 struct __res_state res;
1050 res_ndestroy(&res);
1051 ],[AC_MSG_RESULT([yes])
1052 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1053 ],[AC_MSG_RESULT([no])])
1055 AC_MSG_CHECKING([for res_ninit])
1056 AC_TRY_LINK([#include <sys/types.h>
1057 #include <netinet/in.h>
1058 #include <arpa/nameser.h>
1059 #include <resolv.h>
1060 ],[
1061 struct __res_state res;
1062 res_ninit(&res);
1063 ],[AC_MSG_RESULT([yes])
1064 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1065 ],[AC_MSG_RESULT([no])])
1067 AC_MSG_CHECKING([for res_nquery])
1068 AC_TRY_LINK([#include <sys/types.h>
1069 #include <netinet/in.h>
1070 #include <arpa/nameser.h>
1071 #include <resolv.h>
1072 ],[
1073 struct __res_state res;
1074 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1075 ],[AC_MSG_RESULT([yes])
1076 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1077 ],[AC_MSG_RESULT([no])])
1078 LIBS="$save_libs"
1079 ])
1080 AC_SUBST(NETWORK_LIBS)
1082 AC_CHECK_HEADER([linux/netlink.h],
1083 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1084 [#include <sys/socket.h>])
1085 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1087 AC_CHECK_TYPE([struct ip_mreqn], [
1088 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1089 [#include <netinet/in.h>])
1091 case $host in
1092 *-*-solaris* )
1093 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1094 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1095 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1096 ;;
1097 esac
1099 dnl
1100 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1101 dnl
1102 AS_IF([test "$ac_cv_func_statfs" = yes], [
1103 AC_MSG_CHECKING([number of arguments to statfs()])
1104 AC_TRY_COMPILE([#include <unistd.h>
1105 #ifdef HAVE_SYS_PARAM_H
1106 #include <sys/param.h>
1107 #endif
1108 #ifdef HAVE_SYS_VFS_H
1109 #include <sys/vfs.h>
1110 #endif
1111 #ifdef HAVE_SYS_MOUNT_H
1112 #include <sys/mount.h>
1113 #endif
1114 #ifdef HAVE_SYS_STATFS_H
1115 #include <sys/statfs.h>
1116 #endif], [struct statfs st;
1117 statfs("/", &st);],[
1118 AC_MSG_RESULT([2])
1119 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1120 AC_TRY_COMPILE([#include <unistd.h>
1121 #ifdef HAVE_SYS_PARAM_H
1122 #include <sys/param.h>
1123 #endif
1124 #ifdef HAVE_SYS_VFS_H
1125 #include <sys/vfs.h>
1126 #endif
1127 #ifdef HAVE_SYS_MOUNT_H
1128 #include <sys/mount.h>
1129 #endif
1130 #ifdef HAVE_SYS_STATFS_H
1131 #include <sys/statfs.h>
1132 #endif], [struct statfs st;
1133 statfs("/", &st, sizeof (st), 0);],[
1134 AC_MSG_RESULT([4])
1135 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1136 AC_MSG_RESULT(unknown)
1137 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1138 ])
1140 dnl
1141 dnl open takes O_DIRECTORY as an option
1142 dnl
1143 AC_MSG_CHECKING([open() option O_DIRECTORY])
1144 AC_TRY_COMPILE([#include <fcntl.h>
1145 #include <sys/types.h>
1146 #include <sys/stat.h>],
1147 [open(0, O_DIRECTORY, 0);],[
1148 AC_MSG_RESULT([yes])
1149 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1150 AC_MSG_RESULT([no])])
1152 #
1153 # Check whether to use an included printf
1154 #
1155 AC_FUNC_VSNPRINTF_C99
1156 AC_FUNC_PRINTF_UNIX98
1158 AC_ARG_ENABLE(included-printf,
1159 [AS_HELP_STRING([--enable-included-printf],
1160 [use included printf [default=auto]])],
1161 enable_included_printf="$enableval")
1163 need_included_printf=no
1164 if test "x$enable_included_printf" = "xyes" ; then
1165 need_included_printf=yes
1166 fi
1167 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1168 need_included_printf=yes
1169 fi
1170 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1171 need_included_printf=yes
1172 fi
1173 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1174 test -z "$glib_cv_long_long_format" ; then
1175 need_included_printf=yes
1176 fi
1178 if test "x$enable_included_printf" = "xno" &&
1179 test "x$need_included_printf" = "xyes" ; then
1180 AC_MSG_ERROR([
1181 *** Your C library's printf doesn't appear to have the features that
1182 *** GLib needs, but you specified --enable-included-printf=no.])
1183 fi
1185 enable_included_printf=$need_included_printf
1187 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1188 AS_IF([test "$enable_included_printf" != "yes"], [
1189 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1190 ], [
1191 if test -z "$glib_cv_long_long_format" ; then
1192 glib_cv_long_long_format="ll"
1193 fi
1194 AC_DEFINE(HAVE_VASPRINTF,1)
1195 ])
1197 # Checks needed for gnulib vasnprintf
1198 bh_C_SIGNED
1199 jm_AC_TYPE_LONG_LONG
1200 gt_TYPE_LONGDOUBLE
1201 gt_TYPE_WCHAR_T
1202 gt_TYPE_WINT_T
1203 AC_TYPE_SIZE_T
1204 AC_CHECK_TYPES(ptrdiff_t)
1205 jm_AC_TYPE_INTMAX_T
1206 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1207 AC_FUNC_SNPRINTF_C99
1209 # Check if <sys/select.h> needs to be included for fd_set
1210 AC_MSG_CHECKING([for fd_set])
1211 AC_TRY_COMPILE([#include <sys/types.h>],
1212 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1213 AS_IF([test "$gtk_ok" = "yes"], [
1214 AC_MSG_RESULT([yes, found in sys/types.h])
1215 ], [
1216 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1217 if test "$gtk_ok" = "yes"; then
1218 # *** FIXME: give it a different name
1219 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1220 AC_MSG_RESULT([yes, found in sys/select.h])
1221 else
1222 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1223 AC_MSG_RESULT(no)
1224 fi
1225 ])
1227 dnl Check for nl_langinfo and CODESET
1228 AC_LANG_SAVE
1229 AC_LANG_C
1230 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1231 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1232 [char *codeset = nl_langinfo (CODESET);])],
1233 [glib_cv_langinfo_codeset=yes],
1234 [glib_cv_langinfo_codeset=no])])
1235 if test x$glib_cv_langinfo_codeset = xyes; then
1236 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1237 fi
1239 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1240 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1241 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1242 [char *str;
1243 str = nl_langinfo (PM_STR);
1244 str = nl_langinfo (D_T_FMT);
1245 str = nl_langinfo (D_FMT);
1246 str = nl_langinfo (T_FMT);
1247 str = nl_langinfo (T_FMT_AMPM);
1248 str = nl_langinfo (MON_1);
1249 str = nl_langinfo (ABMON_12);
1250 str = nl_langinfo (DAY_1);
1251 str = nl_langinfo (ABDAY_7);])],
1252 [glib_cv_langinfo_time=yes],
1253 [glib_cv_langinfo_time=no])])
1254 if test x$glib_cv_langinfo_time = xyes; then
1255 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1256 fi
1258 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1259 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1260 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1261 [char *str;
1262 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1263 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1264 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1265 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1266 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1267 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1268 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1269 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1270 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1271 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1272 [glib_cv_langinfo_outdigit=yes],
1273 [glib_cv_langinfo_outdigit=no])])
1274 if test x$glib_cv_langinfo_outdigit = xyes; then
1275 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1276 fi
1278 dnl Check for nl_langinfo and ALTMON_n
1279 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1280 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1281 [char *str;
1282 str = nl_langinfo (ALTMON_1);
1283 str = nl_langinfo (ALTMON_2);
1284 str = nl_langinfo (ALTMON_3);
1285 str = nl_langinfo (ALTMON_4);
1286 str = nl_langinfo (ALTMON_5);
1287 str = nl_langinfo (ALTMON_6);
1288 str = nl_langinfo (ALTMON_7);
1289 str = nl_langinfo (ALTMON_8);
1290 str = nl_langinfo (ALTMON_9);
1291 str = nl_langinfo (ALTMON_10);
1292 str = nl_langinfo (ALTMON_11);
1293 str = nl_langinfo (ALTMON_12);])],
1294 [glib_cv_langinfo_altmon=yes],
1295 [glib_cv_langinfo_altmon=no])])
1296 if test x$glib_cv_langinfo_altmon = xyes; then
1297 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1298 fi
1300 dnl Check for nl_langinfo and _NL_ABALTMON_n
1301 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1302 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1303 [char *str;
1304 str = nl_langinfo (_NL_ABALTMON_1);
1305 str = nl_langinfo (_NL_ABALTMON_2);
1306 str = nl_langinfo (_NL_ABALTMON_3);
1307 str = nl_langinfo (_NL_ABALTMON_4);
1308 str = nl_langinfo (_NL_ABALTMON_5);
1309 str = nl_langinfo (_NL_ABALTMON_6);
1310 str = nl_langinfo (_NL_ABALTMON_7);
1311 str = nl_langinfo (_NL_ABALTMON_8);
1312 str = nl_langinfo (_NL_ABALTMON_9);
1313 str = nl_langinfo (_NL_ABALTMON_10);
1314 str = nl_langinfo (_NL_ABALTMON_11);
1315 str = nl_langinfo (_NL_ABALTMON_12);])],
1316 [glib_cv_langinfo_abaltmon=yes],
1317 [glib_cv_langinfo_abaltmon=no])])
1318 if test x$glib_cv_langinfo_abaltmon = xyes; then
1319 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1320 fi
1321 AC_LANG_RESTORE
1323 dnl ****************************************
1324 dnl *** posix_memalign ***
1325 dnl ****************************************
1326 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1327 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1328 glib_cv_compliant_posix_memalign=0
1329 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1330 AC_TRY_RUN([
1331 #define _XOPEN_SOURCE 600
1332 #include <stdlib.h> /* posix_memalign() should be defined here */
1333 /* some systems break if #include <malloc.h> used */
1334 static void test_memalign (size_t boundary, size_t size) {
1335 void *mem = 0;
1336 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1337 exit (1);
1338 else
1339 free (mem);
1340 }
1341 int main() {
1342 test_memalign ( 128, 128 - 2 * sizeof (void*));
1343 test_memalign ( 256, 256 - 2 * sizeof (void*));
1344 test_memalign ( 512, 512 - 2 * sizeof (void*));
1345 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1346 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1347 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1348 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1349 test_memalign (16384, 16384 - 2 * sizeof (void*));
1350 test_memalign (32768, 32768 - 2 * sizeof (void*));
1351 exit (0); /* success */
1352 }
1353 ],
1354 [glib_cv_compliant_posix_memalign=1], [], [:])
1355 :
1356 fi
1357 ])
1358 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1359 AC_MSG_RESULT(yes)
1360 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1361 ], [
1362 AC_MSG_RESULT(no)
1363 ])
1366 dnl ****************************************
1367 dnl *** strlcpy/strlcat ***
1368 dnl ****************************************
1369 # Check for strlcpy
1370 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1371 AC_TRY_RUN([#include <stdlib.h>
1372 #include <string.h>
1373 int main() {
1374 char p[10];
1375 (void) strlcpy (p, "hi", 10);
1376 if (strlcat (p, "bye", 0) != 3)
1377 return 1;
1378 return 0;
1379 }], glib_cv_have_strlcpy=yes,
1380 glib_cv_have_strlcpy=no,
1381 glib_cv_have_strlcpy=no)])
1382 if test "$glib_cv_have_strlcpy" = "yes"; then
1383 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1384 fi
1387 dnl **********************
1388 dnl *** va_copy checks ***
1389 dnl **********************
1390 dnl we currently check for all three va_copy possibilities, so we get
1391 dnl all results in config.log for bug reports.
1392 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1393 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1394 #include <stdlib.h>
1395 void f (int i, ...) {
1396 va_list args1, args2;
1397 va_start (args1, i);
1398 va_copy (args2, args1);
1399 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1400 exit (1);
1401 va_end (args1); va_end (args2);
1402 }
1403 int main() {
1404 f (0, 42);
1405 return 0;
1406 }]])],
1407 [glib_cv_va_copy=yes],
1408 [glib_cv_va_copy=no])
1409 ])
1410 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1411 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1412 #include <stdlib.h>
1413 void f (int i, ...) {
1414 va_list args1, args2;
1415 va_start (args1, i);
1416 __va_copy (args2, args1);
1417 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1418 exit (1);
1419 va_end (args1); va_end (args2);
1420 }
1421 int main() {
1422 f (0, 42);
1423 return 0;
1424 }]])],
1425 [glib_cv___va_copy=yes],
1426 [glib_cv___va_copy=no])
1427 ])
1429 if test "x$glib_cv_va_copy" = "xyes"; then
1430 g_va_copy_func=va_copy
1431 else if test "x$glib_cv___va_copy" = "xyes"; then
1432 g_va_copy_func=__va_copy
1433 fi
1434 fi
1436 if test -n "$g_va_copy_func"; then
1437 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1438 fi
1440 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1441 AC_TRY_RUN([#include <stdarg.h>
1442 #include <stdlib.h>
1443 void f (int i, ...) {
1444 va_list args1, args2;
1445 va_start (args1, i);
1446 args2 = args1;
1447 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1448 exit (1);
1449 va_end (args1); va_end (args2);
1450 }
1451 int main() {
1452 f (0, 42);
1453 return 0;
1454 }],
1455 [glib_cv_va_val_copy=yes],
1456 [glib_cv_va_val_copy=no],
1457 [glib_cv_va_val_copy=yes])
1458 ])
1460 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1461 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1462 ])
1464 dnl ***********************
1465 dnl *** g_module checks ***
1466 dnl ***********************
1467 G_MODULE_LIBS=
1468 G_MODULE_LIBS_EXTRA=
1469 G_MODULE_PLUGIN_LIBS=
1470 if test x"$glib_native_win32" = xyes; then
1471 dnl No use for this on Win32
1472 G_MODULE_LDFLAGS=
1473 else
1474 export SED
1475 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1476 fi
1477 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1478 G_MODULE_NEED_USCORE=0
1479 G_MODULE_BROKEN_RTLD_GLOBAL=0
1480 G_MODULE_HAVE_DLERROR=0
1481 dnl *** force native WIN32 shared lib loader
1482 if test -z "$G_MODULE_IMPL"; then
1483 case "$host" in
1484 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1485 esac
1486 fi
1487 dnl *** force native AIX library loader
1488 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1489 if test -z "$G_MODULE_IMPL"; then
1490 case "$host" in
1491 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1492 esac
1493 fi
1494 dnl *** dlopen() and dlsym() in system libraries
1495 AS_IF([ test -z "$G_MODULE_IMPL"], [
1496 AC_CHECK_FUNC(dlopen,
1497 [AC_CHECK_FUNC(dlsym,
1498 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1499 [])
1500 ])
1501 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1502 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1503 AC_CHECK_FUNC(NSLinkModule,
1504 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1505 G_MODULE_NEED_USCORE=1],
1506 [])
1507 ])
1508 dnl *** dlopen() and dlsym() in libdl
1509 AS_IF([ test -z "$G_MODULE_IMPL"], [
1510 AC_CHECK_LIB(dl, dlopen,
1511 [AC_CHECK_LIB(dl, dlsym,
1512 [G_MODULE_LIBS=-ldl
1513 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1514 [])
1515 ])
1516 dnl *** additional checks for G_MODULE_IMPL_DL
1517 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1518 LIBS_orig="$LIBS"
1519 LDFLAGS_orig="$LDFLAGS"
1520 LIBS="$G_MODULE_LIBS $LIBS"
1521 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1522 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1523 echo "void glib_plugin_test(void) { }" > plugin.c
1524 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1525 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1526 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1527 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1528 -shrext ".o" -avoid-version plugin.lo \
1529 -rpath /dont/care >/dev/null 2>&1
1530 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1531 glib_cv_rtldglobal_broken,[
1532 AC_TRY_RUN([
1533 #include <dlfcn.h>
1534 #ifndef RTLD_GLOBAL
1535 # define RTLD_GLOBAL 0
1536 #endif
1537 #ifndef RTLD_LAZY
1538 # define RTLD_LAZY 0
1539 #endif
1540 int glib_plugin_test;
1541 int main () {
1542 void *handle, *global, *local;
1543 global = &glib_plugin_test;
1544 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1545 if (!handle) return 0;
1546 local = dlsym (handle, "glib_plugin_test");
1547 return global == local;
1548 } ],
1549 [glib_cv_rtldglobal_broken=no],
1550 [glib_cv_rtldglobal_broken=yes],
1551 [glib_cv_rtldglobal_broken=no])
1552 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1553 rmdir ${objdir} 2>/dev/null
1554 ])
1555 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1556 G_MODULE_BROKEN_RTLD_GLOBAL=1
1557 else
1558 G_MODULE_BROKEN_RTLD_GLOBAL=0
1559 fi
1560 dnl *** check whether we need preceeding underscores
1561 AC_CACHE_CHECK([for preceeding underscore in symbols],
1562 glib_cv_uscore,[
1563 AC_TRY_RUN([#include <dlfcn.h>
1564 int glib_underscore_test (void) { return 42; }
1565 int main() {
1566 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1567 handle = dlopen ((void*)0, 0);
1568 if (handle) {
1569 f1 = dlsym (handle, "glib_underscore_test");
1570 f2 = dlsym (handle, "_glib_underscore_test");
1571 } return (!f2 || f1);
1572 }],
1573 [glib_cv_uscore=yes],
1574 [glib_cv_uscore=no],
1575 [])
1576 rm -f plugin.c plugin.$ac_objext plugin.lo
1577 ])
1578 GLIB_ASSERT_SET(glib_cv_uscore)
1579 if test "x$glib_cv_uscore" = "xyes"; then
1580 G_MODULE_NEED_USCORE=1
1581 else
1582 G_MODULE_NEED_USCORE=0
1583 fi
1585 AC_CHECK_DECL([RTLD_LAZY],
1586 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1587 [], [[#include <dlfcn.h>]])
1588 AC_CHECK_DECL([RTLD_NOW],
1589 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1590 [], [[#include <dlfcn.h>]])
1591 AC_CHECK_DECL([RTLD_GLOBAL],
1592 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1593 [], [[#include <dlfcn.h>]])
1595 LDFLAGS="$LDFLAGS_orig"
1596 dnl *** check for having dlerror()
1597 AC_CHECK_FUNC(dlerror,
1598 [G_MODULE_HAVE_DLERROR=1],
1599 [G_MODULE_HAVE_DLERROR=0])
1600 LIBS="$LIBS_orig"
1601 ])
1602 dnl *** done, have we got an implementation?
1603 if test -z "$G_MODULE_IMPL"; then
1604 G_MODULE_IMPL=0
1605 G_MODULE_SUPPORTED=false
1606 else
1607 G_MODULE_SUPPORTED=true
1608 fi
1610 AC_MSG_CHECKING(for the suffix of module shared libraries)
1611 export SED
1612 module=yes eval std_shrext=$shrext_cmds
1613 # chop the initial dot
1614 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1615 AC_MSG_RESULT(.$glib_gmodule_suffix)
1616 # any reason it may fail?
1617 if test "x$glib_gmodule_suffix" = x; then
1618 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1619 fi
1621 AC_SUBST(G_MODULE_SUPPORTED)
1622 AC_SUBST(G_MODULE_IMPL)
1623 AC_SUBST(G_MODULE_LIBS)
1624 AC_SUBST(G_MODULE_LIBS_EXTRA)
1625 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1626 AC_SUBST(G_MODULE_LDFLAGS)
1627 AC_SUBST(G_MODULE_HAVE_DLERROR)
1628 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1629 AC_SUBST(G_MODULE_NEED_USCORE)
1630 AC_SUBST(GLIB_DEBUG_FLAGS)
1632 dnl **********************
1633 dnl *** g_spawn checks ***
1634 dnl **********************
1636 AC_MSG_CHECKING(for gspawn implementation)
1637 case "$host" in
1638 *-*-mingw*)
1639 GSPAWN=gspawn-win32.lo
1640 ;;
1641 *)
1642 GSPAWN=gspawn.lo
1643 ;;
1644 esac
1645 AC_MSG_RESULT($GSPAWN)
1646 AC_SUBST(GSPAWN)
1648 dnl *************************
1649 dnl *** GIOChannel checks ***
1650 dnl *************************
1652 AC_MSG_CHECKING(for GIOChannel implementation)
1653 case "$host" in
1654 *-*-mingw*)
1655 GIO=giowin32.lo
1656 ;;
1657 *)
1658 GIO=giounix.lo
1659 ;;
1660 esac
1661 AC_MSG_RESULT($GIO)
1662 AC_SUBST(GIO)
1664 dnl *********************************
1665 dnl *** Directory for GIO modules ***
1666 dnl *********************************
1668 AC_ARG_WITH(gio-module-dir,
1669 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1670 [load gio modules from this directory [LIBDIR/gio/modules]])],
1671 [],
1672 [with_gio_module_dir='${libdir}/gio/modules'])
1673 GIO_MODULE_DIR=$with_gio_module_dir
1674 AC_SUBST(GIO_MODULE_DIR)
1676 dnl **********************************
1677 dnl *** Check for libselinux (GIO) ***
1678 dnl **********************************
1679 AC_ARG_ENABLE(selinux,
1680 AS_HELP_STRING([--disable-selinux],
1681 [build without selinux support]))
1682 msg_selinux=no
1683 SELINUX_LIBS=
1684 AS_IF([ test "x$enable_selinux" != "xno"], [
1686 AC_CHECK_LIB(selinux, is_selinux_enabled,
1687 [AC_CHECK_HEADERS(selinux/selinux.h,
1688 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1689 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1690 SELINUX_LIBS="-lselinux"
1691 msg_selinux=yes])
1692 ])
1693 ])
1694 ])
1695 AC_SUBST(SELINUX_LIBS)
1697 dnl *****************************
1698 dnl ** Check for inotify (GIO) **
1699 dnl *****************************
1700 inotify_support=no
1701 AC_CHECK_HEADERS([sys/inotify.h],
1702 [
1703 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1704 ])
1706 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1708 dnl ****************************
1709 dnl ** Check for kqueue (GIO) **
1710 dnl ****************************
1711 kqueue_support=no
1712 AC_CHECK_HEADERS([sys/event.h],
1713 [
1714 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1715 ])
1717 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1719 dnl ****************************
1720 dnl *** Checks for FAM (GIO) ***
1721 dnl ****************************
1723 should_disable_fam=no
1725 AC_ARG_ENABLE(fam,
1726 AS_HELP_STRING([--disable-fam],
1727 [don't use fam for file system monitoring]),
1728 [
1729 if test "x$enable_fam" = "xno"; then
1730 should_disable_fam=yes
1731 fi
1732 ]
1733 )
1734 fam_support=no
1735 FAM_LIBS=
1736 if test "x$should_disable_fam" = "xno"; then
1737 AC_CHECK_LIB(fam, FAMOpen,
1738 [AC_CHECK_HEADERS(fam.h,
1739 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1740 AC_CHECK_LIB(fam, FAMNoExists,
1741 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1742 FAM_LIBS="-lfam"]
1743 fam_support=yes,
1744 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1745 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1746 AC_SUBST(FAM_LIBS)
1747 fi
1748 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1751 dnl *****************************
1752 dnl *** Check for xattr (GIO) ***
1753 dnl *****************************
1754 AC_ARG_ENABLE(xattr,
1755 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1756 msg_xattr=no
1757 XATTR_LIBS=
1758 AS_IF([ test "x$enable_xattr" != "xno"], [
1760 dnl either glibc or libattr can provide xattr support
1762 dnl for both of them, we check for getxattr being in
1763 dnl the library and a valid xattr header.
1765 dnl try glibc
1766 AC_CHECK_LIB(c, getxattr,
1767 [AC_CHECK_HEADERS(sys/xattr.h,
1768 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1769 msg_xattr=yes])
1770 ])
1772 AS_IF([ test "x$msg_xattr" != "xyes"], [
1773 dnl failure. try libattr
1774 AC_CHECK_LIB(attr, getxattr,
1775 [AC_CHECK_HEADERS(attr/xattr.h,
1776 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1777 XATTR_LIBS="-lattr"
1778 msg_xattr=yes])
1779 ])
1780 ])
1782 AS_IF([ test "x$msg_xattr" = "xyes"], [
1783 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1784 AC_TRY_COMPILE([
1785 #include <stdio.h>
1786 #ifdef HAVE_SYS_TYPES_H
1787 #include <sys/types.h>
1788 #endif
1789 #ifdef HAVE_SYS_XATTR_H
1790 #include <sys/xattr.h>
1791 #elif HAVE_ATTR_XATTR_H
1792 #include <attr/xattr.h>
1793 #endif
1794 ],
1795 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1796 [
1797 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1798 AC_MSG_RESULT([yes])
1799 ],
1800 [AC_MSG_RESULT([no])]
1801 )
1802 ])
1803 ])
1804 AC_SUBST(XATTR_LIBS)
1806 dnl ************************
1807 dnl *** check for libelf ***
1808 dnl ************************
1809 AC_ARG_ENABLE(libelf,
1810 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1811 AS_IF([ test "x$enable_libelf" != "xno"],[
1812 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1813 AS_IF([ test $have_libelf = maybe ], [
1814 glib_save_LIBS=$LIBS
1815 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1816 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1817 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1818 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1819 LIBS=$glib_save_LIBS
1821 if test $have_libelf != no; then
1822 LIBELF_LIBS=-lelf
1823 have_libelf=yes
1824 fi
1825 ])
1826 ])
1828 if test x$have_libelf = xyes; then
1829 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1830 fi
1832 dnl ************************
1833 dnl *** check for libmount ***
1834 dnl ************************
1836 dnl The fallback code doesn't really implement the same behaviors - e.g.
1837 dnl so on linux we want to require libmount unless specifically disabled
1838 dnl
1839 enable_libmount_default=${glib_os_linux:-no}
1840 AC_ARG_ENABLE(libmount,
1841 [AS_HELP_STRING([--enable-libmount],
1842 [build with libmount support [default for Linux]])],,
1843 [enable_libmount=$enable_libmount_default])
1844 AS_IF([ test "x$enable_libmount" = "xyes"],[
1845 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1846 if test $have_libmount = no ; then
1847 AC_MSG_ERROR([*** Could not find libmount])
1848 fi
1849 ])
1851 if test x$have_libmount = xyes; then
1852 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1853 fi
1854 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1856 dnl ****************************************
1857 dnl *** platform dependent source checks ***
1858 dnl ****************************************
1860 AC_MSG_CHECKING(for platform-dependent source)
1861 case "$host" in
1862 *-*-cygwin*|*-*-mingw*)
1863 PLATFORMDEP=gwin32.lo
1864 ;;
1865 *)
1866 PLATFORMDEP=
1867 ;;
1868 esac
1869 AC_MSG_RESULT($PLATFORMDEP)
1870 AC_SUBST(PLATFORMDEP)
1872 AC_MSG_CHECKING([whether to compile timeloop])
1873 case "$host" in
1874 *-*-cygwin*|*-*-mingw*|*-*-minix)
1875 enable_timeloop=no
1876 ;;
1877 *)
1878 enable_timeloop=yes
1879 ;;
1880 esac
1881 AC_MSG_RESULT($enable_timeloop)
1882 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1884 AC_MSG_CHECKING([if building for some Win32 platform])
1885 case "$host" in
1886 *-*-mingw*|*-*-cygwin*)
1887 platform_win32=yes
1888 ;;
1889 *)
1890 platform_win32=no
1891 ;;
1892 esac
1893 AC_MSG_RESULT($platform_win32)
1894 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1896 dnl ***********************
1897 dnl *** g_thread checks ***
1898 dnl ***********************
1900 AC_ARG_WITH(threads,
1901 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1902 [specify a thread implementation to use])],
1903 [],
1904 [with_threads=yes])
1906 dnl error and warning message
1907 dnl *************************
1909 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1911 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1912 platform (normally it's "_REENTRANT"). I'll not use any flag on
1913 compilation now, but then your programs might not work.
1914 Please provide information on how it is done on your system."
1916 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1917 "
1919 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1920 provide information on your thread implementation."
1922 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1923 functions will not be MT-safe during their first call because
1924 there is no working 'getpwuid_r' on your system."
1926 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1927 because there is no 'localtime_r' on your system."
1929 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1930 linking threaded applications. As GLib cannot do that
1931 automatically, you will get an linkg error everytime you are
1932 not using the right compiler. In that case you have to relink
1933 with the right compiler. Ususally just '_r' is appended
1934 to the compiler name."
1936 dnl determination of thread implementation
1937 dnl ***************************************
1939 AC_MSG_CHECKING(for thread implementation)
1941 have_threads=no
1942 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1943 AS_IF([ test "x$have_threads" = xno], [
1944 AC_TRY_COMPILE([#include <pthread.h>],
1945 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1946 have_threads=posix)
1947 ])
1948 # Tru64Unix requires -pthread to find pthread.h. See #103020
1949 if test "x$have_threads" = xno; then
1950 glib_save_CPPFLAGS="$CPPFLAGS"
1951 CPPFLAGS="$CPPFLAGS -pthread"
1952 AC_TRY_COMPILE([#include <pthread.h>],
1953 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1954 have_threads=posix)
1955 CPPFLAGS="$glib_save_CPPFLAGS"
1956 fi
1957 ])
1958 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1959 case $host in
1960 *-*-mingw*)
1961 have_threads=win32
1962 ;;
1963 esac
1964 fi
1966 if test "x$have_threads" = xno; then
1967 AC_MSG_RESULT(none available)
1968 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1969 else
1970 AC_MSG_RESULT($have_threads)
1971 fi
1974 dnl determination of G_THREAD_CFLAGS
1975 dnl ********************************
1977 G_THREAD_LIBS=
1978 G_THREAD_LIBS_EXTRA=
1979 G_THREAD_CFLAGS=
1981 dnl
1982 dnl Test program for basic POSIX threads functionality
1983 dnl
1984 m4_define([glib_thread_test],[
1985 #include <pthread.h>
1986 int check_me = 0;
1987 void* func(void* data) {check_me = 42; return &check_me;}
1988 int main()
1989 { pthread_t t;
1990 void *ret;
1991 pthread_create (&t, $1, func, 0);
1992 pthread_join (t, &ret);
1993 return (check_me != 42 || ret != &check_me);
1994 }])
1996 AS_IF([ test x"$have_threads" = xposix], [
1997 # First we test for posix, whether -pthread or -pthreads do the trick as
1998 # both CPPFLAG and LIBS.
1999 # One of them does for most gcc versions and some other platforms/compilers
2000 # too and could be considered as the canonical way to go.
2001 case $host in
2002 *-*-cygwin*|*-*-darwin*)
2003 # skip cygwin and darwin -pthread or -pthreads test
2004 ;;
2005 *-solaris*)
2006 # These compiler/linker flags work with both Sun Studio and gcc
2007 # Sun Studio expands -mt to -D_REENTRANT and -lthread
2008 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2009 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2010 G_THREAD_LIBS="-lpthread -lthread"
2011 ;;
2012 *)
2013 for flag in pthread pthreads mt; do
2014 glib_save_CFLAGS="$CFLAGS"
2015 CFLAGS="$CFLAGS -$flag"
2016 AC_TRY_RUN(glib_thread_test(0),
2017 glib_flag_works=yes,
2018 glib_flag_works=no,
2019 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2020 glib_flag_works=yes,
2021 glib_flag_works=no)])
2022 CFLAGS="$glib_save_CFLAGS"
2023 if test $glib_flag_works = yes ; then
2024 G_THREAD_CFLAGS=-$flag
2025 G_THREAD_LIBS=-$flag
2026 break;
2027 fi
2028 done
2029 ;;
2030 esac
2031 ])
2033 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2035 # The canonical -pthread[s] does not work. Try something different.
2037 case $host in
2038 *-aix*)
2039 if test x"$GCC" = xyes; then
2040 # GCC 3.0 and above needs -pthread.
2041 # Should be coverd by the case above.
2042 # GCC 2.x and below needs -mthreads
2043 G_THREAD_CFLAGS="-mthreads"
2044 G_THREAD_LIBS=$G_THREAD_CFLAGS
2045 else
2046 # We are probably using the aix compiler. Normaly a
2047 # program would have to be compiled with the _r variant
2048 # of the corresponding compiler, but we as GLib cannot
2049 # do that: but the good news is that for compiling the
2050 # only difference is the added -D_THREAD_SAFE compile
2051 # option. This is according to the "C for AIX User's
2052 # Guide".
2053 G_THREAD_CFLAGS="-D_THREAD_SAFE"
2054 fi
2055 ;;
2056 *-sysv5uw7*) # UnixWare 7
2057 # We are not using gcc with -pthread. Catched above.
2058 G_THREAD_CFLAGS="-Kthread"
2059 G_THREAD_LIBS=$G_THREAD_CFLAGS
2060 ;;
2061 *-mingw*)
2062 # No flag needed when using MSVCRT.DLL
2063 G_THREAD_CFLAGS=""
2064 ;;
2065 *)
2066 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2067 ;;
2068 esac
2069 ])
2071 # if we are not finding the localtime_r function, then we probably are
2072 # not using the proper multithread flag
2074 glib_save_CPPFLAGS="$CPPFLAGS"
2075 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2077 # First we test, whether localtime_r is declared in time.h
2078 # directly. Then we test whether a macro localtime_r exists, in
2079 # which case localtime_r in the test program is replaced and thus
2080 # if we still find localtime_r in the output, it is not defined as
2081 # a macro.
2083 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2084 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2085 localtime_r(a,b)],
2086 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2088 CPPFLAGS="$glib_save_CPPFLAGS"
2090 AC_MSG_CHECKING(thread related cflags)
2091 AC_MSG_RESULT($G_THREAD_CFLAGS)
2092 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2094 dnl determination of G_THREAD_LIBS
2095 dnl ******************************
2097 AS_IF([test x$have_threads = xposix], [
2098 glib_save_CPPFLAGS="$CPPFLAGS"
2099 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2100 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2101 case $host in
2102 *-aix*)
2103 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2104 # probably using the aix compiler.
2105 AC_MSG_WARN($AIX_COMPILE_INFO)
2106 ;;
2107 *)
2108 G_THREAD_LIBS=error
2109 glib_save_LIBS="$LIBS"
2110 for thread_lib in "" pthread pthread32 pthreads thread; do
2111 if test x"$thread_lib" = x; then
2112 add_thread_lib=""
2113 IN=""
2114 else
2115 add_thread_lib="-l$thread_lib"
2116 IN=" in -l$thread_lib"
2117 fi
2118 if test x"$have_threads" = xposix; then
2119 defattr=0
2120 else
2121 defattr=pthread_attr_default
2122 fi
2124 LIBS="$add_thread_lib $glib_save_LIBS"
2126 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2127 AC_TRY_RUN(glib_thread_test($defattr),
2128 glib_result=yes,
2129 glib_result=no,
2130 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2131 glib_result=yes,
2132 glib_result=no)])
2133 AC_MSG_RESULT($glib_result)
2135 if test "$glib_result" = "yes" ; then
2136 G_THREAD_LIBS="$add_thread_lib"
2137 break
2138 fi
2139 done
2140 if test "x$G_THREAD_LIBS" = xerror; then
2141 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2142 fi
2143 LIBS="$glib_save_LIBS"
2144 ;;
2145 esac
2146 ])
2148 g_threads_impl="POSIX"
2149 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2150 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2151 CPPFLAGS="$glib_save_CPPFLAGS"
2152 ], [test x$have_threads = xwin32], [
2153 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2154 g_threads_impl="WIN32"
2155 ], [
2156 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2157 g_threads_impl="NONE"
2158 G_THREAD_LIBS=error
2159 ])
2160 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2161 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2162 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2164 if test "x$G_THREAD_LIBS" = xerror; then
2165 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2166 fi
2168 AC_MSG_CHECKING(thread related libraries)
2169 AC_MSG_RESULT($G_THREAD_LIBS)
2171 dnl check for mt safe function variants and some posix functions
2172 dnl ************************************************************
2174 glib_save_LIBS="$LIBS"
2175 # we are not doing the following for now, as this might require glib
2176 # to always be linked with the thread libs on some platforms.
2177 # LIBS="$LIBS $G_THREAD_LIBS"
2178 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2180 LIBS="$G_THREAD_LIBS $LIBS"
2181 AS_IF([ test x"$have_threads" = xposix], [
2182 glib_save_CPPFLAGS="$CPPFLAGS"
2183 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2184 # This is not AC_CHECK_FUNC to also work with function
2185 # name mangling in header files.
2186 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2187 AC_LINK_IFELSE(
2188 [AC_LANG_PROGRAM(
2189 [#include <pthread.h>],
2190 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2191 [AC_MSG_RESULT(yes)
2192 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2193 [Have function pthread_attr_setstacksize])],
2194 [AC_MSG_RESULT(no)])
2195 AC_MSG_CHECKING(for pthread_condattr_setclock)
2196 AC_LINK_IFELSE(
2197 [AC_LANG_PROGRAM(
2198 [#include <pthread.h>],
2199 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2200 [AC_MSG_RESULT(yes)
2201 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2202 [Have function pthread_condattr_setclock])],
2203 [AC_MSG_RESULT(no)])
2204 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2205 AC_LINK_IFELSE(
2206 [AC_LANG_PROGRAM(
2207 [#include <pthread.h>],
2208 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2209 [AC_MSG_RESULT(yes)
2210 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2211 [Have function pthread_cond_timedwait_relative_np])],
2212 [AC_MSG_RESULT(no)])
2213 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2214 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2215 AC_LINK_IFELSE(
2216 [AC_LANG_PROGRAM(
2217 [#include <pthread.h>],
2218 [pthread_setname_np("example")])],
2219 [AC_MSG_RESULT(yes)
2220 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2221 [Have function pthread_setname_np(const char*)])],
2222 [AC_MSG_RESULT(no)])
2223 dnl Sets thread names on Solaris 11.3 & higher
2224 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2225 AC_LINK_IFELSE(
2226 [AC_LANG_PROGRAM(
2227 [#include <pthread.h>],
2228 [pthread_setname_np(pthread_self(), "example")])],
2229 [AC_MSG_RESULT(yes)
2230 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2231 [Have function pthread_setname_np(pthread_t, const char*)])],
2232 [AC_MSG_RESULT(no)])
2233 CPPFLAGS="$glib_save_CPPFLAGS"
2234 ])
2236 LIBS="$glib_save_LIBS"
2238 # now spit out all the warnings.
2239 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2240 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2241 fi
2242 if test "$ac_cv_func_localtime_r" != "yes"; then
2243 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2244 fi
2246 #
2247 # Hack to deal with:
2248 #
2249 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2250 # building shared libraries with linux.
2251 # b) FreeBSD doesn't do this either.
2252 #
2253 case $host in
2254 *android*)
2255 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2256 ;;
2257 *-*-freebsd*|*-*-linux*)
2258 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2259 ;;
2260 *)
2261 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2262 ;;
2263 esac
2265 AC_SUBST(G_THREAD_CFLAGS)
2266 AC_SUBST(G_THREAD_LIBS)
2267 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2268 AC_SUBST(G_THREAD_LIBS_EXTRA)
2270 AC_CHECK_FUNCS(clock_gettime, [], [
2271 AC_CHECK_LIB(rt, clock_gettime, [
2272 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2273 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2274 ])
2275 ])
2278 dnl ************************
2279 dnl *** g_atomic_* tests ***
2280 dnl ************************
2282 dnl We need to decide at configure time if GLib will use real atomic
2283 dnl operations ("lock free") or emulated ones with a mutex. This is
2284 dnl because we must put this information in glibconfig.h so we know if
2285 dnl it is safe or not to inline using compiler intrinsics directly from
2286 dnl the header.
2287 dnl
2288 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2289 dnl user is interested in knowing if they can use the atomic ops across
2290 dnl processes.
2291 dnl
2292 dnl We can currently support the atomic ops natively when building GLib
2293 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2294 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2295 dnl we are using GCC (and not mingw*).
2296 dnl
2297 dnl Note that the atomic ops are only available with GCC on x86 when
2298 dnl using -march=i486 or higher. If we detect that the atomic ops are
2299 dnl not available but would be available given the right flags, we want
2300 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2301 dnl that then to silently fall back on emulated atomic ops just because
2302 dnl the user had the wrong build environment.
2304 dnl We may add other compilers here in the future...
2306 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2307 case $host in
2308 *-*-mingw*)
2309 glib_cv_g_atomic_lock_free=yes
2310 ;;
2311 *)
2312 AC_TRY_LINK([],
2313 [volatile int atomic = 2;\
2314 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2315 [glib_cv_g_atomic_lock_free=yes],
2316 [glib_cv_g_atomic_lock_free=no])
2317 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2318 SAVE_CFLAGS="${CFLAGS}"
2319 CFLAGS="-march=i486"
2320 AC_TRY_LINK([],
2321 [volatile int atomic = 2;\
2322 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2323 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2324 [])
2325 CFLAGS="${SAVE_CFLAGS}"
2326 fi
2327 ;;
2328 esac])
2331 case $host in
2332 *-*-mingw*)
2333 ;;
2334 *)
2335 # Some compilers support atomic operations but do not define
2336 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2337 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2338 AC_TRY_LINK([],
2339 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2340 [],
2341 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2342 fi
2343 ;;
2344 esac
2346 dnl We need a more robust approach here...
2347 case $host_cpu in
2348 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2349 glib_memory_barrier_needed=no
2350 ;;
2351 sparc*|alpha*|powerpc*|ia64)
2352 glib_memory_barrier_needed=yes
2353 ;;
2354 *)
2355 glib_memory_barrier_needed=yes
2356 ;;
2357 esac
2359 dnl ************************
2360 dnl ** Check for futex(2) **
2361 dnl ************************
2362 AC_CACHE_CHECK(for futex(2) system call,
2363 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2364 #include <linux/futex.h>
2365 #include <sys/syscall.h>
2366 #include <unistd.h>
2367 ],[
2368 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2369 ])],glib_cv_futex=yes,glib_cv_futex=no))
2370 if test x"$glib_cv_futex" = xyes; then
2371 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2372 fi
2374 AC_CACHE_CHECK(for eventfd(2) system call,
2375 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2376 #include <sys/eventfd.h>
2377 #include <unistd.h>
2378 ],[
2379 eventfd (0, EFD_CLOEXEC);
2380 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2381 if test x"$glib_cv_eventfd" = x"yes"; then
2382 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2383 fi
2384 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2386 dnl ****************************************
2387 dnl *** GLib POLL* compatibility defines ***
2388 dnl ****************************************
2390 glib_poll_includes=["
2391 #include <sys/types.h>
2392 #include <poll.h>
2393 "]
2395 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2396 test $ac_cv_func_poll = yes ], [
2397 glib_failed=false
2398 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2399 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2400 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2401 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2402 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2403 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2404 if $glib_failed ; then
2405 AC_MSG_ERROR([Could not determine values for POLL* constants])
2406 fi
2407 ], [
2408 glib_cv_value_POLLIN=1
2409 glib_cv_value_POLLOUT=4
2410 glib_cv_value_POLLPRI=2
2411 glib_cv_value_POLLERR=8
2412 glib_cv_value_POLLHUP=16
2413 glib_cv_value_POLLNVAL=32
2414 ])
2416 AC_MSG_CHECKING([for broken poll])
2417 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2418 #include <stdlib.h>
2419 #include <fcntl.h>
2420 #include <poll.h>
2421 int main(void) {
2422 struct pollfd fds[1];
2423 int fd;
2424 fd = open("/dev/null", 1);
2425 fds[0].fd = fd;
2426 fds[0].events = POLLIN;
2427 fds[0].revents = 0;
2428 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2429 exit(1); /* Does not work for devices -- fail */
2430 }
2431 exit(0);
2432 }]])],
2433 [broken_poll=no],
2434 [broken_poll=yes
2435 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2436 [broken_poll="no (cross compiling)"])
2437 AC_MSG_RESULT($broken_poll)
2439 dnl *********************
2440 dnl *** GRegex checks ***
2441 dnl *********************
2443 PCRE_REQUIRED_VERSION=8.13
2445 # Check if we should use the internal or the system-supplied pcre
2446 AC_ARG_WITH(pcre,
2447 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2448 [whether to use system PCRE [default=system]])],
2449 [],
2450 [with_pcre=system])
2452 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2454 AS_IF([ test "x$with_pcre" = xsystem], [
2455 PKG_CHECK_MODULES(PCRE,
2456 libpcre >= $PCRE_REQUIRED_VERSION)
2457 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2458 glib_save_CFLAGS="$CFLAGS"
2459 glib_save_LIBS="$LIBS"
2460 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2461 AC_TRY_RUN([#include <pcre.h>
2462 int main () {
2463 int support;
2464 pcre_config (PCRE_CONFIG_UTF8, &support);
2465 if (!support)
2466 return 1;
2467 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2468 if (!support)
2469 return 1;
2470 return 0;
2471 }],
2472 glib_cv_pcre_has_unicode=yes,
2473 glib_cv_pcre_has_unicode=no,
2474 glib_cv_pcre_has_unicode=yes)
2475 CFLAGS="$glib_save_CFLAGS"
2476 LIBS="$glib_save_LIBS"
2477 ])
2478 if test "$glib_cv_pcre_has_unicode" = "no"; then
2479 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2480 fi
2481 AC_SUBST(PCRE_CFLAGS)
2482 AC_SUBST(PCRE_LIBS)
2483 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2484 PCRE_REQUIRES=libpcre
2485 AC_SUBST(PCRE_REQUIRES)
2486 ], [
2487 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2488 AS_IF([ test x"$GCC" = xyes], [
2489 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2490 save_CFLAGS="$CFLAGS"
2491 CFLAGS="$CFLAGS -Wno-pointer-sign"
2492 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2493 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2494 CFLAGS="$save_CFLAGS"
2495 ])
2496 ])
2497 AC_SUBST(PCRE_WARN_CFLAGS)
2499 dnl **********************
2500 dnl *** Win32 API libs ***
2501 dnl **********************
2503 case $host in
2504 *-*-cygwin*)
2505 G_LIBS_EXTRA="-luser32 -lkernel32"
2506 ;;
2507 *-*-mingw*)
2508 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2509 ;;
2510 *)
2511 G_LIBS_EXTRA=""
2512 ;;
2513 esac
2514 AC_SUBST(G_LIBS_EXTRA)
2516 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2517 dnl since we need it for g_iconv()
2519 AC_MSG_CHECKING([for EILSEQ])
2520 AC_TRY_COMPILE([
2521 #include <errno.h>
2522 ],
2523 [
2524 int error = EILSEQ;
2525 ], have_eilseq=yes, have_eilseq=no);
2526 AC_MSG_RESULT($have_eilseq)
2528 dnl Add a conditional we can use when cross-compiling, so we avoid running
2529 dnl binaries
2530 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2532 dnl **************************
2533 dnl *** Checks for gtk-doc ***
2534 dnl **************************
2535 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2536 # it on it's own line.
2537 m4_ifdef([GTK_DOC_CHECK], [
2538 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2539 ],[
2540 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2541 ])
2543 AC_ARG_ENABLE(man,
2544 [AS_HELP_STRING([--enable-man],
2545 [generate man pages [default=auto]])],,
2546 enable_man=maybe)
2548 AS_IF([test "$enable_man" != no], [
2549 AC_PATH_PROG([XSLTPROC], [xsltproc])
2550 AS_IF([test -z "$XSLTPROC"], [
2551 AS_IF([test "$enable_man" = yes], [
2552 AC_MSG_ERROR([xsltproc is required for --enable-man])
2553 ])
2554 enable_man=no
2555 ])
2556 ])
2558 AS_IF([ test "$enable_man" != no ], [
2559 dnl check for DocBook DTD in the local catalog
2560 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2561 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2562 AS_IF([test "$have_docbook_dtd" != yes], [
2563 AS_IF([test "$enable_man" = yes ], [
2564 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2565 ])
2566 enable_man=no
2567 ])
2568 ])
2570 AS_IF([test "$enable_man" != no], [
2571 dnl check for DocBook XSL stylesheets in the local catalog
2572 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2573 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2574 AS_IF([ test "$have_docbook_style" != yes ], [
2575 AS_IF([ test "$enable_man" = yes ], [
2576 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2577 ])
2578 enable_man=no
2579 ])
2580 ])
2582 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2584 AC_MSG_CHECKING([whether to generate man pages])
2585 AS_IF([ test "$enable_man" != no ], [
2586 AC_MSG_RESULT([yes])
2587 ], [
2588 AC_MSG_RESULT([no])
2589 ])
2591 dnl
2592 dnl Tracing
2593 dnl
2595 AC_ARG_ENABLE([dtrace],
2596 [AS_HELP_STRING([--enable-dtrace],
2597 [include tracing support for dtrace])])
2598 have_dtrace=no
2599 AC_MSG_CHECKING([whether to include dtrace tracing support])
2600 AS_IF([ test "x$enable_dtrace" != xno], [
2601 if test x$glib_have_carbon = xyes; then
2602 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2603 else
2604 AC_MSG_RESULT([yes])
2605 AC_CHECK_PROGS(DTRACE, dtrace)
2606 if test -z "$DTRACE"; then
2607 if test "x$enable_dtrace" = xyes; then
2608 AC_MSG_ERROR([dtrace not found])
2609 fi
2610 else
2611 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2612 [if test "x$enable_dtrace" = xyes; then
2613 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2614 fi])
2615 fi
2616 fi
2617 ], [
2618 AC_MSG_RESULT([no])
2619 ])
2620 if test "x$have_dtrace" = xyes; then
2621 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2622 fi
2623 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2625 AC_MSG_CHECKING([whether to include systemtap tracing support])
2626 AC_ARG_ENABLE([systemtap],
2627 [AS_HELP_STRING([--enable-systemtap],
2628 [include tracing support for systemtap])])
2629 have_systemtap=no
2630 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2631 have_systemtap=yes
2632 fi
2633 AC_MSG_RESULT(${have_systemtap})
2635 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2637 AC_ARG_WITH([tapset-install-dir],
2638 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2639 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2640 [if test "x${withval}" = x; then
2641 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2642 else
2643 ABS_TAPSET_DIR="${withval}"
2644 fi],
2645 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2646 AC_SUBST(ABS_TAPSET_DIR)
2648 dnl ************************************
2649 dnl *** Enable lcov coverage reports ***
2650 dnl ************************************
2652 AC_ARG_ENABLE(coverage,
2653 AS_HELP_STRING([--enable-coverage],
2654 [enable coverage testing with gcov]),
2655 [use_gcov=$enableval], [use_gcov=no])
2657 AS_IF([ test "x$use_gcov" = "xyes"], [
2658 dnl we need gcc:
2659 if test "$GCC" != "yes"; then
2660 AC_MSG_ERROR([GCC is required for --enable-coverage])
2661 fi
2663 dnl Check if ccache is being used
2664 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2665 case `$SHTOOL path $CC` in
2666 *ccache*[)] gcc_ccache=yes;;
2667 *[)] gcc_ccache=no;;
2668 esac
2670 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2671 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2672 fi
2674 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2675 AC_CHECK_PROG(LTP, lcov, lcov)
2676 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2678 AS_IF([ test "$LTP" ], [
2679 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2680 glib_cv_ltp_version=invalid
2681 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2682 for ltp_check_version in $ltp_version_list; do
2683 if test "$ltp_version" = "$ltp_check_version"; then
2684 glib_cv_ltp_version="$ltp_check_version (ok)"
2685 fi
2686 done
2687 ])
2688 ], [
2689 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2690 AC_MSG_ERROR([$ltp_msg])
2691 ])
2693 case $glib_cv_ltp_version in
2694 ""|invalid[)]
2695 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2696 AC_MSG_ERROR([$ltp_msg])
2697 LTP="exit 0;"
2698 ;;
2699 esac
2701 if test -z "$LTP_GENHTML"; then
2702 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2703 fi
2705 dnl Remove all optimization flags from CFLAGS
2706 changequote({,})
2707 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2708 changequote([,])
2710 dnl Add the special gcc flags
2711 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2712 LDFLAGS="$LDFLAGS -lgcov"
2713 ])
2715 dnl *******************************
2716 dnl *** Disable strict aliasing ***
2717 dnl *******************************
2718 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2719 AS_IF([test "${GCC}" = "yes"],[
2720 CFLAGS="$CFLAGS -fno-strict-aliasing"
2721 ])
2723 dnl ******************************
2724 dnl *** output the whole stuff ***
2725 dnl ******************************
2727 dnl this section will only be run if config.status is invoked with no
2728 dnl arguments, or with "glib/glibconfig.h" as an argument.
2729 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2730 [
2731 outfile=glib/glibconfig.h-tmp
2732 cat > $outfile <<\_______EOF
2733 /* glibconfig.h
2734 *
2735 * This is a generated file. Please modify 'configure.ac'
2736 */
2738 #ifndef __GLIBCONFIG_H__
2739 #define __GLIBCONFIG_H__
2741 #include <glib/gmacros.h>
2743 _______EOF
2745 echo '#include <limits.h>' >> $outfile
2746 echo '#include <float.h>' >> $outfile
2747 if test x$glib_values_h = xyes; then
2748 echo '#include <values.h>' >> $outfile
2749 fi
2750 if test "$glib_header_alloca_h" = "yes"; then
2751 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2752 fi
2753 if test x$glib_included_printf != xyes; then
2754 echo "
2755 /* Specifies that GLib's g_print*() functions wrap the
2756 * system printf functions. This is useful to know, for example,
2757 * when using glibc's register_printf_function().
2758 */" >> $outfile
2759 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2760 fi
2762 cat >> $outfile <<_______EOF
2764 G_BEGIN_DECLS
2766 #define G_MINFLOAT FLT_MIN
2767 #define G_MAXFLOAT FLT_MAX
2768 #define G_MINDOUBLE DBL_MIN
2769 #define G_MAXDOUBLE DBL_MAX
2770 #define G_MINSHORT SHRT_MIN
2771 #define G_MAXSHORT SHRT_MAX
2772 #define G_MAXUSHORT USHRT_MAX
2773 #define G_MININT INT_MIN
2774 #define G_MAXINT INT_MAX
2775 #define G_MAXUINT UINT_MAX
2776 #define G_MINLONG LONG_MIN
2777 #define G_MAXLONG LONG_MAX
2778 #define G_MAXULONG ULONG_MAX
2780 _______EOF
2783 ### this should always be true in a modern C/C++ compiler
2784 ### and is statically asserted by glib-init.c
2785 cat >>$outfile <<_______EOF
2786 typedef signed char gint8;
2787 typedef unsigned char guint8;
2788 _______EOF
2791 if test -n "$gint16"; then
2792 cat >>$outfile <<_______EOF
2793 typedef signed $gint16 gint16;
2794 typedef unsigned $gint16 guint16;
2795 #define G_GINT16_MODIFIER $gint16_modifier
2796 #define G_GINT16_FORMAT $gint16_format
2797 #define G_GUINT16_FORMAT $guint16_format
2798 _______EOF
2799 fi
2802 if test -n "$gint32"; then
2803 cat >>$outfile <<_______EOF
2804 typedef signed $gint32 gint32;
2805 typedef unsigned $gint32 guint32;
2806 #define G_GINT32_MODIFIER $gint32_modifier
2807 #define G_GINT32_FORMAT $gint32_format
2808 #define G_GUINT32_FORMAT $guint32_format
2809 _______EOF
2810 fi
2812 cat >>$outfile <<_______EOF
2813 #define G_HAVE_GINT64 1 /* deprecated, always true */
2815 ${glib_extension}typedef signed $gint64 gint64;
2816 ${glib_extension}typedef unsigned $gint64 guint64;
2818 #define G_GINT64_CONSTANT(val) $gint64_constant
2819 #define G_GUINT64_CONSTANT(val) $guint64_constant
2820 _______EOF
2822 if test x$gint64_format != x ; then
2823 cat >>$outfile <<_______EOF
2824 #define G_GINT64_MODIFIER $gint64_modifier
2825 #define G_GINT64_FORMAT $gint64_format
2826 #define G_GUINT64_FORMAT $guint64_format
2827 _______EOF
2828 else
2829 cat >>$outfile <<_______EOF
2830 #undef G_GINT64_MODIFIER
2831 #undef G_GINT64_FORMAT
2832 #undef G_GUINT64_FORMAT
2833 _______EOF
2834 fi
2836 cat >>$outfile <<_______EOF
2838 #define GLIB_SIZEOF_VOID_P $glib_void_p
2839 #define GLIB_SIZEOF_LONG $glib_long
2840 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2841 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2843 _______EOF
2845 cat >>$outfile <<_______EOF
2846 typedef signed $glib_ssize_type_define gssize;
2847 typedef unsigned $glib_size_type_define gsize;
2848 #define G_GSIZE_MODIFIER $gsize_modifier
2849 #define G_GSSIZE_MODIFIER $gssize_modifier
2850 #define G_GSIZE_FORMAT $gsize_format
2851 #define G_GSSIZE_FORMAT $gssize_format
2853 #define G_MAXSIZE G_MAXU$glib_msize_type
2854 #define G_MINSSIZE G_MIN$glib_mssize_type
2855 #define G_MAXSSIZE G_MAX$glib_mssize_type
2857 typedef gint64 goffset;
2858 #define G_MINOFFSET G_MININT64
2859 #define G_MAXOFFSET G_MAXINT64
2861 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2862 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2863 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2865 #define G_POLLFD_FORMAT $g_pollfd_format
2867 _______EOF
2869 if test -z "$glib_unknown_void_p"; then
2870 cat >>$outfile <<_______EOF
2872 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2873 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2875 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2876 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2878 typedef signed $glib_intptr_type_define gintptr;
2879 typedef unsigned $glib_intptr_type_define guintptr;
2881 #define G_GINTPTR_MODIFIER $gintptr_modifier
2882 #define G_GINTPTR_FORMAT $gintptr_format
2883 #define G_GUINTPTR_FORMAT $guintptr_format
2884 _______EOF
2885 else
2886 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2887 fi
2891 cat >>$outfile <<_______EOF
2892 #ifndef G_DISABLE_DEPRECATED
2893 #define g_ATEXIT(proc) (atexit (proc))
2894 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2895 #endif
2896 $glib_defines
2897 $glib_os
2898 $glib_static_compilation
2900 $glib_vacopy
2902 _______EOF
2904 if test x$g_have_iso_c_varargs = xyes ; then
2905 cat >>$outfile <<_______EOF
2906 #ifndef __cplusplus
2907 # define G_HAVE_ISO_VARARGS 1
2908 #endif
2909 _______EOF
2910 fi
2911 if test x$g_have_iso_cxx_varargs = xyes ; then
2912 cat >>$outfile <<_______EOF
2913 #ifdef __cplusplus
2914 # define G_HAVE_ISO_VARARGS 1
2915 #endif
2916 _______EOF
2917 fi
2918 if test x$g_have_gnuc_varargs = xyes ; then
2919 cat >>$outfile <<_______EOF
2921 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2922 * is passed ISO vararg support is turned off, and there is no work
2923 * around to turn it on, so we unconditionally turn it off.
2924 */
2925 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2926 # undef G_HAVE_ISO_VARARGS
2927 #endif
2929 #define G_HAVE_GNUC_VARARGS 1
2930 _______EOF
2931 fi
2933 case x$g_stack_grows in
2934 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2935 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2936 esac
2939 echo >>$outfile
2940 if test x$g_have_eilseq = xno; then
2941 cat >>$outfile <<_______EOF
2942 #ifndef EILSEQ
2943 /* On some pre-C99 systems, EILSEQ is not defined.
2944 * The correspondence between this and the corresponding definition
2945 * in libiconv is essential.
2946 */
2947 # define EILSEQ ENOENT
2948 #endif
2949 _______EOF
2951 fi
2953 if test x$g_have_gnuc_visibility = xyes; then
2954 cat >>$outfile <<_______EOF
2955 #define G_HAVE_GNUC_VISIBILITY 1
2956 _______EOF
2957 fi
2958 cat >>$outfile <<_______EOF
2959 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2960 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2961 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2962 #define G_GNUC_INTERNAL __hidden
2963 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2964 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2965 #else
2966 #define G_GNUC_INTERNAL
2967 #endif
2968 _______EOF
2970 echo >>$outfile
2971 cat >>$outfile <<_______EOF
2972 #define G_THREADS_ENABLED
2973 #define G_THREADS_IMPL_$g_threads_impl_def
2974 _______EOF
2976 if test x"$g_memory_barrier_needed" != xno; then
2977 echo >>$outfile
2978 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2979 fi
2980 if test x"$g_atomic_lock_free" = xyes; then
2981 echo >>$outfile
2982 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2983 fi
2984 echo >>$outfile
2985 g_bit_sizes="16 32 64"
2986 for bits in $g_bit_sizes; do
2987 cat >>$outfile <<_______EOF
2988 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2989 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2990 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2991 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2992 _______EOF
2993 done
2995 cat >>$outfile <<_______EOF
2996 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2997 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2998 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2999 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
3000 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
3001 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
3002 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
3003 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
3004 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
3005 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
3006 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
3007 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
3008 #define G_BYTE_ORDER $g_byte_order
3010 #define GLIB_SYSDEF_POLLIN =$g_pollin
3011 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3012 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3013 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3014 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3015 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3017 #define G_MODULE_SUFFIX "$g_module_suffix"
3019 typedef $g_pid_type GPid;
3020 #define G_PID_FORMAT $g_pid_format
3022 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3023 #define GLIB_SYSDEF_AF_INET $g_af_inet
3024 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3026 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3027 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3028 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3030 #define G_DIR_SEPARATOR '$g_dir_separator'
3031 #define G_DIR_SEPARATOR_S "$g_dir_separator"
3032 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
3033 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
3035 G_END_DECLS
3037 #endif /* __GLIBCONFIG_H__ */
3038 _______EOF
3041 if cmp -s $outfile glib/glibconfig.h; then
3042 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3043 rm -f $outfile
3044 else
3045 mv $outfile glib/glibconfig.h
3046 fi
3047 ],[
3049 # Note that if two cases are the same, case goes with the first one.
3050 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
3051 # on variable expansion in case labels. Look at the generated config.status
3052 # for a hint.
3054 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3055 glib_header_alloca_h="$ac_cv_working_alloca_h"
3056 else
3057 glib_header_alloca_h="$ac_cv_header_alloca_h"
3058 fi
3060 if test x$enable_included_printf = xyes ; then
3061 glib_included_printf=yes
3062 fi
3064 case 2 in
3065 $ac_cv_sizeof_short)
3066 gint16=short
3067 gint16_modifier='"h"'
3068 gint16_format='"hi"'
3069 guint16_format='"hu"'
3070 ;;
3071 $ac_cv_sizeof_int)
3072 gint16=int
3073 gint16_modifier='""'
3074 gint16_format='"i"'
3075 guint16_format='"u"'
3076 ;;
3077 esac
3078 case 4 in
3079 $ac_cv_sizeof_short)
3080 gint32=short
3081 gint32_modifier='"h"'
3082 gint32_format='"hi"'
3083 guint32_format='"hu"'
3084 ;;
3085 $ac_cv_sizeof_int)
3086 gint32=int
3087 gint32_modifier='""'
3088 gint32_format='"i"'
3089 guint32_format='"u"'
3090 ;;
3091 $ac_cv_sizeof_long)
3092 gint32=long
3093 gint32_modifier='"l"'
3094 gint32_format='"li"'
3095 guint32_format='"lu"'
3096 ;;
3097 esac
3098 case 8 in
3099 $ac_cv_sizeof_int)
3100 gint64=int
3101 gint64_modifier='""'
3102 gint64_format='"i"'
3103 guint64_format='"u"'
3104 glib_extension=
3105 gint64_constant='(val)'
3106 guint64_constant='(val)'
3107 ;;
3108 $ac_cv_sizeof_long)
3109 gint64=long
3110 gint64_modifier='"l"'
3111 gint64_format='"li"'
3112 guint64_format='"lu"'
3113 glib_extension=
3114 gint64_constant='(val##L)'
3115 guint64_constant='(val##UL)'
3116 ;;
3117 $ac_cv_sizeof_long_long)
3118 gint64='long long'
3119 if test -n "$glib_cv_long_long_format"; then
3120 gint64_modifier='"'$glib_cv_long_long_format'"'
3121 gint64_format='"'$glib_cv_long_long_format'i"'
3122 guint64_format='"'$glib_cv_long_long_format'u"'
3123 fi
3124 glib_extension='G_GNUC_EXTENSION '
3125 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3126 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3127 ;;
3128 $ac_cv_sizeof___int64)
3129 gint64='__int64'
3130 if test -n "$glib_cv_long_long_format"; then
3131 gint64_modifier='"'$glib_cv_long_long_format'"'
3132 gint64_format='"'$glib_cv_long_long_format'i"'
3133 guint64_format='"'$glib_cv_long_long_format'u"'
3134 fi
3135 glib_extension=
3136 gint64_constant='(val##i64)'
3137 guint64_constant='(val##ui64)'
3138 ;;
3139 esac
3140 glib_size_t=$ac_cv_sizeof_size_t
3141 glib_ssize_t=$ac_cv_sizeof_ssize_t
3142 glib_size_type_define="$glib_size_type"
3143 glib_ssize_type_define="$glib_ssize_type"
3144 glib_void_p=$ac_cv_sizeof_void_p
3145 glib_long=$ac_cv_sizeof_long
3147 case "$glib_size_type" in
3148 short)
3149 gsize_modifier='"h"'
3150 gsize_format='"hu"'
3151 glib_msize_type='SHRT'
3152 ;;
3153 int)
3154 gsize_modifier='""'
3155 gsize_format='"u"'
3156 glib_msize_type='INT'
3157 ;;
3158 long)
3159 gsize_modifier='"l"'
3160 gsize_format='"lu"'
3161 glib_msize_type='LONG'
3162 ;;
3163 "long long"|__int64)
3164 gsize_modifier='"I64"'
3165 gsize_format='"I64u"'
3166 glib_msize_type='INT64'
3167 ;;
3168 esac
3170 case "$glib_ssize_type" in
3171 short)
3172 gssize_modifier='"h"'
3173 gssize_format='"hi"'
3174 glib_mssize_type='SHRT'
3175 ;;
3176 int)
3177 gssize_modifier='""'
3178 gssize_format='"i"'
3179 glib_mssize_type='INT'
3180 ;;
3181 long)
3182 gssize_modifier='"l"'
3183 gssize_format='"li"'
3184 glib_mssize_type='LONG'
3185 ;;
3186 "long long"|__int64)
3187 gssize_modifier='"I64"'
3188 gssize_format='"I64i"'
3189 glib_mssize_type='INT64'
3190 ;;
3191 esac
3193 gintbits=`expr $ac_cv_sizeof_int \* 8`
3194 glongbits=`expr $ac_cv_sizeof_long \* 8`
3195 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3196 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3198 case $ac_cv_sizeof_void_p in
3199 $ac_cv_sizeof_int)
3200 glib_intptr_type_define=int
3201 gintptr_modifier='""'
3202 gintptr_format='"i"'
3203 guintptr_format='"u"'
3204 glib_gpi_cast='(gint)'
3205 glib_gpui_cast='(guint)'
3206 ;;
3207 $ac_cv_sizeof_long)
3208 glib_intptr_type_define=long
3209 gintptr_modifier='"l"'
3210 gintptr_format='"li"'
3211 guintptr_format='"lu"'
3212 glib_gpi_cast='(glong)'
3213 glib_gpui_cast='(gulong)'
3214 ;;
3215 $ac_cv_sizeof_long_long)
3216 glib_intptr_type_define='long long'
3217 gintptr_modifier='"I64"'
3218 gintptr_format='"I64i"'
3219 guintptr_format='"I64u"'
3220 glib_gpi_cast='(gint64)'
3221 glib_gpui_cast='(guint64)'
3222 ;;
3223 $ac_cv_sizeof___int64)
3224 glib_intptr_type_define=__int64
3225 gintptr_modifier='"I64"'
3226 gintptr_format='"I64i"'
3227 guintptr_format='"I64u"'
3228 glib_gpi_cast='(gint64)'
3229 glib_gpui_cast='(guint64)'
3230 ;;
3231 *)
3232 glib_unknown_void_p=yes
3233 ;;
3234 esac
3237 glib_defines="
3238 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3239 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3240 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3241 "
3243 case xyes in
3244 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3245 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3246 *) glib_vacopy=''
3247 esac
3249 if test x$glib_cv_va_val_copy = xno; then
3250 glib_vacopy="\$glib_vacopy
3251 #define G_VA_COPY_AS_ARRAY 1"
3252 fi
3254 g_have_gnuc_varargs=$g_have_gnuc_varargs
3255 g_have_iso_c_varargs=$g_have_iso_c_varargs
3256 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3258 g_have_gnuc_visibility=$g_have_gnuc_visibility
3259 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3261 if test x$ac_cv_c_bigendian = xyes; then
3262 g_byte_order=G_BIG_ENDIAN
3263 g_bs_native=BE
3264 g_bs_alien=LE
3265 else
3266 g_byte_order=G_LITTLE_ENDIAN
3267 g_bs_native=LE
3268 g_bs_alien=BE
3269 fi
3271 g_pollin=$glib_cv_value_POLLIN
3272 g_pollout=$glib_cv_value_POLLOUT
3273 g_pollpri=$glib_cv_value_POLLPRI
3274 g_pollhup=$glib_cv_value_POLLHUP
3275 g_pollerr=$glib_cv_value_POLLERR
3276 g_pollnval=$glib_cv_value_POLLNVAL
3278 # If a family is not found on the system, define that family to
3279 # a negative value, picking a different one for each undefined
3280 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3281 # This is needed because glib-mkenums doesn't handle optional
3282 # values in enums, and thus we have to have all existing values
3283 # defined in the enum.
3284 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3285 g_af_unix=$glib_cv_value_AF_UNIX
3286 else
3287 g_af_unix=-1
3288 fi
3289 g_af_inet=$glib_cv_value_AF_INET
3290 g_af_inet6=$glib_cv_value_AF_INET6
3292 g_msg_peek=$glib_cv_value_MSG_PEEK
3293 g_msg_oob=$glib_cv_value_MSG_OOB
3294 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3296 g_stack_grows=$glib_cv_stack_grows
3298 g_have_eilseq=$have_eilseq
3300 g_threads_impl_def=$g_threads_impl
3302 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3303 g_memory_barrier_needed="$glib_memory_barrier_needed"
3304 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3306 g_module_suffix="$glib_gmodule_suffix"
3307 g_dir_separator="$glib_dir_separator"
3308 g_searchpath_separator="$glib_searchpath_separator"
3310 g_pid_type="$glib_pid_type"
3311 g_pid_format="\"$glib_pid_format\""
3312 g_pollfd_format="\"$glib_pollfd_format\""
3314 case $host in
3315 *-*-cygwin*)
3316 glib_os="#define G_OS_UNIX
3317 #define G_PLATFORM_WIN32
3318 #define G_WITH_CYGWIN"
3319 ;;
3320 *-*-mingw*)
3321 glib_os="#define G_OS_WIN32
3322 #define G_PLATFORM_WIN32"
3323 ;;
3324 *)
3325 glib_os="#define G_OS_UNIX"
3326 ;;
3327 esac
3328 glib_static_compilation=""
3329 if test x$glib_win32_static_compilation = xyes; then
3330 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3331 #define GOBJECT_STATIC_COMPILATION 1"
3332 fi
3333 ])
3335 # Redo enough to get guint32 and guint64 for the alignment checks below
3336 case 4 in
3337 $ac_cv_sizeof_short)
3338 gint32=short
3339 ;;
3340 $ac_cv_sizeof_int)
3341 gint32=int
3342 ;;
3343 $ac_cv_sizeof_long)
3344 gint32=long
3345 ;;
3346 esac
3347 case 8 in
3348 $ac_cv_sizeof_int)
3349 gint64=int
3350 ;;
3351 $ac_cv_sizeof_long)
3352 gint64=long
3353 ;;
3354 $ac_cv_sizeof_long_long)
3355 gint64='long long'
3356 ;;
3357 $ac_cv_sizeof___int64)
3358 gint64='__int64'
3359 ;;
3360 esac
3362 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3363 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3364 typedef unsigned $gint32 guint32;])
3365 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3366 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3367 typedef unsigned $gint64 guint64;])
3368 AC_CHECK_TYPE([unsigned long])
3369 AC_CHECK_ALIGNOF([unsigned long])
3371 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3372 #
3373 # 1.2.14 required for dbus_message_set_serial
3374 PKG_CHECK_MODULES(DBUS1,
3375 dbus-1 >= 1.2.14,
3376 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3377 have_dbus1=no)
3378 AC_SUBST(DBUS1_CFLAGS)
3379 AC_SUBST(DBUS1_LIBS)
3380 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3382 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3383 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3385 # Check whether MSVC toolset is explicitly set
3386 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3387 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3389 dnl
3390 dnl Check for -Bsymbolic-functions linker flag used to avoid
3391 dnl intra-library PLT jumps, if available.
3392 dnl
3394 AC_ARG_ENABLE(Bsymbolic,
3395 [AS_HELP_STRING([--disable-Bsymbolic],
3396 [avoid linking with -Bsymbolic])],,
3397 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3398 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3399 LDFLAGS=-Wl,-Bsymbolic-functions
3400 LIBS=
3401 AC_TRY_LINK([], [return 0],
3402 AC_MSG_RESULT(yes)
3403 enable_Bsymbolic=yes,
3404 AC_MSG_RESULT(no)
3405 enable_Bsymbolic=no)
3406 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3408 if test "x${enable_Bsymbolic}" = "xyes"; then
3409 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3410 fi
3412 dnl
3413 dnl Check for -z,nodelete linker flag: the type system assumes that
3414 dnl libgobject stays loaded for the lifetime of the process.
3415 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3416 dnl we also try to check for the --fatal-warnings linker flag if
3417 dnl auto-detecting.
3418 dnl
3420 AC_ARG_ENABLE([znodelete],
3421 [AS_HELP_STRING([--disable-znodelete],
3422 [avoid linking with -z,nodelete])],,
3423 [SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3424 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3425 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3426 LDFLAGS=-Wl,--fatal-warnings
3427 LIBS=
3428 AC_TRY_LINK([], [return 0],
3429 AC_MSG_RESULT(yes)
3430 [ldflags_fatal=-Wl,--fatal-warnings],
3431 AC_MSG_RESULT(no)
3432 ldflags_fatal=)
3433 AC_MSG_CHECKING([for -z,nodelete linker flag])
3434 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3435 AC_TRY_LINK([], [return 0],
3436 AC_MSG_RESULT(yes)
3437 enable_znodelete=yes,
3438 AC_MSG_RESULT(no)
3439 enable_znodelete=no)
3440 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3442 if test "x${enable_znodelete}" = "xyes"; then
3443 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3444 fi
3446 AC_SUBST(GLIB_LINK_FLAGS)
3448 dnl
3449 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3450 dnl visibility attributes for symbol export control
3451 dnl
3452 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3453 case "$host" in
3454 *-*-mingw*)
3455 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3456 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3457 [defines how to decorate public symbols while building])
3458 CFLAGS="${CFLAGS} -fvisibility=hidden"
3459 ;;
3460 *)
3461 dnl on other compilers, check if we can do -fvisibility=hidden
3462 SAVED_CFLAGS="${CFLAGS}"
3463 CFLAGS="-fvisibility=hidden"
3464 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3465 AC_TRY_COMPILE([], [return 0],
3466 AC_MSG_RESULT(yes)
3467 enable_fvisibility_hidden=yes,
3468 AC_MSG_RESULT(no)
3469 enable_fvisibility_hidden=no)
3470 CFLAGS="${SAVED_CFLAGS}"
3472 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3473 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3474 [defines how to decorate public symbols while building])
3475 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3476 ])
3477 ;;
3478 esac
3479 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3481 dnl Compiler flags; macro originates from systemd
3482 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3483 AC_ARG_ENABLE(compile-warnings,
3484 [AS_HELP_STRING([--disable-compile-warnings],
3485 [Don't use builtin compiler warnings])],,
3486 enable_compile_warnings=yes)
3487 AS_IF([test "x$enable_compile_warnings" != xno], [
3488 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3489 -Wall -Wstrict-prototypes -Wduplicated-branches \
3490 -Werror=declaration-after-statement \
3491 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3492 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3493 -Werror=format=2 -Werror=missing-include-dirs])
3494 ])
3495 AC_SUBST(GLIB_WARN_CFLAGS)
3497 #
3498 # Define variables corresponding to the correct include paths to use for
3499 # in-tree building.
3500 #
3502 # for config.h:
3503 config_h_INCLUDES='-I$(top_builddir)'
3504 AC_SUBST(config_h_INCLUDES)
3506 # glib:
3507 # config.h
3508 # $(top_builddir)/glib: for glibconfig.h
3509 # $(top_srcdir)/glib: for glib.h
3510 # $(top_srcdir): for everything
3511 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3512 AC_SUBST(glib_INCLUDES)
3514 # gobject:
3515 # same as glib
3516 gobject_INCLUDES='$(glib_INCLUDES)'
3517 AC_SUBST(gobject_INCLUDES)
3519 # gmodule:
3520 # glib includes
3521 # $(top_srcdir)/gmodule: for gmodule.h
3522 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3523 AC_SUBST(gmodule_INCLUDES)
3525 # gio:
3526 # same as gmodule
3527 gio_INCLUDES='$(gmodule_INCLUDES)'
3528 AC_SUBST(gio_INCLUDES)
3531 AC_CONFIG_FILES([
3532 glib-2.0.pc
3533 gmodule-2.0.pc
3534 gmodule-export-2.0.pc
3535 gmodule-no-export-2.0.pc
3536 gthread-2.0.pc
3537 gobject-2.0.pc
3538 gio-2.0.pc
3539 gio-unix-2.0.pc
3540 gio-windows-2.0.pc
3541 glib-zip
3542 glib-gettextize
3543 Makefile
3544 build/Makefile
3545 build/win32/Makefile
3546 build/win32/dirent/Makefile
3547 win32/Makefile
3548 win32/vs9/Makefile
3549 win32/vs9/glib-version-paths.vsprops
3550 win32/vs10/Makefile
3551 win32/vs10/glib-version-paths.props
3552 win32/vs11/Makefile
3553 win32/vs12/Makefile
3554 win32/vs14/Makefile
3555 win32/vs15/Makefile
3556 glib/Makefile
3557 glib/libcharset/Makefile
3558 glib/gnulib/Makefile
3559 glib/pcre/Makefile
3560 glib/update-pcre/Makefile
3561 glib/tests/Makefile
3562 gmodule/Makefile
3563 gmodule/gmoduleconf.h
3564 gobject/Makefile
3565 gobject/glib-genmarshal
3566 gobject/glib-mkenums
3567 gobject/tests/Makefile
3568 gthread/Makefile
3569 gio/Makefile
3570 gio/gdbus-2.0/codegen/Makefile
3571 gio/gdbus-2.0/codegen/config.py
3572 gio/gnetworking.h
3573 gio/xdgmime/Makefile
3574 gio/inotify/Makefile
3575 gio/kqueue/Makefile
3576 gio/fam/Makefile
3577 gio/win32/Makefile
3578 gio/tests/Makefile
3579 gio/tests/gdbus-object-manager-example/Makefile
3580 gio/tests/services/Makefile
3581 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3582 gio/tests/modules/Makefile
3583 po/Makefile.in
3584 docs/Makefile
3585 docs/reference/Makefile
3586 docs/reference/glib/Makefile
3587 docs/reference/glib/version.xml
3588 docs/reference/gobject/Makefile
3589 docs/reference/gobject/version.xml
3590 docs/reference/gio/Makefile
3591 docs/reference/gio/version.xml
3592 tests/Makefile
3593 tests/gobject/Makefile
3594 tests/refcount/Makefile
3595 m4macros/Makefile
3596 ])
3598 # We need this command because the configure script will not preserve
3599 # the same attributes of the template files
3600 AC_CONFIG_COMMANDS([chmod-scripts],
3601 [chmod 0755 glib-zip
3602 chmod 0755 glib-gettextize
3603 chmod 0755 gobject/glib-genmarshal
3604 chmod 0755 gobject/glib-mkenums])
3606 # we want to invoke this macro solely so that the config.status script
3607 # and automake generated makefiles know about these generated files.
3608 # They are only needed to distcheck the package
3609 if false; then
3610 AC_CONFIG_FILES([
3611 INSTALL
3612 README
3613 config.h.win32
3614 glib/glibconfig.h.win32
3615 glib/glib.rc
3616 gmodule/gmodule.rc
3617 gobject/gobject.rc
3618 gthread/gthread.rc
3619 gio/gio.rc
3620 ])
3621 fi
3623 AC_OUTPUT