sysdeps/libm-i387/s_frexpf.S

   1 /* ix87 specific frexp implementation for float.
   2    Copyright (C) 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(two25,@object)
  31 two25:  .byte 0, 0, 0, 0x4c
  32         ASM_SIZE_DIRECTIVE(two25)
  33
  34 #ifdef PIC
  35 #define MO(op) op##@GOTOFF(%edx)
  36 #else
  37 #define MO(op) op
  38 #endif
  39
  40         .text
  41 ENTRY(__frexpf)
  42         movl    4(%esp), %eax
  43         xorl    %ecx, %ecx
  44         movl    %eax, %edx
  45         andl    $0x7fffffff, %eax
  46         jz      1f
  47         cmpl    $0x7f800000, %eax
  48         jae     1f
  49
  50         cmpl    $0x00800000, %eax
  51         jae     2f
  52
  53         flds    4(%esp)
  54 #ifdef  PIC
  55         call    3f
  56 3:      popl    %edx
  57         addl    $_GLOBAL_OFFSET_TABLE_+[.-3b], %edx
  58 #endif
  59         fmuls   MO(two25)
  60         movl    $-25, %ecx
  61         fstps   4(%esp)
  62         movl    4(%esp), %eax
  63         movl    %eax, %edx
  64         andl    $0x7fffffff, %eax
  65
  66 2:      shrl    $23, %eax
  67         andl    $0x807fffff, %edx
  68         subl    $126, %eax
  69         orl     $0x3f000000, %edx
  70         addl    %eax, %ecx
  71         movl    %edx, 4(%esp)
  72
  73         /* Store %ecx in the variable pointed to by the second argument,
  74            get the factor from the stack and return.  */
  75 1:      movl    8(%esp), %eax
  76         flds    4(%esp)
  77         movl    %ecx, (%eax)
  78         ret
  79 END(__frexpf)
  80 weak_alias (__frexpf, frexpf)