configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware [default=yes],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 dnl Arguments to enable or disable building the shared, profiled, and
  63 dnl -fomit-frame-pointer libraries.
  64 AC_ARG_ENABLE(shared, dnl
  65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  66             shared=$enableval, shared=default)
  67 AC_ARG_ENABLE(profile, dnl
  68 [  --enable-profile        build profiled library [default=yes]],
  69             profile=$enableval, profile=yes)
  70 AC_ARG_ENABLE(omitfp, dnl
  71 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  72             omitfp=$enableval, omitfp=no)
  73
  74 AC_CANONICAL_HOST
  75 # We keep the original values in `$config_*' and never modify them, so we
  76 # can write them unchanged into config.make.  Everything else uses
  77 # $machine, $vendor, and $os, and changes them whenever convenient.
  78 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  79
  80 # Some configurations imply other options.
  81 case "$host_os" in
  82 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  83   # These systems always use GNU tools.
  84   gnu_ld=yes gnu_as=yes ;;
  85 esac
  86 case "$host_os" in
  87 gnu* | linux* | sysv4* | solaris2*)
  88   # These systems always use the ELF format.
  89   elf=yes ;;
  90 esac
  91
  92 # Linux/Alpha does not use ELF yet.
  93 case "$host_cpu-$host_os" in
  94 alpha*-linux*)
  95   gnu_ld=no elf=no ;;
  96 esac
  97
  98 machine=$config_machine
  99 vendor=$config_vendor
 100 os=$config_os
 101
 102 dnl We need to use [ and ] for other purposes for a while now.
 103 changequote(,)dnl
 104 # Expand the configuration machine name into a subdirectory by architecture
 105 # type and particular chip.
 106 case "$machine" in
 107 a29k | am29000) base_machine=a29k machine=a29k ;;
 108 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 109 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 110 i[345]86)       base_machine=i386 machine=i386/$machine ;;
 111 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 112 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 113 m88???)         base_machine=m88k machine=m88k/$machine ;;
 114 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 115 mips*)          base_machine=mips machine=mips/$machine ;;
 116 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 117 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 118 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 119 esac
 120 changequote([,])dnl
 121 AC_SUBST(base_machine)
 122
 123 # Compute the list of sysdep directories for this configuration.
 124 sysdep_dir=$srcdir/sysdeps
 125 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
 126 dnl We need to use [ and ] for other purposes for a while now.
 127 changequote(,)dnl
 128 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 129 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 130
 131 case "$os" in
 132 gnu*)
 133   base_os=mach/hurd ;;
 134 netbsd* | 386bsd* | freebsd* | bsdi*)
 135   base_os=unix/bsd/bsd4.4 ;;
 136 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 137   base_os=unix/bsd ;;
 138 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 139   base_os=unix/sysv ;;
 140 solaris[2-9]*)
 141   base_os=unix/sysv/sysv4 ;;
 142 none)
 143   base_os=standalone ;;
 144 *)
 145   base_os='' ;;
 146 esac
 147
 148 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 149 tail=$os
 150 ostry=$os
 151 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 152   ostry="$ostry /$o"
 153   tail=$o
 154 done
 155 o=`echo $tail | sed 's/[0-9]*$//'`
 156 if test $o != $tail; then
 157   ostry="$ostry /$o"
 158 fi
 159
 160 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 161 base=
 162 tail=$base_os
 163 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 164   set $b
 165   base="$base /$1"
 166   tail="$2"
 167 done
 168
 169 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 170 mach=
 171 tail=$machine
 172 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 173   set $m
 174   # Prepend the machine's FPU directory unless --without-fp.
 175   if test "$with_fp" = yes; then
 176     mach="$mach /$1/fpu"
 177   fi
 178   mach="$mach /$1"
 179   tail="$2"
 180 done
 181
 182 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 183 changequote([,])dnl
 184
 185 # Find what sysdep directories exist.
 186 sysnames=
 187 for b in $base ''; do
 188   for m0 in $mach ''; do
 189     for v in /$vendor ''; do
 190       for o in /$ostry ''; do
 191         for m in $mach ''; do
 192           try="$m0$b$v$o$m"
 193           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 194           if test -d $sysdep_dir$try; then
 195             sysnames="$sysnames $try"
 196             { test -n "$o" || test -n "$b"; } && os_used=t
 197             { test -n "$m" || test -n "$m0"; } && machine_used=t
 198           fi
 199         done
 200       done
 201     done
 202   done
 203 done
 204
 205 if test -z "$os_used" && test "$os" != none; then
 206   AC_MSG_ERROR(Operating system $os is not supported.)
 207 fi
 208 if test -z "$machine_used" && test "$machine" != none; then
 209   AC_MSG_ERROR(The $machine is not supported.)
 210 fi
 211
 212 # We have now validated the configuration.
 213
 214
 215 # If using ELF, look for an `elf' subdirectory of each machine directory.
 216 # We prepend these rather than inserting them whereever the machine appears
 217 # because things specified by the machine's ELF ABI should override
 218 # OS-specific things, and should always be the same for any OS on the
 219 # machine (otherwise what's the point of an ABI?).
 220 if test "$elf" = yes; then
 221   elf_dirs=
 222   for m in $mach; do
 223     if test -d $sysdep_dir$m/elf; then
 224       elf_dirs="$elf_dirs $m/elf"
 225     fi
 226   done
 227   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 228 fi
 229
 230
 231 # Remove the leading slashes.
 232 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 233
 234
 235 # Expand the list of system names into a full list of directories
 236 # from each element's parent name and Implies file (if present).
 237 set $sysnames
 238 while test $# -gt 0; do
 239   name=$1
 240   shift
 241
 242   if test -f $sysdep_dir/$name/Implies; then
 243     # Collect more names from the `Implies' file (removing comments).
 244     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 245     for x in $implied; do
 246       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 247     done
 248   else
 249     implied=
 250   fi
 251
 252   # Add NAME to the list of names.
 253   names="$names $name"
 254
 255   # Find the parent of NAME, using the empty string if it has none.
 256 changequote(,)dnl
 257   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 258 changequote([,])dnl
 259
 260   # Add the names implied by NAME, and NAME's parent (if it has one), to
 261   # the list of names to be processed (the argument list).  We prepend the
 262   # implied names to the list and append the parent.  We want implied
 263   # directories to come before further directories inferred from the
 264   # configuration components; this ensures that for sysv4, unix/common
 265   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 266   # after sysv4).
 267   sysnames="`echo $implied $* $parent`"
 268   test -n "$sysnames" && set $sysnames
 269 done
 270
 271 # Add the default directories.
 272 names="$names generic stub"
 273
 274 # Now uniquize the list.
 275 seen=
 276 sysnames=
 277 for name in $names; do
 278   if echo "$seen" | fgrep -x $name >/dev/null; then
 279     # Already in the list.
 280     true;
 281   else
 282     # A new one.
 283     if test -z "$seen"; then
 284       seen="$name" sysnames="$name"
 285     else
 286       seen="$seen
 287 $name"
 288       sysnames="$sysnames $name"
 289     fi
 290   fi
 291 done
 292 libc_cv_sysdirs="$sysnames"])
 293 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 294
 295 AC_PROG_INSTALL
 296 if test "$INSTALL" = "${srcdir}/install-sh"; then
 297   # The makefiles need to use a different form to find it in $srcdir.
 298   INSTALL='$(..)./install-sh'
 299 fi
 300 AC_PROG_LN_S
 301 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 302
 303 AC_CHECK_TOOL(CC, gcc)
 304 AC_PROG_CPP
 305 AC_CHECK_TOOL(AR, ar)
 306 AC_CHECK_TOOL(RANLIB, ranlib, :)
 307
 308 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 309 echo '#include <stddef.h>
 310 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 311 if eval "$ac_cpp conftest.c 2>/dev/null" \
 312 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 313   libc_cv_signed_size_t=no
 314 else
 315   libc_cv_signed_size_t=yes
 316 fi
 317 rm -f conftest*])
 318 if test $libc_cv_signed_size_t = yes; then
 319   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 320   cat >> confdefs.h <<\EOF
 321 #undef __SIZE_TYPE__
 322 #define __SIZE_TYPE__ unsigned
 323 EOF
 324 fi
 325
 326 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 327 AC_TRY_COMPILE(dnl
 328 [#define __need_size_t
 329 #define __need_wchar_t
 330 #include <stddef.h>
 331 #define __need_NULL
 332 #include <stddef.h>], [size_t size; wchar_t wchar;
 333 #ifdef offsetof
 334 #error stddef.h ignored __need_*
 335 #endif
 336 if (&size == NULL || &wchar == NULL) abort ();],
 337                libc_cv_friendly_stddef=yes,
 338                libc_cv_friendly_stddef=no)])
 339 if test $libc_cv_friendly_stddef = yes; then
 340   config_vars="$config_vars
 341 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 342 fi
 343
 344 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 345                libc_cv_need_minus_P, [dnl
 346 cat > conftest.S <<EOF
 347 #include "confdefs.h"
 348 /* Nothing whatsoever.  */
 349 EOF
 350 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 351   libc_cv_need_minus_P=no
 352 else
 353   libc_cv_need_minus_P=yes
 354 fi
 355 rm -f conftest*])
 356 if test $libc_cv_need_minus_P = yes; then
 357   config_vars="$config_vars
 358 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 359 fi
 360
 361 AC_CACHE_CHECK(for assembler global-symbol directive,
 362                libc_cv_asm_global_directive, [dnl
 363 libc_cv_asm_global_directive=UNKNOWN
 364 for ac_globl in .globl .global; do
 365   cat > conftest.s <<EOF
 366 .text
 367 ${ac_globl} foo
 368 foo: .long 0
 369 EOF
 370   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 371     libc_cv_asm_global_directive=${ac_globl}
 372   fi
 373   rm -f conftest*
 374   test $libc_cv_asm_global_directive != UNKNOWN && break
 375 done])
 376 if test $libc_cv_asm_global_directive = UNKNOWN; then
 377   AC_MSG_ERROR(cannot determine asm global directive)
 378 else
 379   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 380 fi
 381
 382 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 383 cat > conftest.s <<EOF
 384 .text
 385 foo: .long 0
 386 .set glibc_conftest_frobozz,foo
 387 $libc_cv_asm_global_directive glibc_conftest_frobozz
 388 EOF
 389 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 390 # (but it doesn't work), so we must do a linking check to be sure.
 391 cat > conftest1.c <<\EOF
 392 extern int glibc_conftest_frobozz;
 393 main () { printf ("%d\n", glibc_conftest_frobozz); }
 394 EOF
 395 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 396             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 397   libc_cv_asm_set_directive=yes
 398 else
 399   libc_cv_asm_set_directive=no
 400 fi
 401 rm -f conftest*])
 402 if test $libc_cv_asm_set_directive = yes; then
 403   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 404 fi
 405
 406 if test $elf != yes; then
 407   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 408                  [AC_TRY_COMPILE(, [asm (".section .init");
 409                                     asm (".section .fini");],
 410                                  libc_cv_have_initfini=yes,
 411                                  libc_cv_have_initfini=no)])
 412   AC_SUBST(libc_cv_have_initfini)dnl
 413   if test $libc_cv_have_initfini = yes; then
 414     AC_DEFINE(HAVE_INITFINI)
 415   fi
 416 fi
 417
 418 if test $elf = yes; then
 419   libc_cv_asm_underscores=no
 420 else
 421   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 422                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 423                               libc_cv_asm_underscores=yes,
 424                               libc_cv_asm_underscores=no)])
 425 fi
 426 if test $libc_cv_asm_underscores = no; then
 427   AC_DEFINE(NO_UNDERSCORES)
 428 fi
 429
 430 if test $elf = yes; then
 431   libc_cv_weak_symbols=yes
 432   libc_cv_asm_weak_directive=yes
 433   libc_cv_asm_weakext_directive=no
 434 else
 435   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 436                  [dnl
 437 cat > conftest.s <<EOF
 438 .text
 439 ${libc_cv_asm_global_directive} foo
 440 foo: .long 0
 441 .weak foo
 442 .weak bar; bar = foo
 443 EOF
 444   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 445     libc_cv_asm_weak_directive=yes
 446   else
 447     libc_cv_asm_weak_directive=no
 448   fi
 449   rm -f conftest*])
 450
 451 if test $libc_cv_asm_weak_directive = no; then
 452   AC_CACHE_CHECK(for assembler .weakext directive,
 453                  libc_cv_asm_weakext_directive,
 454                  [dnl
 455 cat > conftest.s <<EOF
 456 .text
 457 ${libc_cv_asm_global_directive} foo
 458 foo: .long 0
 459 .weakext foo
 460 .weakext bar, foo
 461 EOF
 462   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 463     libc_cv_asm_weakext_directive=yes
 464   else
 465     libc_cv_asm_weakext_directive=no
 466   fi
 467   rm -f conftest*])
 468
 469   fi # no .weak
 470 fi # not ELF
 471
 472 if test $libc_cv_asm_weak_directive = yes; then
 473   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 474 elif test $libc_cv_asm_weakext_directive = yes; then
 475   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 476 fi
 477
 478 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 479 cat > conftest.c <<\EOF
 480 main () { exit (0); }
 481 EOF
 482 if ${CC-cc} $CFLAGS -Wl,--no-whole-archive \
 483             -o conftest conftest.c 2>/dev/null; then
 484   libc_cv_ld_no_whole_archive=yes
 485 else
 486   libc_cv_ld_no_whole_archive=no
 487 fi
 488 rm -f conftest*])
 489 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 490
 491 ### End of automated tests.
 492 ### Now run sysdeps configure fragments.
 493
 494 # sysdeps configure fragments may set these with files to be linked below.
 495 libc_link_dests=
 496 libc_link_sources=
 497
 498 # Iterate over all the sysdep directories we will use, running their
 499 # configure fragments, and looking for a uname implementation.
 500 uname=
 501 for dir in $sysnames; do
 502   if test -r $sysdep_dir/$dir/configure; then
 503     AC_MSG_RESULT(running configure fragment for $dir)
 504     . $sysdep_dir/$dir/configure
 505   fi
 506 [
 507   if test -z "$uname"; then
 508     if test -r $sysdep_dir/$dir/uname.c ||
 509        test -r $sysdep_dir/$dir/uname.S ||
 510        { test -r $sysdep_dir/$dir/syscalls.list &&
 511          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 512       uname=$dir
 513     fi
 514   fi
 515 ]dnl
 516 done
 517
 518 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 519
 520 # If we will use the generic uname implementation, we must figure out what
 521 # it will say by examining the system, and write the results in config-name.h.
 522 if test "$uname" = generic; then
 523
 524 changequote(,)dnl
 525   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 526 changequote([,])dnl
 527   if test $uname_sysname != $config_os; then
 528     config_release=`echo $config_os | sed s/$uname_sysname//`
 529   fi
 530 dnl
 531 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 532     if test -r /vmunix; then
 533       kernel_id=`strings /vmunix | grep UNIX`
 534     elif test -r /dynix; then
 535       kernel_id=`strings /dynix | grep DYNIX`
 536     else
 537       kernel_id=
 538     fi
 539 ])dnl
 540
 541   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 542 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 543 changequote(,)dnl
 544   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 545 changequote([,])dnl
 546   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 547          != x$config_release; then
 548     # The configuration release is a substring of the kernel release.
 549     libc_cv_uname_release=$kernel_release
 550   elif test x$config_release != x; then
 551     libc_cv_uname_release=$config_release
 552   elif test x$kernel_release != x; then
 553     libc_cv_uname_release=$kernel_release
 554   else
 555     libc_cv_uname_release=unknown
 556   fi])
 557   uname_release="$libc_cv_uname_release"
 558
 559   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 560 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 561 changequote(,)dnl
 562   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 563 changequote([,])dnl
 564   if test -n "$kernel_version"; then
 565     libc_cv_uname_version="$kernel_version"
 566   else
 567     libc_cv_uname_version=unknown
 568   fi])
 569   uname_version="$libc_cv_uname_version"
 570
 571 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 572   config_uname=config-name.h:config-name.in
 573 else
 574   # For non-generic uname, we don't need to create config-name.h at all.
 575   config_uname=
 576 fi
 577
 578 AC_MSG_CHECKING(stdio selection)
 579 AC_SUBST(stdio)
 580 case $stdio in
 581 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 582 default) stdio=stdio ;;
 583 esac
 584 AC_MSG_RESULT($stdio)
 585
 586 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 587 if test $gnu_ld = yes; then
 588   AC_DEFINE(HAVE_GNU_LD)
 589 fi
 590 if test $gnu_as = yes; then
 591   AC_DEFINE(HAVE_GNU_AS)
 592 fi
 593 if test $elf = yes; then
 594   AC_DEFINE(HAVE_ELF)
 595 fi
 596
 597 AC_SUBST(shared)
 598 if test $shared = default; then
 599   if test $gnu_ld = yes; then
 600     shared=$elf
 601   fi
 602 fi
 603 AC_SUBST(profile)
 604 AC_SUBST(omitfp)
 605
 606 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 607   config_makefile=
 608 else
 609   config_makefile=Makefile
 610 fi
 611
 612 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 613           [echo '$config_vars' >> config.make])