sysdeps/unix/sysv/linux/am33/clone.S

   1 /* Copyright 2001 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Alexandre Oliva <aoliva@redhat.com>.
   4    Based on ../i386/clone.S.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 /* clone() is even more special than fork() as it mucks with stacks
  22    and invokes a function in the right context after its all over.  */
  23
  24 #include <sysdep.h>
  25 #define _ERRNO_H        1
  26 #include <bits/errno.h>
  27 #include <asm-syntax.h>
  28 #include <bp-sym.h>
  29
  30 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg); */
  31
  32         .text
  33 ENTRY (BP_SYM (__clone))
  34         /* Sanity check arguments.  */
  35         cmp     0,d0    /* no NULL function pointers */
  36         beq     L(error_inval)
  37         cmp     0,d1    /* no NULL stack pointers */
  38         beq     L(error_inval)
  39
  40         /* Allocate room for a function call in the new stack, and
  41            store fn and arg in it.  They will be read back in
  42            thread_start.  */
  43         mov     d1,a0
  44         sub     12,a0
  45         mov     d0,(a0)
  46         mov     (16,sp),d1
  47         mov     d1,(4,a0)
  48
  49         /* Do the system call */
  50         mov     a0,d1
  51         mov     (12,sp),a0
  52         mov     SYS_ify(clone),d0
  53         syscall 0
  54
  55         cmp     0,d0
  56         beq     thread_start
  57         blt     L(to_SYSCALL_ERROR_LABEL)
  58
  59 L(pseudo_end):
  60         ret
  61
  62 L(error_inval):
  63         mov     -EINVAL,d0
  64 L(to_SYSCALL_ERROR_LABEL):
  65         jmp     SYSCALL_ERROR_LABEL
  66
  67 thread_start:
  68         mov     0,a3    /* terminate the stack frame */
  69         mov     (4,sp),d0
  70         mov     (sp),a0
  71         calls   (a0)
  72 #ifdef PIC
  73 L(here):
  74         mov     pc,a2
  75         add     _GLOBAL_OFFSET_TABLE_-(L(here) - .),a2
  76 #endif
  77         call    JUMPTARGET (_exit),[],0
  78
  79 PSEUDO_END (BP_SYM (__clone))
  80
  81 weak_alias (BP_SYM (__clone), BP_SYM (clone))