sysdeps/arm/eabi/__longjmp.S

   1 /* longjmp for ARM.
   2    Copyright (C) 1997, 1998, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU General Public License
  16    along with GCC; see the file COPYING.  If not, write to the Free
  17    Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  18    02110-1301, USA.  */
  19
  20 #include <sysdep.h>
  21 #define _SETJMP_H
  22 #define _ASM
  23 #include <bits/setjmp.h>
  24 #define __ASSEMBLY__
  25 #include <asm/procinfo.h>
  26 #include <rtld-global-offsets.h>
  27
  28 /* __longjmp(jmpbuf, val) */
  29
  30 ENTRY (__longjmp)
  31         mov     ip, r0
  32         movs    r0, r1          /* get the return value in place */
  33         moveq   r0, #1          /* can't let setjmp() return zero! */
  34
  35         LOADREGS(ia, ip!, {v1-v6, sl, fp, sp, lr})
  36
  37 #ifdef IS_IN_rtld
  38         ldr     a2, 1f
  39         ldr     a3, Lrtld_local_ro
  40 0:      add     a2, pc, a2
  41         add     a2, a2, a3
  42         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  43 #else
  44 #ifdef PIC
  45         ldr     a2, 1f
  46         ldr     a3, Lrtld_global_ro
  47 0:      add     a2, pc, a2
  48         ldr     a2, [a2, a3]
  49         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  50 #else
  51         ldr     a2, Lhwcap
  52         ldr     a2, [a2, #0]
  53 #endif
  54 #endif
  55
  56         tst     a2, #HWCAP_VFP
  57         beq     Lno_vfp
  58
  59         /* Restore the VFP registers.  */
  60         /* Following instruction is fldmiax ip!, {d8-d15}.  */
  61         ldc     p11, cr8, [r12], #68
  62         /* Restore the floating-point status register.  */
  63         ldr     r1, [ip], #4
  64         /* Following instruction is fmxr fpscr, r1.  */
  65         mcr     p10, 7, r1, cr1, cr0, 0
  66 Lno_vfp:
  67
  68         DO_RET(lr)
  69
  70 #ifdef IS_IN_rtld
  71 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
  72 Lrtld_local_ro:
  73         .long   C_SYMBOL_NAME(_rtld_local_ro)(GOTOFF)
  74 #else
  75 #ifdef PIC
  76 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
  77 Lrtld_global_ro:
  78         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
  79 #else
  80 Lhwcap:
  81         .long   C_SYMBOL_NAME(_dl_hwcap)
  82 #endif
  83 #endif
  84
  85 END (__longjmp)