| blob | 606eef5935769f3971faefc70b4420e308dfb21c |
1 /* setjmp for PowerPC64.
2 Copyright (C) 1995-2003, 2004, 2005, 2006 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, write to the Free
17 Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18 02111-1307 USA. */
20 #include <sysdep.h>
21 #define _ASM
22 #ifdef __NO_VMX__
23 #include <novmxsetjmp.h>
24 #else
25 #include <jmpbuf-offsets.h>
26 #endif
27 #include <bp-sym.h>
28 #include <bp-asm.h>
30 #ifndef __NO_VMX__
31 .section ".toc","aw"
32 .LC__dl_hwcap:
33 # ifdef SHARED
34 .tc _rtld_global_ro[TC],_rtld_global_ro
35 # else
36 .tc _dl_hwcap[TC],_dl_hwcap
37 # endif
38 .section ".text"
39 #endif
41 .machine "altivec"
42 ENTRY (BP_SYM (__sigsetjmp))
43 CALL_MCOUNT 2
44 .globl JUMPTARGET(GLUE(__sigsetjmp,_ent))
45 .hidden JUMPTARGET(GLUE(__sigsetjmp,_ent))
46 JUMPTARGET(GLUE(__sigsetjmp,_ent)):
47 CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
48 #ifdef PTR_MANGLE
49 mr r5, r1
50 PTR_MANGLE (r5, r6)
51 std r5,(JB_GPR1*8)(3)
52 #else
53 std r1,(JB_GPR1*8)(3)
54 #endif
55 mflr r0
56 #if defined SHARED && !defined IS_IN_rtld
57 ld r5,40(r1) /* Retrieve the callers TOC. */
58 std r5,(JB_GPR2*8)(3)
59 #else
60 std r2,(JB_GPR2*8)(3)
61 #endif
62 std r14,((JB_GPRS+0)*8)(3)
63 stfd fp14,((JB_FPRS+0)*8)(3)
64 #ifdef PTR_MANGLE
65 PTR_MANGLE2 (r0, r6)
66 #endif
67 std r0,(JB_LR*8)(3)
68 std r15,((JB_GPRS+1)*8)(3)
69 stfd fp15,((JB_FPRS+1)*8)(3)
70 mfcr r0
71 std r16,((JB_GPRS+2)*8)(3)
72 stfd fp16,((JB_FPRS+2)*8)(3)
73 std r0,(JB_CR*8)(3)
74 std r17,((JB_GPRS+3)*8)(3)
75 stfd fp17,((JB_FPRS+3)*8)(3)
76 std r18,((JB_GPRS+4)*8)(3)
77 stfd fp18,((JB_FPRS+4)*8)(3)
78 std r19,((JB_GPRS+5)*8)(3)
79 stfd fp19,((JB_FPRS+5)*8)(3)
80 std r20,((JB_GPRS+6)*8)(3)
81 stfd fp20,((JB_FPRS+6)*8)(3)
82 std r21,((JB_GPRS+7)*8)(3)
83 stfd fp21,((JB_FPRS+7)*8)(3)
84 std r22,((JB_GPRS+8)*8)(3)
85 stfd fp22,((JB_FPRS+8)*8)(3)
86 std r23,((JB_GPRS+9)*8)(3)
87 stfd fp23,((JB_FPRS+9)*8)(3)
88 std r24,((JB_GPRS+10)*8)(3)
89 stfd fp24,((JB_FPRS+10)*8)(3)
90 std r25,((JB_GPRS+11)*8)(3)
91 stfd fp25,((JB_FPRS+11)*8)(3)
92 std r26,((JB_GPRS+12)*8)(3)
93 stfd fp26,((JB_FPRS+12)*8)(3)
94 std r27,((JB_GPRS+13)*8)(3)
95 stfd fp27,((JB_FPRS+13)*8)(3)
96 std r28,((JB_GPRS+14)*8)(3)
97 stfd fp28,((JB_FPRS+14)*8)(3)
98 std r29,((JB_GPRS+15)*8)(3)
99 stfd fp29,((JB_FPRS+15)*8)(3)
100 std r30,((JB_GPRS+16)*8)(3)
101 stfd fp30,((JB_FPRS+16)*8)(3)
102 std r31,((JB_GPRS+17)*8)(3)
103 stfd fp31,((JB_FPRS+17)*8)(3)
104 #ifndef __NO_VMX__
105 ld r6,.LC__dl_hwcap@toc(r2)
106 # ifdef SHARED
107 /* Load _rtld-global._dl_hwcap. */
108 ld r6,RTLD_GLOBAL_RO_DL_HWCAP_OFFSET(r6)
109 # else
110 ld r6,0(r6) /* Load extern _dl_hwcap. */
111 # endif
112 andis. r6,r6,(PPC_FEATURE_HAS_ALTIVEC >> 16)
113 beq L(no_vmx)
114 la r5,((JB_VRS)*8)(3)
115 andi. r6,r5,0xf
116 mfspr r0,VRSAVE
117 stw r0,((JB_VRSAVE)*8)(3)
118 addi r6,r5,16
119 beq+ L(aligned_save_vmx)
120 lvsr v0,0,r5
121 vspltisb v1,-1 /* set v1 to all 1's */
122 vspltisb v2,0 /* set v2 to all 0's */
123 vperm v3,v2,v1,v0 /* v3 contains shift mask with num all 1 bytes
124 on left = misalignment */
127 /* Special case for v20 we need to preserve what is in save area
128 below v20 before obliterating it */
129 lvx v5,0,r5
130 vperm v20,v20,v20,v0
131 vsel v5,v5,v20,v3
132 vsel v20,v20,v2,v3
133 stvx v5,0,r5
135 # define save_2vmx_partial(savevr,prev_savevr,hivr,shiftvr,maskvr,savegpr,addgpr) \
136 addi addgpr,addgpr,32; \
137 vperm savevr,savevr,savevr,shiftvr; \
138 vsel hivr,prev_savevr,savevr,maskvr; \
139 stvx hivr,0,savegpr;
141 save_2vmx_partial(v21,v20,v5,v0,v3,r6,r5)
142 save_2vmx_partial(v22,v21,v5,v0,v3,r5,r6)
143 save_2vmx_partial(v23,v22,v5,v0,v3,r6,r5)
144 save_2vmx_partial(v24,v23,v5,v0,v3,r5,r6)
145 save_2vmx_partial(v25,v24,v5,v0,v3,r6,r5)
146 save_2vmx_partial(v26,v25,v5,v0,v3,r5,r6)
147 save_2vmx_partial(v27,v26,v5,v0,v3,r6,r5)
148 save_2vmx_partial(v28,v27,v5,v0,v3,r5,r6)
149 save_2vmx_partial(v29,v28,v5,v0,v3,r6,r5)
150 save_2vmx_partial(v30,v29,v5,v0,v3,r5,r6)
152 /* Special case for r31 we need to preserve what is in save area
153 above v31 before obliterating it */
154 addi r5,r5,32
155 vperm v31,v31,v31,v0
156 lvx v4,0,r5
157 vsel v5,v30,v31,v3
158 stvx v5,0,r6
159 vsel v4,v31,v4,v3
160 stvx v4,0,r5
161 b L(no_vmx)
163 L(aligned_save_vmx):
164 stvx 20,0,r5
165 addi r5,r5,32
166 stvx 21,0,r6
167 addi r6,r6,32
168 stvx 22,0,r5
169 addi r5,r5,32
170 stvx 23,0,r6
171 addi r6,r6,32
172 stvx 24,0,r5
173 addi r5,r5,32
174 stvx 25,0,r6
175 addi r6,r6,32
176 stvx 26,0,r5
177 addi r5,r5,32
178 stvx 27,0,r6
179 addi r6,r6,32
180 stvx 28,0,r5
181 addi r5,r5,32
182 stvx 29,0,r6
183 addi r6,r6,32
184 stvx 30,0,r5
185 stvx 31,0,r6
186 L(no_vmx):
187 #else
188 li r6,0
189 #endif
190 #if defined NOT_IN_libc && defined IS_IN_rtld
191 li r3,0
192 blr
193 #else
194 b JUMPTARGET (BP_SYM (__sigjmp_save))
195 #endif
196 END (BP_SYM (__sigsetjmp))