sysdeps/powerpc/powerpc32/elf/start.S

   1 /* Startup code for programs linked with GNU libc.
   2    Copyright (C) 1998,1999,2000,2001,2002,2003,2009
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, write to the Free
  35    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  36    02111-1307 USA.  */
  37
  38 #include <sysdep.h>
  39 #include "bp-sym.h"
  40
  41  /* These are the various addresses we require.  */
  42 #ifdef PIC
  43         .section ".data"
  44 #else
  45         .section ".rodata"
  46 #endif
  47         .align  2
  48 L(start_addresses):
  49         .long   _SDA_BASE_
  50         .long   BP_SYM (main)
  51         .long   __libc_csu_init
  52         .long   __libc_csu_fini
  53         ASM_SIZE_DIRECTIVE(L(start_addresses))
  54
  55         .section ".text"
  56 #if defined PIC && !defined HAVE_ASM_PPC_REL16
  57 L(start_addressesp):
  58         .long   L(start_addresses)-L(branch)
  59 #endif
  60 ENTRY(_start)
  61  /* Save the stack pointer, in case we're statically linked under Linux.  */
  62         mr      r9,r1
  63  /* Set up an initial stack frame, and clear the LR.  */
  64         clrrwi  r1,r1,4
  65 #ifdef PIC
  66         bcl     20,31,L(branch)
  67 L(branch):
  68         li      r0,0
  69         mflr    r13
  70 #else
  71         li      r0,0
  72 #endif
  73         stwu    r1,-16(r1)
  74         mtlr    r0
  75         stw     r0,0(r1)
  76  /* Set r13 to point at the 'small data area', and put the address of
  77     start_addresses in r8.  Also load the GOT pointer so that new PLT
  78     calls work, like the one to __libc_start_main.  */
  79 #ifdef PIC
  80 # ifdef HAVE_ASM_PPC_REL16
  81         addis   r30,r13,_GLOBAL_OFFSET_TABLE_-L(branch)@ha
  82         addis   r8,r13,L(start_addresses)-L(branch)@ha
  83         addi    r30,r30,_GLOBAL_OFFSET_TABLE_-L(branch)@l
  84         lwzu    r13,L(start_addresses)-L(branch)@l(r8)
  85 # else
  86         lwz     r8,L(start_addressesp)-L(branch)(r13)
  87         add     r8,r13,r8
  88         lwz     r13,0(r8)
  89 # endif
  90 #else
  91         lis     r8,L(start_addresses)@ha
  92         lwzu    r13,L(start_addresses)@l(r8)
  93 #endif
  94  /* and continue in libc-start, in glibc.  */
  95         b       JUMPTARGET(BP_SYM (__libc_start_main))
  96 END(_start)
  97
  98 /* Define a symbol for the first piece of initialized data.  */
  99         .section ".data"
 100         .globl  __data_start
 101 __data_start:
 102         .long   0
 103 weak_alias (__data_start, data_start)