sysdeps/libm-i387/s_asinh.S

   1 /* ix87 specific implementation of arcsinh.
   2    Copyright (C) 1996 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(huge,@object)
  31 huge:   .double 1e+300
  32         ASM_SIZE_DIRECTIVE(huge)
  33         ASM_TYPE_DIRECTIVE(one,@object)
  34 one:    .double 1.0
  35         ASM_SIZE_DIRECTIVE(one)
  36         ASM_TYPE_DIRECTIVE(limit,@object)
  37 limit:  .double 0.29
  38         ASM_SIZE_DIRECTIVE(limit)
  39
  40 #ifdef PIC
  41 #define MO(op) op##@GOTOFF(%edx)
  42 #else
  43 #define MO(op) op
  44 #endif
  45
  46         .text
  47 ENTRY(__asinh)
  48         movl    8(%esp), %ecx
  49         movl    $0x7fffffff, %eax
  50         andl    %ecx, %eax
  51         andl    $0x80000000, %ecx
  52         xorl    %ecx, 8(%esp)
  53         fldl    4(%esp)                 // |x|
  54         cmpl    $0x3e300000, %eax
  55         jb      2f                      // |x| < 2^-28
  56         fldln2                          // log(2) : |x|
  57         cmpl    $0x41b00000, %eax
  58         fxch                            // |x| : log(2)
  59         ja      3f                      // |x| > 2^28
  60 #ifdef  PIC
  61         call    1f
  62 1:      popl    %edx
  63         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
  64 #endif
  65         cmpl    $0x40000000, %eax
  66         ja      5f                      // |x| > 2
  67
  68         // 2^-28 <= |x| <= 2 => y = sign(x)*log1p(|x|+|x|^2/(1+sqrt(1+|x|^2)))
  69         fld     %st                     // |x| : |x| : log(2)
  70         fmul    %st(1)                  // |x|^2 : |x| : log(2)
  71         fld     %st                     // |x|^2 : |x|^2 : |x| : log(2)
  72         faddl   MO(one)                 // 1+|x|^2 : |x|^2 : |x| : log(2)
  73         fsqrt                           // sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  74         faddl   MO(one)                 // 1+sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  75         fdivrp                          // |x|^2/(1+sqrt(1+|x|^2)) : |x| : log(2)
  76         faddp                           // |x|+|x|^2/(1+sqrt(1+|x|^2)) : log(2)
  77         fcoml   MO(limit)
  78         fnstsw
  79         sahf
  80         ja      6f
  81         fyl2xp1
  82         jecxz   4f
  83         fchs
  84 4:      ret
  85
  86 6:      faddl   MO(one)
  87         fyl2x
  88         jecxz   4f
  89         fchs
  90 4:      ret
  91
  92         // |x| < 2^-28 => y = x (inexact iff |x| != 0.0)
  93         .align ALIGNARG(4)
  94 2:
  95 #ifdef  PIC
  96         call    1f
  97 1:      popl    %edx
  98         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
  99 #endif
 100         jecxz   4f
 101         fchs                            // x
 102 4:      fld     %st                     // x : x
 103         faddl   MO(huge)                // huge+x : x
 104         fstp    %st(0)                  // x
 105         ret
 106
 107         // |x| > 2^28 => y = sign(x) * (log(|x|) + log(2))
 108         .align ALIGNARG(4)
 109 3:      fyl2x                           // log(|x|)
 110         fldln2                          // log(2) : log(|x|)
 111         faddp                           // log(|x|)+log(2)
 112         jecxz   4f
 113         fchs
 114 4:      ret
 115
 116         // |x| > 2 => y = sign(x) * log(2*|x| + 1/(|x|+sqrt(x*x+1)))
 117         .align ALIGNARG(4)
 118 5:      fld     %st                     // |x| : |x| : log(2)
 119         fadd    %st, %st(1)             // |x| : 2*|x| : log(2)
 120         fld     %st                     // |x| : |x| : 2*|x| : log(2)
 121         fmul    %st(1)                  // |x|^2 : |x| : 2*|x| : log(2)
 122         faddl   MO(one)                 // 1+|x|^2 : |x| : 2*|x| : log(2)
 123         fsqrt                           // sqrt(1+|x|^2) : |x| : 2*|x| : log(2)
 124         faddp                           // |x|+sqrt(1+|x|^2) : 2*|x| : log(2)
 125         fdivrl  MO(one)                 // 1/(|x|+sqrt(1+|x|^2)) : 2*|x| : log(2)
 126         faddp                           // 2*|x|+1/(|x|+sqrt(1+|x|^2)) : log(2)
 127         fyl2x                           // log(2*|x|+1/(|x|+sqrt(1+|x|^2)))
 128         jecxz   4f
 129         fchs
 130 4:      ret
 131 END(__asinh)
 132 weak_alias (__asinh, asinh)