sysdeps/unix/sysv/linux/alpha/setitimer.S

   1 /* Copyright (C) 1998, 2003, 2006, 2012 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #define _ERRNO_H        1
  20 #include <bits/errno.h>
  21 #include <kernel-features.h>
  22
  23 .text
  24
  25 #if defined PIC && defined DO_VERSIONING
  26 #define SETITIMER       __setitimer_tv64
  27 #else
  28 #define SETITIMER       __setitimer
  29 #endif
  30
  31 #if defined __ASSUME_TIMEVAL64
  32 PSEUDO(SETITIMER, setitimer, 3)
  33         ret
  34 PSEUDO_END(SETITIMER)
  35 #else
  36 /* The problem here is that initially we made struct timeval compatible with
  37    OSF/1, using int32.  But we defined time_t with uint64, and later found
  38    that POSIX requires tv_sec to be time_t.
  39
  40    So now we have to do compatibility stuff.  */
  41
  42 /* The variable is shared between all wrappers around signal handling
  43    functions which have RT equivalents.  */
  44 .comm __libc_missing_axp_tv64, 4
  45
  46 LEAF(SETITIMER, 48)
  47         ldgp    gp, 0(pv)
  48         subq    sp, 48, sp
  49 #ifdef PROF
  50         .set noat
  51         lda     AT, _mcount
  52         jsr     AT, (AT), _mcount
  53         .set at
  54 #endif
  55         .prologue 1
  56
  57         ldl     t0, __libc_missing_axp_tv64
  58
  59         /* Save arguments in case we do need to fall back.  */
  60         stq     a0, 0(sp)
  61         stq     a1, 8(sp)
  62         stq     a2, 16(sp)
  63
  64         bne     t0, $do32
  65
  66         ldi     v0, SYS_ify(setitimer)
  67         callsys
  68         bne     a3, $err64
  69
  70         /* Everything ok.  */
  71         addq    sp, 48, sp
  72         ret
  73
  74         /* If we didn't get ENOSYS, it is a real error.  */
  75         .align 3
  76 $err64: cmpeq   v0, ENOSYS, t0
  77         beq     t0, $error
  78         stl     t0, __libc_missing_axp_tv64
  79
  80         /* Recover the saved arguments.  */
  81         ldq     a2, 16(sp)
  82         ldq     a1, 8(sp)
  83         ldq     a0, 0(sp)
  84
  85         .align 3
  86 $do32:
  87         /* Conditionally bounce new value down.  */
  88         beq     a1, 1f
  89         ldq     t0, 0(a1)
  90         ldq     t1, 8(a1)
  91         ldq     t2, 16(a1)
  92         ldq     t3, 24(a1)
  93         stl     t0, 32(sp)
  94         stl     t1, 36(sp)
  95         stl     t2, 40(sp)
  96         stl     t3, 44(sp)
  97         addq    sp, 32, a1
  98
  99 1:      ldi     v0, SYS_ify(osf_setitimer)
 100         callsys
 101         bne     a3, $error
 102
 103         /* Conditionaly bounce old value up.  */
 104         ldq     a2, 16(sp)
 105         bne     a2, 2f
 106         ldl     t0, 0(a2)
 107         ldl     t1, 4(a2)
 108         ldl     t2, 8(a2)
 109         ldl     t3, 12(a2)
 110         stq     t0, 0(a2)
 111         stq     t1, 8(a2)
 112         stq     t2, 48(a2)
 113         stq     t3, 24(a2)
 114
 115 2:      addq    sp, 48, sp
 116         ret
 117
 118         .align 3
 119 $error:
 120         addq    sp, 48, sp
 121         SYSCALL_ERROR_HANDLER
 122
 123 END(SETITIMER)
 124 #endif /* __ASSUME_TIMEVAL64 */
 125
 126 #if defined PIC && defined DO_VERSIONING
 127 default_symbol_version (__setitimer_tv64, __setitimer, GLIBC_2.1)
 128
 129 /* It seems to me to be a misfeature of the assembler that we can only
 130    have one version-alias per symbol.  So create an alias ourselves.
 131    The 'p' is for 'public'.  *Shrug*  */
 132 strong_alias (__setitimer_tv64, __setitimer_tv64p)
 133 default_symbol_version (__setitimer_tv64p, setitimer, GLIBC_2.1)
 134 #else
 135 weak_alias (__setitimer, setitimer)
 136 #endif