sysdeps/m68k/m68020/mul_1.S

   1 /* mc68020 __mpn_mul_1 -- Multiply a limb vector with a limb and store
   2    the result in a second limb vector.
   3
   4 Copyright (C) 1992, 1994, 1996, 1998 Free Software Foundation, Inc.
   5
   6 This file is part of the GNU MP Library.
   7
   8 The GNU MP Library is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU Lesser General Public License as published by
  10 the Free Software Foundation; either version 2.1 of the License, or (at your
  11 option) any later version.
  12
  13 The GNU MP Library is distributed in the hope that it will be useful, but
  14 WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 License for more details.
  17
  18 You should have received a copy of the GNU Lesser General Public License
  19 along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 MA 02111-1307, USA. */
  22
  23 /*
  24   INPUT PARAMETERS
  25   res_ptr       (sp + 4)
  26   s1_ptr        (sp + 8)
  27   s1_size       (sp + 12)
  28   s2_limb       (sp + 16)
  29 */
  30
  31 #include "sysdep.h"
  32 #include "asm-syntax.h"
  33
  34         TEXT
  35 ENTRY(__mpn_mul_1)
  36
  37 #define res_ptr a0
  38 #define s1_ptr a1
  39 #define s1_size d2
  40 #define s2_limb d4
  41
  42 /* Save used registers on the stack.  */
  43         moveml  R(d2)-R(d4),MEM_PREDEC(sp)
  44 #if 0
  45         movel   R(d2),MEM_PREDEC(sp)
  46         movel   R(d3),MEM_PREDEC(sp)
  47         movel   R(d4),MEM_PREDEC(sp)
  48 #endif
  49
  50 /* Copy the arguments to registers.  Better use movem?  */
  51         movel   MEM_DISP(sp,16),R(res_ptr)
  52         movel   MEM_DISP(sp,20),R(s1_ptr)
  53         movel   MEM_DISP(sp,24),R(s1_size)
  54         movel   MEM_DISP(sp,28),R(s2_limb)
  55
  56         eorw    #1,R(s1_size)
  57         clrl    R(d1)
  58         lsrl    #1,R(s1_size)
  59         bcc     L(L1)
  60         subql   #1,R(s1_size)
  61         subl    R(d0),R(d0)     /* (d0,cy) <= (0,0) */
  62
  63 L(Loop:)
  64         movel   MEM_POSTINC(s1_ptr),R(d3)
  65         mulul   R(s2_limb),R(d1):R(d3)
  66         addxl   R(d0),R(d3)
  67         movel   R(d3),MEM_POSTINC(res_ptr)
  68 L(L1:)  movel   MEM_POSTINC(s1_ptr),R(d3)
  69         mulul   R(s2_limb),R(d0):R(d3)
  70         addxl   R(d1),R(d3)
  71         movel   R(d3),MEM_POSTINC(res_ptr)
  72
  73         dbf     R(s1_size),L(Loop)
  74         clrl    R(d3)
  75         addxl   R(d3),R(d0)
  76         subl    #0x10000,R(s1_size)
  77         bcc     L(Loop)
  78
  79 /* Restore used registers from stack frame.  */
  80         moveml  MEM_POSTINC(sp),R(d2)-R(d4)
  81 #if 0
  82         movel   MEM_POSTINC(sp),R(d4)
  83         movel   MEM_POSTINC(sp),R(d3)
  84         movel   MEM_POSTINC(sp),R(d2)
  85 #endif
  86         rts
  87 END(__mpn_mul_1)