sysdeps/unix/sysv/linux/alpha/syscall.S

   1 /* Copyright (C) 1996 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by David Mosberger <davidm@azstarnet.com>, 1996.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22 /*
  23  * This is for COMPATIBILITY with Linux/x86 only.  Linux/Alpha system
  24  * calls return an error indication in a3.  This allows arbitrary 64bit
  25  * values to be returned in v0 (because negative values are not
  26  * mistaken as error numbers).  However, C allows only one value to
  27  * be returned, so the interface below folds the error indication passed in
  28  * a3 back into v0: it sets v0 to -errno if an error occurs.  Thus,
  29  * no negative 64bit numbers can be returned.  To avoid this problem,
  30  * use assembly stubs wherever possible/convenient.
  31  *
  32  * Usage:
  33  *
  34  * long syscall(syscall_number, arg1, arg2, arg3, arg4, arg5)
  35  *
  36  * syscall_number = the index of the system call we're invoking
  37  * arg1-arg5 = up to 5 integer arguments to the system call
  38  *
  39  * We need to do some arg shifting: the kernel expects the
  40  * syscall number in v0 and the first five args in a0-a4.
  41  *
  42  */
  43
  44
  45 LEAF(__syscall, 0)
  46 #ifdef PROF
  47         ldgp    gp, 0(pv)
  48         .set noat
  49         lda     AT, _mcount
  50         jsr     AT, (AT), _mcount
  51         .set at
  52         .prologue 1
  53 #else
  54         .prologue 0
  55 #endif
  56
  57         mov     a0, v0          /* Syscall number -> v0 */
  58         mov     a1, a0          /* arg1-arg5 -> a0-a4 */
  59         mov     a2, a1
  60         mov     a3, a2
  61         mov     a4, a3
  62         mov     a5, a4
  63
  64         call_pal PAL_callsys    /* Invoke system call */
  65         bne     a3, $error
  66         ret
  67
  68 $error:
  69 #ifndef PROF
  70         br      gp, 2f
  71 2:      ldgp    gp, 0(gp)
  72 #endif
  73         SYSCALL_ERROR_HANDLER
  74
  75 END(__syscall)
  76
  77 weak_alias (__syscall, syscall)