sysdeps/i386/rshift.S

   1 /* i80386 __mpn_rshift --
   2    Copyright (C) 1992, 1994, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU MP Library.
   4
   5    The GNU MP Library is free software; you can redistribute it and/or modify
   6    it under the terms of the GNU Library General Public License as published by
   7    the Free Software Foundation; either version 2 of the License, or (at your
   8    option) any later version.
   9
  10    The GNU MP Library is distributed in the hope that it will be useful, but
  11    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  12    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  13    License for more details.
  14
  15    You should have received a copy of the GNU Library General Public License
  16    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  17    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  18    MA 02111-1307, USA. */
  19
  20 /*
  21   INPUT PARAMETERS
  22   res_ptr       (sp + 4)
  23   s_ptr         (sp + 8)
  24   size          (sp + 12)
  25   cnt           (sp + 16)
  26 */
  27
  28 #include "sysdep.h"
  29 #include "asm-syntax.h"
  30
  31 .text
  32         ALIGN (3)
  33         .globl C_SYMBOL_NAME(__mpn_rshift)
  34 C_SYMBOL_NAME(__mpn_rshift:)
  35         pushl   %edi
  36         pushl   %esi
  37         pushl   %ebx
  38
  39         movl    16(%esp),%edi           /* res_ptr */
  40         movl    20(%esp),%esi           /* s_ptr */
  41         movl    24(%esp),%edx           /* size */
  42         movl    28(%esp),%ecx           /* cnt */
  43
  44         leal    -4(%edi,%edx,4),%edi
  45         leal    (%esi,%edx,4),%esi
  46         negl    %edx
  47
  48         movl    (%esi,%edx,4),%ebx      /* read least significant limb */
  49         xorl    %eax,%eax
  50         shrdl   %cl,%ebx,%eax           /* compute carry limb */
  51         incl    %edx
  52         jz      L(end)
  53         pushl   %eax                    /* push carry limb onto stack */
  54         testb   $1,%edx
  55         jnz     L(1)                    /* enter loop in the middle */
  56         movl    %ebx,%eax
  57
  58         ALIGN (3)
  59 L(oop): movl    (%esi,%edx,4),%ebx      /* load next higher limb */
  60         shrdl   %cl,%ebx,%eax           /* compute result limb */
  61         movl    %eax,(%edi,%edx,4)      /* store it */
  62         incl    %edx
  63 L(1):   movl    (%esi,%edx,4),%eax
  64         shrdl   %cl,%eax,%ebx
  65         movl    %ebx,(%edi,%edx,4)
  66         incl    %edx
  67         jnz     L(oop)
  68
  69         shrl    %cl,%eax                /* compute most significant limb */
  70         movl    %eax,(%edi)             /* store it */
  71
  72         popl    %eax                    /* pop carry limb */
  73
  74         popl    %ebx
  75         popl    %esi
  76         popl    %edi
  77         ret
  78
  79 L(end): shrl    %cl,%ebx                /* compute most significant limb */
  80         movl    %ebx,(%edi)             /* store it */
  81
  82         popl    %ebx
  83         popl    %esi
  84         popl    %edi
  85         ret