sysdeps/s390/s390-64/elf/start.S

   1 /* Startup code compliant to the 64 bit S/390 ELF ABI.
   2    Copyright (C) 2001, 2002, 2003, 2004, 2006 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, write to the Free
  35    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  36    02111-1307 USA.  */
  37
  38 /*
  39    This is the canonical entry point, usually the first thing in the text
  40    segment. Most registers' values are unspecified, except for:
  41
  42    %r14         Contains a function pointer to be registered with `atexit'.
  43                 This is how the dynamic linker arranges to have DT_FINI
  44                 functions called for shared libraries that have been loaded
  45                 before this code runs.
  46
  47    %r15         The stack contains the arguments and environment:
  48                 0(%r15)                 argc
  49                 8(%r15)                 argv[0]
  50                 ...
  51                 (8*argc)(%r15)          NULL
  52                 (8*(argc+1))(%r15)      envp[0]
  53                 ...
  54                                         NULL
  55 */
  56
  57         .text
  58         .globl _start
  59         .type _start,@function
  60 _start:
  61         /* Load argc and argv from stack.  */
  62         la      %r4,8(%r15)             # get argv
  63         lg      %r3,0(%r15)             # get argc
  64
  65         /* Align the stack to a double word boundary.  */
  66         lghi    %r0,-16
  67         ngr     %r15,%r0
  68
  69         /* Setup a stack frame and a parameter area.  */
  70         aghi    %r15,-176               # make room on stack
  71         xc      0(8,%r15),0(%r15)       # clear back-chain
  72
  73         /* Set up arguments for __libc_start_main:
  74            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
  75            Note that envp will be determined later in __libc_start_main.
  76          */
  77         stmg    %r14,%r15,160(%r15)     # store rtld_fini/stack_end to parameter area
  78         la      %r7,160(%r15)
  79         larl    %r6,__libc_csu_fini     # load pointer to __libc_csu_fini
  80         larl    %r5,__libc_csu_init     # load pointer to __libc_csu_init
  81
  82         /* Ok, now branch to the libc main routine.  */
  83 #ifdef PIC
  84         larl    %r2,main@GOTENT         # load pointer to main
  85         lg      %r2,0(%r2)
  86         brasl   %r14,__libc_start_main@plt
  87 #else
  88         larl    %r2,main                # load pointer to main
  89         brasl   %r14,__libc_start_main
  90 #endif
  91
  92         /* Crash if __libc_start_main returns.  */
  93         .word   0
  94
  95         /* Define a symbol for the first piece of initialized data.  */
  96         .data
  97         .globl __data_start
  98 __data_start:
  99         .long 0
 100         .weak data_start
 101         data_start = __data_start