sysdeps/unix/sysv/linux/alpha/gettimeofday.S

   1 /* Copyright (C) 1998, 2002, 2003, 2006 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <kernel-features.h>
  23
  24 .text
  25
  26 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
  27 #define GETTIMEOFDAY    __gettimeofday_tv64
  28 #else
  29 #define GETTIMEOFDAY    __gettimeofday
  30 #endif
  31
  32 #if defined __ASSUME_TIMEVAL64
  33 PSEUDO(GETTIMEOFDAY, gettimeofday, 2)
  34         ret
  35 PSEUDO_END(GETTIMEOFDAY)
  36 #else
  37
  38 /* The problem here is that initially we made struct timeval compatible with
  39    OSF/1, using int32.  But we defined time_t with uint64, and later found
  40    that POSIX requires tv_sec to be time_t.
  41
  42    So now we have to do compatibility stuff.  */
  43
  44 /* The variable is shared between all wrappers around signal handling
  45    functions which have RT equivalents.  */
  46 .comm __libc_missing_axp_tv64, 4
  47
  48 LEAF(GETTIMEOFDAY, 16)
  49         ldgp    gp, 0(pv)
  50         subq    sp, 16, sp
  51 #ifdef PROF
  52         .set noat
  53         lda     AT, _mcount
  54         jsr     AT, (AT), _mcount
  55         .set at
  56 #endif
  57         .prologue 1
  58
  59         ldl     t0, __libc_missing_axp_tv64
  60
  61         /* Save arguments in case we do need to fall back.  */
  62         stq     a0, 0(sp)
  63         stq     a1, 8(sp)
  64
  65         bne     t0, $do32
  66
  67         ldi     v0, SYS_ify(gettimeofday)
  68         callsys
  69         bne     a3, $err64
  70
  71         /* Everything ok.  */
  72         addq    sp, 16, sp
  73         ret
  74
  75         /* If we didn't get ENOSYS, it is a real error.  */
  76         .align 3
  77 $err64: cmpeq   v0, ENOSYS, t0
  78         beq     t0, $error
  79         stl     t0, __libc_missing_axp_tv64
  80
  81         /* Recover the saved arguments.  */
  82         ldq     a1, 8(sp)
  83         ldq     a0, 0(sp)
  84
  85         .align 3
  86 $do32:  ldi     v0, SYS_ify(osf_gettimeofday)
  87         callsys
  88         bne     a3, $error
  89
  90         /* Copy back to proper format.  */
  91         ldq     a0, 0(sp)
  92         beq     a0, 2f
  93         ldl     t0, 0(a0)
  94         ldl     t1, 4(a0)
  95         stq     t0, 0(a0)
  96         stq     t1, 8(a0)
  97
  98 2:      addq    sp, 16, sp
  99         ret
 100
 101         .align 3
 102 $error:
 103         addq    sp, 16, sp
 104         SYSCALL_ERROR_HANDLER
 105
 106 END(GETTIMEOFDAY)
 107 #endif /* __ASSUME_TIMEVAL64 */
 108
 109 #if defined HAVE_ELF && defined PIC && defined DO_VERSIONING
 110 default_symbol_version (__gettimeofday_tv64, __gettimeofday, GLIBC_2.1)
 111
 112 /* It seems to me to be a misfeature of the assembler that we can only
 113    have one version-alias per symbol.  So create an alias ourselves.
 114    The 'p' is for 'public'.  *Shrug*  */
 115 strong_alias (__gettimeofday_tv64, __gettimeofday_tv64p)
 116 default_symbol_version (__gettimeofday_tv64p, gettimeofday, GLIBC_2.1)
 117 #else
 118 weak_alias (__gettimeofday, gettimeofday)
 119 #endif
 120 strong_alias(GETTIMEOFDAY, __gettimeofday_internal)