sysdeps/sparc/sparc64/addmul_1.S

   1 /* SPARC v9 __mpn_addmul_1 -- Multiply a limb vector with a single limb and
   2    add the product to a second limb vector.
   3
   4    Copyright (C) 1996, 1999 Free Software Foundation, Inc.
   5
   6    This file is part of the GNU MP Library.
   7
   8    The GNU MP Library is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU Lesser General Public License as published by
  10    the Free Software Foundation; either version 2.1 of the License, or (at your
  11    option) any later version.
  12
  13    The GNU MP Library is distributed in the hope that it will be useful, but
  14    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16    License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public License
  19    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21    MA 02111-1307, USA.  */
  22
  23 #include <sysdep.h>
  24
  25
  26 /* INPUT PARAMETERS
  27    res_ptr      o0
  28    s1_ptr       o1
  29    size         o2
  30    s2_limb      o3  */
  31
  32
  33 ENTRY(__mpn_addmul_1)
  34         save    %sp,-192,%sp
  35
  36         sub     %g0,%i2,%o7
  37         mov     0,%o0                   ! zero cy_limb
  38         sllx    %o7,3,%o7
  39         sethi   %hi(0x80000000),%o2
  40         srl     %i3,0,%o1               ! extract low 32 bits of s2_limb
  41         sub     %i1,%o7,%o3
  42         srlx    %i3,32,%i3              ! extract high 32 bits of s2_limb
  43         sub     %i0,%o7,%o4
  44         add     %o2,%o2,%o2             ! o2 = 0x100000000
  45
  46         !   hi   !
  47              !  mid-1 !
  48              !  mid-2 !
  49                  !   lo   !
  50 1:
  51         ldx     [%o3+%o7],%g5
  52         srl     %g5,0,%i0               ! zero hi bits
  53         ldx     [%o4+%o7],%l1
  54         srlx    %g5,32,%g5
  55         mulx    %o1,%i0,%i4             ! lo product
  56         mulx    %i3,%i0,%i1             ! mid-1 product
  57         mulx    %o1,%g5,%l2             ! mid-2 product
  58         mulx    %i3,%g5,%i5             ! hi product
  59         srlx    %i4,32,%i0              ! extract high 32 bits of lo product...
  60         add     %i1,%i0,%i1             ! ...and add it to the mid-1 product
  61         addcc   %i1,%l2,%i1             ! add mid products
  62         mov     0,%l0                   ! we need the carry from that add...
  63         movcs   %xcc,%o2,%l0            ! ...compute it and...
  64         sllx    %i1,32,%i0              !  align low bits of mid product
  65         add     %i5,%l0,%i5             ! ...add to bit 32 of the hi product
  66         srl     %i4,0,%g5               ! zero high 32 bits of lo product
  67         add     %i0,%g5,%i0             ! combine into low 64 bits of result
  68         srlx    %i1,32,%i1              ! extract high bits of mid product...
  69         addcc   %i0,%o0,%i0             !  add cy_limb to low 64 bits of result
  70         add     %i5,%i1,%i1             ! ...and add them to the high result
  71         mov     0,%g5
  72         movcs   %xcc,1,%g5
  73         addcc   %l1,%i0,%i0
  74         stx     %i0,[%o4+%o7]
  75         add     %g5,1,%l1
  76         movcs   %xcc,%l1,%g5
  77         addcc   %o7,8,%o7
  78         bne,pt  %xcc,1b
  79          add    %i1,%g5,%o0             ! compute new cy_limb
  80
  81         jmpl    %i7+8, %g0
  82          restore %o0,%g0,%o0
  83
  84 END(__mpn_addmul_1)