sysdeps/unix/sysv/linux/alpha/utimes.S

   1 /* Copyright (C) 1998, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include "kernel-features.h"
  23
  24 .text
  25
  26 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
  27 #define UTIMES  __utimes_tv64
  28 #else
  29 #define UTIMES  __utimes
  30 #endif
  31
  32 #if defined __ASSUME_TIMEVAL64
  33 PSEUDO(UTIMES, utimes, 2)
  34         ret
  35 PSEUDO_END(UTIMES)
  36 #else
  37 /* The problem here is that initially we made struct timeval compatible with
  38    OSF/1, using int32.  But we defined time_t with uint64, and later found
  39    that POSIX requires tv_sec to be time_t.
  40
  41    So now we have to do compatibility stuff.  */
  42
  43 /* The variable is shared between all wrappers around signal handling
  44    functions which have RT equivalents.  */
  45 .comm __libc_missing_axp_tv64, 4
  46
  47 LEAF(UTIMES, 16)
  48         ldgp    gp, 0(pv)
  49         subq    sp, 16, sp
  50 #ifdef PROF
  51         .set noat
  52         lda     AT, _mcount
  53         jsr     AT, (AT), _mcount
  54         .set at
  55 #endif
  56         .prologue 1
  57
  58         ldl     t0, __libc_missing_axp_tv64
  59
  60         /* Save arguments in case we do need to fall back.  */
  61         stq     a0, 0(sp)
  62         stq     a1, 8(sp)
  63
  64         bne     t0, $do32
  65
  66         ldi     v0, SYS_ify(utimes)
  67         callsys
  68         bne     a3, $err64
  69
  70         /* Everything ok.  */
  71         addq    sp, 16, sp
  72         ret
  73
  74         /* If we didn't get ENOSYS, it is a real error.  */
  75         .align 3
  76 $err64: cmpeq   v0, ENOSYS, t0
  77         beq     t0, $error
  78         stl     t0, __libc_missing_axp_tv64
  79
  80         /* Recover the saved arguments.  */
  81         ldq     a1, 8(sp)
  82         ldq     a0, 0(sp)
  83
  84         .align 3
  85 $do32:
  86         /* Conditionally bounce values down.  */
  87         beq     a1, 1f
  88         ldq     t0, 0(a1)
  89         ldq     t1, 8(a1)
  90         ldq     t2, 16(a1)
  91         ldq     t3, 24(a1)
  92         stl     t0, 0(sp)
  93         stl     t1, 4(sp)
  94         stl     t2, 8(sp)
  95         stl     t3, 12(sp)
  96         mov     sp, a1
  97
  98 1:      ldi     v0, SYS_ify(osf_utimes)
  99         callsys
 100         bne     a3, $error
 101
 102         addq    sp, 16, sp
 103         ret
 104
 105         .align 3
 106 $error:
 107         addq    sp, 16, sp
 108         SYSCALL_ERROR_HANDLER
 109
 110 END(UTIMES)
 111 #endif /* __ASSUME_TIMEVAL64 */
 112
 113 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
 114 default_symbol_version (__utimes_tv64, __utimes, GLIBC_2.1)
 115
 116 /* It seems to me to be a misfeature of the assembler that we can only
 117    have one version-alias per symbol.  So create an alias ourselves.
 118    The 'p' is for 'public'.  *Shrug*  */
 119 strong_alias (__utimes_tv64, __utimes_tv64p)
 120 default_symbol_version (__utimes_tv64p, utimes, GLIBC_2.1)
 121 #else
 122 weak_alias (__utimes, utimes)
 123 #endif