sysdeps/mips/mips64/memset.S

   1 /* Copyright (C) 2002-2012 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Hartvig Ekner <hartvige@mips.com>, 2002.
   4    Ported to mips3 n32/n64 by Alexandre Oliva <aoliva@redhat.com>
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library.  If not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <sys/asm.h>
  22
  23
  24 /* void *memset(void *s, int c, size_t n);
  25
  26    This could probably be optimized further.  */
  27
  28 #if __MIPSEB
  29 # define SDHI   sdl             /* high part is left in big-endian      */
  30 #else
  31 # define SDHI   sdr             /* high part is right in little-endian  */
  32 #endif
  33
  34 ENTRY (memset)
  35         .set    noreorder
  36
  37         slti    ta1, a2, 16             # Less than 16?
  38         bne     ta1, zero, L(last16)
  39         move    v0, a0                  # Setup exit value before too late
  40
  41         beq     a1, zero, L(ueven)      # If zero pattern, no need to extend
  42         andi    a1, 0xff                # Avoid problems with bogus arguments
  43         dsll    ta0, a1, 8
  44         or      a1, ta0
  45         dsll    ta0, a1, 16
  46         or      a1, ta0                 # a1 is now pattern in full word
  47         dsll    ta0, a1, 32
  48         or      a1, ta0                 # a1 is now pattern in double word
  49
  50 L(ueven):
  51         PTR_SUBU ta0, zero, a0          # Unaligned address?
  52         andi    ta0, 0x7
  53         beq     ta0, zero, L(chkw)
  54         PTR_SUBU a2, ta0
  55         SDHI    a1, 0(a0)               # Yes, handle first unaligned part
  56         PTR_ADDU a0, ta0                # Now both a0 and a2 are updated
  57
  58 L(chkw):
  59         andi    ta0, a2, 0xf            # Enough left for one loop iteration?
  60         beq     ta0, a2, L(chkl)
  61         PTR_SUBU a3, a2, ta0
  62         PTR_ADDU a3, a0                 # a3 is last loop address +1
  63         move    a2, ta0                 # a2 is now # of bytes left after loop
  64 L(loopw):
  65         PTR_ADDIU a0, 16                # Handle 2 dwords pr. iteration
  66         sd      a1, -16(a0)
  67         bne     a0, a3, L(loopw)
  68         sd      a1,  -8(a0)
  69
  70 L(chkl):
  71         andi    ta0, a2, 0x8            # Check if there is at least a double
  72         beq     ta0, zero, L(last16)    #  word remaining after the loop
  73         PTR_SUBU a2, ta0
  74         sd      a1, 0(a0)               # Yes...
  75         PTR_ADDIU a0, 8
  76
  77 L(last16):
  78         blez    a2, L(exit)             # Handle last 16 bytes (if cnt>0)
  79         PTR_ADDU a3, a2, a0             # a3 is last address +1
  80 L(lst16l):
  81         PTR_ADDIU a0, 1
  82         bne     a0, a3, L(lst16l)
  83         sb      a1, -1(a0)
  84 L(exit):
  85         j       ra                      # Bye, bye
  86         nop
  87
  88         .set    reorder
  89 END (memset)
  90 libc_hidden_builtin_def (memset)