sysdeps/alpha/strncat.S

   1 /* Copyright (C) 1996 Free Software Foundation, Inc.
   2    Contributed by Richard Henderson (rth@tamu.edu)
   3
   4 This file is part of the GNU C Library.
   5
   6 The GNU C Library is free software; you can redistribute it and/or
   7 modify it under the terms of the GNU Library General Public License as
   8 published by the Free Software Foundation; either version 2 of the
   9 License, or (at your option) any later version.
  10
  11 The GNU C Library is distributed in the hope that it will be useful,
  12 but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 Library General Public License for more details.
  15
  16 You should have received a copy of the GNU Library General Public
  17 License along with the GNU C Library; see the file COPYING.LIB.  If
  18 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  19 Cambridge, MA 02139, USA.  */
  20
  21 /* Append no more than COUNT characters from the null-terminated string SRC
  22    to the null-terminated string DST.  Always null-terminate the new DST.  */
  23
  24 #include <sysdep.h>
  25
  26         .text
  27
  28 ENTRY(strncat)
  29         ldgp    gp, 0(pv)
  30         .prologue 1
  31
  32         mov     a0, v0          # set up return value
  33         beq     a2, $zerocount
  34
  35         /* Find the end of the string.  */
  36
  37         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  38         lda     t1, -1(zero)
  39         insqh   t1, a0, t1
  40         andnot  a0, 7, a0
  41         or      t1, t0, t0
  42         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  43         bne     t1, $found
  44
  45 $loop:  ldq     t0, 8(a0)
  46         addq    a0, 8, a0       # addr += 8
  47         cmpbge  zero, t0, t1
  48         beq     t1, $loop
  49
  50 $found: negq    t1, t2          # clear all but least set bit
  51         and     t1, t2, t1
  52
  53         and     t1, 0xf0, t2    # binary search for that set bit
  54         and     t1, 0xcc, t3
  55         and     t1, 0xaa, t4
  56         cmovne  t2, 4, t2
  57         cmovne  t3, 2, t3
  58         cmovne  t4, 1, t4
  59         addq    t2, t3, t2
  60         addq    a0, t4, a0
  61         addq    a0, t2, a0
  62
  63         /* Now do the append.  */
  64
  65         jsr     t9, __stxncpy
  66
  67         /* Worry about the null termination.  */
  68
  69         zapnot  t0, t8, t1      # was last byte a null?
  70         bne     t1, 0f
  71         ret
  72
  73 0:      and     t10, 0x80, t1
  74         bne     t1, 1f
  75
  76         /* Here there are bytes left in the current word.  Clear one.  */
  77         addq    t10, t10, t10   # end-of-count bit <<= 1
  78         zap     t0, t10, t0
  79         stq_u   t0, 0(a0)
  80         ret
  81
  82 1:      /* Here we must read the next DST word and clear the first byte.  */
  83         ldq_u   t0, 8(a0)
  84         zap     t0, 1, t0
  85         stq_u   t0, 8(a0)
  86
  87 $zerocount:
  88         ret
  89
  90         END(strncat)