sysdeps/hppa/elf/start.S

   1 /* ELF startup code for HPPA.
   2    Copyright (C) 2002 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, write to the Free
  34    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  35    02111-1307 USA.  */
  36
  37         .import main, code
  38         .import $global$, data
  39         .import __libc_start_main, code
  40         .import __libc_csu_fini, code
  41         .import __libc_csu_init, code
  42
  43         /* Have the linker create plabel words so we get PLABEL32
  44            relocs and not 21/14.  The use of 21/14 relocs is only
  45            supported in the latest dynamic linker.  */
  46         .section        .rodata
  47         .align 4
  48 .Lpmain:
  49         .word P%main
  50 .Lp__libc_start_main:
  51         .word P%__libc_start_main
  52 .Lp__libc_csu_fini:
  53         .word P%__libc_csu_fini
  54 .Lp__libc_csu_init:
  55         .word P%__libc_csu_init
  56
  57         .text
  58         .align 4
  59         .globl _start
  60         .export _start, ENTRY
  61         .type _start,@function
  62 _start:
  63         /* At entry to the function we have:
  64
  65                 r26 - Unused
  66                 r25 - argc
  67                 r24 - argv
  68                 r23 - False _dl_fini plabel address
  69
  70            This function is called from the lower half of RTLD_START.
  71
  72            The call to __libc_start_main expects:
  73
  74                 1. r26 - Application main
  75                 2. r25 - argc
  76                 3. r24 - argv
  77                 4. r23 - __libc_csu_init
  78                 5. sp-52 - __libc_csu_fini
  79                 6. sp-56 - rtld_fini
  80                 7. sp-60 - stackend  */
  81
  82         .proc
  83         .callinfo
  84         /* Clear previous-sp.  */
  85         stw     %r0, -4(%sp)
  86         /* Setup the stack and frame.  */
  87         stw     %rp, -20(%sp)
  88         ldo     64(%sp), %sp
  89         stw     %sp, -4(%sp)
  90         stw     %r19, -32(%sp)
  91
  92         /* argc and argv should be in 25 and 24 (2nd and 3rd argument) */
  93         /* void (*rtld_fini) (void) (6th argument) */
  94         stw     %r23, -56(%sp)
  95         /* Need to setup 1, 4, 5, and 7th arguments */
  96
  97 #if SHARED
  98         /* load main (1st argument) */
  99         addil   LR'.Lpmain, %r19
 100         ldw     RR'.Lpmain(%r1), %r26
 101         ldw     0(%r26),%r26
 102         /* void (*init) (void) (4th argument) */
 103         addil   LR'.Lp__libc_csu_init, %r19
 104         ldw     RR'.Lp__libc_csu_init(%r1), %r23
 105         ldw     0(%r23), %r23
 106         /* void (*fini) (void) (5th argument) */
 107         addil   LR'.Lp__libc_csu_fini, %r19
 108         ldw     RR'.Lp__libc_csu_fini(%r1), %r22
 109         ldw     0(%r22), %r22
 110 #else
 111         /* load main (1st argument) */
 112         ldil    LR'.Lpmain, %r26
 113         ldw     RR'.Lpmain(%r26), %r26
 114         /* void (*init) (void) (4th argument) */
 115         ldil    LR'.Lp__libc_csu_init, %r23
 116         ldw     RR'.Lp__libc_csu_init(%r23), %r23
 117         /* void (*fini) (void) (5th argument) */
 118         ldil    LR'.Lp__libc_csu_fini, %r22
 119         ldw     RR'.Lp__libc_csu_fini(%r22), %r22
 120 #endif
 121         /* Store 5th argument */
 122         stw     %r22, -52(%sp)
 123         /* void *stack_end (7th argument) */
 124         stw     %sp, -60(%sp)
 125
 126         /* load global */
 127         ldil    L%$global$, %dp
 128         ldo     R%$global$(%dp), %dp
 129
 130         bl      __libc_start_main,%r2
 131         nop
 132         /* die horribly if it returned (it shouldn't) */
 133         iitlbp %r0,(%sr0,%r0)
 134         nop
 135
 136         .procend
 137
 138 /* Define a symbol for the first piece of initialized data.  */
 139         .data
 140         .globl __data_start
 141 __data_start:
 142         .long 0
 143         .weak data_start
 144         data_start = __data_start