sysdeps/alpha/strcat.S

   1 /* Copyright (C) 1996, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson <rth@tamu.edu>, 1996.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* Append a null-terminated string from SRC to DST.  */
  21
  22 #include <sysdep.h>
  23
  24         .text
  25
  26 ENTRY(strcat)
  27         ldgp    gp, 0(pv)
  28 #ifdef PROF
  29         .set noat
  30         lda     AT, _mcount
  31         jsr     AT, (AT), _mcount
  32         .set at
  33 #endif
  34         .prologue 1
  35
  36         mov     a0, v0          # set up return value
  37
  38         /* Find the end of the string.  */
  39
  40         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  41         lda     t1, -1(zero)
  42         insqh   t1, a0, t1
  43         andnot  a0, 7, a0
  44         or      t1, t0, t0
  45         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  46         bne     t1, $found
  47
  48 $loop:  ldq     t0, 8(a0)
  49         addq    a0, 8, a0       # addr += 8
  50         cmpbge  zero, t0, t1
  51         beq     t1, $loop
  52
  53 $found: negq    t1, t2          # clear all but least set bit
  54         and     t1, t2, t1
  55
  56         and     t1, 0xf0, t2    # binary search for that set bit
  57         and     t1, 0xcc, t3
  58         and     t1, 0xaa, t4
  59         cmovne  t2, 4, t2
  60         cmovne  t3, 2, t3
  61         cmovne  t4, 1, t4
  62         addq    t2, t3, t2
  63         addq    a0, t4, a0
  64         addq    a0, t2, a0
  65
  66         /* Now do the append.  */
  67
  68         mov     ra, t9
  69         jmp     $31, __stxcpy
  70
  71         END(strcat)
  72 libc_hidden_builtin_def (strcat)