sysdeps/unix/sysv/linux/hppa/nptl/pt-vfork.S

   1 /* Copyright (C) 2005, 2010 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <tcb-offsets.h>
  23
  24 /* Clone the calling process, but without copying the whole address space.
  25    The calling process is suspended until the new process exits or is
  26    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  27    and the process ID of the new process to the old process.  */
  28
  29 /* Load the thread register.
  30    Load the saved PID value.
  31    Negate the value.
  32    Store the temporary PID. */
  33 #define SAVE_PID                                                        \
  34         mfctl %cr27, %r26                               ASM_LINE_SEP    \
  35         ldw PID_THREAD_OFFSET(%r26),%r1                 ASM_LINE_SEP    \
  36         sub %r0,%r1,%r1                                 ASM_LINE_SEP    \
  37         stw %r1,PID_THREAD_OFFSET(%r26)                 ASM_LINE_SEP
  38 /* If we are the parent...
  39    Get the thread pointer.
  40    Load the saved PID.
  41    Negate the value (got back original)
  42    Restore the PID. */
  43 #define RESTORE_PID                                                     \
  44         cmpb,=,n %r0,%ret0,.Lthread_start               ASM_LINE_SEP    \
  45         mfctl %cr27, %r26                               ASM_LINE_SEP    \
  46         ldw PID_THREAD_OFFSET(%r26),%r1                 ASM_LINE_SEP    \
  47         sub %r0,%r1,%r1                                 ASM_LINE_SEP    \
  48         stw %r1,PID_THREAD_OFFSET(%r26)                 ASM_LINE_SEP    \
  49 .Lthread_start:                                         ASM_LINE_SEP
  50
  51         /* r26, r25, r24, r23 are free since vfork has no arguments */
  52 ENTRY(__vfork)
  53         /* We must not create a frame. When the child unwinds to call
  54            exec it will clobber the same frame that the parent
  55            needs to unwind.  */
  56
  57         /* Save the PIC register. */
  58 #ifdef PIC
  59         copy    %r19, %r25      /* parent */
  60 #endif
  61
  62         /* Save the process PID */
  63         SAVE_PID
  64
  65         /* Syscall saves and restores all register states */
  66         ble     0x100(%sr2,%r0)
  67         ldi     __NR_vfork,%r20
  68
  69         /* Conditionally restore the PID */
  70         RESTORE_PID
  71
  72         /* Check for error */
  73         ldi     -4096,%r1
  74         comclr,>>= %r1,%ret0,%r0        /* Note: unsigned compare. */
  75         b,n     .Lerror
  76
  77         /* Return, and DO NOT restore rp. The child may have called
  78            functions that updated the frame's rp. This works because
  79            the kernel ensures rp is preserved across the vfork
  80            syscall.  */
  81         bv,n    %r0(%rp)
  82
  83 .Lerror:
  84         /* Now we need a stack to call a function. We are assured
  85            that there is no child now, so it's safe to create
  86            a frame.  */
  87         stw     %rp, -20(%sp)
  88         stwm    %r3, 64(%sp)
  89         stw     %sp, -4(%sp)
  90
  91         sub     %r0,%ret0,%r3
  92         SYSCALL_ERROR_HANDLER
  93         /* Restore the PIC register (in delay slot) on error */
  94 #ifdef PIC
  95         copy    %r25, %r19    /* parent */
  96 #else
  97         nop
  98 #endif
  99         /* Write syscall return into errno location */
 100         stw     %r3, 0(%ret0)
 101         ldw     -84(%sp), %rp
 102         bv      %r0(%rp)
 103         ldwm    -64(%sp), %r3
 104 PSEUDO_END (__vfork)
 105 libc_hidden_def (__vfork)
 106 weak_alias (__vfork, vfork)
 107