sysdeps/rs6000/mul_1.s

   1 # IBM POWER __mpn_mul_1 -- Multiply a limb vector with a limb and store
   2 # the result in a second limb vector.
   3
   4 # Copyright (C) 1992, 1994 Free Software Foundation, Inc.
   5
   6 # This file is part of the GNU MP Library.
   7
   8 # The GNU MP Library is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2.1 of the License, or (at your
  11 # option) any later version.
  12
  13 # The GNU MP Library is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 # License for more details.
  17
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 # MA 02111-1307, USA.
  22
  23
  24 # INPUT PARAMETERS
  25 # res_ptr       r3
  26 # s1_ptr        r4
  27 # size          r5
  28 # s2_limb       r6
  29
  30 # The RS/6000 has no unsigned 32x32->64 bit multiplication instruction.  To
  31 # obtain that operation, we have to use the 32x32->64 signed multiplication
  32 # instruction, and add the appropriate compensation to the high limb of the
  33 # result.  We add the multiplicand if the multiplier has its most significant
  34 # bit set, and we add the multiplier if the multiplicand has its most
  35 # significant bit set.  We need to preserve the carry flag between each
  36 # iteration, so we have to compute the compensation carefully (the natural,
  37 # srai+and doesn't work).  Since the POWER architecture has a branch unit
  38 # we can branch in zero cycles, so that's how we perform the additions.
  39
  40         .toc
  41         .csect .__mpn_mul_1[PR]
  42         .align 2
  43         .globl __mpn_mul_1
  44         .globl .__mpn_mul_1
  45         .csect __mpn_mul_1[DS]
  46 __mpn_mul_1:
  47         .long .__mpn_mul_1[PR], TOC[tc0], 0
  48         .csect .__mpn_mul_1[PR]
  49 .__mpn_mul_1:
  50
  51         cal     3,-4(3)
  52         l       0,0(4)
  53         cmpi    0,6,0
  54         mtctr   5
  55         mul     9,0,6
  56         srai    7,0,31
  57         and     7,7,6
  58         mfmq    8
  59         ai      0,0,0           # reset carry
  60         cax     9,9,7
  61         blt     Lneg
  62 Lpos:   bdz     Lend
  63 Lploop: lu      0,4(4)
  64         stu     8,4(3)
  65         cmpi    0,0,0
  66         mul     10,0,6
  67         mfmq    0
  68         ae      8,0,9
  69         bge     Lp0
  70         cax     10,10,6         # adjust high limb for negative limb from s1
  71 Lp0:    bdz     Lend0
  72         lu      0,4(4)
  73         stu     8,4(3)
  74         cmpi    0,0,0
  75         mul     9,0,6
  76         mfmq    0
  77         ae      8,0,10
  78         bge     Lp1
  79         cax     9,9,6           # adjust high limb for negative limb from s1
  80 Lp1:    bdn     Lploop
  81         b       Lend
  82
  83 Lneg:   cax     9,9,0
  84         bdz     Lend
  85 Lnloop: lu      0,4(4)
  86         stu     8,4(3)
  87         cmpi    0,0,0
  88         mul     10,0,6
  89         cax     10,10,0         # adjust high limb for negative s2_limb
  90         mfmq    0
  91         ae      8,0,9
  92         bge     Ln0
  93         cax     10,10,6         # adjust high limb for negative limb from s1
  94 Ln0:    bdz     Lend0
  95         lu      0,4(4)
  96         stu     8,4(3)
  97         cmpi    0,0,0
  98         mul     9,0,6
  99         cax     9,9,0           # adjust high limb for negative s2_limb
 100         mfmq    0
 101         ae      8,0,10
 102         bge     Ln1
 103         cax     9,9,6           # adjust high limb for negative limb from s1
 104 Ln1:    bdn     Lnloop
 105         b       Lend
 106
 107 Lend0:  cal     9,0(10)
 108 Lend:   st      8,4(3)
 109         aze     3,9
 110         br