sysdeps/vax/strrchr.s

   1 /*
   2  * Copyright (c) 1988 Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 4. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if defined(LIBC_SCCS) && !defined(lint)
  31         .asciz "@(#)strrchr.s   5.4 (Berkeley) 6/1/90"
  32 #endif /* LIBC_SCCS and not lint */
  33
  34 /*
  35  * Find the last occurrence of c in the string cp.
  36  * Return pointer to match or null pointer.
  37  *
  38  * char *
  39  * strrchr(cp, c)
  40  *      char *cp, c;
  41  */
  42 #include "DEFS.h"
  43
  44         .lcomm  tbl,256
  45
  46 ENTRY(strrchr, 0)
  47         movzwl  $65535,r4       /* handy 65535 */
  48         movq    4(ap),r1        /* r1 = cp; r2 = c */
  49         movzbl  r2,r2
  50         beql    Lzero           /* special case for c == '\0' */
  51
  52         clrl    r5              /* r5 = pointer to last match */
  53
  54 /*
  55  * Fancy scanc version.  Alas, it is not reentrant.
  56  */
  57         movab   tbl,r3          /* r3 = address of table */
  58         bbss    $0,(r3),Lreent  /* ensure not reentering */
  59         movab   (r3)[r2],r4
  60         incb    (r4)            /* mark both '\0' and c */
  61 0:
  62         scanc   $65535,(r1),(r3),$1     /* look for c or '\0' */
  63         beql    0b              /* keep looking */
  64         tstb    (r1)
  65         beql    1f              /* done if '\0' */
  66         movab   (r1)+,r5        /* save most recently found, and skip over it */
  67         jbr     0b              /* keep looking */
  68 1:
  69         movl    r5,r0           /* return last found (if any) */
  70         clrb    (r4)            /* clean up table */
  71         clrb    (r3)
  72         ret
  73
  74 /*
  75  * Special case for \0.
  76  */
  77 Lzero:
  78         locc    $0,r4,(r1)      /* just find end of string */
  79         beql    Lzero           /* still looking */
  80         movl    r1,r0           /* found it */
  81         ret
  82
  83 /*
  84  * Slower reentrant version is two two-step searches.  The first
  85  * phase runs until we know where the string ends; it locates any
  86  * occurrences of c within a 65535-byte block.  Once we have found
  87  * the end of the string, we find any further occurrences before
  88  * that location.
  89  */
  90 Lreent:
  91 0:      /* first phase */
  92         movl    r1,r3
  93         locc    $0,r4,(r3)      /* look for '\0' */
  94         bneq    1f
  95         locc    r2,r4,(r3)      /* continue phase 1 search for c */
  96         beql    0b
  97         movab   (r1)+,r5        /* found c: save and increment pointer */
  98         brb     0b              /* and continue */
  99
 100 1:      /* second phase */
 101         subl3   r3,r1,r0        /* length of short block */
 102         movl    r3,r1
 103 2:
 104         locc    r2,r0,(r1)      /* look for c */
 105         beql    3f              /* skip if not found */
 106         movab   (r1)+,r5        /* save pointer as before */
 107         sobgtr  r0,2b           /* adjust count and loop */
 108 3:
 109         movl    r5,r0           /* return stashed pointer */
 110         ret
 111
 112 weak_alias (strrchr, rindex)