sysdeps/unix/sysv/linux/cris/socket.S

   1 /* Copyright (C) 1995, 1996, 1997, 1999, 2001 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #include <socketcall.h>
  21
  22 #define P(a, b) P2(a, b)
  23 #define P2(a, b) a##b
  24
  25 /* The socket-oriented system calls are handled unusally in Linux.
  26    They are all gated through the single `socketcall' system call number.
  27    `socketcall' takes two arguments: the first is the subcode, specifying
  28    which socket function is being called; and the second is a pointer to
  29    the arguments to the specific function.
  30
  31    The .S files for the other calls just #define socket and #include this.
  32    They also #define a 'number-of-arguments' word in NARGS, which
  33    defaults to 3.  */
  34
  35 #ifndef NARGS
  36 #ifdef socket
  37 #error NARGS not defined
  38 #endif
  39 #define NARGS 3
  40 #endif
  41
  42         .syntax no_register_prefix
  43
  44 #ifndef __socket
  45 #define __socket P(__,socket)
  46 #endif
  47
  48 ENTRY(__socket)
  49         subq    NARGS*4,sp
  50
  51 #if NARGS >= 2
  52         move.d  sp,r9
  53         move.d  r10,[r9+]
  54 #else
  55         move.d  r10,[sp]
  56 #endif
  57 #if NARGS >= 2
  58         move.d  r11,[r9+]
  59 #endif
  60 #if NARGS >= 3
  61         move.d  r12,[r9+]
  62 #endif
  63 #if NARGS >= 4
  64         move.d  r13,[r9+]
  65 #endif
  66 #if NARGS >= 5
  67         move.d  [sp+NARGS*4],r13
  68         move.d  r13,[r9+]
  69 #endif
  70 #if NARGS >= 6
  71         move.d  [sp+NARGS*4+4],r13
  72         move.d  r13,[r9+]
  73 #endif
  74 #if NARGS >= 7
  75         move.d  [sp+NARGS*4+8],r13
  76         move.d  r13,[r9+]
  77 #endif
  78 #if NARGS >= 8
  79         move.d  [sp+NARGS*4+12],r13
  80         move.d  r13,[r9+]
  81 #endif
  82 #if NARGS >= 9
  83 #error Too many arguments!
  84 #endif
  85         moveq   P(SOCKOP_,socket),r10
  86         move.d  sp,r11
  87         movu.w  SYS_ify(socketcall),r9
  88         break   13
  89         cmps.w  -4096,r10
  90         bhs     0f
  91         addq    NARGS*4,sp
  92         Ret
  93         nop
  94 PSEUDO_END (__socket)
  95
  96 weak_alias (__socket, socket)