sysdeps/libm-i387/e_pow.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(infinity,@object)
  31 inf_zero:
  32 infinity:
  33         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  34         ASM_SIZE_DIRECTIVE(infinity)
  35         ASM_TYPE_DIRECTIVE(zero,@object)
  36 zero:   .double 0.0
  37         ASM_SIZE_DIRECTIVE(zero)
  38         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  39 minf_mzero:
  40 minfinity:
  41         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  42 mzero:
  43         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  44         ASM_SIZE_DIRECTIVE(minf_mzero)
  45         ASM_TYPE_DIRECTIVE(one,@object)
  46 one:    .double 1.0
  47         ASM_SIZE_DIRECTIVE(one)
  48         ASM_TYPE_DIRECTIVE(limit,@object)
  49 limit:  .double 0.29
  50         ASM_SIZE_DIRECTIVE(limit)
  51
  52 #ifdef PIC
  53 #define MO(op) op##@GOTOFF(%ecx)
  54 #define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  55 #else
  56 #define MO(op) op
  57 #define MOX(op,x,f) op(,x,f)
  58 #endif
  59
  60         .text
  61 ENTRY(__ieee754_pow)
  62         fldl    12(%esp)        // y
  63         fxam
  64
  65 #ifdef  PIC
  66         call    1f
  67 1:      popl    %ecx
  68         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %ecx
  69 #endif
  70
  71         fnstsw
  72         movb    %ah, %dl
  73         andb    $0x45, %ah
  74         cmpb    $0x40, %ah      // is y == 0 ?
  75         je      11f
  76
  77         cmpb    $0x05, %ah      // is y == ±inf ?
  78         je      12f
  79
  80         cmpb    $0x01, %ah      // is y == NaN ?
  81         je      30f
  82
  83         fldl    4(%esp)         // x : y
  84
  85         subl    $8,%esp
  86
  87         fxam
  88         fnstsw
  89         movb    %ah, %dh
  90         andb    $0x45, %ah
  91         cmpb    $0x40, %ah
  92         je      20f             // x is ±0
  93
  94         cmpb    $0x05, %ah
  95         je      15f             // x is ±inf
  96
  97         fxch                    // y : x
  98
  99         /* First see whether `y' is a natural number.  In this case we
 100            can use a more precise algorithm.  */
 101         fld     %st             // y : y : x
 102         fistpll (%esp)          // y : x
 103         fildll  (%esp)          // int(y) : y : x
 104         fucomp  %st(1)          // y : x
 105         fnstsw
 106         sahf
 107         jne     2f
 108
 109         /* OK, we have an integer value for y.  */
 110         popl    %eax
 111         popl    %edx
 112         orl     $0, %edx
 113         fstp    %st(0)          // x
 114         jns     4f              // y >= 0, jump
 115         fdivrl  MO(one)         // 1/x          (now referred to as x)
 116         negl    %eax
 117         adcl    $0, %edx
 118         negl    %edx
 119 4:      fldl    MO(one)         // 1 : x
 120         fxch
 121
 122 6:      shrdl   $1, %edx, %eax
 123         jnc     5f
 124         fxch
 125         fmul    %st(1)          // x : ST*x
 126         fxch
 127 5:      fmul    %st(0), %st     // x*x : ST*x
 128         movl    %eax, %ecx
 129         orl     %edx, %ecx
 130         jnz     6b
 131         fstp    %st(0)          // ST*x
 132 30:     ret
 133
 134         .align ALIGNARG(4)
 135 2:      /* y is a real number.  */
 136         fxch                    // x : y
 137         fldl    MO(one)         // 1.0 : x : y
 138         fld     %st(1)          // x : 1.0 : x : y
 139         fsub    %st(1)          // x-1 : 1.0 : x : y
 140         fabs                    // |x-1| : 1.0 : x : y
 141         fcompl  MO(limit)       // 1.0 : x : y
 142         fnstsw
 143         fxch                    // x : 1.0 : y
 144         sahf
 145         ja      7f
 146         fsub    %st(1)          // x-1 : 1.0 : y
 147         fyl2xp1                 // log2(x) : y
 148         jmp     8f
 149
 150 7:      fyl2x                   // log2(x) : y
 151 8:      fmul    %st(1)          // y*log2(x) : y
 152         fst     %st(1)          // y*log2(x) : y*log2(x)
 153         frndint                 // int(y*log2(x)) : y*log2(x)
 154         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 155         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 156         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 157         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 158         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 159         addl    $8, %esp
 160         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 161         ret
 162
 163
 164         // pow(x,±0) = 1
 165         .align ALIGNARG(4)
 166 11:     fstp    %st(0)          // pop y
 167         fldl    MO(one)
 168         ret
 169
 170         // y == ±inf
 171         .align ALIGNARG(4)
 172 12:     fstp    %st(0)          // pop y
 173         fldl    4(%esp)         // x
 174         fabs
 175         fcompl  MO(one)         // < 1, == 1, or > 1
 176         fnstsw
 177         andb    $0x45, %ah
 178         cmpb    $0x45, %ah
 179         je      13f             // jump if x is NaN
 180
 181         cmpb    $0x40, %ah
 182         je      14f             // jump if |x| == 1
 183
 184         shlb    $1, %ah
 185         xorb    %ah, %dl
 186         andl    $2, %edx
 187         fldl    MOX(inf_zero, %edx, 4)
 188         ret
 189
 190         .align ALIGNARG(4)
 191 14:     fldl    MO(infinity)
 192         fmull   MO(zero)        // raise invalid exception
 193         ret
 194
 195         .align ALIGNARG(4)
 196 13:     fldl    4(%esp)         // load x == NaN
 197         ret
 198
 199         .align ALIGNARG(4)
 200         // x is ±inf
 201 15:     fstp    %st(0)          // y
 202         testb   $2, %dh
 203         jz      16f             // jump if x == +inf
 204
 205         // We must find out whether y is an odd integer.
 206         fld     %st             // y : y
 207         fistpll (%esp)          // y
 208         fildll  (%esp)          // int(y) : y
 209         fucompp                 // <empty>
 210         fnstsw
 211         sahf
 212         jne     17f
 213
 214         // OK, the value is an integer, but is the number of bits small
 215         // enough so that all are coming from the mantissa?
 216         popl    %eax
 217         popl    %edx
 218         andb    $1, %al
 219         jz      18f             // jump if not odd
 220         movl    %edx, %eax
 221         orl     %edx, %edx
 222         jns     155f
 223         negl    %eax
 224 155:    cmpl    $0x00200000, %eax
 225         ja      18f             // does not fit in mantissa bits
 226         // It's an odd integer.
 227         shrl    $31, %edx
 228         fldl    MOX(minf_mzero, %edx, 8)
 229         ret
 230
 231         .align ALIGNARG(4)
 232 16:     fcompl  MO(zero)
 233         addl    $8, %esp
 234         fnstsw
 235         shrl    $5, %eax
 236         andl    $8, %eax
 237         fldl    MOX(inf_zero, %eax, 1)
 238         ret
 239
 240         .align ALIGNARG(4)
 241 17:     shll    $30, %edx       // sign bit for y in right position
 242         addl    $8, %esp
 243 18:     shrl    $31, %edx
 244         fldl    MOX(inf_zero, %edx, 8)
 245         ret
 246
 247         .align ALIGNARG(4)
 248         // x is ±0
 249 20:     fstp    %st(0)          // y
 250         testb   $2, %dl
 251         jz      21f             // y > 0
 252
 253         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 254         testb   $2, %dh
 255         jz      25f
 256
 257         fld     %st             // y : y
 258         fistpll (%esp)          // y
 259         fildll  (%esp)          // int(y) : y
 260         fucompp                 // <empty>
 261         fnstsw
 262         sahf
 263         jne     26f
 264
 265         // OK, the value is an integer, but is the number of bits small
 266         // enough so that all are coming from the mantissa?
 267         popl    %eax
 268         popl    %edx
 269         andb    $1, %al
 270         jz      27f             // jump if not odd
 271         cmpl    $0xffe00000, %edx
 272         jbe     27f             // does not fit in mantissa bits
 273         // It's an odd integer.
 274         // Raise divide-by-zero exception and get minus infinity value.
 275         fldl    MO(one)
 276         fdivl   MO(zero)
 277         fchs
 278         ret
 279
 280 25:     fstp    %st(0)
 281 26:     popl    %eax
 282         popl    %edx
 283 27:     // Raise divide-by-zero exception and get infinity value.
 284         fldl    MO(one)
 285         fdivl   MO(zero)
 286         ret
 287
 288         .align ALIGNARG(4)
 289         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 290 21:     testb   $2, %dh
 291         jz      22f
 292
 293         fld     %st             // y : y
 294         fistpll (%esp)          // y
 295         fildll  (%esp)          // int(y) : y
 296         fucompp                 // <empty>
 297         fnstsw
 298         sahf
 299         jne     23f
 300
 301         // OK, the value is an integer, but is the number of bits small
 302         // enough so that all are coming from the mantissa?
 303         popl    %eax
 304         popl    %edx
 305         andb    $1, %al
 306         jz      24f             // jump if not odd
 307         cmpl    $0xffe00000, %edx
 308         jae     24f             // does not fit in mantissa bits
 309         // It's an odd integer.
 310         fldl    MO(mzero)
 311         ret
 312
 313 22:     fstp    %st(0)
 314 23:     popl    %eax
 315         popl    %edx
 316 24:     fldl    MO(zero)
 317         ret
 318
 319 END(__ieee754_pow)