sysdeps/arm/elf/start.S

   1 /* Startup code for ARM & ELF
   2    Copyright (C) 1995, 1996, 1997, 1998, 2001, 2002, 2005
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, write to the Free
  35    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  36    02111-1307 USA.  */
  37
  38 /* This is the canonical entry point, usually the first thing in the text
  39    segment.
  40
  41         Note that the code in the .init section has already been run.
  42         This includes _init and _libc_init
  43
  44
  45         At this entry point, most registers' values are unspecified, except:
  46
  47    a1           Contains a function pointer to be registered with `atexit'.
  48                 This is how the dynamic linker arranges to have DT_FINI
  49                 functions called for shared libraries that have been loaded
  50                 before this code runs.
  51
  52    sp           The stack contains the arguments and environment:
  53                 0(sp)                   argc
  54                 4(sp)                   argv[0]
  55                 ...
  56                 (4*argc)(sp)            NULL
  57                 (4*(argc+1))(sp)        envp[0]
  58                 ...
  59                                         NULL
  60 */
  61
  62         .text
  63         .globl _start
  64         .type _start,#function
  65 _start:
  66 #if !defined(__USING_SJLJ_EXCEPTIONS__)
  67        /* Protect against unhandled exceptions.  */
  68        .fnstart
  69 #endif
  70         /* Fetch address of fini */
  71         ldr ip, =__libc_csu_fini
  72
  73         /* Clear the frame pointer since this is the outermost frame.  */
  74         mov fp, #0
  75
  76         /* Pop argc off the stack and save a pointer to argv */
  77         ldr a2, [sp], #4
  78         mov a3, sp
  79
  80         /* Push stack limit */
  81         str a3, [sp, #-4]!
  82
  83         /* Push rtld_fini */
  84         str a1, [sp, #-4]!
  85
  86         /* Set up the other arguments in registers */
  87         ldr a1, =main
  88         ldr a4, =__libc_csu_init
  89
  90         /* Push fini */
  91         str ip, [sp, #-4]!
  92
  93         /* __libc_start_main (main, argc, argv, init, fini, rtld_fini, stack_end) */
  94
  95         /* Let the libc call main and exit with its return code.  */
  96         bl __libc_start_main
  97
  98         /* should never get here....*/
  99         bl abort
 100
 101 #if !defined(__USING_SJLJ_EXCEPTIONS__)
 102        .cantunwind
 103        .fnend
 104 #endif
 105
 106 /* Define a symbol for the first piece of initialized data.  */
 107         .data
 108         .globl __data_start
 109 __data_start:
 110         .long 0
 111         .weak data_start
 112         data_start = __data_start