sysdeps/i386/fpu/e_powl.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004, 2005
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <machine/asm.h>
  23
  24 #ifdef __ELF__
  25         .section .rodata
  26 #else
  27         .text
  28 #endif
  29
  30         .align ALIGNARG(4)
  31         ASM_TYPE_DIRECTIVE(infinity,@object)
  32 inf_zero:
  33 infinity:
  34         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  35         ASM_SIZE_DIRECTIVE(infinity)
  36         ASM_TYPE_DIRECTIVE(zero,@object)
  37 zero:   .double 0.0
  38         ASM_SIZE_DIRECTIVE(zero)
  39         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  40 minf_mzero:
  41 minfinity:
  42         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  43 mzero:
  44         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  45         ASM_SIZE_DIRECTIVE(minf_mzero)
  46         ASM_TYPE_DIRECTIVE(one,@object)
  47 one:    .double 1.0
  48         ASM_SIZE_DIRECTIVE(one)
  49         ASM_TYPE_DIRECTIVE(limit,@object)
  50 limit:  .double 0.29
  51         ASM_SIZE_DIRECTIVE(limit)
  52         ASM_TYPE_DIRECTIVE(p63,@object)
  53 p63:    .byte 0, 0, 0, 0, 0, 0, 0xe0, 0x43
  54         ASM_SIZE_DIRECTIVE(p63)
  55
  56 #ifdef PIC
  57 #define MO(op) op##@GOTOFF(%ecx)
  58 #define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  59 #else
  60 #define MO(op) op
  61 #define MOX(op,x,f) op(,x,f)
  62 #endif
  63
  64         .text
  65 ENTRY(__ieee754_powl)
  66         fldt    16(%esp)        // y
  67         fxam
  68
  69 #ifdef  PIC
  70         LOAD_PIC_REG (cx)
  71 #endif
  72
  73         fnstsw
  74         movb    %ah, %dl
  75         andb    $0x45, %ah
  76         cmpb    $0x40, %ah      // is y == 0 ?
  77         je      11f
  78
  79         cmpb    $0x05, %ah      // is y == ±inf ?
  80         je      12f
  81
  82         cmpb    $0x01, %ah      // is y == NaN ?
  83         je      30f
  84
  85         fldt    4(%esp)         // x : y
  86
  87         subl    $8,%esp
  88         cfi_adjust_cfa_offset (8)
  89
  90         fxam
  91         fnstsw
  92         movb    %ah, %dh
  93         andb    $0x45, %ah
  94         cmpb    $0x40, %ah
  95         je      20f             // x is ±0
  96
  97         cmpb    $0x05, %ah
  98         je      15f             // x is ±inf
  99
 100         fxch                    // y : x
 101
 102         /* fistpll raises invalid exception for |y| >= 1L<<63.  */
 103         fld     %st             // y : y : x
 104         fabs                    // |y| : y : x
 105         fcompl  MO(p63)         // y : x
 106         fnstsw
 107         sahf
 108         jnc     2f
 109
 110         /* First see whether `y' is a natural number.  In this case we
 111            can use a more precise algorithm.  */
 112         fld     %st             // y : y : x
 113         fistpll (%esp)          // y : x
 114         fildll  (%esp)          // int(y) : y : x
 115         fucomp  %st(1)          // y : x
 116         fnstsw
 117         sahf
 118         jne     2f
 119
 120         /* OK, we have an integer value for y.  */
 121         popl    %eax
 122         cfi_adjust_cfa_offset (-4)
 123         popl    %edx
 124         cfi_adjust_cfa_offset (-4)
 125         orl     $0, %edx
 126         fstp    %st(0)          // x
 127         jns     4f              // y >= 0, jump
 128         fdivrl  MO(one)         // 1/x          (now referred to as x)
 129         negl    %eax
 130         adcl    $0, %edx
 131         negl    %edx
 132 4:      fldl    MO(one)         // 1 : x
 133         fxch
 134
 135 6:      shrdl   $1, %edx, %eax
 136         jnc     5f
 137         fxch
 138         fmul    %st(1)          // x : ST*x
 139         fxch
 140 5:      fmul    %st(0), %st     // x*x : ST*x
 141         shrl    $1, %edx
 142         movl    %eax, %ecx
 143         orl     %edx, %ecx
 144         jnz     6b
 145         fstp    %st(0)          // ST*x
 146         ret
 147
 148         /* y is ±NAN */
 149 30:     fldt    4(%esp)         // x : y
 150         fldl    MO(one)         // 1.0 : x : y
 151         fucomp  %st(1)          // x : y
 152         fnstsw
 153         sahf
 154         je      31f
 155         fxch                    // y : x
 156 31:     fstp    %st(1)
 157         ret
 158
 159         cfi_adjust_cfa_offset (8)
 160         .align ALIGNARG(4)
 161 2:      /* y is a real number.  */
 162         fxch                    // x : y
 163         fldl    MO(one)         // 1.0 : x : y
 164         fld     %st(1)          // x : 1.0 : x : y
 165         fsub    %st(1)          // x-1 : 1.0 : x : y
 166         fabs                    // |x-1| : 1.0 : x : y
 167         fcompl  MO(limit)       // 1.0 : x : y
 168         fnstsw
 169         fxch                    // x : 1.0 : y
 170         sahf
 171         ja      7f
 172         fsub    %st(1)          // x-1 : 1.0 : y
 173         fyl2xp1                 // log2(x) : y
 174         jmp     8f
 175
 176 7:      fyl2x                   // log2(x) : y
 177 8:      fmul    %st(1)          // y*log2(x) : y
 178         fxam
 179         fnstsw
 180         andb    $0x45, %ah
 181         cmpb    $0x05, %ah      // is y*log2(x) == ±inf ?
 182         je      28f
 183         fst     %st(1)          // y*log2(x) : y*log2(x)
 184         frndint                 // int(y*log2(x)) : y*log2(x)
 185         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 186         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 187         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 188         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 189         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 190         addl    $8, %esp
 191         cfi_adjust_cfa_offset (-8)
 192         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 193         ret
 194
 195         cfi_adjust_cfa_offset (8)
 196 28:     fstp    %st(1)          // y*log2(x)
 197         fldl    MO(one)         // 1 : y*log2(x)
 198         fscale                  // 2^(y*log2(x)) : y*log2(x)
 199         addl    $8, %esp
 200         cfi_adjust_cfa_offset (-8)
 201         fstp    %st(1)          // 2^(y*log2(x))
 202         ret
 203
 204         // pow(x,±0) = 1
 205         .align ALIGNARG(4)
 206 11:     fstp    %st(0)          // pop y
 207         fldl    MO(one)
 208         ret
 209
 210         // y == ±inf
 211         .align ALIGNARG(4)
 212 12:     fstp    %st(0)          // pop y
 213         fldt    4(%esp)         // x
 214         fabs
 215         fcompl  MO(one)         // < 1, == 1, or > 1
 216         fnstsw
 217         andb    $0x45, %ah
 218         cmpb    $0x45, %ah
 219         je      13f             // jump if x is NaN
 220
 221         cmpb    $0x40, %ah
 222         je      14f             // jump if |x| == 1
 223
 224         shlb    $1, %ah
 225         xorb    %ah, %dl
 226         andl    $2, %edx
 227         fldl    MOX(inf_zero, %edx, 4)
 228         ret
 229
 230         .align ALIGNARG(4)
 231 14:     fldl    MO(one)
 232         ret
 233
 234         .align ALIGNARG(4)
 235 13:     fldt    4(%esp)         // load x == NaN
 236         ret
 237
 238         cfi_adjust_cfa_offset (8)
 239         .align ALIGNARG(4)
 240         // x is ±inf
 241 15:     fstp    %st(0)          // y
 242         testb   $2, %dh
 243         jz      16f             // jump if x == +inf
 244
 245         // We must find out whether y is an odd integer.
 246         fld     %st             // y : y
 247         fistpll (%esp)          // y
 248         fildll  (%esp)          // int(y) : y
 249         fucompp                 // <empty>
 250         fnstsw
 251         sahf
 252         jne     17f
 253
 254         // OK, the value is an integer, but is it odd?
 255         popl    %eax
 256         cfi_adjust_cfa_offset (-4)
 257         popl    %edx
 258         cfi_adjust_cfa_offset (-4)
 259         andb    $1, %al
 260         jz      18f             // jump if not odd
 261         // It's an odd integer.
 262         shrl    $31, %edx
 263         fldl    MOX(minf_mzero, %edx, 8)
 264         ret
 265
 266         cfi_adjust_cfa_offset (8)
 267         .align ALIGNARG(4)
 268 16:     fcompl  MO(zero)
 269         addl    $8, %esp
 270         cfi_adjust_cfa_offset (-8)
 271         fnstsw
 272         shrl    $5, %eax
 273         andl    $8, %eax
 274         fldl    MOX(inf_zero, %eax, 1)
 275         ret
 276
 277         cfi_adjust_cfa_offset (8)
 278         .align ALIGNARG(4)
 279 17:     shll    $30, %edx       // sign bit for y in right position
 280         addl    $8, %esp
 281         cfi_adjust_cfa_offset (-8)
 282 18:     shrl    $31, %edx
 283         fldl    MOX(inf_zero, %edx, 8)
 284         ret
 285
 286         cfi_adjust_cfa_offset (8)
 287         .align ALIGNARG(4)
 288         // x is ±0
 289 20:     fstp    %st(0)          // y
 290         testb   $2, %dl
 291         jz      21f             // y > 0
 292
 293         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 294         testb   $2, %dh
 295         jz      25f
 296
 297         fld     %st             // y : y
 298         fistpll (%esp)          // y
 299         fildll  (%esp)          // int(y) : y
 300         fucompp                 // <empty>
 301         fnstsw
 302         sahf
 303         jne     26f
 304
 305         // OK, the value is an integer, but is it odd?
 306         popl    %eax
 307         cfi_adjust_cfa_offset (-4)
 308         popl    %edx
 309         cfi_adjust_cfa_offset (-4)
 310         andb    $1, %al
 311         jz      27f             // jump if not odd
 312         // It's an odd integer.
 313         // Raise divide-by-zero exception and get minus infinity value.
 314         fldl    MO(one)
 315         fdivl   MO(zero)
 316         fchs
 317         ret
 318
 319         cfi_adjust_cfa_offset (8)
 320 25:     fstp    %st(0)
 321 26:     addl    $8, %esp
 322         cfi_adjust_cfa_offset (-8)
 323 27:     // Raise divide-by-zero exception and get infinity value.
 324         fldl    MO(one)
 325         fdivl   MO(zero)
 326         ret
 327
 328         cfi_adjust_cfa_offset (8)
 329         .align ALIGNARG(4)
 330         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 331 21:     testb   $2, %dh
 332         jz      22f
 333
 334         fld     %st             // y : y
 335         fistpll (%esp)          // y
 336         fildll  (%esp)          // int(y) : y
 337         fucompp                 // <empty>
 338         fnstsw
 339         sahf
 340         jne     23f
 341
 342         // OK, the value is an integer, but is it odd?
 343         popl    %eax
 344         cfi_adjust_cfa_offset (-4)
 345         popl    %edx
 346         cfi_adjust_cfa_offset (-4)
 347         andb    $1, %al
 348         jz      24f             // jump if not odd
 349         // It's an odd integer.
 350         fldl    MO(mzero)
 351         ret
 352
 353         cfi_adjust_cfa_offset (8)
 354 22:     fstp    %st(0)
 355 23:     addl    $8, %esp        // Don't use 2 x pop
 356         cfi_adjust_cfa_offset (-8)
 357 24:     fldl    MO(zero)
 358         ret
 359
 360 END(__ieee754_powl)