sysdeps/sh/sh4/setjmp.S

   1 /* setjmp for SH4.
   2    Copyright (C) 1999, 2000, 2005, 2006, 2009 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <jmpbuf-offsets.h>
  22
  23 ENTRY (__sigsetjmp)
  24         /* Save registers */
  25         add     #JB_SIZE, r4
  26 #ifdef __SH_FPU_ANY__
  27         fmov.s  fr15, @-r4
  28         fmov.s  fr14, @-r4
  29         fmov.s  fr13, @-r4
  30         fmov.s  fr12, @-r4
  31         sts.l   fpscr, @-r4
  32 #endif /* __SH_FPU_ANY__ */
  33         stc.l   gbr, @-r4
  34 #ifdef PTR_MANGLE
  35         sts     pr, r2
  36         PTR_MANGLE (r2, r1)
  37         mov.l   r2, @-r4
  38         mov     r15, r2
  39         PTR_MANGLE2 (r2, r1)
  40         mov.l   r2, @-r4
  41         mov     r14, r2
  42         PTR_MANGLE2 (r2, r1)
  43         mov.l   r2, @-r4
  44         mov     #0, r1
  45 #else
  46         sts.l   pr, @-r4
  47         mov.l   r15, @-r4
  48         mov.l   r14, @-r4
  49 #endif
  50         mov.l   r13, @-r4
  51         mov.l   r12, @-r4
  52         mov.l   r11, @-r4
  53         mov.l   r10, @-r4
  54         mov.l   r9, @-r4
  55         mov.l   r8, @-r4
  56
  57 #if defined NOT_IN_libc && defined IS_IN_rtld
  58         /* In ld.so we never save the signal mask.  */
  59         rts
  60          mov    #0, r0
  61 #else
  62         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  63 # ifdef SHARED
  64         mov.l   1f, r1
  65         mova    1f, r0
  66         bra     2f
  67          add    r1, r0
  68         .align  2
  69 1:
  70         .long   _GLOBAL_OFFSET_TABLE_
  71 2:
  72         mov.l   .L1, r1
  73         mov.l   @(r0,r1), r1
  74         jmp     @r1
  75          nop
  76         .align  2
  77 .L1:
  78         .long   C_SYMBOL_NAME(__sigjmp_save@GOT)
  79 # else
  80         mov.l   .L1, r1
  81         jmp     @r1
  82          nop
  83         .align  2
  84 .L1:
  85         .long   C_SYMBOL_NAME(__sigjmp_save)
  86 # endif
  87 #endif
  88 END (__sigsetjmp)