sysdeps/alpha/strlen.S

   1 /* Copyright (C) 1996, 1997, 2003 Free Software Foundation, Inc.
   2    Contributed by David Mosberger (davidm@cs.arizona.edu).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* Finds length of a 0-terminated string.  Optimized for the Alpha
  21    architecture:
  22
  23       - memory accessed as aligned quadwords only
  24       - uses cmpbge to compare 8 bytes in parallel
  25       - does binary search to find 0 byte in last quadword (HAKMEM
  26         needed 12 instructions to do this instead of the 8 instructions
  27         that the binary search needs).
  28 */
  29
  30 #include <sysdep.h>
  31
  32         .set noreorder
  33         .set noat
  34
  35 ENTRY(strlen)
  36 #ifdef PROF
  37         ldgp    gp, 0(pv)
  38         lda     AT, _mcount
  39         jsr     AT, (AT), _mcount
  40         .prologue 1
  41 #else
  42         .prologue 0
  43 #endif
  44
  45         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  46         lda     t1, -1(zero)
  47         insqh   t1, a0, t1
  48         andnot  a0, 7, v0
  49         or      t1, t0, t0
  50         nop                     # dual issue the next two on ev5
  51         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  52         bne     t1, $found
  53
  54 $loop:  ldq     t0, 8(v0)
  55         addq    v0, 8, v0       # addr += 8
  56         cmpbge  zero, t0, t1
  57         beq     t1, $loop
  58
  59 $found: negq    t1, t2          # clear all but least set bit
  60         and     t1, t2, t1
  61
  62         and     t1, 0xf0, t2    # binary search for that set bit
  63         and     t1, 0xcc, t3
  64         and     t1, 0xaa, t4
  65         cmovne  t2, 4, t2
  66         cmovne  t3, 2, t3
  67         cmovne  t4, 1, t4
  68         addq    t2, t3, t2
  69         addq    v0, t4, v0
  70         addq    v0, t2, v0
  71         nop                     # dual issue next two on ev4 and ev5
  72
  73         subq    v0, a0, v0
  74         ret
  75
  76         END(strlen)
  77 libc_hidden_builtin_def (strlen)