sysdeps/libm-i387/e_powf.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(infinity,@object)
  31 inf_zero:
  32 infinity:
  33         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  34         ASM_SIZE_DIRECTIVE(infinity)
  35         ASM_TYPE_DIRECTIVE(zero,@object)
  36 zero:   .double 0.0
  37         ASM_SIZE_DIRECTIVE(zero)
  38         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  39 minf_mzero:
  40 minfinity:
  41         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  42 mzero:
  43         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  44         ASM_SIZE_DIRECTIVE(minf_mzero)
  45         ASM_TYPE_DIRECTIVE(one,@object)
  46 one:    .double 1.0
  47         ASM_SIZE_DIRECTIVE(one)
  48         ASM_TYPE_DIRECTIVE(limit,@object)
  49 limit:  .double 0.29
  50         ASM_SIZE_DIRECTIVE(limit)
  51         ASM_TYPE_DIRECTIVE(nan,@object)
  52 nan:    .byte 0, 0, 0, 0, 0, 0, 0xff, 0x7f
  53         ASM_SIZE_DIRECTIVE(nan)
  54
  55 #ifdef PIC
  56 #define MO(op) op##@GOTOFF(%ecx)
  57 #define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  58 #else
  59 #define MO(op) op
  60 #define MOX(op,x,f) op(,x,f)
  61 #endif
  62
  63         .text
  64 ENTRY(__ieee754_powf)
  65         flds    8(%esp) // y
  66         fxam
  67
  68 #ifdef  PIC
  69         call    1f
  70 1:      popl    %ecx
  71         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %ecx
  72 #endif
  73
  74         fnstsw
  75         movb    %ah, %dl
  76         andb    $0x45, %ah
  77         cmpb    $0x40, %ah      // is y == 0 ?
  78         je      11f
  79
  80         cmpb    $0x05, %ah      // is y == ±inf ?
  81         je      12f
  82
  83         cmpb    $0x01, %ah      // is y == NaN ?
  84         je      30f
  85
  86         flds    4(%esp)         // x : y
  87
  88         subl    $4, %esp
  89
  90         fxam
  91         fnstsw
  92         movb    %ah, %dh
  93         andb    $0x45, %ah
  94         cmpb    $0x40, %ah
  95         je      20f             // x is ±0
  96
  97         cmpb    $0x05, %ah
  98         je      15f             // x is ±inf
  99
 100         fxch                    // y : x
 101
 102         /* First see whether `y' is a natural number.  In this case we
 103            can use a more precise algorithm.  */
 104         fld     %st             // y : y : x
 105         fistpl  (%esp)          // y : x
 106         fildl   (%esp)          // int(y) : y : x
 107         fucomp  %st(1)          // y : x
 108         fnstsw
 109         sahf
 110         jne     2f
 111
 112         /* OK, we have an integer value for y.  */
 113         popl    %edx
 114         orl     $0, %edx
 115         fstp    %st(0)          // x
 116         jns     4f              // y >= 0, jump
 117         fdivrl  MO(one)         // 1/x          (now referred to as x)
 118         negl    %edx
 119 4:      fldl    MO(one)         // 1 : x
 120         fxch
 121
 122 6:      shrl    $1, %edx
 123         jnc     5f
 124         fxch
 125         fmul    %st(1)          // x : ST*x
 126         fxch
 127 5:      fmul    %st(0), %st     // x*x : ST*x
 128         testl   %edx, %edx
 129         jnz     6b
 130         fstp    %st(0)          // ST*x
 131 30:     ret
 132
 133         .align ALIGNARG(4)
 134 2:      /* y is a real number.  */
 135         fxch                    // x : y
 136         fldl    MO(one)         // 1.0 : x : y
 137         fld     %st(1)          // x : 1.0 : x : y
 138         fsub    %st(1)          // x-1 : 1.0 : x : y
 139         fabs                    // |x-1| : 1.0 : x : y
 140         fcompl  MO(limit)       // 1.0 : x : y
 141         fnstsw
 142         fxch                    // x : 1.0 : y
 143         sahf
 144         ja      7f
 145         fsub    %st(1)          // x-1 : 1.0 : y
 146         fyl2xp1                 // log2(x) : y
 147         jmp     8f
 148
 149 7:      fyl2x                   // log2(x) : y
 150 8:      fmul    %st(1)          // y*log2(x) : y
 151         fst     %st(1)          // y*log2(x) : y*log2(x)
 152         frndint                 // int(y*log2(x)) : y*log2(x)
 153         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 154         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 155         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 156         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 157         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 158         addl    $4, %esp
 159         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 160         ret
 161
 162
 163         // pow(x,±0) = 1
 164         .align ALIGNARG(4)
 165 11:     fstp    %st(0)          // pop y
 166         fldl    MO(one)
 167         ret
 168
 169         // y == ±inf
 170         .align ALIGNARG(4)
 171 12:     fstp    %st(0)          // pop y
 172         flds    4(%esp)         // x
 173         fabs
 174         fcompl  MO(one)         // < 1, == 1, or > 1
 175         fnstsw
 176         andb    $0x45, %ah
 177         cmpb    $0x45, %ah
 178         je      13f             // jump if x is NaN
 179
 180         cmpb    $0x40, %ah
 181         je      14f             // jump if |x| == 1
 182
 183         shlb    $1, %ah
 184         xorb    %ah, %dl
 185         andl    $2, %edx
 186         fldl    MOX(inf_zero, %edx, 4)
 187         ret
 188
 189         .align ALIGNARG(4)
 190 14:     fldl    MO(nan)
 191         faddl   MO(zero)        // raise invalid exception
 192         ret
 193
 194         .align ALIGNARG(4)
 195 13:     flds    4(%esp)         // load x == NaN
 196         ret
 197
 198         .align ALIGNARG(4)
 199         // x is ±inf
 200 15:     fstp    %st(0)          // y
 201         testb   $2, %dh
 202         jz      16f             // jump if x == +inf
 203
 204         // We must find out whether y is an odd integer.
 205         fld     %st             // y : y
 206         fistpl  (%esp)          // y
 207         fildl   (%esp)          // int(y) : y
 208         fucompp                 // <empty>
 209         fnstsw
 210         sahf
 211         jne     17f
 212
 213         // OK, the value is an integer, but is the number of bits small
 214         // enough so that all are coming from the mantissa?
 215         popl    %edx
 216         testb   $1, %dl
 217         jz      18f             // jump if not odd
 218         movl    %edx, %eax
 219         orl     %edx, %edx
 220         jns     155f
 221         negl    %eax
 222 155:    cmpl    $0x01000000, %eax
 223         ja      18f             // does not fit in mantissa bits
 224         // It's an odd integer.
 225         shrl    $31, %edx
 226         fldl    MOX(minf_mzero, %edx, 8)
 227         ret
 228
 229         .align ALIGNARG(4)
 230 16:     fcompl  MO(zero)
 231         addl    $4, %esp
 232         fnstsw
 233         shrl    $5, %eax
 234         andl    $8, %eax
 235         fldl    MOX(inf_zero, %eax, 1)
 236         ret
 237
 238         .align ALIGNARG(4)
 239 17:     shll    $30, %edx       // sign bit for y in right position
 240         addl    $4, %esp
 241 18:     shrl    $31, %edx
 242         fldl    MOX(inf_zero, %edx, 8)
 243         ret
 244
 245         .align ALIGNARG(4)
 246         // x is ±0
 247 20:     fstp    %st(0)          // y
 248         testb   $2, %dl
 249         jz      21f             // y > 0
 250
 251         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 252         testb   $2, %dh
 253         jz      25f
 254
 255         fld     %st             // y : y
 256         fistpl  (%esp)          // y
 257         fildl   (%esp)          // int(y) : y
 258         fucompp                 // <empty>
 259         fnstsw
 260         sahf
 261         jne     26f
 262
 263         // OK, the value is an integer, but is the number of bits small
 264         // enough so that all are coming from the mantissa?
 265         popl    %edx
 266         testb   $1, %dl
 267         jz      27f             // jump if not odd
 268         cmpl    $0xff000000, %edx
 269         jbe     27f             // does not fit in mantissa bits
 270         // It's an odd integer.
 271         // Raise divide-by-zero exception and get minus infinity value.
 272         fldl    MO(one)
 273         fdivl   MO(zero)
 274         fchs
 275         ret
 276
 277 25:     fstp    %st(0)
 278 26:     popl    %eax
 279 27:     // Raise divide-by-zero exception and get infinity value.
 280         fldl    MO(one)
 281         fdivl   MO(zero)
 282         ret
 283
 284         .align ALIGNARG(4)
 285         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 286 21:     testb   $2, %dh
 287         jz      22f
 288
 289         fld     %st             // y : y
 290         fistpl  (%esp)          // y
 291         fildl   (%esp)          // int(y) : y
 292         fucompp                 // <empty>
 293         fnstsw
 294         sahf
 295         jne     23f
 296
 297         // OK, the value is an integer, but is the number of bits small
 298         // enough so that all are coming from the mantissa?
 299         popl    %edx
 300         testb   $1, %dl
 301         jz      24f             // jump if not odd
 302         cmpl    $0xff000000, %edx
 303         jae     24f             // does not fit in mantissa bits
 304         // It's an odd integer.
 305         fldl    MO(mzero)
 306         ret
 307
 308 22:     fstp    %st(0)
 309 23:     popl    %eax
 310 24:     fldl    MO(zero)
 311         ret
 312
 313 END(__ieee754_powf)