configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81
  82 dnl Generic infrastructure for drop-in additions to libc.
  83 AC_ARG_ENABLE(add-ons, dnl
  84 [  --enable-add-ons=DIR... configure and build named extra directories],
  85               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  86               [add_ons=])
  87 AC_CONFIG_SUBDIRS($add_ons)
  88 add_ons_pfx=
  89 if test x"$add_ons" != x; then
  90   for f in $add_ons; do
  91     add_ons_pfx="$add_ons_pfx $f/"
  92   done
  93 fi
  94
  95 dnl On some platforms we cannot use dynamic loading.  We must provide
  96 dnl static NSS modules.
  97 AC_ARG_ENABLE(static-nss, dnl
  98 [  --enable-static-nss     build static NSS modules [default=no]],
  99               static_nss=$enableval, static_nss=no)
 100 if test x"$static_nss" = xyes; then
 101   AC_DEFINE(DO_STATIC_NSS)
 102 fi
 103
 104 AC_CANONICAL_HOST
 105
 106 # The way shlib-versions is used to generate soversions.mk uses a
 107 # fairly simplistic model for name recognition that can't distinguish
 108 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 109 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 110 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 111 case "$host_os" in
 112 linux*)
 113   ;;
 114 gnu*)
 115   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 116   ;;
 117 esac
 118
 119 # We keep the original values in `$config_*' and never modify them, so we
 120 # can write them unchanged into config.make.  Everything else uses
 121 # $machine, $vendor, and $os, and changes them whenever convenient.
 122 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 123
 124 # Some configurations imply other options.
 125 case "$host_os" in
 126 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 127   # These systems always use GNU tools.
 128   gnu_ld=yes gnu_as=yes ;;
 129 esac
 130 case "$host_os" in
 131 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 132 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 133   ;;
 134 gnu* | linux* | sysv4* | solaris2*)
 135   # These systems (almost) always use the ELF format.
 136   elf=yes
 137   ;;
 138 esac
 139
 140 machine=$config_machine
 141 vendor=$config_vendor
 142 os=$config_os
 143
 144 dnl We need to use [ and ] for other purposes for a while now.
 145 changequote(,)dnl
 146 # Expand the configuration machine name into a subdirectory by architecture
 147 # type and particular chip.
 148 case "$machine" in
 149 a29k | am29000) base_machine=a29k machine=a29k ;;
 150 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 151 arm*)           base_machine=arm machine=arm/$machine ;;
 152 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 153 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 154 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 155 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 156 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 157 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 158 m88???)         base_machine=m88k machine=m88k/$machine ;;
 159 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 160 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 161 mips*)          base_machine=mips machine=mips/$machine ;;
 162 sparc | sparcv[67])
 163                 base_machine=sparc machine=sparc/sparc32 ;;
 164 sparcv8 | supersparc | hypersparc)
 165                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 166 sparc64 | ultrasparc)
 167                 base_machine=sparc machine=sparc/sparc64 ;;
 168 esac
 169 changequote([,])dnl
 170 AC_SUBST(base_machine)
 171
 172 # Compute the list of sysdep directories for this configuration.
 173 # This can take a while to compute.
 174 sysdep_dir=$srcdir/sysdeps
 175 AC_MSG_CHECKING(sysdep dirs)
 176 dnl We need to use [ and ] for other purposes for a while now.
 177 changequote(,)dnl
 178 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 179 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 180
 181 case "$os" in
 182 gnu*)
 183   base_os=mach/hurd ;;
 184 netbsd* | 386bsd* | freebsd* | bsdi*)
 185   base_os=unix/bsd/bsd4.4 ;;
 186 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 187   base_os=unix/bsd ;;
 188 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 189   base_os=unix/sysv ;;
 190 solaris[2-9]*)
 191   base_os=unix/sysv/sysv4 ;;
 192 none)
 193   base_os=standalone ;;
 194 *)
 195   base_os='' ;;
 196 esac
 197
 198 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 199 tail=$os
 200 ostry=$os
 201 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 202   ostry="$ostry /$o"
 203   tail=$o
 204 done
 205 o=`echo $tail | sed 's/[0-9]*$//'`
 206 if test $o != $tail; then
 207   ostry="$ostry /$o"
 208 fi
 209 # For linux-gnu, try linux-gnu, then linux.
 210 o=`echo $tail | sed 's/-.*$//'`
 211 if test $o != $tail; then
 212   ostry="$ostry /$o"
 213 fi
 214
 215 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 216 base=
 217 tail=$base_os
 218 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 219   set $b
 220   base="$base /$1"
 221   tail="$2"
 222 done
 223
 224 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 225 mach=
 226 tail=$machine
 227 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 228   set $m
 229   # Prepend the machine's FPU directory unless --without-fp.
 230   if test "$with_fp" = yes; then
 231     mach="$mach /$1/fpu"
 232   fi
 233   mach="$mach /$1"
 234   tail="$2"
 235 done
 236
 237 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 238 changequote([,])dnl
 239
 240 # Find what sysdep directories exist.
 241 sysnames=
 242 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 243 for d in $add_ons_pfx ''; do
 244   for b in $base ''; do
 245     for m0 in $mach ''; do
 246       for v in /$vendor ''; do
 247         for o in /$ostry ''; do
 248           for m in $mach ''; do
 249             if test "$m0$b$v$o$m"; then
 250               try="${d}sysdeps$m0$b$v$o$m"
 251               test -n "$enable_debug_configure" &&
 252               echo "$0 [DEBUG]: try $try" >&2
 253               case $try in
 254                 /*) dest=$try ;;
 255                 *)  dest=$srcdir/$try ;;
 256               esac
 257               if test -d $dest; then
 258                 sysnames="$sysnames $try"
 259                 { test -n "$o" || test -n "$b"; } && os_used=t
 260                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 261               fi
 262             fi
 263           done
 264         done
 265       done
 266     done
 267   done
 268 done
 269 IFS="$ac_save_ifs"
 270
 271 if test -z "$os_used" && test "$os" != none; then
 272   AC_MSG_ERROR(Operating system $os is not supported.)
 273 fi
 274 if test -z "$machine_used" && test "$machine" != none; then
 275   AC_MSG_ERROR(The $machine is not supported.)
 276 fi
 277
 278 # We have now validated the configuration.
 279
 280
 281 # If using ELF, look for an `elf' subdirectory of each machine directory.
 282 # We prepend these rather than inserting them whereever the machine appears
 283 # because things specified by the machine's ELF ABI should override
 284 # OS-specific things, and should always be the same for any OS on the
 285 # machine (otherwise what's the point of an ABI?).
 286 if test "$elf" = yes; then
 287   elf_dirs=
 288   for d in $add_ons_pfx ''; do
 289     case $d in
 290       /*) xsrcdir= ;;
 291       *)  xsrcdir=$srcdir/ ;;
 292     esac
 293     for m in $mach; do
 294       if test -d $xsrcdir${d}sysdeps$m/elf; then
 295         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 296       fi
 297     done
 298   done
 299   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 300 fi
 301
 302
 303 # Expand the list of system names into a full list of directories
 304 # from each element's parent name and Implies file (if present).
 305 set $sysnames
 306 names=
 307 while test $# -gt 0; do
 308   name=$1
 309   shift
 310
 311   case " $names " in *" $name "*)
 312     # Already in the list.
 313     continue
 314   esac
 315
 316   # Report each name as we discover it, so there is no long pause in output.
 317   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 318
 319   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 320
 321   case $name in
 322     /*) xsrcdir= ;;
 323     *)  xsrcdir=$srcdir/ ;;
 324   esac
 325   test -n "$enable_debug_configure" &&
 326   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 327
 328   if test -f $xsrcdir$name/Implies; then
 329     # Collect more names from the `Implies' file (removing comments).
 330     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 331     implied=
 332     for x in $implied_candidate; do
 333       if test -d $xsrcdir$name_base/$x; then
 334         implied="$implied $name_base/$x";
 335       else
 336         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 337       fi
 338     done
 339   else
 340     implied=
 341   fi
 342
 343   # Add NAME to the list of names.
 344   names="$names $name"
 345
 346   # Find the parent of NAME, using the empty string if it has none.
 347 changequote(,)dnl
 348   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 349 changequote([,])dnl
 350
 351   # Add the names implied by NAME, and NAME's parent (if it has one), to
 352   # the list of names to be processed (the argument list).  We prepend the
 353   # implied names to the list and append the parent.  We want implied
 354   # directories to come before further directories inferred from the
 355   # configuration components; this ensures that for sysv4, unix/common
 356   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 357   # after sysv4).
 358   sysnames="`echo $implied $* $parent`"
 359   test -n "$sysnames" && set $sysnames
 360 done
 361
 362 # Add the default directories.
 363 sysnames="$names sysdeps/generic sysdeps/stub"
 364 AC_SUBST(sysnames)
 365 # The other names were emitted during the scan.
 366 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 367
 368
 369 ### Locate tools.
 370
 371 AC_PROG_INSTALL
 372 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 373   # The makefiles need to use a different form to find it in $srcdir.
 374   INSTALL='$(..)./install-sh -c'
 375 fi
 376 AC_PROG_LN_S
 377 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 378
 379 AC_PROG_CC_LOCAL
 380 AC_CANONICAL_BUILD
 381 if test $host != $build; then
 382   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 383 fi
 384 AC_SUBST(cross_compiling)
 385 AC_PROG_CPP
 386 AC_CHECK_TOOL(AR, ar)
 387 AC_CHECK_TOOL(RANLIB, ranlib, :)
 388
 389 AC_PATH_PROG(BASH, bash, no)
 390 if test "$BASH" != no &&
 391    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 392   libc_cv_have_bash2=yes
 393 else
 394   libc_cv_have_bash2=no
 395 fi
 396 AC_SUBST(libc_cv_have_bash2)
 397
 398 dnl We need a ksh compatible shell for tzselect.
 399 if test "$BASH" = no; then
 400   AC_PATH_PROG(KSH, ksh, no)
 401   if test "$KSH" = no; then
 402     libc_cv_have_ksh=no
 403   else
 404     libc_cv_have_ksh=yes
 405   fi
 406 else
 407   KSH="$BASH"
 408   AC_SUBST(KSH)
 409   libc_cv_have_ksh=yes
 410 fi
 411 AC_SUBST(libc_cv_have_ksh)
 412
 413 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 414 echo '#include <stddef.h>
 415 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 416 if eval "$ac_cpp conftest.c 2>/dev/null" \
 417 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 418   libc_cv_signed_size_t=no
 419 else
 420   libc_cv_signed_size_t=yes
 421 fi
 422 rm -f conftest*])
 423 if test $libc_cv_signed_size_t = yes; then
 424   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 425   cat >> confdefs.h <<\EOF
 426 #undef __SIZE_TYPE__
 427 #define __SIZE_TYPE__ unsigned
 428 EOF
 429 fi
 430
 431 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 432 AC_TRY_COMPILE(dnl
 433 [#define __need_size_t
 434 #define __need_wchar_t
 435 #include <stddef.h>
 436 #define __need_NULL
 437 #include <stddef.h>], [size_t size; wchar_t wchar;
 438 #ifdef offsetof
 439 #error stddef.h ignored __need_*
 440 #endif
 441 if (&size == NULL || &wchar == NULL) abort ();],
 442                libc_cv_friendly_stddef=yes,
 443                libc_cv_friendly_stddef=no)])
 444 if test $libc_cv_friendly_stddef = yes; then
 445   config_vars="$config_vars
 446 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 447 fi
 448
 449 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 450                libc_cv_need_minus_P, [dnl
 451 cat > conftest.S <<EOF
 452 #include "confdefs.h"
 453 /* Nothing whatsoever.  */
 454 EOF
 455 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 456   libc_cv_need_minus_P=no
 457 else
 458   libc_cv_need_minus_P=yes
 459 fi
 460 rm -f conftest*])
 461 if test $libc_cv_need_minus_P = yes; then
 462   config_vars="$config_vars
 463 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 464 fi
 465
 466 AC_CACHE_CHECK(for assembler global-symbol directive,
 467                libc_cv_asm_global_directive, [dnl
 468 libc_cv_asm_global_directive=UNKNOWN
 469 for ac_globl in .globl .global; do
 470   cat > conftest.s <<EOF
 471 .text
 472 ${ac_globl} foo
 473 foo:
 474 EOF
 475   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 476     libc_cv_asm_global_directive=${ac_globl}
 477   fi
 478   rm -f conftest*
 479   test $libc_cv_asm_global_directive != UNKNOWN && break
 480 done])
 481 if test $libc_cv_asm_global_directive = UNKNOWN; then
 482   AC_MSG_ERROR(cannot determine asm global directive)
 483 else
 484   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 485 fi
 486
 487 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 488 cat > conftest.s <<EOF
 489 .text
 490 foo:
 491 .set glibc_conftest_frobozz,foo
 492 $libc_cv_asm_global_directive glibc_conftest_frobozz
 493 EOF
 494 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 495 # (but it doesn't work), so we must do a linking check to be sure.
 496 cat > conftest1.c <<\EOF
 497 extern int glibc_conftest_frobozz;
 498 main () { printf ("%d\n", glibc_conftest_frobozz); }
 499 EOF
 500 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 501             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 502   libc_cv_asm_set_directive=yes
 503 else
 504   libc_cv_asm_set_directive=no
 505 fi
 506 rm -f conftest*])
 507 if test $libc_cv_asm_set_directive = yes; then
 508   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 509 fi
 510
 511 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 512 [cat > conftest.s <<EOF
 513 .text
 514 _sym:
 515 .symver _sym,sym@VERS
 516 EOF
 517 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 518   libc_cv_asm_symver_directive=yes
 519 else
 520   libc_cv_asm_symver_directive=no
 521 fi
 522 rm -f conftest*])
 523 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 524 if test $libc_cv_asm_symver_directive = yes; then
 525   cat > conftest.s <<EOF
 526 .text
 527 _sym:
 528 .symver _sym,sym@VERS
 529 EOF
 530   cat > conftest.map <<EOF
 531 VERS {
 532         global: sym;
 533 };
 534 EOF
 535   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 536     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 537                                         -nostartfiles -nostdlib
 538                                         -Wl,--version-script,conftest.map
 539                        1>&AC_FD_CC]);
 540     then
 541       libc_cv_ld_version_script_option=yes
 542     else
 543       libc_cv_ld_version_script_option=no
 544     fi
 545   else
 546     libc_cv_ld_version_script_option=no
 547   fi
 548 else
 549   libc_cv_ld_version_script_option=no
 550 fi
 551 rm -f conftest*])
 552 if test $libc_cv_asm_symver_directive = yes &&
 553    test $libc_cv_ld_version_script_option = yes; then
 554   VERSIONING=yes
 555   AC_DEFINE(DO_VERSIONING)
 556 else
 557   VERSIONING=no
 558 fi
 559 AC_SUBST(VERSIONING)
 560
 561 if test $elf = yes; then
 562   AC_CACHE_CHECK(for .previous assembler directive,
 563                  libc_cv_asm_previous_directive, [dnl
 564   cat > conftest.s <<EOF
 565 .section foo_section
 566 .previous
 567 EOF
 568   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 569     libc_cv_asm_previous_directive=yes
 570   else
 571     libc_cv_asm_previous_directive=no
 572   fi
 573   rm -f conftest*])
 574   if test $libc_cv_asm_previous_directive = yes; then
 575     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 576   else
 577     AC_CACHE_CHECK(for .popsection assembler directive,
 578                    libc_cv_asm_popsection_directive, [dnl
 579     cat > conftest.s <<EOF
 580 .pushsection foo_section
 581 .popsection
 582 EOF
 583     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 584       libc_cv_asm_popsection_directive=yes
 585     else
 586       libc_cv_asm_popsection_directive=no
 587     fi
 588     rm -f conftest*])
 589     if test $libc_cv_asm_popsection_directive = yes; then
 590       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 591     fi
 592   fi
 593 fi
 594
 595 if test $elf != yes; then
 596   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 597                  [AC_TRY_COMPILE(, [asm (".section .init");
 598                                     asm (".section .fini");
 599                                     asm (".text");],
 600                                  libc_cv_have_initfini=yes,
 601                                  libc_cv_have_initfini=no)])
 602   AC_SUBST(libc_cv_have_initfini)dnl
 603   if test $libc_cv_have_initfini = yes; then
 604     AC_DEFINE(HAVE_INITFINI)
 605   fi
 606 fi
 607
 608 if test $elf = yes; then
 609   libc_cv_asm_underscores=no
 610 else
 611   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 612                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 613                               libc_cv_asm_underscores=yes,
 614                               libc_cv_asm_underscores=no)])
 615 fi
 616 if test $libc_cv_asm_underscores = no; then
 617   AC_DEFINE(NO_UNDERSCORES)
 618 fi
 619
 620 if test $elf = yes; then
 621   libc_cv_weak_symbols=yes
 622   libc_cv_asm_weak_directive=yes
 623   libc_cv_asm_weakext_directive=no
 624 else
 625   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 626                  [dnl
 627 cat > conftest.s <<EOF
 628 .text
 629 ${libc_cv_asm_global_directive} foo
 630 foo:
 631 .weak foo
 632 .weak bar; bar = foo
 633 EOF
 634   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 635     libc_cv_asm_weak_directive=yes
 636   else
 637     libc_cv_asm_weak_directive=no
 638   fi
 639   rm -f conftest*])
 640
 641 if test $libc_cv_asm_weak_directive = no; then
 642   AC_CACHE_CHECK(for assembler .weakext directive,
 643                  libc_cv_asm_weakext_directive,
 644                  [dnl
 645 cat > conftest.s <<EOF
 646 .text
 647 ${libc_cv_asm_global_directive} foo
 648 foo:
 649 .weakext foo
 650 .weakext foo, bar
 651 EOF
 652   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 653     libc_cv_asm_weakext_directive=yes
 654   else
 655     libc_cv_asm_weakext_directive=no
 656   fi
 657   rm -f conftest*])
 658
 659   fi # no .weak
 660 fi # not ELF
 661
 662 if test $libc_cv_asm_weak_directive = yes; then
 663   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 664 elif test $libc_cv_asm_weakext_directive = yes; then
 665   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 666 fi
 667
 668 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 669 cat > conftest.c <<\EOF
 670 _start () {}
 671 int __eh_pc;
 672 __throw () {}
 673 EOF
 674 dnl No \ in command here because it ends up inside ''.
 675 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 676                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 677                             -o conftest conftest.c 1>&AC_FD_CC]); then
 678   libc_cv_ld_no_whole_archive=yes
 679 else
 680   libc_cv_ld_no_whole_archive=no
 681 fi
 682 rm -f conftest*])
 683 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 684
 685 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 686 cat > conftest.c <<\EOF
 687 _start () {}
 688 int __eh_pc;
 689 __throw () {}
 690 EOF
 691 dnl No \ in command here because it ends up inside ''.
 692 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 693                             -nostdlib -nostartfiles -fno-exceptions
 694                             -o conftest conftest.c 1>&AC_FD_CC]); then
 695   libc_cv_gcc_no_exceptions=yes
 696 else
 697   libc_cv_gcc_no_exceptions=no
 698 fi
 699 rm -f conftest*])
 700 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 701
 702 ### End of automated tests.
 703 ### Now run sysdeps configure fragments.
 704
 705 # sysdeps configure fragments may set these with files to be linked below.
 706 libc_link_dests=
 707 libc_link_sources=
 708
 709 # Iterate over all the sysdep directories we will use, running their
 710 # configure fragments, and looking for a uname implementation.
 711 uname=
 712 for dir in $sysnames; do
 713   case $dir in
 714     /*) dest=$dir ;;
 715     *)  dest=$srcdir/$dir ;;
 716   esac
 717   if test -r $dest/configure; then
 718     AC_MSG_RESULT(running configure fragment for $dest)
 719     . $dest/configure
 720   fi
 721 [
 722   if test -z "$uname"; then
 723     if test -r $dest/uname.c ||
 724        test -r $dest/uname.S ||
 725        { test -r $dest/syscalls.list &&
 726          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
 727       uname=$dir
 728     fi
 729   fi
 730 ]dnl
 731 done
 732
 733 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 734
 735 # If we will use the generic uname implementation, we must figure out what
 736 # it will say by examining the system, and write the results in config-name.h.
 737 if test "$uname" = "sysdeps/generic"; then
 738
 739 changequote(,)dnl
 740   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 741 changequote([,])dnl
 742   if test $uname_sysname != $config_os; then
 743     config_release=`echo $config_os | sed s/$uname_sysname//`
 744   fi
 745 dnl
 746 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 747     if test -r /vmunix; then
 748       kernel_id=`strings /vmunix | grep UNIX`
 749     elif test -r /dynix; then
 750       kernel_id=`strings /dynix | grep DYNIX`
 751     else
 752       kernel_id=
 753     fi
 754 ])dnl
 755
 756   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 757 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 758 changequote(,)dnl
 759   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 760 changequote([,])dnl
 761   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 762          != x$config_release; then
 763     # The configuration release is a substring of the kernel release.
 764     libc_cv_uname_release=$kernel_release
 765   elif test x$config_release != x; then
 766     libc_cv_uname_release=$config_release
 767   elif test x$kernel_release != x; then
 768     libc_cv_uname_release=$kernel_release
 769   else
 770     libc_cv_uname_release=unknown
 771   fi])
 772   uname_release="$libc_cv_uname_release"
 773
 774   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 775 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 776 changequote(,)dnl
 777   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 778 changequote([,])dnl
 779   if test -n "$kernel_version"; then
 780     libc_cv_uname_version="$kernel_version"
 781   else
 782     libc_cv_uname_version=unknown
 783   fi])
 784   uname_version="$libc_cv_uname_version"
 785
 786 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 787   config_uname=config-name.h:config-name.in
 788 else
 789   # For non-generic uname, we don't need to create config-name.h at all.
 790   config_uname=
 791 fi
 792
 793 AC_MSG_CHECKING(stdio selection)
 794 AC_SUBST(stdio)
 795 case $stdio in
 796 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 797 default) stdio=stdio ;;
 798 esac
 799 AC_MSG_RESULT($stdio)
 800
 801 AC_SUBST(libc_cv_slibdir)
 802 AC_SUBST(libc_cv_sysconfdir)
 803 AC_SUBST(libc_cv_rootsbindir)
 804
 805 AC_SUBST(has_ldconfig)
 806
 807 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 808 if test $gnu_ld = yes; then
 809   AC_DEFINE(HAVE_GNU_LD)
 810 fi
 811 if test $gnu_as = yes; then
 812   AC_DEFINE(HAVE_GNU_AS)
 813 fi
 814 if test $elf = yes; then
 815   AC_DEFINE(HAVE_ELF)
 816 fi
 817
 818 AC_SUBST(shared)
 819 if test $shared = default; then
 820   if test $gnu_ld = yes; then
 821     shared=$elf
 822   else
 823     # For now we do not assume shared libs are available.  In future more
 824     # tests might become available.
 825     shared=no
 826   fi
 827 fi
 828 AC_SUBST(profile)
 829 AC_SUBST(omitfp)
 830 AC_SUBST(bounded)
 831 AC_SUBST(static_nss)
 832 AC_SUBST(nopic_initfini)
 833
 834 AC_SUBST(DEFINES)
 835
 836 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 837   config_makefile=
 838 else
 839   config_makefile=Makefile
 840 fi
 841
 842 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 843 AC_SUBST(VERSION)
 844
 845 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 846           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])