configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78
  79 dnl Generic infrastructure for drop-in additions to libc.
  80 AC_ARG_ENABLE(add-ons, dnl
  81 [  --enable-add-ons=DIR... configure and build named extra directories],
  82               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  83               [add_ons=])
  84 AC_CONFIG_SUBDIRS($add_ons)
  85 add_ons_pfx=
  86 if test x"$add_ons" != x; then
  87   for f in $add_ons; do
  88     add_ons_pfx="$add_ons_pfx $f/"
  89   done
  90 fi
  91
  92 AC_CANONICAL_HOST
  93
  94 # The way shlib-versions is used to generate soversions.mk uses a
  95 # fairly simplistic model for name recognition that can't distinguish
  96 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
  97 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
  98 # tell.  This doesn't get used much beyond that, so it's fairly safe.
  99 case "$host_os" in
 100 linux*)
 101   ;;
 102 gnu*)
 103   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 104   ;;
 105 esac
 106
 107 # We keep the original values in `$config_*' and never modify them, so we
 108 # can write them unchanged into config.make.  Everything else uses
 109 # $machine, $vendor, and $os, and changes them whenever convenient.
 110 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 111
 112 # Some configurations imply other options.
 113 case "$host_os" in
 114 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 115   # These systems always use GNU tools.
 116   gnu_ld=yes gnu_as=yes ;;
 117 esac
 118 case "$host_os" in
 119 linux*ecoff*)
 120   ;;
 121 gnu* | linux* | sysv4* | solaris2*)
 122   # These systems (almost) always use the ELF format.
 123   elf=yes
 124   ;;
 125 esac
 126
 127 machine=$config_machine
 128 vendor=$config_vendor
 129 os=$config_os
 130
 131 dnl We need to use [ and ] for other purposes for a while now.
 132 changequote(,)dnl
 133 # Expand the configuration machine name into a subdirectory by architecture
 134 # type and particular chip.
 135 case "$machine" in
 136 a29k | am29000) base_machine=a29k machine=a29k ;;
 137 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 138 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 139 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 140 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 141 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 142 m88???)         base_machine=m88k machine=m88k/$machine ;;
 143 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 144 mips*)          base_machine=mips machine=mips/$machine ;;
 145 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 146 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 147 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 148 esac
 149 changequote([,])dnl
 150 AC_SUBST(base_machine)
 151
 152 # Compute the list of sysdep directories for this configuration.
 153 # This can take a while to compute.
 154 sysdep_dir=$srcdir/sysdeps
 155 AC_MSG_CHECKING(sysdep dirs)
 156 dnl We need to use [ and ] for other purposes for a while now.
 157 changequote(,)dnl
 158 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 159 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 160
 161 case "$os" in
 162 gnu*)
 163   base_os=mach/hurd ;;
 164 netbsd* | 386bsd* | freebsd* | bsdi*)
 165   base_os=unix/bsd/bsd4.4 ;;
 166 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 167   base_os=unix/bsd ;;
 168 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 169   base_os=unix/sysv ;;
 170 solaris[2-9]*)
 171   base_os=unix/sysv/sysv4 ;;
 172 none)
 173   base_os=standalone ;;
 174 *)
 175   base_os='' ;;
 176 esac
 177
 178 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 179 tail=$os
 180 ostry=$os
 181 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 182   ostry="$ostry /$o"
 183   tail=$o
 184 done
 185 o=`echo $tail | sed 's/[0-9]*$//'`
 186 if test $o != $tail; then
 187   ostry="$ostry /$o"
 188 fi
 189 # For linux-gnu, try linux-gnu, then linux.
 190 o=`echo $tail | sed 's/-.*$//'`
 191 if test $o != $tail; then
 192   ostry="$ostry /$o"
 193 fi
 194
 195 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 196 base=
 197 tail=$base_os
 198 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 199   set $b
 200   base="$base /$1"
 201   tail="$2"
 202 done
 203
 204 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 205 mach=
 206 tail=$machine
 207 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 208   set $m
 209   # Prepend the machine's FPU directory unless --without-fp.
 210   if test "$with_fp" = yes; then
 211     mach="$mach /$1/fpu"
 212   fi
 213   mach="$mach /$1"
 214   tail="$2"
 215 done
 216
 217 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 218 changequote([,])dnl
 219
 220 # Find what sysdep directories exist.
 221 sysnames=
 222 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 223 for d in $add_ons_pfx ''; do
 224   for b in $base ''; do
 225     for m0 in $mach ''; do
 226       for v in /$vendor ''; do
 227         for o in /$ostry ''; do
 228           for m in $mach ''; do
 229             if test "$m0$b$v$o$m"; then
 230               try="${d}sysdeps$m0$b$v$o$m"
 231               test -n "$enable_debug_configure" &&
 232               echo "$0 [DEBUG]: try $try" >&2
 233               case $try in
 234                 /*) dest=$try ;;
 235                 *)  dest=$srcdir/$try ;;
 236               esac
 237               if test -d $dest; then
 238                 sysnames="$sysnames $try"
 239                 { test -n "$o" || test -n "$b"; } && os_used=t
 240                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 241               fi
 242             fi
 243           done
 244         done
 245       done
 246     done
 247   done
 248 done
 249 IFS="$ac_save_ifs"
 250
 251 if test -z "$os_used" && test "$os" != none; then
 252   AC_MSG_ERROR(Operating system $os is not supported.)
 253 fi
 254 if test -z "$machine_used" && test "$machine" != none; then
 255   AC_MSG_ERROR(The $machine is not supported.)
 256 fi
 257
 258 # We have now validated the configuration.
 259
 260
 261 # If using ELF, look for an `elf' subdirectory of each machine directory.
 262 # We prepend these rather than inserting them whereever the machine appears
 263 # because things specified by the machine's ELF ABI should override
 264 # OS-specific things, and should always be the same for any OS on the
 265 # machine (otherwise what's the point of an ABI?).
 266 if test "$elf" = yes; then
 267   elf_dirs=
 268   for d in $add_ons_pfx ''; do
 269     case $d in
 270       /*) xsrcdir= ;;
 271       *)  xsrcdir=$srcdir/ ;;
 272     esac
 273     for m in $mach; do
 274       if test -d $xsrcdir${d}sysdeps$m/elf; then
 275         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 276       fi
 277     done
 278   done
 279   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 280 fi
 281
 282
 283 # Expand the list of system names into a full list of directories
 284 # from each element's parent name and Implies file (if present).
 285 set $sysnames
 286 names=
 287 while test $# -gt 0; do
 288   name=$1
 289   shift
 290
 291   case " $names " in *" $name "*)
 292     # Already in the list.
 293     continue
 294   esac
 295
 296   # Report each name as we discover it, so there is no long pause in output.
 297   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 298
 299   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 300
 301   case $name in
 302     /*) xsrcdir= ;;
 303     *)  xsrcdir=$srcdir/ ;;
 304   esac
 305   test -n "$enable_debug_configure" &&
 306   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 307
 308   if test -f $xsrcdir$name/Implies; then
 309     # Collect more names from the `Implies' file (removing comments).
 310     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 311     implied=
 312     for x in $implied_candidate; do
 313       if test -d $xsrcdir$name_base/$x; then
 314         implied="$implied $name_base/$x";
 315       else
 316         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 317       fi
 318     done
 319   else
 320     implied=
 321   fi
 322
 323   # Add NAME to the list of names.
 324   names="$names $name"
 325
 326   # Find the parent of NAME, using the empty string if it has none.
 327 changequote(,)dnl
 328   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 329 changequote([,])dnl
 330
 331   # Add the names implied by NAME, and NAME's parent (if it has one), to
 332   # the list of names to be processed (the argument list).  We prepend the
 333   # implied names to the list and append the parent.  We want implied
 334   # directories to come before further directories inferred from the
 335   # configuration components; this ensures that for sysv4, unix/common
 336   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 337   # after sysv4).
 338   sysnames="`echo $implied $* $parent`"
 339   test -n "$sysnames" && set $sysnames
 340 done
 341
 342 # Add the default directories.
 343 sysnames="$names sysdeps/generic sysdeps/stub"
 344 AC_SUBST(sysnames)
 345 # The other names were emitted during the scan.
 346 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 347
 348
 349 ### Locate tools.
 350
 351 AC_PROG_INSTALL
 352 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 353   # The makefiles need to use a different form to find it in $srcdir.
 354   INSTALL='$(..)./install-sh -c'
 355 fi
 356 AC_PROG_LN_S
 357 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 358
 359 AC_CHECK_TOOL(CC, gcc)
 360 if test $host != $build; then
 361   AC_CHECK_PROG(BUILD_CC, gcc cc)
 362 fi
 363 AC_PROG_CPP
 364 AC_CHECK_TOOL(AR, ar)
 365 AC_CHECK_TOOL(RANLIB, ranlib, :)
 366
 367 AC_PATH_PROG(BASH, bash, no)
 368 if test "$BASH" != no &&
 369    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 370   libc_cv_have_bash2=yes
 371 else
 372   libc_cv_have_bash2=no
 373 fi
 374 AC_SUBST(libc_cv_have_bash2)
 375
 376 dnl We need a ksh compatible shell for tzselect.
 377 if test "$BASH" = no; then
 378   AC_PATH_PROG(KSH, ksh, no)
 379   if test "$KSH" = no; then
 380     libc_cv_have_ksh=no
 381   else
 382     libc_cv_have_ksh=yes
 383   fi
 384 else
 385   KSH="$BASH"
 386   AC_SUBST(KSH)
 387   libc_cv_have_ksh=yes
 388 fi
 389 AC_SUBST(libc_cv_have_ksh)
 390
 391 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 392 echo '#include <stddef.h>
 393 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 394 if eval "$ac_cpp conftest.c 2>/dev/null" \
 395 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 396   libc_cv_signed_size_t=no
 397 else
 398   libc_cv_signed_size_t=yes
 399 fi
 400 rm -f conftest*])
 401 if test $libc_cv_signed_size_t = yes; then
 402   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 403   cat >> confdefs.h <<\EOF
 404 #undef __SIZE_TYPE__
 405 #define __SIZE_TYPE__ unsigned
 406 EOF
 407 fi
 408
 409 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 410 AC_TRY_COMPILE(dnl
 411 [#define __need_size_t
 412 #define __need_wchar_t
 413 #include <stddef.h>
 414 #define __need_NULL
 415 #include <stddef.h>], [size_t size; wchar_t wchar;
 416 #ifdef offsetof
 417 #error stddef.h ignored __need_*
 418 #endif
 419 if (&size == NULL || &wchar == NULL) abort ();],
 420                libc_cv_friendly_stddef=yes,
 421                libc_cv_friendly_stddef=no)])
 422 if test $libc_cv_friendly_stddef = yes; then
 423   config_vars="$config_vars
 424 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 425 fi
 426
 427 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 428                libc_cv_need_minus_P, [dnl
 429 cat > conftest.S <<EOF
 430 #include "confdefs.h"
 431 /* Nothing whatsoever.  */
 432 EOF
 433 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 434   libc_cv_need_minus_P=no
 435 else
 436   libc_cv_need_minus_P=yes
 437 fi
 438 rm -f conftest*])
 439 if test $libc_cv_need_minus_P = yes; then
 440   config_vars="$config_vars
 441 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 442 fi
 443
 444 AC_CACHE_CHECK(for assembler global-symbol directive,
 445                libc_cv_asm_global_directive, [dnl
 446 libc_cv_asm_global_directive=UNKNOWN
 447 for ac_globl in .globl .global; do
 448   cat > conftest.s <<EOF
 449 .text
 450 ${ac_globl} foo
 451 foo: .long 0
 452 EOF
 453   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 454     libc_cv_asm_global_directive=${ac_globl}
 455   fi
 456   rm -f conftest*
 457   test $libc_cv_asm_global_directive != UNKNOWN && break
 458 done])
 459 if test $libc_cv_asm_global_directive = UNKNOWN; then
 460   AC_MSG_ERROR(cannot determine asm global directive)
 461 else
 462   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 463 fi
 464
 465 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 466 cat > conftest.s <<EOF
 467 .text
 468 foo: .long 0
 469 .set glibc_conftest_frobozz,foo
 470 $libc_cv_asm_global_directive glibc_conftest_frobozz
 471 EOF
 472 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 473 # (but it doesn't work), so we must do a linking check to be sure.
 474 cat > conftest1.c <<\EOF
 475 extern int glibc_conftest_frobozz;
 476 main () { printf ("%d\n", glibc_conftest_frobozz); }
 477 EOF
 478 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 479             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 480   libc_cv_asm_set_directive=yes
 481 else
 482   libc_cv_asm_set_directive=no
 483 fi
 484 rm -f conftest*])
 485 if test $libc_cv_asm_set_directive = yes; then
 486   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 487 fi
 488
 489 if test $elf = yes; then
 490   AC_CACHE_CHECK(for .previous assembler directive,
 491                  libc_cv_asm_previous_directive, [dnl
 492   cat > conftest.s <<EOF
 493 .section foo_section
 494 .previous
 495 EOF
 496   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 497     libc_cv_asm_previous_directive=yes
 498   else
 499     libc_cv_asm_previous_directive=no
 500   fi
 501   rm -f conftest*])
 502   if test $libc_cv_asm_previous_directive = yes; then
 503     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 504   else
 505     AC_CACHE_CHECK(for .popsection assembler directive,
 506                    libc_cv_asm_popsection_directive, [dnl
 507     cat > conftest.s <<EOF
 508 .pushsection foo_section
 509 .popsection
 510 EOF
 511     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 512       libc_cv_asm_popsection_directive=yes
 513     else
 514       libc_cv_asm_popsection_directive=no
 515     fi
 516     rm -f conftest*])
 517     if test $libc_cv_asm_popsection_directive = yes; then
 518       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 519     fi
 520   fi
 521 fi
 522
 523 if test $elf != yes; then
 524   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 525                  [AC_TRY_COMPILE(, [asm (".section .init");
 526                                     asm (".section .fini");
 527                                     asm (".text");],
 528                                  libc_cv_have_initfini=yes,
 529                                  libc_cv_have_initfini=no)])
 530   AC_SUBST(libc_cv_have_initfini)dnl
 531   if test $libc_cv_have_initfini = yes; then
 532     AC_DEFINE(HAVE_INITFINI)
 533   fi
 534 fi
 535
 536 if test $elf = yes; then
 537   libc_cv_asm_underscores=no
 538 else
 539   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 540                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 541                               libc_cv_asm_underscores=yes,
 542                               libc_cv_asm_underscores=no)])
 543 fi
 544 if test $libc_cv_asm_underscores = no; then
 545   AC_DEFINE(NO_UNDERSCORES)
 546 fi
 547
 548 if test $elf = yes; then
 549   libc_cv_weak_symbols=yes
 550   libc_cv_asm_weak_directive=yes
 551   libc_cv_asm_weakext_directive=no
 552 else
 553   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 554                  [dnl
 555 cat > conftest.s <<EOF
 556 .text
 557 ${libc_cv_asm_global_directive} foo
 558 foo: .long 0
 559 .weak foo
 560 .weak bar; bar = foo
 561 EOF
 562   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 563     libc_cv_asm_weak_directive=yes
 564   else
 565     libc_cv_asm_weak_directive=no
 566   fi
 567   rm -f conftest*])
 568
 569 if test $libc_cv_asm_weak_directive = no; then
 570   AC_CACHE_CHECK(for assembler .weakext directive,
 571                  libc_cv_asm_weakext_directive,
 572                  [dnl
 573 cat > conftest.s <<EOF
 574 .text
 575 ${libc_cv_asm_global_directive} foo
 576 foo: .long 0
 577 .weakext foo
 578 .weakext foo, bar
 579 EOF
 580   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 581     libc_cv_asm_weakext_directive=yes
 582   else
 583     libc_cv_asm_weakext_directive=no
 584   fi
 585   rm -f conftest*])
 586
 587   fi # no .weak
 588 fi # not ELF
 589
 590 if test $libc_cv_asm_weak_directive = yes; then
 591   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 592 elif test $libc_cv_asm_weakext_directive = yes; then
 593   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 594 fi
 595
 596 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 597 cat > conftest.c <<\EOF
 598 _start () {}
 599 int __eh_pc;
 600 __throw () {}
 601 EOF
 602 dnl No \ in command here because it ends up inside ''.
 603 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 604                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 605                             -o conftest conftest.c]); then
 606   libc_cv_ld_no_whole_archive=yes
 607 else
 608   libc_cv_ld_no_whole_archive=no
 609 fi
 610 rm -f conftest*])
 611 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 612
 613 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 614 cat > conftest.c <<\EOF
 615 _start () {}
 616 int __eh_pc;
 617 __throw () {}
 618 EOF
 619 dnl No \ in command here because it ends up inside ''.
 620 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 621                             -nostdlib -nostartfiles -fno-exceptions
 622                             -o conftest conftest.c]); then
 623   libc_cv_gcc_no_exceptions=yes
 624 else
 625   libc_cv_gcc_no_exceptions=no
 626 fi
 627 rm -f conftest*])
 628 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 629
 630 ### End of automated tests.
 631 ### Now run sysdeps configure fragments.
 632
 633 # sysdeps configure fragments may set these with files to be linked below.
 634 libc_link_dests=
 635 libc_link_sources=
 636
 637 # Iterate over all the sysdep directories we will use, running their
 638 # configure fragments, and looking for a uname implementation.
 639 uname=
 640 for dir in $sysnames; do
 641   case $dir in
 642     /*) dest=$dir ;;
 643     *)  dest=$srcdir/$dir ;;
 644   esac
 645   if test -r $dest/configure; then
 646     AC_MSG_RESULT(running configure fragment for $dest)
 647     . $dest/configure
 648   fi
 649 [
 650   if test -z "$uname"; then
 651     if test -r $sysdep_dir/$dir/uname.c ||
 652        test -r $sysdep_dir/$dir/uname.S ||
 653        { test -r $sysdep_dir/$dir/syscalls.list &&
 654          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 655       uname=$dir
 656     fi
 657   fi
 658 ]dnl
 659 done
 660
 661 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 662
 663 # If we will use the generic uname implementation, we must figure out what
 664 # it will say by examining the system, and write the results in config-name.h.
 665 if test "$uname" = generic; then
 666
 667 changequote(,)dnl
 668   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 669 changequote([,])dnl
 670   if test $uname_sysname != $config_os; then
 671     config_release=`echo $config_os | sed s/$uname_sysname//`
 672   fi
 673 dnl
 674 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 675     if test -r /vmunix; then
 676       kernel_id=`strings /vmunix | grep UNIX`
 677     elif test -r /dynix; then
 678       kernel_id=`strings /dynix | grep DYNIX`
 679     else
 680       kernel_id=
 681     fi
 682 ])dnl
 683
 684   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 685 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 686 changequote(,)dnl
 687   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 688 changequote([,])dnl
 689   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 690          != x$config_release; then
 691     # The configuration release is a substring of the kernel release.
 692     libc_cv_uname_release=$kernel_release
 693   elif test x$config_release != x; then
 694     libc_cv_uname_release=$config_release
 695   elif test x$kernel_release != x; then
 696     libc_cv_uname_release=$kernel_release
 697   else
 698     libc_cv_uname_release=unknown
 699   fi])
 700   uname_release="$libc_cv_uname_release"
 701
 702   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 703 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 704 changequote(,)dnl
 705   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 706 changequote([,])dnl
 707   if test -n "$kernel_version"; then
 708     libc_cv_uname_version="$kernel_version"
 709   else
 710     libc_cv_uname_version=unknown
 711   fi])
 712   uname_version="$libc_cv_uname_version"
 713
 714 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 715   config_uname=config-name.h:config-name.in
 716 else
 717   # For non-generic uname, we don't need to create config-name.h at all.
 718   config_uname=
 719 fi
 720
 721 AC_MSG_CHECKING(stdio selection)
 722 AC_SUBST(stdio)
 723 case $stdio in
 724 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 725 default) stdio=stdio ;;
 726 esac
 727 AC_MSG_RESULT($stdio)
 728
 729 AC_SUBST(libc_cv_slibdir)
 730 AC_SUBST(libc_cv_sysconfdir)
 731 AC_SUBST(libc_cv_rootsbindir)
 732
 733 AC_SUBST(has_ldconfig)
 734
 735 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 736 if test $gnu_ld = yes; then
 737   AC_DEFINE(HAVE_GNU_LD)
 738 fi
 739 if test $gnu_as = yes; then
 740   AC_DEFINE(HAVE_GNU_AS)
 741 fi
 742 if test $elf = yes; then
 743   AC_DEFINE(HAVE_ELF)
 744 fi
 745
 746 AC_SUBST(shared)
 747 if test $shared = default; then
 748   if test $gnu_ld = yes; then
 749     shared=$elf
 750   else
 751     # For now we do not assume shared libs are available.  In future more
 752     # tests might become available.
 753     shared=no
 754   fi
 755 fi
 756 AC_SUBST(profile)
 757 AC_SUBST(omitfp)
 758
 759 AC_SUBST(DEFINES)
 760
 761 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 762   config_makefile=
 763 else
 764   config_makefile=Makefile
 765 fi
 766
 767 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 768 AC_SUBST(VERSION)
 769
 770 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 771           [echo '$config_vars' >> config.make])