sysdeps/cris/elf/start.S

   1 /* Startup code compliant to the ELF CRIS ABI (to-be-written).
   2    Copyright (C) 2001, 2002 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, write to the Free
  34    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  35    02111-1307 USA.  */
  36
  37 #include <sysdep.h>
  38
  39 /* This is the canonical entry point, usually the first thing in the text
  40    segment.  When the entry point runs, most registers' values are
  41    unspecified, except for:
  42
  43    R10          Contains a function pointer to be registered with `atexit'.
  44                 This is how the dynamic linker arranges to have DT_FINI
  45                 functions called for shared libraries that have been loaded
  46                 before this code runs.
  47
  48    SP           The stack contains the arguments and environment:
  49                 [SP]                    argc
  50                 [SP+4]                  argv[0]
  51                 ...
  52                 [SP+4*argc]             NULL
  53                 [SP+4*(argc+1)]         envp[0]
  54                 ...
  55                                         NULL
  56 */
  57
  58         .syntax no_register_prefix
  59
  60         .text
  61         .globl  _start
  62         .type _start,@function
  63 _start:
  64         /* Clear the frame pointer, to mark the outermost frame.  */
  65         moveq   0,r8
  66
  67         /* Move the shared library termination function to the right place
  68            for __libc_main.  */
  69         move.d  r10,r9
  70
  71         /* Extract the arguments as encoded on the stack and set up the
  72            arguments for `main': argc, argv.  envp will be determined
  73            later in __libc_start_main.  */
  74
  75         /* Get the argument count.  */
  76         move.d  [sp],r11
  77
  78         /* Store the stack pointer as end of stack.  We overwrite
  79            the incoming argc.  */
  80         move.d  sp,[sp]
  81
  82         /* The argument vector starts just after the argument count.  */
  83         move.d  sp,r12
  84         addq    4,r12
  85
  86         /* There are seven arguments to __libc_start_main:
  87            r10:  main - Address of it.
  88            r11:  argc
  89            r12:  argv
  90            r13:  init - Function to call.
  91
  92            [sp]: fini - Function to register with atexit.
  93            [sp+4]: rtld_fini - Another function to register with atexit.
  94            [sp+8]: stack_end - Top of stack (actually same as argv).
  95
  96            The last two are passed on stack.  */
  97
  98         /* Store the fini function coming from the dynamic loader.  */
  99         push    r9
 100
 101         /* Get the addresses of our own entry points to `.fini' and
 102            `.init'.  */
 103
 104 #ifdef __PIC__
 105         /* If for some reason this program is compiled as PIC, set up R0.  */
 106         move.d  pc,r0
 107         sub.d   .:GOTOFF,r0
 108
 109         move.d  __libc_csu_init:PLTG,r13
 110         add.d   r0,r13
 111         move.d  __libc_csu_fini:PLTG,r9
 112         add.d   r0,r9
 113         move.d  main:PLTG,r10
 114         add.d   r0,r10
 115 #else
 116         move.d  __libc_csu_init,r13
 117         move.d  __libc_csu_fini,r9
 118         move.d  main,r10
 119 #endif
 120         push    r9
 121
 122         /* Call the user's main function, and exit with its value.  But
 123            let the libc call main.  */
 124         PLTCALL (__libc_start_main)
 125
 126         /* Crash if somehow `exit' does return.  We have at least 8192
 127            invalid addresses to choose from.  */
 128         test.d  [6502]
 129
 130         /* Stop the unstoppable.  */
 131 0:
 132         ba      0b
 133         nop
 134
 135 /* Define a symbol for the first piece of initialized data.  */
 136         .data
 137         .globl __data_start
 138 __data_start:
 139         .long   0
 140         .weak   data_start
 141         data_start = __data_start