sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #include <jmp_buf.h>
  23
  24         /* Binary compatibility entry point.  */
  25 ENTRY (__setjmp)
  26         popl %eax               /* Pop return address.  */
  27         popl %ecx               /* Pop jmp_buf.  */
  28         pushl $0                /* Push zero argument.  */
  29         pushl %ecx              /* Push jmp_buf.  */
  30         pushl %eax              /* Push back return address.  */
  31
  32 ENTRY (__sigsetjmp)
  33         movl 4(%esp), %eax      /* User's jmp_buf in %eax.  */
  34         /* Save registers.  */
  35         movl %ebx, (JB_BX*4)(%eax)
  36         movl %esi, (JB_SI*4)(%eax)
  37         movl %edi, (JB_DI*4)(%eax)
  38         movl %ebp, (JB_BP*4)(%eax)
  39         leal 4(%esp), %ecx      /* Save SP as it will be after we return.  */
  40         movl %ecx, (JB_SP*4)(%eax)
  41         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  42         movl %ecx, (JB_PC*4)(%eax)
  43
  44         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  45 #ifdef  PIC
  46         /* We cannot use the PLT, because it requires that %ebx be set, but
  47            we can't save and restore our caller's value.  Instead, we do an
  48            indirect jump through the GOT, using for the temporary register
  49            %ecx, which is call-clobbered.  */
  50         call here
  51 here:   popl %ecx
  52         addl $_GLOBAL_OFFSET_TABLE_+[.-here], %ecx
  53         movl C_SYMBOL_NAME(__sigjmp_save@GOT)(%ecx), %ecx
  54         jmp *%ecx
  55 #else
  56         jmp __sigjmp_save
  57 #endif
  58 END (__sigsetjmp)