sysdeps/unix/sysv/linux/alpha/getitimer.S

   1 /* Copyright (C) 1998, 2003, 2006, 2012 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #define _ERRNO_H        1
  20 #include <bits/errno.h>
  21 #include <kernel-features.h>
  22
  23 .text
  24
  25 #if defined PIC && defined DO_VERSIONING
  26 #define GETITIMER       __getitimer_tv64
  27 #else
  28 #define GETITIMER       getitimer
  29 #endif
  30
  31 #if defined __ASSUME_TIMEVAL64
  32 PSEUDO(GETITIMER, getitimer, 2)
  33         ret
  34 PSEUDO_END(GETITIMER)
  35 #else
  36 /* The problem here is that initially we made struct timeval compatible with
  37    OSF/1, using int32.  But we defined time_t with uint64, and later found
  38    that POSIX requires tv_sec to be time_t.
  39
  40    So now we have to do compatibility stuff.  */
  41
  42 /* The variable is shared between all wrappers around signal handling
  43    functions which have RT equivalents.  */
  44 .comm __libc_missing_axp_tv64, 4
  45
  46 LEAF(GETITIMER, 16)
  47         ldgp    gp, 0(pv)
  48         subq    sp, 16, sp
  49 #ifdef PROF
  50         .set noat
  51         lda     AT, _mcount
  52         jsr     AT, (AT), _mcount
  53         .set at
  54 #endif
  55         .prologue 1
  56
  57         ldl     t0, __libc_missing_axp_tv64
  58
  59         /* Save arguments in case we do need to fall back.  */
  60         stq     a0, 0(sp)
  61         stq     a1, 8(sp)
  62
  63         bne     t0, $do32
  64
  65         ldi     v0, SYS_ify(getitimer)
  66         callsys
  67         bne     a3, $err64
  68
  69         /* Everything ok.  */
  70         addq    sp, 16, sp
  71         ret
  72
  73         /* If we didn't get ENOSYS, it is a real error.  */
  74         .align 3
  75 $err64: cmpeq   v0, ENOSYS, t0
  76         beq     t0, $error
  77         stl     t0, __libc_missing_axp_tv64
  78
  79         /* Recover the saved arguments.  */
  80         ldq     a1, 8(sp)
  81         ldq     a0, 0(sp)
  82
  83         .align 3
  84 $do32:  ldi     v0, SYS_ify(osf_getitimer)
  85         callsys
  86         bne     a3, $error
  87
  88         /* Copy back to proper format.  */
  89         ldq     a1, 8(sp)
  90         ldl     t0, 0(a1)
  91         ldl     t1, 4(a1)
  92         ldl     t2, 8(a1)
  93         ldl     t3, 12(a1)
  94         stq     t0, 0(a1)
  95         stq     t1, 8(a1)
  96         stq     t2, 16(a1)
  97         stq     t3, 24(a1)
  98
  99         addq    sp, 16, sp
 100         ret
 101
 102         .align 3
 103 $error:
 104         addq    sp, 16, sp
 105         SYSCALL_ERROR_HANDLER
 106
 107 END(GETITIMER)
 108 #endif /* __ASSUME_TIMEVAL64 */
 109
 110 #if defined PIC && defined DO_VERSIONING
 111 default_symbol_version (__getitimer_tv64, getitimer, GLIBC_2.1)
 112 #endif