sysdeps/hppa/add_n.S

   1 ;! HP-PA  __mpn_add_n -- Add two limb vectors of the same length > 0 and store
   2 ;! sum in a third limb vector.
   3
   4 ;! Copyright (C) 1992, 1994 Free Software Foundation, Inc.
   5
   6 ;! This file is part of the GNU MP Library.
   7
   8 ;! The GNU MP Library is free software; you can redistribute it and/or modify
   9 ;! it under the terms of the GNU Lesser General Public License as published by
  10 ;! the Free Software Foundation; either version 2.1 of the License, or (at your
  11 ;! option) any later version.
  12
  13 ;! The GNU MP Library is distributed in the hope that it will be useful, but
  14 ;! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ;! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 ;! License for more details.
  17
  18 ;! You should have received a copy of the GNU Lesser General Public License
  19 ;! along with the GNU MP Library.  If not, see
  20 ;! <http://www.gnu.org/licenses/>.
  21
  22
  23 ;! INPUT PARAMETERS
  24 ;! res_ptr      gr26
  25 ;! s1_ptr       gr25
  26 ;! s2_ptr       gr24
  27 ;! size         gr23
  28
  29 ;! One might want to unroll this as for other processors, but it turns
  30 ;! out that the data cache contention after a store makes such
  31 ;! unrolling useless.  We can't come under 5 cycles/limb anyway.
  32
  33         .text
  34         .export         __mpn_add_n
  35 __mpn_add_n:
  36         .proc
  37         .callinfo       frame=0,no_calls
  38         .entry
  39
  40         ldws,ma         4(%r25),%r21
  41         ldws,ma         4(%r24),%r20
  42
  43         addib,=         -1,%r23,L$end   ;! check for (SIZE == 1)
  44          add            %r21,%r20,%r28  ;! add first limbs ignoring cy
  45
  46 L$loop: ldws,ma         4(%r25),%r21
  47         ldws,ma         4(%r24),%r20
  48         stws,ma         %r28,4(%r26)
  49         addib,<>        -1,%r23,L$loop
  50          addc           %r21,%r20,%r28
  51
  52 L$end:  stws            %r28,0(%r26)
  53         bv              0(%r2)
  54          addc           %r0,%r0,%r28
  55
  56         .exit
  57         .procend