sysdeps/tile/start.S

   1 /* Copyright (C) 2011 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Chris Metcalf <cmetcalf@tilera.com>, 2011.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library.  If not, see
  34    <http://www.gnu.org/licenses/>.  */
  35
  36 /* This is the canonical entry point, usually the first thing in the text
  37    segment.  The ELF standard tells us that the stack is set up like this on
  38    entry (the left side is the offset from "sp"), in units of
  39    __SIZEOF_POINTER__ entries:
  40
  41                 +0              argc
  42                 +1              argv[0]
  43                 ...
  44                 +(argc+1)       NULL
  45                 +(argc+2)       envp[0]
  46                 ...
  47                                 NULL
  48                 ...             ElfInfo
  49
  50    The ElfInfo is pairs of key/value long words following the envp
  51    pointers and terminated by a zero-valued key.
  52
  53    Although not mandated by the standard, it happens to be the case
  54    that we store the actual argv and envp strings immediately after
  55    the ElfInfo data on the stack.
  56
  57    On entry r0 points to the shared library termination function, or 0
  58    if there isn't one.
  59 */
  60
  61 #include <features.h>
  62 #include <sysdep.h>
  63 #include <arch/abi.h>
  64
  65         .text
  66         .global _start
  67         .type   _start,@function
  68         .align 8
  69 _start:
  70         /* Linux starts us with sp pointing at the conventional Elf layout,
  71            but we need to allow two "caller" words for our ABI convention.  */
  72         {
  73          /* Load argc (stored as a "long", equivalent to a pointer type). */
  74          LD_PTR r1, sp
  75
  76          /* Save incoming 'sp', which points to the Elf argument block. */
  77          move r52, sp
  78         }
  79
  80         {
  81          /* Allocate stack frame callee space for __libc_start_main. */
  82          ADDI_PTR r12, sp, -(2 * REGSIZE)
  83         }
  84
  85         {
  86          /* Get our PC. */
  87          lnk r13
  88
  89          /* sp is not necessarily properly aligned on startup because
  90             of the way ld.so pops off leading argv elements. So align it. */
  91          andi sp, r12, -8
  92         }
  93 .Lmy_pc:
  94
  95         {
  96          /* Pass the address of the shared library termination function. */
  97          move r5, r0
  98
  99          /* Compute location where __libc_start_main's caller is supposed to
 100             store its frame pointer. */
 101          ADDI_PTR r12, sp, REGSIZE
 102
 103          /* Zero out callee space for return address. Unnecessary but free.
 104             This is just paranoia to help backtracing not go awry. */
 105          ST sp, zero
 106         }
 107         {
 108          /* Zero out our frame pointer for __libc_start_main. */
 109          ST r12, zero
 110
 111          /* Zero out lr to make __libc_start_main the end of backtrace.  */
 112          move lr, zero
 113
 114          /* Compute a pointer to argv. envp will be determined
 115             later in __libc_start_main.  We set up the first argument
 116             (the address of main) below. */
 117          ADDI_PTR r2, r52, __SIZEOF_POINTER__
 118         }
 119         {
 120          /* Pass the highest stack address to user code. */
 121          ADDI_PTR r6, sp, (2 * REGSIZE)
 122
 123          /* Pass address of main() in r0, and of our own entry
 124             points to .fini and .init in r3 and r4.  */
 125 #ifdef __tilegx__
 126          moveli r0, hw2_last(main - .Lmy_pc)
 127         }
 128         {
 129          moveli r3, hw2_last(__libc_csu_init - .Lmy_pc)
 130          shl16insli r0, r0, hw1(main - .Lmy_pc)
 131         }
 132         {
 133          shl16insli r3, r3, hw1(__libc_csu_init - .Lmy_pc)
 134          shl16insli r0, r0, hw0(main - .Lmy_pc)
 135         }
 136         {
 137          shl16insli r3, r3, hw0(__libc_csu_init - .Lmy_pc)
 138          moveli r4, hw2_last(__libc_csu_fini - .Lmy_pc)
 139         }
 140         {
 141          ADD_PTR r0, r0, r13
 142          shl16insli r4, r4, hw1(__libc_csu_fini - .Lmy_pc)
 143         }
 144         {
 145          ADD_PTR r3, r3, r13
 146          shl16insli r4, r4, hw0(__libc_csu_fini - .Lmy_pc)
 147         }
 148         {
 149          ADD_PTR r4, r4, r13
 150 #else
 151          addli r0, r13, lo16(main - .Lmy_pc)
 152         }
 153         {
 154          auli r0, r0, ha16(main - .Lmy_pc)
 155          addli r3, r13, lo16(__libc_csu_init - .Lmy_pc)
 156         }
 157         {
 158          auli r3, r3, ha16(__libc_csu_init - .Lmy_pc)
 159          addli r4, r13, lo16(__libc_csu_fini - .Lmy_pc)
 160         }
 161         {
 162          auli r4, r4, ha16(__libc_csu_fini - .Lmy_pc)
 163
 164 #endif
 165
 166          /* Call the user's main function, and exit with its value.
 167             But let the libc call main. */
 168          j plt(__libc_start_main)
 169         }
 170         {
 171          /* Tell backtracer to give up (_start has no caller). */
 172          info INFO_OP_CANNOT_BACKTRACE
 173         }
 174 .size _start, .-_start
 175
 176 /* Define a symbol for the first piece of initialized data.  */
 177         .data
 178         .global __data_start
 179         .align 8
 180 __data_start:
 181         .long 0
 182         .weak data_start
 183         data_start = __data_start